git.sesse.net Git - nageru/blob - meson.build

   1 project('nageru', 'cpp', default_options: ['buildtype=debugoptimized'], version: '1.8.0')
   2
   3 cxx = meson.get_compiler('cpp')
   4 qt5 = import('qt5')
   5 protoc = find_program('protoc')
   6
   7 embedded_bmusb = get_option('embedded_bmusb')
   8
   9 alsadep = dependency('alsa')
  10 bmusbdep = dependency('bmusb', required: not embedded_bmusb)
  11 dldep = cxx.find_library('dl')
  12 epoxydep = dependency('epoxy')
  13 libavcodecdep = dependency('libavcodec')
  14 libavformatdep = dependency('libavformat')
  15 libswresampledep = dependency('libswresample')
  16 libavutildep = dependency('libavutil')
  17 libjpegdep = dependency('libjpeg')
  18 libswscaledep = dependency('libswscale')
  19 libusbdep = dependency('libusb-1.0')
  20 luajitdep = dependency('luajit')
  21 movitdep = dependency('movit')
  22 protobufdep = dependency('protobuf')
  23 qcustomplotdep = cxx.find_library('qcustomplot')
  24 qt5deps = dependency('qt5', modules: ['Core', 'Gui', 'Widgets', 'OpenGLExtensions', 'OpenGL', 'Network'])
  25 sdl2_imagedep = dependency('SDL2_image', required: false)
  26 sdl2dep = dependency('sdl2', required: false)
  27 sqlite3dep = dependency('sqlite3')
  28 threaddep = dependency('threads')
  29 vadrmdep = dependency('libva-drm')
  30 vax11dep = dependency('libva-x11')
  31 x11dep = dependency('x11')
  32 x264dep = dependency('x264')
  33 zitaresamplerdep = cxx.find_library('zita-resampler')
  34
  35 # Use lld if we can; it links a lot faster than ld.bfd or gold.
  36 code = '''#include <stdio.h>
  37 int main() { printf("Hello, world!\n"); return 0; }
  38 '''
  39 if cxx.links(code, args: '-fuse-ld=lld', name: 'check for LLD')
  40         add_project_link_arguments('-fuse-ld=lld', language: 'cpp')
  41 endif
  42
  43 # Add the right MOVIT_SHADER_DIR definition.
  44 movit_shader_dir = movitdep.get_pkgconfig_variable('shaderdir')
  45 add_project_arguments('-DMOVIT_SHADER_DIR="' + movit_shader_dir + '"', language: 'cpp')
  46
  47 # Make the Nageru version available as a #define.
  48 add_project_arguments('-DNAGERU_VERSION="' + meson.project_version() + '"', language: 'cpp')
  49
  50 # This needs to be done before declaring any build targets.
  51 if get_option('cef_dir') != ''
  52         add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  53 endif
  54
  55 top_include = include_directories('.')
  56
  57 subdir('shared')
  58
  59 # Nageru. (Not a subdir() because we don't want the output in nageru/nageru.)
  60
  61 nageru_srcs = []
  62 nageru_deps = [shareddep, qt5deps, libjpegdep, movitdep, protobufdep,
  63         vax11dep, vadrmdep, x11dep, libavformatdep, libswresampledep, libavcodecdep, libavutildep,
  64         libswscaledep, libusbdep, luajitdep, dldep, x264dep, alsadep, zitaresamplerdep,
  65         qcustomplotdep, threaddep]
  66 nageru_include_dirs = [include_directories('nageru')]
  67 nageru_link_with = []
  68 nageru_build_rpath = ''
  69 nageru_install_rpath = ''
  70
  71 kaeru_link_with = []
  72 kaeru_extra_deps = []
  73
  74 # CEF.
  75 exe_dir = join_paths(get_option('prefix'), 'lib/nageru')
  76 cef_dir = get_option('cef_dir')
  77 cef_build_type = get_option('cef_build_type')
  78 have_cef = (cef_dir != '')
  79 if have_cef
  80         # This is done in the top-level file; just kept here for reference.
  81         # add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  82
  83         system_cef = (cef_build_type == 'system')
  84         if system_cef
  85                 cef_lib_dir = cef_dir
  86                 cef_resource_dir = '/usr/share/cef/Resources'
  87         else
  88                 cef_lib_dir = join_paths(cef_dir, cef_build_type)
  89                 cef_resource_dir = join_paths(cef_dir, 'Resources')
  90
  91                 nageru_include_dirs += include_directories(cef_dir)
  92                 nageru_include_dirs += include_directories(join_paths(cef_dir, 'include'))
  93                 nageru_build_rpath = cef_lib_dir
  94                 nageru_install_rpath = '$ORIGIN/'
  95         endif
  96
  97         cefdep = cxx.find_library('cef')
  98         nageru_deps += cefdep
  99
 100         # CEF wrapper library; not built as part of the CEF binary distribution,
 101         # but should be if CEF is installed as a system library.
 102         if system_cef
 103                 cefdlldep = cxx.find_library('cef_dll_wrapper')
 104                 nageru_deps += cefdlldep
 105         else
 106                 cmake = find_program('cmake')
 107                 cef_compile_script = find_program('scripts/compile_cef_dll_wrapper.sh')
 108
 109                 cef_dll_target = custom_target('libcef_dll_wrapper',
 110                         input: join_paths(cef_dir, 'libcef_dll/CMakeLists.txt'),
 111                         output: ['libcef_dll_wrapper.a', 'cef-stamp'],
 112                         command: [cef_compile_script, '@BUILD_DIR@', cef_dir, cmake, '@OUTPUT@'])
 113
 114                 # Putting the .a in sources seemingly hits a bug where the .a files get sorted
 115                 # in the wrong order. This is a workaround; see
 116                 # https://github.com/mesonbuild/meson/issues/3613#issuecomment-408276296 .
 117                 cefdlldep = declare_dependency(sources: cef_dll_target[1], link_args: cef_dll_target.full_path())
 118                 nageru_deps += cefdlldep
 119         endif
 120
 121         cef_libs = ['libEGL.so', 'libGLESv2.so', 'natives_blob.bin', 'snapshot_blob.bin', 'v8_context_snapshot.bin']
 122         cef_resources = ['cef.pak', 'cef_100_percent.pak', 'cef_200_percent.pak', 'cef_extensions.pak', 'devtools_resources.pak']
 123         if not get_option('cef_no_icudtl')
 124                 cef_resources += ['icudtl.dat']
 125         endif
 126         if cef_build_type != 'system'
 127                 cef_libs += ['libcef.so']
 128         endif
 129
 130         # Symlink the files into the build directory, so that running nageru without ninja install works.
 131         run_command('mkdir', join_paths(meson.current_build_dir(), 'locales/'))
 132         foreach file : cef_libs
 133                 run_command('ln', '-s', join_paths(cef_lib_dir, file), meson.current_build_dir())
 134                 install_data(join_paths(cef_lib_dir, file), install_dir: exe_dir)
 135         endforeach
 136         foreach file : cef_resources
 137                 run_command('ln', '-s', join_paths(cef_resource_dir, file), meson.current_build_dir())
 138                 install_data(join_paths(cef_resource_dir, file), install_dir: exe_dir)
 139         endforeach
 140         run_command('ln', '-s', join_paths(cef_resource_dir, 'locales/en-US.pak'), join_paths(meson.current_build_dir(), 'locales/'))
 141         install_data(join_paths(cef_resource_dir, 'locales/en-US.pak'), install_dir: join_paths(exe_dir, 'locales'))
 142 endif
 143
 144 # bmusb.
 145 if embedded_bmusb
 146         bmusb_dir = include_directories('nageru/bmusb')
 147         nageru_include_dirs += bmusb_dir
 148
 149         bmusb = static_library('bmusb', 'nageru/bmusb/bmusb.cpp', 'nageru/bmusb/fake_capture.cpp',
 150                 dependencies: [libusbdep],
 151                 include_directories: [bmusb_dir])
 152         nageru_link_with += bmusb
 153         kaeru_link_with += bmusb
 154 else
 155         nageru_deps += bmusbdep
 156         kaeru_extra_deps += bmusbdep
 157 endif
 158
 159 # Protobuf compilation.
 160 gen = generator(protoc, \
 161         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 162         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/nageru', '--cpp_out=@BUILD_DIR@', '@INPUT@'])
 163 proto_generated = gen.process(['nageru/state.proto', 'nageru/midi_mapping.proto', 'nageru/json.proto'])
 164 protobuf_lib = static_library('protobufs', proto_generated, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 165 protobuf_hdrs = declare_dependency(sources: proto_generated)
 166 nageru_link_with += protobuf_lib
 167
 168 # Preprocess Qt as needed.
 169 qt_files = qt5.preprocess(
 170         moc_headers: ['nageru/analyzer.h', 'nageru/clickable_label.h', 'nageru/compression_reduction_meter.h', 'nageru/correlation_meter.h',
 171                 'nageru/ellipsis_label.h', 'nageru/glwidget.h', 'nageru/input_mapping_dialog.h', 'nageru/lrameter.h', 'nageru/mainwindow.h', 'nageru/midi_mapping_dialog.h',
 172                 'nageru/nonlinear_fader.h', 'nageru/vumeter.h'],
 173         ui_files: ['nageru/analyzer.ui', 'nageru/audio_expanded_view.ui', 'nageru/audio_miniview.ui', 'nageru/display.ui',
 174                 'nageru/input_mapping.ui', 'nageru/mainwindow.ui', 'nageru/midi_mapping.ui'],
 175         dependencies: qt5deps)
 176
 177 # Qt objects.
 178 nageru_srcs += ['nageru/glwidget.cpp', 'nageru/mainwindow.cpp', 'nageru/vumeter.cpp', 'nageru/lrameter.cpp', 'nageru/compression_reduction_meter.cpp',
 179         'nageru/correlation_meter.cpp', 'nageru/analyzer.cpp', 'nageru/input_mapping_dialog.cpp', 'nageru/midi_mapping_dialog.cpp',
 180         'nageru/nonlinear_fader.cpp', 'nageru/context_menus.cpp', 'nageru/vu_common.cpp', 'nageru/piecewise_interpolator.cpp', 'nageru/midi_mapper.cpp']
 181
 182 # Auxiliary objects used for nearly everything.
 183 aux_srcs = ['nageru/flags.cpp']
 184 aux = static_library('aux', aux_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 185 nageru_link_with += aux
 186
 187 # Audio objects.
 188 audio_mixer_srcs = ['nageru/audio_mixer.cpp', 'nageru/alsa_input.cpp', 'nageru/alsa_pool.cpp', 'nageru/ebu_r128_proc.cc', 'nageru/stereocompressor.cpp',
 189         'nageru/resampling_queue.cpp', 'nageru/flags.cpp', 'nageru/correlation_measurer.cpp', 'nageru/filter.cpp', 'nageru/input_mapping.cpp']
 190 audio = static_library('audio', audio_mixer_srcs, dependencies: [nageru_deps, protobuf_hdrs], include_directories: nageru_include_dirs)
 191 nageru_link_with += audio
 192
 193 # Mixer objects.
 194 nageru_srcs += ['nageru/chroma_subsampler.cpp', 'nageru/v210_converter.cpp', 'nageru/mixer.cpp', 'nageru/pbo_frame_allocator.cpp',
 195         'nageru/theme.cpp', 'nageru/image_input.cpp', 'nageru/alsa_output.cpp',
 196         'nageru/timecode_renderer.cpp', 'nageru/tweaked_inputs.cpp', 'nageru/mjpeg_encoder.cpp']
 197
 198 # Streaming and encoding objects (largely the set that is shared between Nageru and Kaeru).
 199 stream_srcs = ['nageru/quicksync_encoder.cpp', 'nageru/x264_encoder.cpp', 'nageru/x264_dynamic.cpp', 'nageru/x264_speed_control.cpp', 'nageru/video_encoder.cpp',
 200         'nageru/audio_encoder.cpp', 'nageru/ffmpeg_util.cpp', 'nageru/ffmpeg_capture.cpp',
 201         'nageru/print_latency.cpp', 'nageru/basic_stats.cpp', 'nageru/ref_counted_frame.cpp']
 202 stream = static_library('stream', stream_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 203 nageru_link_with += stream
 204
 205 # DeckLink.
 206 decklink_dir = include_directories('nageru/decklink', is_system: true)
 207 decklink_lib = static_library('decklink', 'nageru/decklink/DeckLinkAPIDispatch.cpp', include_directories: decklink_dir, cpp_args: '-w')
 208 nageru_link_with += decklink_lib
 209
 210 nageru_srcs += ['nageru/decklink_capture.cpp', 'nageru/decklink_util.cpp', 'nageru/decklink_output.cpp']
 211 nageru_include_dirs += decklink_dir
 212
 213 # CEF input.
 214 if have_cef
 215         nageru_srcs += ['nageru/nageru_cef_app.cpp', 'nageru/cef_capture.cpp']
 216 endif
 217
 218 nageru_srcs += qt_files
 219 nageru_srcs += proto_generated
 220
 221 # Shaders needed at runtime.
 222 shaders = ['nageru/cbcr_subsample.vert', 'nageru/cbcr_subsample.frag', 'nageru/uyvy_subsample.vert', 'nageru/uyvy_subsample.frag', 'nageru/v210_subsample.comp', 'nageru/timecode.vert', 'nageru/timecode.frag', 'nageru/timecode_10bit.frag']
 223 foreach shader : shaders
 224         run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 225 endforeach
 226
 227 nageru_shader_srcs = bin2h_gen.process(shaders)
 228 nageru_srcs += nageru_shader_srcs
 229
 230 # Everything except main.cpp. (We do this because if you specify a .cpp file in
 231 # both Nageru and Kaeru, it gets compiled twice. In the older Makefiles, Kaeru
 232 # depended on a smaller set of objects.)
 233 core = static_library('core', nageru_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 234 nageru_link_with += core
 235
 236 # Nageru executable; it goes into /usr/lib/nageru since CEF files go there, too
 237 # (we can't put them straight into /usr/bin).
 238 executable('nageru', 'nageru/main.cpp',
 239         dependencies: nageru_deps,
 240         include_directories: nageru_include_dirs,
 241         link_with: nageru_link_with,
 242         build_rpath: nageru_build_rpath,
 243         install_rpath: nageru_install_rpath,
 244         install: true,
 245         install_dir: exe_dir
 246 )
 247 meson.add_install_script('nageru/scripts/setup_nageru_symlink.sh')
 248
 249 # Kaeru executable.
 250 executable('kaeru', 'nageru/kaeru.cpp',
 251         dependencies: [nageru_deps, kaeru_extra_deps],
 252         include_directories: nageru_include_dirs,
 253         link_with: [stream, aux, kaeru_link_with],
 254         install: true)
 255
 256 # Audio mixer microbenchmark.
 257 executable('benchmark_audio_mixer', 'nageru/benchmark_audio_mixer.cpp', dependencies: nageru_deps, include_directories: nageru_include_dirs, link_with: [audio, aux])
 258
 259 # These are needed for a default run.
 260 data_files = ['nageru/theme.lua', 'nageru/simple.lua', 'nageru/bg.jpeg', 'nageru/akai_midimix.midimapping']
 261 install_data(data_files, install_dir: join_paths(get_option('prefix'), 'share/nageru'))
 262 foreach file : data_files
 263         run_command('ln', '-s', join_paths(meson.current_source_dir(), file), meson.current_build_dir())
 264 endforeach
 265
 266 # Futatabi. (Not a subdir() because we don't want the output in nageru/nageru.)
 267
 268 # Protobuf compilation.
 269 gen = generator(protoc, \
 270         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 271         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/futatabi', '--cpp_out=@BUILD_DIR@', '@INPUT@'])
 272 proto_generated = gen.process('futatabi/state.proto', 'futatabi/frame.proto')
 273
 274 # Preprocess Qt as needed.
 275 moc_files = qt5.preprocess(
 276         moc_headers: ['futatabi/mainwindow.h', 'futatabi/jpeg_frame_view.h', 'futatabi/clip_list.h'],
 277         ui_files: ['futatabi/mainwindow.ui'],
 278         dependencies: qt5deps)
 279
 280 # Flow objects.
 281 futatabi_srcs = ['futatabi/flow.cpp', 'futatabi/gpu_timers.cpp']
 282
 283 # All the other files.
 284 futatabi_srcs += ['futatabi/main.cpp', 'futatabi/player.cpp', 'futatabi/video_stream.cpp', 'futatabi/chroma_subsampler.cpp']
 285 futatabi_srcs += ['futatabi/vaapi_jpeg_decoder.cpp', 'futatabi/db.cpp', 'futatabi/ycbcr_converter.cpp', 'futatabi/flags.cpp']
 286 futatabi_srcs += ['futatabi/mainwindow.cpp', 'futatabi/jpeg_frame_view.cpp', 'futatabi/clip_list.cpp', 'futatabi/frame_on_disk.cpp']
 287 futatabi_srcs += ['futatabi/export.cpp']
 288 futatabi_srcs += moc_files
 289 futatabi_srcs += proto_generated
 290
 291 # Shaders needed at runtime.
 292 shaders = ['futatabi/chroma_subsample.vert', 'futatabi/densify.vert', 'futatabi/equations.vert', 'futatabi/hole_fill.vert', 'futatabi/motion_search.vert', 'futatabi/sor.vert', 'futatabi/splat.vert', 'futatabi/vs.vert']
 293 shaders += ['futatabi/add_base_flow.frag', 'futatabi/blend.frag', 'futatabi/chroma_subsample.frag', 'futatabi/densify.frag', 'futatabi/derivatives.frag', 'futatabi/diffusivity.frag',
 294         'futatabi/equations.frag', 'futatabi/gray.frag', 'futatabi/hole_blend.frag', 'futatabi/hole_fill.frag', 'futatabi/motion_search.frag', 'futatabi/prewarp.frag', 'futatabi/resize_flow.frag',
 295         'futatabi/sobel.frag', 'futatabi/sor.frag', 'futatabi/splat.frag']
 296
 297 foreach shader : shaders
 298         run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 299 endforeach
 300
 301 futatabi_shader_srcs = bin2h_gen.process(shaders)
 302 futatabi_srcs += futatabi_shader_srcs
 303
 304 executable('futatabi', futatabi_srcs,
 305         dependencies: [shareddep, qt5deps, libjpegdep, movitdep, libmicrohttpddep, protobufdep, sqlite3dep, vax11dep, vadrmdep, x11dep, libavformatdep, libavcodecdep, libavutildep, libswscaledep],
 306         link_with: shared,
 307         include_directories: [include_directories('futatabi')],
 308         install: true)
 309
 310 # Test binaries for the optical flow code.
 311 if sdl2dep.found() and sdl2_imagedep.found()
 312         executable('flow', 'futatabi/flow_main.cpp', 'futatabi/flow.cpp', 'futatabi/gpu_timers.cpp', futatabi_shader_srcs, dependencies: [shareddep, epoxydep, sdl2dep, sdl2_imagedep])
 313 endif
 314 executable('eval', 'futatabi/eval.cpp', 'futatabi/util.cpp')
 315 executable('vis', 'futatabi/vis.cpp', 'futatabi/util.cpp')