git.sesse.net Git - nageru/blob - meson.build

   1 project('nageru', 'cpp', default_options: ['buildtype=debugoptimized'], version: '1.9.1')
   2
   3 cxx = meson.get_compiler('cpp')
   4 qt5 = import('qt5')
   5 protoc = find_program('protoc')
   6
   7 embedded_bmusb = get_option('embedded_bmusb')
   8
   9 alsadep = dependency('alsa')
  10 bmusbdep = dependency('bmusb', required: not embedded_bmusb)
  11 dldep = cxx.find_library('dl')
  12 eigendep = dependency('eigen3')
  13 epoxydep = dependency('epoxy')
  14 libavcodecdep = dependency('libavcodec')
  15 libavformatdep = dependency('libavformat')
  16 libswresampledep = dependency('libswresample')
  17 libavutildep = dependency('libavutil')
  18 libjpegdep = dependency('libjpeg')
  19 libswscaledep = dependency('libswscale')
  20 libusbdep = dependency('libusb-1.0')
  21 luajitdep = dependency('luajit')
  22 movitdep = dependency('movit')
  23 protobufdep = dependency('protobuf')
  24 qcustomplotdep = cxx.find_library('qcustomplot')
  25 qt5deps = dependency('qt5', modules: ['Core', 'Gui', 'Widgets', 'OpenGLExtensions', 'OpenGL', 'Network'])
  26 sdl2_imagedep = dependency('SDL2_image', required: false)
  27 sdl2dep = dependency('sdl2', required: false)
  28 sqlite3dep = dependency('sqlite3')
  29 threaddep = dependency('threads')
  30 vadrmdep = dependency('libva-drm')
  31 vax11dep = dependency('libva-x11')
  32 x11dep = dependency('x11')
  33 x264dep = dependency('x264')
  34 zitaresamplerdep = cxx.find_library('zita-resampler')
  35
  36 # Use lld if we can; it links a lot faster than ld.bfd or gold.
  37 code = '''#include <stdio.h>
  38 int main() { printf("Hello, world!\n"); return 0; }
  39 '''
  40 if cxx.links(code, args: '-fuse-ld=lld', name: 'check for LLD')
  41         add_project_link_arguments('-fuse-ld=lld', language: 'cpp')
  42 endif
  43
  44 # Add the right MOVIT_SHADER_DIR definition.
  45 movit_shader_dir = movitdep.get_pkgconfig_variable('shaderdir')
  46 add_project_arguments('-DMOVIT_SHADER_DIR="' + movit_shader_dir + '"', language: 'cpp')
  47
  48 # Make the Nageru version available as a #define.
  49 add_project_arguments('-DNAGERU_VERSION="' + meson.project_version() + '"', language: 'cpp')
  50
  51 # Make the prefix (e.g. /usr/local) available as a #define.
  52 add_project_arguments('-DPREFIX="' + get_option('prefix') + '"', language: 'cpp')
  53
  54 # This needs to be done before declaring any build targets.
  55 if get_option('cef_dir') != ''
  56         add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  57 endif
  58
  59 top_include = include_directories('.')
  60
  61 subdir('shared')
  62
  63 # Nageru. (Not a subdir() because we don't want the output in nageru/nageru.)
  64
  65 nageru_srcs = []
  66 nageru_deps = [shareddep, qt5deps, libjpegdep, movitdep, protobufdep,
  67         vax11dep, vadrmdep, x11dep, libavformatdep, libswresampledep, libavcodecdep, libavutildep,
  68         libswscaledep, libusbdep, luajitdep, dldep, x264dep, alsadep, zitaresamplerdep,
  69         qcustomplotdep, threaddep, eigendep]
  70 nageru_include_dirs = [include_directories('nageru')]
  71 nageru_link_with = []
  72 nageru_build_rpath = ''
  73 nageru_install_rpath = ''
  74
  75 kaeru_link_with = []
  76 kaeru_extra_deps = []
  77
  78 # CEF.
  79 exe_dir = join_paths(get_option('prefix'), 'lib/nageru')
  80 cef_dir = get_option('cef_dir')
  81 cef_build_type = get_option('cef_build_type')
  82 have_cef = (cef_dir != '')
  83 if have_cef
  84         # This is done in the top-level file; just kept here for reference.
  85         # add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  86
  87         system_cef = (cef_build_type == 'system')
  88         if system_cef
  89                 cef_lib_dir = cef_dir
  90                 cef_resource_dir = '/usr/share/cef/Resources'
  91         else
  92                 cef_lib_dir = join_paths(cef_dir, cef_build_type)
  93                 cef_resource_dir = join_paths(cef_dir, 'Resources')
  94
  95                 nageru_include_dirs += include_directories(cef_dir)
  96                 nageru_include_dirs += include_directories(join_paths(cef_dir, 'include'))
  97                 nageru_build_rpath = cef_lib_dir
  98                 nageru_install_rpath = '$ORIGIN/'
  99         endif
 100
 101         cefdep = cxx.find_library('cef', dirs: cef_lib_dir)
 102         nageru_deps += cefdep
 103
 104         # CEF wrapper library; not built as part of the CEF binary distribution,
 105         # but should be if CEF is installed as a system library.
 106         if system_cef
 107                 cefdlldep = cxx.find_library('cef_dll_wrapper')
 108                 nageru_deps += cefdlldep
 109         else
 110                 cmake = find_program('cmake')
 111                 cef_compile_script = find_program('nageru/scripts/compile_cef_dll_wrapper.sh')
 112
 113                 cef_dll_target = custom_target('libcef_dll_wrapper',
 114                         input: join_paths(cef_dir, 'libcef_dll/CMakeLists.txt'),
 115                         output: ['libcef_dll_wrapper.a', 'cef-stamp'],
 116                         command: [cef_compile_script, '@BUILD_DIR@', cef_dir, cmake, '@OUTPUT@'])
 117
 118                 # Putting the .a in sources seemingly hits a bug where the .a files get sorted
 119                 # in the wrong order. This is a workaround; see
 120                 # https://github.com/mesonbuild/meson/issues/3613#issuecomment-408276296 .
 121                 cefdlldep = declare_dependency(sources: cef_dll_target[1], link_args: cef_dll_target.full_path())
 122                 nageru_deps += cefdlldep
 123         endif
 124
 125         cef_libs = ['libEGL.so', 'libGLESv2.so', 'natives_blob.bin', 'snapshot_blob.bin', 'v8_context_snapshot.bin']
 126         cef_resources = ['cef.pak', 'cef_100_percent.pak', 'cef_200_percent.pak', 'cef_extensions.pak', 'devtools_resources.pak']
 127         if not get_option('cef_no_icudtl')
 128                 cef_resources += ['icudtl.dat']
 129         endif
 130         if cef_build_type != 'system'
 131                 cef_libs += ['libcef.so']
 132         endif
 133
 134         # Symlink the files into the build directory, so that running nageru without ninja install works.
 135         run_command('mkdir', join_paths(meson.current_build_dir(), 'locales/'))
 136         foreach file : cef_libs
 137                 run_command('ln', '-s', join_paths(cef_lib_dir, file), meson.current_build_dir())
 138                 install_data(join_paths(cef_lib_dir, file), install_dir: exe_dir)
 139         endforeach
 140         foreach file : cef_resources
 141                 run_command('ln', '-s', join_paths(cef_resource_dir, file), meson.current_build_dir())
 142                 install_data(join_paths(cef_resource_dir, file), install_dir: exe_dir)
 143         endforeach
 144         run_command('ln', '-s', join_paths(cef_resource_dir, 'locales/en-US.pak'), join_paths(meson.current_build_dir(), 'locales/'))
 145         install_data(join_paths(cef_resource_dir, 'locales/en-US.pak'), install_dir: join_paths(exe_dir, 'locales'))
 146 endif
 147
 148 # bmusb.
 149 if embedded_bmusb
 150         bmusb_dir = include_directories('nageru/bmusb')
 151         nageru_include_dirs += bmusb_dir
 152
 153         bmusb = static_library('bmusb', 'nageru/bmusb/bmusb.cpp', 'nageru/bmusb/fake_capture.cpp',
 154                 dependencies: [libusbdep],
 155                 include_directories: [bmusb_dir])
 156         nageru_link_with += bmusb
 157         kaeru_link_with += bmusb
 158 else
 159         nageru_deps += bmusbdep
 160         kaeru_extra_deps += bmusbdep
 161 endif
 162
 163 # Protobuf compilation.
 164 gen = generator(protoc, \
 165         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 166         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/nageru', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 167 proto_generated = gen.process(['nageru/state.proto', 'nageru/json.proto', 'nageru/nageru_midi_mapping.proto'])
 168 protobuf_lib = static_library('nageru_protobufs', proto_generated, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 169 protobuf_hdrs = declare_dependency(sources: proto_generated)
 170 nageru_link_with += protobuf_lib
 171
 172 # Preprocess Qt as needed.
 173 qt_files = qt5.preprocess(
 174         moc_headers: ['nageru/analyzer.h', 'nageru/clickable_label.h', 'nageru/compression_reduction_meter.h', 'nageru/correlation_meter.h',
 175                 'nageru/ellipsis_label.h', 'nageru/glwidget.h', 'nageru/input_mapping_dialog.h', 'nageru/lrameter.h', 'nageru/mainwindow.h', 'nageru/midi_mapping_dialog.h',
 176                 'nageru/nonlinear_fader.h', 'nageru/vumeter.h'],
 177         ui_files: ['nageru/analyzer.ui', 'nageru/audio_expanded_view.ui', 'nageru/audio_miniview.ui', 'nageru/display.ui',
 178                 'nageru/input_mapping.ui', 'nageru/mainwindow.ui', 'nageru/midi_mapping.ui'],
 179         dependencies: qt5deps)
 180
 181 # Qt objects.
 182 nageru_srcs += ['nageru/glwidget.cpp', 'nageru/mainwindow.cpp', 'nageru/vumeter.cpp', 'nageru/lrameter.cpp', 'nageru/compression_reduction_meter.cpp',
 183         'nageru/correlation_meter.cpp', 'nageru/analyzer.cpp', 'nageru/input_mapping_dialog.cpp', 'nageru/midi_mapping_dialog.cpp',
 184         'nageru/nonlinear_fader.cpp', 'nageru/context_menus.cpp', 'nageru/vu_common.cpp', 'nageru/piecewise_interpolator.cpp', 'nageru/midi_mapper.cpp']
 185
 186 # Auxiliary objects used for nearly everything.
 187 aux_srcs = ['nageru/flags.cpp']
 188 aux = static_library('aux', aux_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 189 nageru_link_with += aux
 190
 191 # Audio objects.
 192 audio_mixer_srcs = ['nageru/audio_mixer.cpp', 'nageru/alsa_input.cpp', 'nageru/alsa_pool.cpp', 'nageru/ebu_r128_proc.cc', 'nageru/stereocompressor.cpp',
 193         'nageru/resampling_queue.cpp', 'nageru/flags.cpp', 'nageru/correlation_measurer.cpp', 'nageru/filter.cpp', 'nageru/input_mapping.cpp']
 194 audio = static_library('audio', audio_mixer_srcs, dependencies: [nageru_deps, protobuf_hdrs], include_directories: nageru_include_dirs)
 195 nageru_link_with += audio
 196
 197 # Mixer objects.
 198 nageru_srcs += ['nageru/chroma_subsampler.cpp', 'nageru/v210_converter.cpp', 'nageru/mixer.cpp', 'nageru/pbo_frame_allocator.cpp',
 199         'nageru/theme.cpp', 'nageru/scene.cpp', 'nageru/image_input.cpp', 'nageru/alsa_output.cpp',
 200         'nageru/timecode_renderer.cpp', 'nageru/tweaked_inputs.cpp', 'nageru/mjpeg_encoder.cpp']
 201
 202 # Streaming and encoding objects (largely the set that is shared between Nageru and Kaeru).
 203 stream_srcs = ['nageru/quicksync_encoder.cpp', 'nageru/x264_encoder.cpp', 'nageru/x264_dynamic.cpp', 'nageru/x264_speed_control.cpp', 'nageru/video_encoder.cpp',
 204         'nageru/audio_encoder.cpp', 'nageru/ffmpeg_util.cpp', 'nageru/ffmpeg_capture.cpp',
 205         'nageru/print_latency.cpp', 'nageru/basic_stats.cpp', 'nageru/ref_counted_frame.cpp']
 206 stream = static_library('stream', stream_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 207 nageru_link_with += stream
 208
 209 # DeckLink.
 210 decklink_dir = include_directories('nageru/decklink', is_system: true)
 211 decklink_lib = static_library('decklink', 'nageru/decklink/DeckLinkAPIDispatch.cpp', include_directories: decklink_dir, cpp_args: '-w')
 212 nageru_link_with += decklink_lib
 213
 214 nageru_srcs += ['nageru/decklink_capture.cpp', 'nageru/decklink_util.cpp', 'nageru/decklink_output.cpp']
 215 nageru_include_dirs += decklink_dir
 216
 217 # CEF input.
 218 if have_cef
 219         nageru_srcs += ['nageru/nageru_cef_app.cpp', 'nageru/cef_capture.cpp']
 220 endif
 221
 222 nageru_srcs += qt_files
 223 nageru_srcs += proto_generated
 224
 225 # Shaders needed at runtime.
 226 shaders = ['nageru/cbcr_subsample.vert', 'nageru/cbcr_subsample.frag', 'nageru/uyvy_subsample.vert', 'nageru/uyvy_subsample.frag', 'nageru/v210_subsample.comp', 'nageru/timecode.vert', 'nageru/timecode.frag', 'nageru/timecode_10bit.frag']
 227 foreach shader : shaders
 228         run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 229 endforeach
 230
 231 nageru_shader_srcs = bin2h_gen.process(shaders)
 232 nageru_srcs += nageru_shader_srcs
 233
 234 # Everything except main.cpp. (We do this because if you specify a .cpp file in
 235 # both Nageru and Kaeru, it gets compiled twice. In the older Makefiles, Kaeru
 236 # depended on a smaller set of objects.)
 237 core = static_library('core', nageru_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 238 nageru_link_with += core
 239
 240 # Nageru executable; it goes into /usr/lib/nageru since CEF files go there, too
 241 # (we can't put them straight into /usr/bin).
 242 executable('nageru', 'nageru/main.cpp',
 243         dependencies: nageru_deps,
 244         include_directories: nageru_include_dirs,
 245         link_with: nageru_link_with,
 246         build_rpath: nageru_build_rpath,
 247         install_rpath: nageru_install_rpath,
 248         install: true,
 249         install_dir: exe_dir
 250 )
 251 meson.add_install_script('nageru/scripts/setup_nageru_symlink.sh')
 252
 253 # Kaeru executable.
 254 executable('kaeru', 'nageru/kaeru.cpp',
 255         dependencies: [nageru_deps, kaeru_extra_deps],
 256         include_directories: nageru_include_dirs,
 257         link_with: [stream, aux, kaeru_link_with],
 258         install: true)
 259
 260 # Audio mixer microbenchmark.
 261 executable('benchmark_audio_mixer', 'nageru/benchmark_audio_mixer.cpp', dependencies: nageru_deps, include_directories: nageru_include_dirs, link_with: [audio, aux])
 262
 263 # These are needed for a default run.
 264 data_files = ['nageru/theme.lua', 'nageru/simple.lua', 'nageru/bg.jpeg', 'nageru/akai_midimix.midimapping', 'futatabi/behringer_cmd_pl1.midimapping']
 265 install_data(data_files, install_dir: join_paths(get_option('prefix'), 'share/nageru'))
 266 foreach file : data_files
 267         run_command('ln', '-s', join_paths(meson.current_source_dir(), file), meson.current_build_dir())
 268 endforeach
 269
 270 # Futatabi. (Not a subdir() because we don't want the output in nageru/nageru.)
 271
 272 # Protobuf compilation.
 273 gen = generator(protoc, \
 274         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 275         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/futatabi', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 276 proto_generated = gen.process('futatabi/state.proto', 'futatabi/frame.proto', 'futatabi/futatabi_midi_mapping.proto')
 277
 278 # Preprocess Qt as needed.
 279 moc_files = qt5.preprocess(
 280         moc_headers: ['futatabi/mainwindow.h', 'futatabi/jpeg_frame_view.h', 'futatabi/clip_list.h', 'futatabi/midi_mapping_dialog.h'],
 281         ui_files: ['futatabi/mainwindow.ui', 'futatabi/midi_mapping.ui'],
 282         qresources: ['futatabi/mainwindow.qrc'],
 283         dependencies: qt5deps)
 284
 285 # Flow objects.
 286 futatabi_srcs = ['futatabi/flow.cpp', 'futatabi/gpu_timers.cpp']
 287
 288 # All the other files.
 289 futatabi_srcs += ['futatabi/main.cpp', 'futatabi/player.cpp', 'futatabi/video_stream.cpp', 'futatabi/chroma_subsampler.cpp']
 290 futatabi_srcs += ['futatabi/vaapi_jpeg_decoder.cpp', 'futatabi/db.cpp', 'futatabi/ycbcr_converter.cpp', 'futatabi/flags.cpp']
 291 futatabi_srcs += ['futatabi/mainwindow.cpp', 'futatabi/jpeg_frame_view.cpp', 'futatabi/clip_list.cpp', 'futatabi/frame_on_disk.cpp']
 292 futatabi_srcs += ['futatabi/export.cpp', 'futatabi/midi_mapper.cpp', 'futatabi/midi_mapping_dialog.cpp']
 293 futatabi_srcs += ['futatabi/exif_parser.cpp']
 294 futatabi_srcs += moc_files
 295 futatabi_srcs += proto_generated
 296
 297 # Shaders needed at runtime.
 298 shaders = ['futatabi/chroma_subsample.vert', 'futatabi/densify.vert', 'futatabi/equations.vert', 'futatabi/hole_fill.vert', 'futatabi/motion_search.vert', 'futatabi/sor.vert', 'futatabi/splat.vert', 'futatabi/vs.vert']
 299 shaders += ['futatabi/add_base_flow.frag', 'futatabi/blend.frag', 'futatabi/chroma_subsample.frag', 'futatabi/densify.frag', 'futatabi/derivatives.frag', 'futatabi/diffusivity.frag',
 300         'futatabi/equations.frag', 'futatabi/gray.frag', 'futatabi/hole_blend.frag', 'futatabi/hole_fill.frag', 'futatabi/motion_search.frag', 'futatabi/prewarp.frag', 'futatabi/resize_flow.frag',
 301         'futatabi/sobel.frag', 'futatabi/sor.frag', 'futatabi/splat.frag']
 302
 303 foreach shader : shaders
 304         run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 305 endforeach
 306
 307 futatabi_shader_srcs = bin2h_gen.process(shaders)
 308 futatabi_srcs += futatabi_shader_srcs
 309
 310 executable('futatabi', futatabi_srcs,
 311         dependencies: [shareddep, qt5deps, libjpegdep, movitdep, libmicrohttpddep, protobufdep, sqlite3dep, vax11dep, vadrmdep, x11dep, threaddep, libavformatdep, libavcodecdep, libavutildep, libswscaledep, eigendep],
 312         link_with: shared,
 313         include_directories: [include_directories('futatabi')],
 314         install: true)
 315
 316 # Test binaries for the optical flow code.
 317 if sdl2dep.found() and sdl2_imagedep.found()
 318         executable('flow', 'futatabi/flow_main.cpp', 'futatabi/flow.cpp', 'futatabi/gpu_timers.cpp', futatabi_shader_srcs, dependencies: [shareddep, epoxydep, sdl2dep, sdl2_imagedep])
 319 endif
 320 executable('eval', 'futatabi/eval.cpp', 'futatabi/util.cpp')
 321 executable('vis', 'futatabi/vis.cpp', 'futatabi/util.cpp')