git.sesse.net Git - nageru/blob - meson.build

   1 project('nageru', 'cpp', default_options: ['buildtype=debugoptimized'], version: '1.9.0')
   2
   3 cxx = meson.get_compiler('cpp')
   4 qt5 = import('qt5')
   5 protoc = find_program('protoc')
   6
   7 embedded_bmusb = get_option('embedded_bmusb')
   8
   9 alsadep = dependency('alsa')
  10 bmusbdep = dependency('bmusb', required: not embedded_bmusb)
  11 dldep = cxx.find_library('dl')
  12 epoxydep = dependency('epoxy')
  13 libavcodecdep = dependency('libavcodec')
  14 libavformatdep = dependency('libavformat')
  15 libswresampledep = dependency('libswresample')
  16 libavutildep = dependency('libavutil')
  17 libjpegdep = dependency('libjpeg')
  18 libswscaledep = dependency('libswscale')
  19 libusbdep = dependency('libusb-1.0')
  20 luajitdep = dependency('luajit')
  21 movitdep = dependency('movit')
  22 protobufdep = dependency('protobuf')
  23 qcustomplotdep = cxx.find_library('qcustomplot')
  24 qt5deps = dependency('qt5', modules: ['Core', 'Gui', 'Widgets', 'OpenGLExtensions', 'OpenGL', 'Network'])
  25 sdl2_imagedep = dependency('SDL2_image', required: false)
  26 sdl2dep = dependency('sdl2', required: false)
  27 sqlite3dep = dependency('sqlite3')
  28 threaddep = dependency('threads')
  29 vadrmdep = dependency('libva-drm')
  30 vax11dep = dependency('libva-x11')
  31 x11dep = dependency('x11')
  32 x264dep = dependency('x264')
  33 zitaresamplerdep = cxx.find_library('zita-resampler')
  34
  35 # Use lld if we can; it links a lot faster than ld.bfd or gold.
  36 code = '''#include <stdio.h>
  37 int main() { printf("Hello, world!\n"); return 0; }
  38 '''
  39 if cxx.links(code, args: '-fuse-ld=lld', name: 'check for LLD')
  40         add_project_link_arguments('-fuse-ld=lld', language: 'cpp')
  41 endif
  42
  43 # Add the right MOVIT_SHADER_DIR definition.
  44 movit_shader_dir = movitdep.get_pkgconfig_variable('shaderdir')
  45 add_project_arguments('-DMOVIT_SHADER_DIR="' + movit_shader_dir + '"', language: 'cpp')
  46
  47 # Make the Nageru version available as a #define.
  48 add_project_arguments('-DNAGERU_VERSION="' + meson.project_version() + '"', language: 'cpp')
  49
  50 # Make the prefix (e.g. /usr/local) available as a #define.
  51 add_project_arguments('-DPREFIX="' + get_option('prefix') + '"', language: 'cpp')
  52
  53 # This needs to be done before declaring any build targets.
  54 if get_option('cef_dir') != ''
  55         add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  56 endif
  57
  58 top_include = include_directories('.')
  59
  60 subdir('shared')
  61
  62 # Nageru. (Not a subdir() because we don't want the output in nageru/nageru.)
  63
  64 nageru_srcs = []
  65 nageru_deps = [shareddep, qt5deps, libjpegdep, movitdep, protobufdep,
  66         vax11dep, vadrmdep, x11dep, libavformatdep, libswresampledep, libavcodecdep, libavutildep,
  67         libswscaledep, libusbdep, luajitdep, dldep, x264dep, alsadep, zitaresamplerdep,
  68         qcustomplotdep, threaddep]
  69 nageru_include_dirs = [include_directories('nageru')]
  70 nageru_link_with = []
  71 nageru_build_rpath = ''
  72 nageru_install_rpath = ''
  73
  74 kaeru_link_with = []
  75 kaeru_extra_deps = []
  76
  77 # CEF.
  78 exe_dir = join_paths(get_option('prefix'), 'lib/nageru')
  79 cef_dir = get_option('cef_dir')
  80 cef_build_type = get_option('cef_build_type')
  81 have_cef = (cef_dir != '')
  82 if have_cef
  83         # This is done in the top-level file; just kept here for reference.
  84         # add_project_arguments('-DHAVE_CEF=1', language: 'cpp')
  85
  86         system_cef = (cef_build_type == 'system')
  87         if system_cef
  88                 cef_lib_dir = cef_dir
  89                 cef_resource_dir = '/usr/share/cef/Resources'
  90         else
  91                 cef_lib_dir = join_paths(cef_dir, cef_build_type)
  92                 cef_resource_dir = join_paths(cef_dir, 'Resources')
  93
  94                 nageru_include_dirs += include_directories(cef_dir)
  95                 nageru_include_dirs += include_directories(join_paths(cef_dir, 'include'))
  96                 nageru_build_rpath = cef_lib_dir
  97                 nageru_install_rpath = '$ORIGIN/'
  98         endif
  99
 100         cefdep = cxx.find_library('cef', dirs: cef_lib_dir)
 101         nageru_deps += cefdep
 102
 103         # CEF wrapper library; not built as part of the CEF binary distribution,
 104         # but should be if CEF is installed as a system library.
 105         if system_cef
 106                 cefdlldep = cxx.find_library('cef_dll_wrapper')
 107                 nageru_deps += cefdlldep
 108         else
 109                 cmake = find_program('cmake')
 110                 cef_compile_script = find_program('nageru/scripts/compile_cef_dll_wrapper.sh')
 111
 112                 cef_dll_target = custom_target('libcef_dll_wrapper',
 113                         input: join_paths(cef_dir, 'libcef_dll/CMakeLists.txt'),
 114                         output: ['libcef_dll_wrapper.a', 'cef-stamp'],
 115                         command: [cef_compile_script, '@BUILD_DIR@', cef_dir, cmake, '@OUTPUT@'])
 116
 117                 # Putting the .a in sources seemingly hits a bug where the .a files get sorted
 118                 # in the wrong order. This is a workaround; see
 119                 # https://github.com/mesonbuild/meson/issues/3613#issuecomment-408276296 .
 120                 cefdlldep = declare_dependency(sources: cef_dll_target[1], link_args: cef_dll_target.full_path())
 121                 nageru_deps += cefdlldep
 122         endif
 123
 124         cef_libs = ['libEGL.so', 'libGLESv2.so', 'natives_blob.bin', 'snapshot_blob.bin', 'v8_context_snapshot.bin']
 125         cef_resources = ['cef.pak', 'cef_100_percent.pak', 'cef_200_percent.pak', 'cef_extensions.pak', 'devtools_resources.pak']
 126         if not get_option('cef_no_icudtl')
 127                 cef_resources += ['icudtl.dat']
 128         endif
 129         if cef_build_type != 'system'
 130                 cef_libs += ['libcef.so']
 131         endif
 132
 133         # Symlink the files into the build directory, so that running nageru without ninja install works.
 134         run_command('mkdir', join_paths(meson.current_build_dir(), 'locales/'))
 135         foreach file : cef_libs
 136                 run_command('ln', '-s', join_paths(cef_lib_dir, file), meson.current_build_dir())
 137                 install_data(join_paths(cef_lib_dir, file), install_dir: exe_dir)
 138         endforeach
 139         foreach file : cef_resources
 140                 run_command('ln', '-s', join_paths(cef_resource_dir, file), meson.current_build_dir())
 141                 install_data(join_paths(cef_resource_dir, file), install_dir: exe_dir)
 142         endforeach
 143         run_command('ln', '-s', join_paths(cef_resource_dir, 'locales/en-US.pak'), join_paths(meson.current_build_dir(), 'locales/'))
 144         install_data(join_paths(cef_resource_dir, 'locales/en-US.pak'), install_dir: join_paths(exe_dir, 'locales'))
 145 endif
 146
 147 # bmusb.
 148 if embedded_bmusb
 149         bmusb_dir = include_directories('nageru/bmusb')
 150         nageru_include_dirs += bmusb_dir
 151
 152         bmusb = static_library('bmusb', 'nageru/bmusb/bmusb.cpp', 'nageru/bmusb/fake_capture.cpp',
 153                 dependencies: [libusbdep],
 154                 include_directories: [bmusb_dir])
 155         nageru_link_with += bmusb
 156         kaeru_link_with += bmusb
 157 else
 158         nageru_deps += bmusbdep
 159         kaeru_extra_deps += bmusbdep
 160 endif
 161
 162 # Protobuf compilation.
 163 gen = generator(protoc, \
 164         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 165         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/nageru', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 166 proto_generated = gen.process(['nageru/state.proto', 'nageru/json.proto', 'nageru/nageru_midi_mapping.proto'])
 167 protobuf_lib = static_library('nageru_protobufs', proto_generated, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 168 protobuf_hdrs = declare_dependency(sources: proto_generated)
 169 nageru_link_with += protobuf_lib
 170
 171 # Preprocess Qt as needed.
 172 qt_files = qt5.preprocess(
 173         moc_headers: ['nageru/analyzer.h', 'nageru/clickable_label.h', 'nageru/compression_reduction_meter.h', 'nageru/correlation_meter.h',
 174                 'nageru/ellipsis_label.h', 'nageru/glwidget.h', 'nageru/input_mapping_dialog.h', 'nageru/lrameter.h', 'nageru/mainwindow.h', 'nageru/midi_mapping_dialog.h',
 175                 'nageru/nonlinear_fader.h', 'nageru/vumeter.h'],
 176         ui_files: ['nageru/analyzer.ui', 'nageru/audio_expanded_view.ui', 'nageru/audio_miniview.ui', 'nageru/display.ui',
 177                 'nageru/input_mapping.ui', 'nageru/mainwindow.ui', 'nageru/midi_mapping.ui'],
 178         dependencies: qt5deps)
 179
 180 # Qt objects.
 181 nageru_srcs += ['nageru/glwidget.cpp', 'nageru/mainwindow.cpp', 'nageru/vumeter.cpp', 'nageru/lrameter.cpp', 'nageru/compression_reduction_meter.cpp',
 182         'nageru/correlation_meter.cpp', 'nageru/analyzer.cpp', 'nageru/input_mapping_dialog.cpp', 'nageru/midi_mapping_dialog.cpp',
 183         'nageru/nonlinear_fader.cpp', 'nageru/context_menus.cpp', 'nageru/vu_common.cpp', 'nageru/piecewise_interpolator.cpp', 'nageru/midi_mapper.cpp']
 184
 185 # Auxiliary objects used for nearly everything.
 186 aux_srcs = ['nageru/flags.cpp']
 187 aux = static_library('aux', aux_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 188 nageru_link_with += aux
 189
 190 # Audio objects.
 191 audio_mixer_srcs = ['nageru/audio_mixer.cpp', 'nageru/alsa_input.cpp', 'nageru/alsa_pool.cpp', 'nageru/ebu_r128_proc.cc', 'nageru/stereocompressor.cpp',
 192         'nageru/resampling_queue.cpp', 'nageru/flags.cpp', 'nageru/correlation_measurer.cpp', 'nageru/filter.cpp', 'nageru/input_mapping.cpp']
 193 audio = static_library('audio', audio_mixer_srcs, dependencies: [nageru_deps, protobuf_hdrs], include_directories: nageru_include_dirs)
 194 nageru_link_with += audio
 195
 196 # Mixer objects.
 197 nageru_srcs += ['nageru/chroma_subsampler.cpp', 'nageru/v210_converter.cpp', 'nageru/mixer.cpp', 'nageru/pbo_frame_allocator.cpp',
 198         'nageru/theme.cpp', 'nageru/scene.cpp', 'nageru/image_input.cpp', 'nageru/alsa_output.cpp',
 199         'nageru/timecode_renderer.cpp', 'nageru/tweaked_inputs.cpp', 'nageru/mjpeg_encoder.cpp']
 200
 201 # Streaming and encoding objects (largely the set that is shared between Nageru and Kaeru).
 202 stream_srcs = ['nageru/quicksync_encoder.cpp', 'nageru/x264_encoder.cpp', 'nageru/x264_dynamic.cpp', 'nageru/x264_speed_control.cpp', 'nageru/video_encoder.cpp',
 203         'nageru/audio_encoder.cpp', 'nageru/ffmpeg_util.cpp', 'nageru/ffmpeg_capture.cpp',
 204         'nageru/print_latency.cpp', 'nageru/basic_stats.cpp', 'nageru/ref_counted_frame.cpp']
 205 stream = static_library('stream', stream_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 206 nageru_link_with += stream
 207
 208 # DeckLink.
 209 decklink_dir = include_directories('nageru/decklink', is_system: true)
 210 decklink_lib = static_library('decklink', 'nageru/decklink/DeckLinkAPIDispatch.cpp', include_directories: decklink_dir, cpp_args: '-w')
 211 nageru_link_with += decklink_lib
 212
 213 nageru_srcs += ['nageru/decklink_capture.cpp', 'nageru/decklink_util.cpp', 'nageru/decklink_output.cpp']
 214 nageru_include_dirs += decklink_dir
 215
 216 # CEF input.
 217 if have_cef
 218         nageru_srcs += ['nageru/nageru_cef_app.cpp', 'nageru/cef_capture.cpp']
 219 endif
 220
 221 nageru_srcs += qt_files
 222 nageru_srcs += proto_generated
 223
 224 # Shaders needed at runtime.
 225 shaders = ['nageru/cbcr_subsample.vert', 'nageru/cbcr_subsample.frag', 'nageru/uyvy_subsample.vert', 'nageru/uyvy_subsample.frag', 'nageru/v210_subsample.comp', 'nageru/timecode.vert', 'nageru/timecode.frag', 'nageru/timecode_10bit.frag']
 226 foreach shader : shaders
 227         run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 228 endforeach
 229
 230 nageru_shader_srcs = bin2h_gen.process(shaders)
 231 nageru_srcs += nageru_shader_srcs
 232
 233 # Everything except main.cpp. (We do this because if you specify a .cpp file in
 234 # both Nageru and Kaeru, it gets compiled twice. In the older Makefiles, Kaeru
 235 # depended on a smaller set of objects.)
 236 core = static_library('core', nageru_srcs, dependencies: nageru_deps, include_directories: nageru_include_dirs)
 237 nageru_link_with += core
 238
 239 # Nageru executable; it goes into /usr/lib/nageru since CEF files go there, too
 240 # (we can't put them straight into /usr/bin).
 241 executable('nageru', 'nageru/main.cpp',
 242         dependencies: nageru_deps,
 243         include_directories: nageru_include_dirs,
 244         link_with: nageru_link_with,
 245         build_rpath: nageru_build_rpath,
 246         install_rpath: nageru_install_rpath,
 247         install: true,
 248         install_dir: exe_dir
 249 )
 250 meson.add_install_script('nageru/scripts/setup_nageru_symlink.sh')
 251
 252 # Kaeru executable.
 253 executable('kaeru', 'nageru/kaeru.cpp',
 254         dependencies: [nageru_deps, kaeru_extra_deps],
 255         include_directories: nageru_include_dirs,
 256         link_with: [stream, aux, kaeru_link_with],
 257         install: true)
 258
 259 # Audio mixer microbenchmark.
 260 executable('benchmark_audio_mixer', 'nageru/benchmark_audio_mixer.cpp', dependencies: nageru_deps, include_directories: nageru_include_dirs, link_with: [audio, aux])
 261
 262 # These are needed for a default run.
 263 data_files = ['nageru/theme.lua', 'nageru/simple.lua', 'nageru/bg.jpeg', 'nageru/akai_midimix.midimapping', 'futatabi/behringer_cmd_pl1.midimapping']
 264 install_data(data_files, install_dir: join_paths(get_option('prefix'), 'share/nageru'))
 265 foreach file : data_files
 266         run_command('ln', '-s', join_paths(meson.current_source_dir(), file), meson.current_build_dir())
 267 endforeach
 268
 269 # Futatabi. (Not a subdir() because we don't want the output in nageru/nageru.)
 270
 271 # Protobuf compilation.
 272 gen = generator(protoc, \
 273         output    : ['@BASENAME@.pb.cc', '@BASENAME@.pb.h'],
 274         arguments : ['--proto_path=@CURRENT_SOURCE_DIR@/futatabi', '--cpp_out=@BUILD_DIR@', '-I@CURRENT_SOURCE_DIR@/shared', '@INPUT@'])
 275 proto_generated = gen.process('futatabi/state.proto', 'futatabi/frame.proto', 'futatabi/futatabi_midi_mapping.proto')
 276
 277 # Preprocess Qt as needed.
 278 moc_files = qt5.preprocess(
 279         moc_headers: ['futatabi/mainwindow.h', 'futatabi/jpeg_frame_view.h', 'futatabi/clip_list.h', 'futatabi/midi_mapping_dialog.h'],
 280         ui_files: ['futatabi/mainwindow.ui', 'futatabi/midi_mapping.ui'],
 281         qresources: ['futatabi/mainwindow.qrc'],
 282         dependencies: qt5deps)
 283
 284 # Flow objects.
 285 futatabi_srcs = ['futatabi/flow.cpp', 'futatabi/gpu_timers.cpp']
 286
 287 # All the other files.
 288 futatabi_srcs += ['futatabi/main.cpp', 'futatabi/player.cpp', 'futatabi/video_stream.cpp', 'futatabi/chroma_subsampler.cpp']
 289 futatabi_srcs += ['futatabi/vaapi_jpeg_decoder.cpp', 'futatabi/db.cpp', 'futatabi/ycbcr_converter.cpp', 'futatabi/flags.cpp']
 290 futatabi_srcs += ['futatabi/mainwindow.cpp', 'futatabi/jpeg_frame_view.cpp', 'futatabi/clip_list.cpp', 'futatabi/frame_on_disk.cpp']
 291 futatabi_srcs += ['futatabi/export.cpp', 'futatabi/midi_mapper.cpp', 'futatabi/midi_mapping_dialog.cpp']
 292 futatabi_srcs += moc_files
 293 futatabi_srcs += proto_generated
 294
 295 # Shaders needed at runtime.
 296 shaders = ['futatabi/chroma_subsample.vert', 'futatabi/densify.vert', 'futatabi/equations.vert', 'futatabi/hole_fill.vert', 'futatabi/motion_search.vert', 'futatabi/sor.vert', 'futatabi/splat.vert', 'futatabi/vs.vert']
 297 shaders += ['futatabi/add_base_flow.frag', 'futatabi/blend.frag', 'futatabi/chroma_subsample.frag', 'futatabi/densify.frag', 'futatabi/derivatives.frag', 'futatabi/diffusivity.frag',
 298         'futatabi/equations.frag', 'futatabi/gray.frag', 'futatabi/hole_blend.frag', 'futatabi/hole_fill.frag', 'futatabi/motion_search.frag', 'futatabi/prewarp.frag', 'futatabi/resize_flow.frag',
 299         'futatabi/sobel.frag', 'futatabi/sor.frag', 'futatabi/splat.frag']
 300
 301 foreach shader : shaders
 302         run_command('ln', '-s', join_paths(meson.current_source_dir(), shader), meson.current_build_dir())
 303 endforeach
 304
 305 futatabi_shader_srcs = bin2h_gen.process(shaders)
 306 futatabi_srcs += futatabi_shader_srcs
 307
 308 executable('futatabi', futatabi_srcs,
 309         dependencies: [shareddep, qt5deps, libjpegdep, movitdep, libmicrohttpddep, protobufdep, sqlite3dep, vax11dep, vadrmdep, x11dep, libavformatdep, libavcodecdep, libavutildep, libswscaledep],
 310         link_with: shared,
 311         include_directories: [include_directories('futatabi')],
 312         install: true)
 313
 314 # Test binaries for the optical flow code.
 315 if sdl2dep.found() and sdl2_imagedep.found()
 316         executable('flow', 'futatabi/flow_main.cpp', 'futatabi/flow.cpp', 'futatabi/gpu_timers.cpp', futatabi_shader_srcs, dependencies: [shareddep, epoxydep, sdl2dep, sdl2_imagedep])
 317 endif
 318 executable('eval', 'futatabi/eval.cpp', 'futatabi/util.cpp')
 319 executable('vis', 'futatabi/vis.cpp', 'futatabi/util.cpp')