#! /usr/bin/perl

use ccbs;
use strict;
use warnings;

my $cgi = new CGI;
my $id = $cgi->param('id');

my $dbh = ccbs::db_connect();

my $tournament = $dbh->selectrow_hashref('SELECT * FROM tournaments WHERE tournament=?', undef, $id);

# Swoop all the data in in a big join, then order it over to quasi-sane Perl objects.
# (round -> parallel -> player -> songs -> title,chosen,score)
my $scores = ccbs::db_fetch_all($dbh,
	'SELECT round,parallel,nick,title,chosen,score FROM scores NATURAL JOIN players NATURAL JOIN songs NATURAL JOIN roundparticipation WHERE tournament=? ORDER BY round,parallel,position,songnumber',
	$id);

my @rounds = ();

my ($round, $parallel, $player) = (-1,-1,'');
for my $score (@$scores) {
	if ($score->{'round'} != $round) {
		$round = $score->{'round'};
		push @rounds, { round => $round, parallels => [] };
		$parallel = -1;
	}
	my $p = $rounds[$#rounds]->{'parallels'};
	if ($score->{'parallel'} != $parallel) {
		$parallel = $score->{'parallel'};
		push @$p, { parallel => $parallel, players => [] };
		$player = '';
	}
	my $pl = $p->[$#$p]->{'players'};
	if ($score->{'nick'} ne $player) {
		$player = $score->{'nick'};
		push @$pl, { nick => $player, songs => [] };
	}
	
	push @{$pl->[$#$pl]->{'songs'}}, {
		title => $score->{'title'},
		chosen => $score->{'chosen'},
		score => $score->{'score'}
	};
}

ccbs::print_header();
ccbs::process_template('show-tournament.tmpl', 'Turnering', { tournament => $tournament, rounds => \@rounds });
