#! /usr/bin/perl

use ccbs;
use strict;
use warnings;

my $cgi = new CGI;
my $id = $cgi->param('id');

my $dbh = ccbs::db_connect();

my $tournament = $dbh->selectrow_hashref('SELECT * FROM tournaments NATURAL JOIN seasons NATURAL JOIN countries NATURAL JOIN machines NATURAL JOIN scoringsystems WHERE tournament=?', undef, $id);
my $rankings = ccbs::db_fetch_all($dbh, 'SELECT ranking,nick,COALESCE(points,-1) AS points FROM tournamentrankings NATURAL JOIN players WHERE tournament=? ORDER BY ranking', $id);
my $songs = ccbs::db_fetch_all($dbh, 'SELECT song,title FROM machinesongs NATURAL JOIN songs WHERE machine=? ORDER BY LOWER(title)', $tournament->{'machine'});

# Swoop all the data in in a big join, then order it over to quasi-sane Perl objects.
# (round -> parallel -> player -> songs -> title,chosen,score)
my $scores = ccbs::db_fetch_all($dbh,
	'SELECT round,parallel,position,playmode,difficulty,songnumber,player,nick,song,title,chosen,score FROM roundparticipation NATURAL JOIN players NATURAL JOIN scores NATURAL LEFT JOIN songs WHERE tournament=? ORDER BY round,parallel,position,songnumber',
	$id);

my @rounds = ();

my ($round, $parallel, $player) = (-1,-1,'');
for my $score (@$scores) {
	if ($score->{'round'} != $round) {
		$round = $score->{'round'};
		push @rounds, { round => $round, parallels => [] };
		$parallel = -1;
	}
	my $p = $rounds[$#rounds]->{'parallels'};
	if ($score->{'parallel'} != $parallel) {
		$parallel = $score->{'parallel'};
		push @$p, { parallel => $parallel, players => [], songs => [], num_songs => 0 };
		$player = '';

		# Information on songs is not selected from roundrandomsongs etc.,
		# but is filled in the first time the song is seen for this round
		# (ie. below)
	}
	if ($score->{'position'} == 1) {
		if ($score->{'chosen'}) {
			push @{$p->[$#$p]->{'songs'}}, '';
		} else {
			push @{$p->[$#$p]->{'songs'}}, $score->{'title'};
		}
		$p->[$#$p]->{'num_songs'}++;
	}
	
	my $pl = $p->[$#$p]->{'players'};
	if ($score->{'nick'} ne $player) {
		$player = $score->{'nick'};
		push @$pl, { player => $score->{'player'}, nick => $player, songs => [], total => 0, locked => 1 };
	}
	
	push @{$pl->[$#$pl]->{'songs'}}, $score;

	if (defined($score->{'score'})) {
		$pl->[$#$pl]->{'total'} += $score->{'score'};
	} else {
		$pl->[$#$pl]->{'locked'} = 0;
	}
}

my $num_rounds = scalar @rounds;
my $num_rankings = scalar @$rankings;

# If there have been no rounds, check out the number of participants; if not, check the
# number of qualified from the last round
my $num_qualified;
if ($num_rounds == 0) {
	my $ref = $dbh->selectrow_hashref('SELECT COUNT(*) AS num_participants FROM tournamentparticipation WHERE tournament=?', undef, $id);
	$num_qualified = $ref->{'num_participants'};
} else {
	my $ref = $dbh->selectrow_hashref('SELECT SUM(numqualifying) AS numqualifying FROM rounds NATURAL JOIN groups WHERE tournament=? AND round=?', undef, $id, $num_rounds);
	$num_qualified = $ref->{'numqualifying'};
}

ccbs::print_header();
ccbs::process_template('show-tournament.tmpl', $tournament->{'tournamentname'}, {
	tournament => $tournament,
	rankings => $rankings,
	num_rankings => $num_rankings,
	rounds => \@rounds,
	num_rounds => $num_rounds,
	num_qualified => $num_qualified,
	songs => $songs
});
$dbh->disconnect;
