git.sesse.net Git - pr0n/blob - perl/Sesse/pr0n/Index.pm

   1 package Sesse::pr0n::Index;
   2 use strict;
   3 use warnings;
   4
   5 use Sesse::pr0n::Common qw(error dberror);
   6 use Apache2::Request;
   7 use POSIX;
   8
   9 sub handler {
  10         my $r = shift;
  11         my $apr = Apache2::Request->new($r);
  12         my $dbh = Sesse::pr0n::Common::get_dbh();
  13
  14         # Find the event
  15         $r->uri =~ m#^/([a-zA-Z0-9-]+)/?$#
  16                 or error($r, "Could not extract event");
  17         my $event = $1;
  18
  19         # Fix common error: pr0n.sesse.net/event -> pr0n.sesse.net/event/
  20         if ($r->uri !~ m#/$#) {
  21                 $r->headers_out->{'location'} = "/$event/";
  22                 return Apache2::Const::REDIRECT;
  23         }
  24
  25         # Internal? (Ugly?)
  26         if ($r->get_server_name =~ /internal/ || $r->get_server_name =~ /skoyen\.bilder\.knatten\.com/) {
  27                 my $user = Sesse::pr0n::Common::check_access($r);
  28                 if (!defined($user)) {
  29                         return Apache2::Const::OK;
  30                 }
  31         }
  32
  33         # Read the appropriate settings from the query string into the settings hash
  34         my %defsettings = (
  35                 thumbxres => 80,
  36                 thumbyres => 64,
  37                 xres => -1,
  38                 yres => -1,
  39                 start => 1,
  40                 num => -1,
  41                 all => 1,
  42                 infobox => 1,
  43                 rot => 0,
  44                 sel => 0,
  45                 fullscreen => 0,
  46         );
  47
  48         # Any NEF files => default to processing
  49         my $ref = $dbh->selectrow_hashref('SELECT * FROM images WHERE event=? AND LOWER(filename) LIKE \'%.nef\' LIMIT 1',
  50                 undef, $event)
  51                 and $defsettings{'xres'} = $defsettings{'yres'} = undef;
  52
  53         # Reduce the front page load when in overload mode.
  54         if (Sesse::pr0n::Overload::is_in_overload($r)) {
  55                 $defsettings{'num'} = 100;
  56         }
  57
  58         my %settings = %defsettings;
  59
  60         for my $s qw(thumbxres thumbyres xres yres start num all infobox rot sel fullscreen) {
  61                 my $val = $apr->param($s);
  62                 if (defined($val) && $val =~ /^(\d+)$/) {
  63                         $settings{$s} = $val;
  64                 }
  65                 if (($s eq "num" || $s eq "xres" || $s eq "yres") && defined($val) && $val == -1) {
  66                         $settings{$s} = $val;
  67                 }
  68         }
  69
  70         my $thumbxres = $settings{'thumbxres'};
  71         my $thumbyres = $settings{'thumbyres'};
  72         my $xres = $settings{'xres'};
  73         my $yres = $settings{'yres'};
  74         my $start = $settings{'start'};
  75         my $num = $settings{'num'};
  76         my $all = $settings{'all'};
  77         my $infobox = $settings{'infobox'} ? '' : 'nobox/';
  78         my $rot = $settings{'rot'};
  79         my $sel = $settings{'sel'};
  80
  81         if (defined($num) && $num == -1) {
  82                 $num = undef;
  83         }
  84
  85         $ref = $dbh->selectrow_hashref('SELECT name,date,EXTRACT(EPOCH FROM last_update) AS last_update FROM events WHERE id=? AND vhost=?',
  86                 undef, $event, $r->get_server_name)
  87                 or error($r, "Could not find event $event", 404, "File not found");
  88
  89         my $date = HTML::Entities::encode_entities(Encode::decode_utf8($ref->{'date'}));
  90         my $name = HTML::Entities::encode_entities(Encode::decode_utf8($ref->{'name'}));
  91         $r->set_last_modified($ref->{'last_update'});
  92
  93         # If the client can use cache, do so
  94         if ((my $rc = $r->meets_conditions) != Apache2::Const::OK) {
  95                 return $rc;
  96         }
  97
  98         # Count the number of selected images.
  99         $ref = $dbh->selectrow_hashref("SELECT COUNT(*) AS num_selected FROM images WHERE event=? AND selected=\'t\'", undef, $event);
 100         my $num_selected = $ref->{'num_selected'};
 101
 102         # Find all images related to this event.
 103         my $q;
 104         my $where = ($all == 0) ? ' AND selected=\'t\'' : '';
 105
 106         if (defined($start) && defined($num) && !$settings{'fullscreen'}) {
 107                 $q = $dbh->prepare("SELECT *, (date - INTERVAL '6 hours')::date AS day FROM images WHERE event=? $where ORDER BY (date - INTERVAL '6 hours')::date,takenby,date,filename LIMIT $num OFFSET " . ($start-1))
 108                         or dberror($r, "prepare()");
 109         } else {
 110                 $q = $dbh->prepare("SELECT *, (date - INTERVAL '6 hours')::date AS day FROM images WHERE event=? $where ORDER BY (date - INTERVAL '6 hours')::date,takenby,date,filename")
 111                         or dberror($r, "prepare()");
 112         }
 113         $q->execute($event)
 114                 or dberror($r, "image enumeration");
 115
 116         # Print the page itself
 117         if ($settings{'fullscreen'}) {
 118                 $r->content_type("text/html; charset=utf-8");
 119                 Sesse::pr0n::Templates::print_template($r, "fullscreen-header", { title => "$name [$event]" });
 120                 while (my $ref = $q->fetchrow_hashref()) {
 121                         $r->print("        \"" . $infobox . $ref->{'filename'} . "\",\n");
 122                 }
 123
 124                 my %settings_no_fullscreen = %settings;
 125                 $settings_no_fullscreen{'fullscreen'} = 0;
 126
 127                 my $returnurl = "http://" . $r->get_server_name . "/" . $event . "/" .
 128                         Sesse::pr0n::Common::get_query_string(\%settings_no_fullscreen, \%defsettings);
 129
 130                 # *whistle*
 131                 $returnurl =~ s/&amp;/&/g;
 132
 133                 Sesse::pr0n::Templates::print_template($r, "fullscreen-footer", {
 134                         vhost => $r->get_server_name,
 135                         event => $event,
 136                         start => $settings{'start'} - 1,
 137                         returnurl => $returnurl,
 138                         sel => $settings{'sel'},
 139                 });
 140         } else {
 141                 Sesse::pr0n::Common::header($r, "$name [$event]");
 142                 Sesse::pr0n::Templates::print_template($r, "date", { date => $date });
 143
 144                 if (Sesse::pr0n::Overload::is_in_overload($r)) {
 145                         Sesse::pr0n::Templates::print_template($r, "overloadmode");
 146                 }
 147
 148                 print_thumbsize($r, $event, \%settings, \%defsettings);
 149                 print_viewres($r, $event, \%settings, \%defsettings);
 150                 print_pagelimit($r, $event, \%settings, \%defsettings);
 151                 print_infobox($r, $event, \%settings, \%defsettings);
 152                 print_nextprev($r, $event, \%settings, \%defsettings);
 153                 print_selected($r, $event, \%settings, \%defsettings) if ($num_selected > 0);
 154                 print_fullscreen($r, $event, \%settings, \%defsettings);
 155
 156                 # Find the equipment used
 157                 my $eq = $dbh->prepare('
 158                         SELECT
 159                                 TRIM(model.value) AS model,
 160                                 coalesce(TRIM(lens_spec.value), TRIM(lens.value)) AS lens,
 161                                 COUNT(*) AS num
 162                         FROM images i
 163                                 LEFT JOIN exif_info model ON i.id=model.image
 164                                 LEFT JOIN ( SELECT * FROM exif_info WHERE tag=\'Lens\' ) lens ON i.id=lens.image
 165                                 LEFT JOIN ( SELECT * FROM exif_info WHERE tag=\'LensSpec\') lens_spec ON i.id=lens_spec.image
 166                         WHERE event=? AND model.tag=\'Model\'
 167                         GROUP BY 1,2
 168                         ORDER BY 1,2')
 169                         or die "Couldn't prepare to find equipment: $!";
 170                 $eq->execute($event)
 171                         or die "Couldn't find equipment: $!";
 172
 173                 my @equipment = ();
 174                 my %cameras_seen = ();
 175                 while (my $ref = $eq->fetchrow_hashref) {
 176                         if (!defined($ref->{'lens'}) && exists($cameras_seen{$ref->{'model'}})) {
 177                                 #
 178                                 # Some compact cameras seem to add lens info sometimes and not at other
 179                                 # times; if we have seen a camera with at least one specific lens earlier,
 180                                 # just combine entries without a lens with the previous one.
 181                                 #
 182                                 $equipment[$#equipment]->{'num'} += $ref->{'num'};
 183                                 next;
 184                         }
 185                         push @equipment, $ref;
 186                         $cameras_seen{$ref->{'model'}} = 1;
 187                 }
 188                 $eq->finish;
 189
 190                 if (scalar @equipment > 0) {
 191                         Sesse::pr0n::Templates::print_template($r, "equipment-start");
 192                         for my $e (@equipment) {
 193                                 my $eqspec = $e->{'model'};
 194                                 $eqspec .= ', ' . $e->{'lens'} if (defined($e->{'lens'}));
 195
 196                                 # This isn't correct for all languages. Fix if we ever need to care. :-)
 197                                 if ($e->{'num'} == 1) {
 198                                         Sesse::pr0n::Templates::print_template($r, "equipment-item-singular", { eqspec => $eqspec });
 199                                 } else {
 200                                         Sesse::pr0n::Templates::print_template($r, "equipment-item", { eqspec => $eqspec, num => $e->{'num'} });
 201                                 }
 202                         }
 203                         Sesse::pr0n::Templates::print_template($r, "equipment-end");
 204                 }
 205
 206
 207                 my $toclose = 0;
 208                 my $lastupl = "";
 209                 my $img_num = $start;
 210
 211                 # Print out all thumbnails
 212                 if ($rot == 1) {
 213                         $r->print("    <form method=\"post\" action=\"/rotate\">\n");
 214                         $r->print("      <input type=\"hidden\" name=\"event\" value=\"$event\" />\n");
 215
 216                         while (my $ref = $q->fetchrow_hashref()) {
 217                                 my $imgsz = "";
 218                                 my $takenby = $ref->{'takenby'};
 219                                 if (defined($ref->{'day'})) {
 220                                          $takenby .= ", " . $ref->{'day'};
 221                                 }
 222
 223                                 if ($takenby ne $lastupl) {
 224                                         $lastupl = $takenby;
 225                                         $r->print("    <h2>");
 226                                         Sesse::pr0n::Templates::print_template($r, "submittedby", { author => $lastupl });
 227                                         print_fullscreen_fromhere($r, $event, \%settings, \%defsettings, $img_num);
 228                                         $r->print("</h2>\n");
 229                                 }
 230                                 if ($ref->{'width'} != -1 && $ref->{'height'} != -1) {
 231                                         my $width = $ref->{'width'};
 232                                         my $height = $ref->{'height'};
 233
 234                                         ($width, $height) = Sesse::pr0n::Common::scale_aspect($width, $height, $thumbxres, $thumbyres);
 235                                         $imgsz = " width=\"$width\" height=\"$height\"";
 236                                 }
 237
 238                                 my $filename = $ref->{'filename'};
 239                                 my $uri = $infobox . $filename;
 240                                 if (defined($xres) && defined($yres) && $xres != -1) {
 241                                         $uri = "${xres}x$yres/$infobox$filename";
 242                                 } elsif (defined($xres) && $xres == -1) {
 243                                         $uri = "original/$infobox$filename";
 244                                 }
 245
 246                                 $r->print("    <p><a href=\"$uri\"><img src=\"${thumbxres}x${thumbyres}/$filename\" alt=\"\"$imgsz /></a>\n");
 247                                 $r->print("      90 <input type=\"checkbox\" name=\"rot-" .
 248                                         $ref->{'id'} . "-90\" />\n");
 249                                 $r->print("      180 <input type=\"checkbox\" name=\"rot-" .
 250                                         $ref->{'id'} . "-180\" />\n");
 251                                 $r->print("      270 <input type=\"checkbox\" name=\"rot-" .
 252                                         $ref->{'id'} . "-270\" />\n");
 253                                 $r->print("      &nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;" .
 254                                         "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;Del <input type=\"checkbox\" name=\"del-" . $ref->{'id'} . "\" /></p>\n");
 255
 256                                 ++$img_num;
 257                         }
 258                         $r->print("      <input type=\"submit\" value=\"Rotate\" />\n");
 259                         $r->print("    </form>\n");
 260                 } else {
 261                         while (my $ref = $q->fetchrow_hashref()) {
 262                                 my $imgsz = "";
 263                                 my $takenby = $ref->{'takenby'};
 264                                 if (defined($ref->{'day'})) {
 265                                          $takenby .= ", " . $ref->{'day'};
 266                                 }
 267
 268                                 if ($takenby ne $lastupl) {
 269                                         $r->print("    </p>\n\n") if ($lastupl ne "");
 270                                         $lastupl = $takenby;
 271                                         $r->print("    <h2>");
 272                                         Sesse::pr0n::Templates::print_template($r, "submittedby", { author => $lastupl });
 273                                         print_fullscreen_fromhere($r, $event, \%settings, \%defsettings, $img_num);
 274                                         $r->print("</h2>\n");
 275                                         $r->print("    <p class=\"photos\">\n");
 276                                 }
 277                                 if ($ref->{'width'} != -1 && $ref->{'height'} != -1) {
 278                                         my $width = $ref->{'width'};
 279                                         my $height = $ref->{'height'};
 280
 281                                         ($width, $height) = Sesse::pr0n::Common::scale_aspect($width, $height, $thumbxres, $thumbyres);
 282                                         $imgsz = " width=\"$width\" height=\"$height\"";
 283                                 }
 284
 285                                 my $filename = $ref->{'filename'};
 286                                 my $uri = $infobox . $filename;
 287                                 if (defined($xres) && defined($yres) && $xres != -1) {
 288                                         $uri = "${xres}x$yres/$infobox$filename";
 289                                 } elsif (defined($xres) && $xres == -1) {
 290                                         $uri = "original/$infobox$filename";
 291                                 }
 292
 293                                 $r->print("      <a href=\"$uri\"><img src=\"${thumbxres}x${thumbyres}/$filename\" alt=\"\"$imgsz /></a>\n");
 294
 295                                 ++$img_num;
 296                         }
 297                         $r->print("    </p>\n");
 298                 }
 299
 300                 print_nextprev($r, $event, \%settings, \%defsettings);
 301                 Sesse::pr0n::Common::footer($r);
 302         }
 303
 304         return Apache2::Const::OK;
 305 }
 306
 307 sub eq_with_undef {
 308         my ($a, $b) = @_;
 309
 310         return 1 if (!defined($a) && !defined($b));
 311         return 0 unless (defined($a) && defined($b));
 312         return ($a eq $b);
 313 }
 314
 315 sub print_changes {
 316         my ($r, $event, $template, $settings, $defsettings, $var1, $var2, $alternatives) = @_;
 317
 318         my $title = Sesse::pr0n::Templates::fetch_template($r, $template);
 319         chomp $title;
 320         $r->print("    <p>$title:\n");
 321
 322         for my $a (@$alternatives) {
 323                 my $text;
 324                 my %newsettings = %$settings;
 325
 326                 if (ref $a) {
 327                         my ($v1, $v2);
 328                         ($text, $v1, $v2) = @$a;
 329
 330                         $newsettings{$var1} = $v1;
 331                         $newsettings{$var2} = $v2;
 332                 } else {
 333                         $text = $a;
 334
 335                         # Parse the current alternative
 336                         my ($v1, $v2) = split /x/, $a;
 337
 338                         $newsettings{$var1} = $v1;
 339                         $newsettings{$var2} = $v2;
 340                 }
 341
 342                 $r->print("      ");
 343
 344                 # Check if these settings are current (print only label)
 345                 if (eq_with_undef($settings->{$var1}, $newsettings{$var1}) &&
 346                     eq_with_undef($settings->{$var2}, $newsettings{$var2})) {
 347                         $r->print($text);
 348                 } else {
 349                         Sesse::pr0n::Common::print_link($r, $text, "/$event/", \%newsettings, $defsettings);
 350                 }
 351                 $r->print("\n");
 352         }
 353         $r->print("    </p>\n");
 354 }
 355
 356 sub print_thumbsize {
 357         my ($r, $event, $settings, $defsettings) = @_;
 358         my @alternatives = qw(80x64 120x96 160x128 240x192 320x256);
 359
 360         print_changes($r, $event, 'thumbsize', $settings, $defsettings,
 361                       'thumbxres', 'thumbyres', \@alternatives);
 362 }
 363 sub print_viewres {
 364         my ($r, $event, $settings, $defsettings) = @_;
 365         my @alternatives = qw(320x256 512x384 640x480 800x600 1024x768 1280x960);
 366         chomp (my $unlimited = Sesse::pr0n::Templates::fetch_template($r, 'viewres-unlimited'));
 367         chomp (my $original = Sesse::pr0n::Templates::fetch_template($r, 'viewres-original'));
 368         push @alternatives, [ $unlimited, undef, undef ];
 369         push @alternatives, [ $original, -1, -1 ];
 370
 371         print_changes($r, $event, 'viewres', $settings, $defsettings,
 372                       'xres', 'yres', \@alternatives);
 373 }
 374
 375 sub print_pagelimit {
 376         my ($r, $event, $settings, $defsettings) = @_;
 377
 378         my $title = Sesse::pr0n::Templates::fetch_template($r, 'imgsperpage');
 379         chomp $title;
 380         $r->print("    <p>$title:\n");
 381
 382         # Get choices
 383         chomp (my $unlimited = Sesse::pr0n::Templates::fetch_template($r, 'imgsperpage-unlimited'));
 384         my @alternatives = qw(10 50 100 500);
 385         push @alternatives, $unlimited;
 386
 387         for my $num (@alternatives) {
 388                 my %newsettings = %$settings;
 389
 390                 if ($num !~ /^\d+$/) { # unlimited
 391                         $newsettings{'num'} = -1;
 392                 } else {
 393                         $newsettings{'num'} = $num;
 394                 }
 395
 396                 $r->print("      ");
 397                 if (eq_with_undef($settings->{'num'}, $newsettings{'num'})) {
 398                         $r->print($num);
 399                 } else {
 400                         Sesse::pr0n::Common::print_link($r, $num, "/$event/", \%newsettings, $defsettings);
 401                 }
 402                 $r->print("\n");
 403         }
 404         $r->print("    </p>\n");
 405 }
 406
 407 sub print_infobox {
 408         my ($r, $event, $settings, $defsettings) = @_;
 409
 410         chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'infobox'));
 411         chomp (my $on = Sesse::pr0n::Templates::fetch_template($r, 'infobox-on'));
 412         chomp (my $off = Sesse::pr0n::Templates::fetch_template($r, 'infobox-off'));
 413
 414         $r->print("    <p>$title:\n");
 415
 416         my %newsettings = %$settings;
 417
 418         if ($settings->{'infobox'} == 1) {
 419                 $r->print($on);
 420         } else {
 421                 $newsettings{'infobox'} = 1;
 422                 Sesse::pr0n::Common::print_link($r, $on, "/$event/", \%newsettings, $defsettings);
 423         }
 424
 425         $r->print(' ');
 426
 427         if ($settings->{'infobox'} == 0) {
 428                 $r->print($off);
 429         } else {
 430                 $newsettings{'infobox'} = 0;
 431                 Sesse::pr0n::Common::print_link($r, $off, "/$event/", \%newsettings, $defsettings);
 432         }
 433
 434         $r->print('</p>');
 435 }
 436
 437 sub print_nextprev {
 438         my ($r, $event, $settings, $defsettings) = @_;
 439         my $start = $settings->{'start'};
 440         my $num = $settings->{'num'};
 441         my $dbh = Sesse::pr0n::Common::get_dbh();
 442
 443         $num = undef if (defined($num) && $num == -1);
 444         return unless (defined($start) && defined($num));
 445
 446         # determine total number
 447         my $ref = $dbh->selectrow_hashref('SELECT count(*) AS num_images FROM images WHERE event=?',
 448                 undef, $event)
 449                 or dberror($r, "image enumeration");
 450         my $num_images = $ref->{'num_images'};
 451
 452         return if ($start == 1 && $start + $num >= $num_images);
 453
 454         my $end = $start + $num - 1;
 455         if ($end > $num_images) {
 456                 $end = $num_images;
 457         }
 458
 459         $r->print("    <p>\n");
 460
 461         # Previous
 462         if ($start > 1) {
 463                 my $newstart = $start - $num;
 464                 if ($newstart < 1) {
 465                         $newstart = 1;
 466                 }
 467                 my $newend = $newstart + $num - 1;
 468                 if ($newend > $num_images) {
 469                         $newend = $num_images;
 470                 }
 471
 472                 my %newsettings = %$settings;
 473                 $newsettings{'start'} = $newstart;
 474                 chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'prevpage'));
 475                 chomp (my $accesskey = Sesse::pr0n::Templates::fetch_template($r, 'prevaccesskey'));
 476                 Sesse::pr0n::Common::print_link($r, "$title ($newstart-$newend)\n", "/$event/", \%newsettings, $defsettings, $accesskey);
 477         }
 478
 479         # This
 480         chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'thispage'));
 481         $r->print("    $title ($start-$end)\n");
 482
 483         # Next
 484         if ($end < $num_images) {
 485                 my $newstart = $start + $num;
 486                 my $newend = $newstart + $num - 1;
 487                 if ($newend > $num_images) {
 488                         $newend = $num_images;
 489                 }
 490
 491                 my %newsettings = %$settings;
 492                 $newsettings{'start'} = $newstart;
 493                 chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'nextpage'));
 494                 chomp (my $accesskey = Sesse::pr0n::Templates::fetch_template($r, 'nextaccesskey'));
 495                 Sesse::pr0n::Common::print_link($r, "$title ($newstart-$newend)", "/$event/", \%newsettings, $defsettings, $accesskey);
 496         }
 497
 498         $r->print("    </p>\n");
 499 }
 500
 501 sub print_selected {
 502         my ($r, $event, $settings, $defsettings) = @_;
 503
 504         chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'show'));
 505         chomp (my $all = Sesse::pr0n::Templates::fetch_template($r, 'show-all'));
 506         chomp (my $sel = Sesse::pr0n::Templates::fetch_template($r, 'show-selected'));
 507
 508         $r->print("    <p>$title:\n");
 509
 510         my %newsettings = %$settings;
 511
 512         if ($settings->{'all'} == 0) {
 513                 $r->print($sel);
 514         } else {
 515                 $newsettings{'all'} = 0;
 516                 Sesse::pr0n::Common::print_link($r, $sel, "/$event/", \%newsettings, $defsettings);
 517         }
 518
 519         $r->print(' ');
 520
 521         if ($settings->{'all'} == 1) {
 522                 $r->print($all);
 523         } else {
 524                 $newsettings{'all'} = 1;
 525                 Sesse::pr0n::Common::print_link($r, $all, "/$event/", \%newsettings, $defsettings);
 526         }
 527
 528         $r->print('</p>');
 529 }
 530
 531 sub print_fullscreen {
 532         my ($r, $event, $settings, $defsettings) = @_;
 533
 534         chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'fullscreen'));
 535
 536         my %newsettings = %$settings;
 537         $newsettings{'fullscreen'} = 1;
 538
 539         $r->print("    <p>");
 540         Sesse::pr0n::Common::print_link($r, $title, "/$event/", \%newsettings, $defsettings);
 541         $r->print("</p>\n");
 542 }
 543
 544 sub print_fullscreen_fromhere {
 545         my ($r, $event, $settings, $defsettings, $start) = @_;
 546
 547         chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'fullscreen-fromhere'));
 548
 549         my %newsettings = %$settings;
 550         $newsettings{'fullscreen'} = 1;
 551         $newsettings{'start'} = $start;
 552
 553         $r->print("    <p class=\"fsfromhere\">");
 554         Sesse::pr0n::Common::print_link($r, $title, "/$event/", \%newsettings, $defsettings);
 555         $r->print("</p>\n");
 556 }
 557
 558 1;
 559
 560