#version 440

layout(local_size_x = 1) in;

const uint prob_bits = 12;
const uint prob_scale = 1 << prob_bits;
const uint RANS_BYTE_L = (1u << 23);
const uint BLOCKS_PER_STREAM = 320;
const uint STREAM_BUF_SIZE = 256;  // In uint32s. 1 kB per stream ought to be enough for everyone :-)
const uint NUM_SYMS = 256;
const uint ESCAPE_LIMIT = NUM_SYMS - 1;
const uint WIDTH_BLOCKS = 160;  // TODO: send in as a uniform.

#define MAPPING(s0, s1, s2, s3, s4, s5, s6, s7) ((s0) | (s1 << 2) | (s2 << 4) | (s3 << 6) | (s4 << 8) | (s5 << 10) | (s6 << 12) | (s7 << 14))

const uint luma_mapping[8] = {
	MAPPING(0, 0, 1, 1, 2, 2, 3, 3),
	MAPPING(0, 0, 1, 2, 2, 2, 3, 3),
	MAPPING(1, 1, 2, 2, 2, 3, 3, 3),
	MAPPING(1, 1, 2, 2, 2, 3, 3, 3),
	MAPPING(1, 2, 2, 2, 2, 3, 3, 3),
	MAPPING(2, 2, 2, 2, 3, 3, 3, 3),
	MAPPING(2, 2, 3, 3, 3, 3, 3, 3),
	MAPPING(3, 3, 3, 3, 3, 3, 3, 3),
};

layout(std430, binding = 10) buffer outputBuf
{
	uint rans_output[];
};

layout(std430, binding = 11) buffer outputBuf2
{
	uint rans_bytes_written[];
};

layout(std140, binding = 13) uniform DistBlock
{
	uvec4 ransdist[4 * 256];
	uint sign_biases[4];
};

struct RansEncoder {
	uint stream_num;         // const
	uint lut_base;           // const
	uint sign_bias;          // const
	uint rans_start_offset;  // const
	uint rans_offset;
	uint rans;
	uint bit_buffer;
	uint bytes_in_buffer;
};

layout(r16ui) uniform restrict readonly uimage2D dc_ac7_tex;
layout(r16ui) uniform restrict readonly uimage2D ac1_ac6_tex;
layout(r16ui) uniform restrict readonly uimage2D ac2_ac5_tex;
layout(r8i) uniform restrict readonly iimage2D ac3_tex;
layout(r8i) uniform restrict readonly iimage2D ac4_tex;

void RansPutByte(uint x, inout RansEncoder enc)
{
	enc.bit_buffer = (enc.bit_buffer << 8) | x;
	if (++enc.bytes_in_buffer == 4) {
		rans_output[--enc.rans_offset] = enc.bit_buffer;
		enc.bytes_in_buffer = 0;
	}
}

void RansEncInit(uint streamgroup_num, uint coeff_row, uint coeff_col, uint dist_num, out RansEncoder enc)
{
	enc.stream_num = streamgroup_num * 64 + coeff_row * 8 + coeff_col;
	enc.lut_base = dist_num * 256;
	enc.sign_bias = sign_biases[dist_num];
	enc.rans_offset = enc.stream_num * STREAM_BUF_SIZE + STREAM_BUF_SIZE;  // Starts at the end.
	enc.rans_start_offset = enc.rans_offset;
	enc.rans = RANS_BYTE_L;
	enc.bit_buffer = 0;
	enc.bytes_in_buffer = 0;
}

void RansEncRenorm(inout RansEncoder enc, uint freq, uint prob_bits)
{
	uint x_max = ((RANS_BYTE_L >> prob_bits) << 8) * freq; // this turns into a shift.
	while (enc.rans >= x_max) {
		RansPutByte(enc.rans & 0xffu, enc);
		enc.rans >>= 8;
	}
}

void RansEncPut(inout RansEncoder enc, uint start, uint freq, uint prob_bits)
{
	RansEncRenorm(enc, freq, prob_bits);
	enc.rans = ((enc.rans / freq) << prob_bits) + (enc.rans % freq) + start;
}

void RansEncPutSymbol(inout RansEncoder enc, uvec4 sym)
{
	uint x_max = sym.x;
	uint rcp_freq = sym.y;
	uint bias = sym.z;
	uint rcp_shift = (sym.w & 0xffffu);
	uint cmpl_freq = (sym.w >> 16);

	// renormalize
	while (enc.rans >= x_max) {
		RansPutByte(enc.rans & 0xffu, enc);
		enc.rans >>= 8;
	}

	uint q, unused;
	umulExtended(enc.rans, rcp_freq, q, unused);
	enc.rans += bias + (q >> rcp_shift) * cmpl_freq;
}

uint RansEncFlush(inout RansEncoder enc)
{
	RansPutByte(enc.rans >> 24, enc);
	RansPutByte(enc.rans >> 16, enc);
	RansPutByte(enc.rans >> 8, enc);
	RansPutByte(enc.rans >> 0, enc);

	uint num_bytes_written = (enc.rans_start_offset - enc.rans_offset) * 4 + enc.bytes_in_buffer;

	// Make sure there's nothing left in the buffer.
	RansPutByte(0, enc);
	RansPutByte(0, enc);
	RansPutByte(0, enc);

	return num_bytes_written;
}

