git.sesse.net Git - movit/blob - deconvolution_sharpen_effect.frag

   1 uniform vec4 PREFIX(samples)[(R + 1) * (R + 1)];
   2
   3 vec4 FUNCNAME(vec2 tc) {
   4         // The full matrix has five different symmetry cases, that look like this:
   5         //
   6         // D * * C * * D
   7         // * D * C * D *
   8         // * * D C D * *
   9         // B B B A B B B
  10         // * * D C D * *
  11         // * D * C * D *
  12         // D * * C * * D
  13         //
  14         // We only store the lower-right part of the matrix:
  15         //
  16         // A B B
  17         // C D *
  18         // C * D
  19
  20         // Case A: Top-left sample has no symmetry.
  21         vec4 sum = PREFIX(samples)[0].z * INPUT(tc);
  22
  23         // Case B: Uppermost samples have left/right symmetry.
  24         for (int x = 1; x <= R; ++x) {
  25                 vec4 sample = PREFIX(samples)[x];
  26                 sum += sample.z * (INPUT(tc - sample.xy) + INPUT(tc + sample.xy));
  27         }
  28
  29         // Case C: Leftmost samples have top/bottom symmetry.
  30         for (int y = 1; y <= R; ++y) {
  31                 vec4 sample = PREFIX(samples)[y * (R + 1)];
  32                 sum += sample.z * (INPUT(tc - sample.xy) + INPUT(tc + sample.xy));
  33         }
  34
  35         // Case D: Diagonal samples have four-way symmetry.
  36         for (int xy = 1; xy <= R; ++xy) {
  37                 vec4 sample = PREFIX(samples)[xy * (R + 1) + xy];
  38
  39                 vec4 local_sum = INPUT(tc - sample.xy) + INPUT(tc + sample.xy);
  40                 sample.y = -sample.y;
  41                 local_sum += INPUT(tc - sample.xy) + INPUT(tc + sample.xy);
  42
  43                 sum += sample.z * local_sum;
  44         }
  45
  46         // Case *: All other samples have eight-way symmetry.
  47         for (int y = 1; y <= R; ++y) {
  48                 for (int x = y + 1; x <= R; ++x) {
  49                         vec4 sample = PREFIX(samples)[y * (R + 1) + x];
  50                         vec2 mirror_sample = vec2(sample.x, -sample.y);
  51
  52                         vec4 local_sum = INPUT(tc - sample.xy) + INPUT(tc + sample.xy);
  53                         local_sum += INPUT(tc - mirror_sample.xy) + INPUT(tc + mirror_sample.xy);
  54
  55                         sample.xy = sample.yx;
  56                         mirror_sample.xy = mirror_sample.yx;
  57
  58                         local_sum += INPUT(tc - sample.xy) + INPUT(tc + sample.xy);
  59                         local_sum += INPUT(tc - mirror_sample.xy) + INPUT(tc + mirror_sample.xy);
  60
  61                         sum += sample.z * local_sum;
  62                 }
  63         }
  64
  65         return sum;
  66 }