int sign_extend(uint coeff, uint bits)
{
	return int(coeff << (32 - bits)) >> (32 - bits);
}

void encode_coeff(int signed_k, inout RansEncoder enc)
{
	uint k = abs(signed_k);

	if (k >= ESCAPE_LIMIT) {
		// Put the coefficient as a 1/(2^12) symbol _before_
		// the 255 coefficient, since the decoder will read the
		// 255 coefficient first.
		RansEncPut(enc, k, 1, prob_bits);
		k = ESCAPE_LIMIT;
	}

	uvec4 sym = ransdist[enc.lut_base + ((k - 1) & (NUM_SYMS - 1))];
	RansEncPutSymbol(enc, sym);
	
	if (signed_k < 0) {
		enc.rans += enc.sign_bias;
	}
}

void encode_end(inout RansEncoder enc)
{
	uint bytes_written = RansEncFlush(enc);
	rans_bytes_written[enc.stream_num] = bytes_written;
}

void encode_9_7(uint streamgroup_num, uint coeff_row, layout(r16ui) restrict readonly uimage2D tex, uint col1, uint col2, uint dist1, uint dist2)
{
	RansEncoder enc1, enc2;
	RansEncInit(streamgroup_num, coeff_row, col1, dist1, enc1);
	RansEncInit(streamgroup_num, coeff_row, col2, dist2, enc2);

	for (uint subblock_idx = 0; subblock_idx < BLOCKS_PER_STREAM; ++subblock_idx) {
		// TODO: Use SSBOs instead of a texture?
		uint x = (streamgroup_num * BLOCKS_PER_STREAM + subblock_idx) % WIDTH_BLOCKS;
		uint y = (streamgroup_num * BLOCKS_PER_STREAM + subblock_idx) / WIDTH_BLOCKS;
		uint f = imageLoad(tex, ivec2(x, y * 8 + coeff_row)).x;

		encode_coeff(sign_extend(f & 0x1ffu, 9), enc1);
		encode_coeff(sign_extend(f >> 9, 7), enc2);
	}

	encode_end(enc1);
	encode_end(enc2);
}

void encode_8(uint streamgroup_num, uint coeff_row, layout(r8i) restrict readonly iimage2D tex, uint col, uint dist)
{
	RansEncoder enc;
	RansEncInit(streamgroup_num, coeff_row, col, dist, enc);

	for (uint subblock_idx = 0; subblock_idx < BLOCKS_PER_STREAM; ++subblock_idx) {
		// TODO: Use SSBOs instead of a texture?
		uint x = (streamgroup_num * BLOCKS_PER_STREAM + subblock_idx) % WIDTH_BLOCKS;
		uint y = (streamgroup_num * BLOCKS_PER_STREAM + subblock_idx) / WIDTH_BLOCKS;
		int f = imageLoad(tex, ivec2(x, y * 8 + coeff_row)).x;

		encode_coeff(f, enc);
	}

	encode_end(enc);
}

void main()
{
	uint streamgroup_num = gl_WorkGroupID.x;
	uint coeff_row = gl_WorkGroupID.y;    // 0..7
	uint coeff_colset = gl_WorkGroupID.z;   // 0 = dc+ac7, 1 = ac1+ac6, 2 = ac2+ac5, 3 = ac3, 4 = ac5
	uint m = luma_mapping[coeff_row];

	// TODO: DC coeff pred

	if (coeff_colset == 0) {
		uint dist_dc = bitfieldExtract(m, 0, 2);
		uint dist_ac7 = bitfieldExtract(m, 14, 2);
		encode_9_7(streamgroup_num, coeff_row, dc_ac7_tex, 0, 7, dist_dc, dist_ac7);
	} else if (coeff_colset == 1) {
		uint dist_ac1 = bitfieldExtract(m, 2, 2);
		uint dist_ac6 = bitfieldExtract(m, 12, 2);
		encode_9_7(streamgroup_num, coeff_row, ac1_ac6_tex, 1, 6, dist_ac1, dist_ac6);
	} else if (coeff_colset == 2) {
		uint dist_ac2 = bitfieldExtract(m, 4, 2);
		uint dist_ac5 = bitfieldExtract(m, 10, 2);
		encode_9_7(streamgroup_num, coeff_row, ac2_ac5_tex, 2, 5, dist_ac2, dist_ac5);
	} else if (coeff_colset == 3) {
		uint dist_ac3 = bitfieldExtract(m, 6, 2);
		encode_8(streamgroup_num, coeff_row, ac3_tex, 3, dist_ac3);
	} else {
		uint dist_ac4 = bitfieldExtract(m, 8, 2);
		encode_8(streamgroup_num, coeff_row, ac4_tex, 4, dist_ac4);
	}
}