Tweak the CSS and stuff beyond repair.
[pr0n] / perl / Sesse / pr0n / Index.pm
1 package Sesse::pr0n::Index;
2 use strict;
3 use warnings;
4
5 use Sesse::pr0n::Common qw(error dberror);
6 use Apache2::Request;
7 use POSIX;
8
9 sub handler {
10         my $r = shift;
11         my $apr = Apache2::Request->new($r);
12         my $dbh = Sesse::pr0n::Common::get_dbh();
13
14         # Find the event
15         $r->uri =~ m#^/([a-zA-Z0-9-]+)/?$#
16                 or error($r, "Could not extract event");
17         my $event = $1;
18
19         # Fix common error: pr0n.sesse.net/event -> pr0n.sesse.net/event/
20         if ($r->uri !~ m#/$#) {
21                 $r->headers_out->{'location'} = "/$event/";
22                 return Apache2::Const::REDIRECT;
23         }
24
25         # Internal? (Ugly?) 
26         if ($r->get_server_name =~ /internal/ || $r->get_server_name =~ /skoyen\.bilder\.knatten\.com/) {
27                 my $user = Sesse::pr0n::Common::check_access($r);
28                 if (!defined($user)) {
29                         return Apache2::Const::OK;
30                 }
31         }
32
33         # Read the appropriate settings from the query string into the settings hash
34         my %defsettings = (
35                 thumbxres => 80,
36                 thumbyres => 64,
37                 xres => -1,
38                 yres => -1,
39                 start => 1,
40                 num => -1,
41                 all => 1,
42                 infobox => 1,
43                 rot => 0,
44                 sel => 0,
45                 fullscreen => 0,
46         );
47         
48         # Any NEF files => default to processing
49         my $ref = $dbh->selectrow_hashref('SELECT * FROM images WHERE event=? AND LOWER(filename) LIKE \'%.nef\' LIMIT 1',
50                 undef, $event)
51                 and $defsettings{'xres'} = $defsettings{'yres'} = undef;
52         
53         # Reduce the front page load when in overload mode.
54         if (Sesse::pr0n::Overload::is_in_overload($r)) {
55                 $defsettings{'num'} = 100;
56         }
57                 
58         my %settings = %defsettings;
59
60         for my $s qw(thumbxres thumbyres xres yres start num all infobox rot sel fullscreen) {
61                 my $val = $apr->param($s);
62                 if (defined($val) && $val =~ /^(\d+)$/) {
63                         $settings{$s} = $val;
64                 }
65                 if (($s eq "num" || $s eq "xres" || $s eq "yres") && defined($val) && $val == -1) {
66                         $settings{$s} = $val;
67                 }
68         }
69
70         my $thumbxres = $settings{'thumbxres'};
71         my $thumbyres = $settings{'thumbyres'};
72         my $xres = $settings{'xres'};
73         my $yres = $settings{'yres'};
74         my $start = $settings{'start'};
75         my $num = $settings{'num'};
76         my $all = $settings{'all'};
77         my $infobox = $settings{'infobox'} ? '' : 'nobox/';
78         my $rot = $settings{'rot'};
79         my $sel = $settings{'sel'};
80
81         if (defined($num) && $num == -1) {
82                 $num = undef;
83         }
84
85         $ref = $dbh->selectrow_hashref('SELECT name,date,EXTRACT(EPOCH FROM last_update) AS last_update FROM events WHERE id=? AND vhost=?',
86                 undef, $event, $r->get_server_name)
87                 or error($r, "Could not find event $event", 404, "File not found");
88
89         my $date = HTML::Entities::encode_entities(Encode::decode_utf8($ref->{'date'}));
90         my $name = HTML::Entities::encode_entities(Encode::decode_utf8($ref->{'name'}));
91         $r->set_last_modified($ref->{'last_update'});
92                                 
93         # If the client can use cache, do so
94         if ((my $rc = $r->meets_conditions) != Apache2::Const::OK) {
95                 return $rc;
96         }
97         
98         # Count the number of selected images.
99         $ref = $dbh->selectrow_hashref("SELECT COUNT(*) AS num_selected FROM images WHERE event=? AND selected=\'t\'", undef, $event);
100         my $num_selected = $ref->{'num_selected'};
101
102         # Find all images related to this event.
103         my $q;
104         my $where = ($all == 0) ? ' AND selected=\'t\'' : '';
105
106         if (defined($start) && defined($num) && !$settings{'fullscreen'}) {
107                 $q = $dbh->prepare("SELECT *, (date - INTERVAL '6 hours')::date AS day FROM images WHERE event=? $where ORDER BY (date - INTERVAL '6 hours')::date,takenby,date,filename LIMIT $num OFFSET " . ($start-1))
108                         or dberror($r, "prepare()");
109         } else {
110                 $q = $dbh->prepare("SELECT *, (date - INTERVAL '6 hours')::date AS day FROM images WHERE event=? $where ORDER BY (date - INTERVAL '6 hours')::date,takenby,date,filename")
111                         or dberror($r, "prepare()");
112         }
113         $q->execute($event)
114                 or dberror($r, "image enumeration");
115
116         # Print the page itself
117         if ($settings{'fullscreen'}) {
118                 $r->content_type("text/html; charset=utf-8");
119                 Sesse::pr0n::Templates::print_template($r, "fullscreen-header", { title => "$name [$event]" });
120                 while (my $ref = $q->fetchrow_hashref()) {
121                         $r->print("        \"" . $infobox . $ref->{'filename'} . "\",\n");
122                 }
123
124                 my %settings_no_fullscreen = %settings;
125                 $settings_no_fullscreen{'fullscreen'} = 0;
126
127                 my $returnurl = "http://" . $r->get_server_name . "/" . $event . "/" .
128                         Sesse::pr0n::Common::get_query_string(\%settings_no_fullscreen, \%defsettings);
129
130                 # *whistle*
131                 $returnurl =~ s/&/&/g;
132
133                 Sesse::pr0n::Templates::print_template($r, "fullscreen-footer", {
134                         vhost => $r->get_server_name,
135                         event => $event,
136                         start => $settings{'start'} - 1,
137                         returnurl => $returnurl,
138                         sel => $settings{'sel'},
139                 });
140         } else {
141                 Sesse::pr0n::Common::header($r, "$name [$event]");
142                 Sesse::pr0n::Templates::print_template($r, "date", { date => $date });
143
144                 if (Sesse::pr0n::Overload::is_in_overload($r)) {
145                         Sesse::pr0n::Templates::print_template($r, "overloadmode");
146                 }
147
148                 print_thumbsize($r, $event, \%settings, \%defsettings);
149                 print_viewres($r, $event, \%settings, \%defsettings);
150                 print_pagelimit($r, $event, \%settings, \%defsettings);
151                 print_infobox($r, $event, \%settings, \%defsettings);
152                 print_nextprev($r, $event, \%settings, \%defsettings);
153                 print_selected($r, $event, \%settings, \%defsettings) if ($num_selected > 0);
154                 print_fullscreen($r, $event, \%settings, \%defsettings);
155                 
156                 # Find the equipment used
157                 my $eq = $dbh->prepare('
158                         SELECT 
159                                 TRIM(model.value) AS model,
160                                 coalesce(TRIM(lens_spec.value), TRIM(lens.value)) AS lens,
161                                 COUNT(*) AS num
162                         FROM images i
163                                 LEFT JOIN exif_info model ON i.id=model.image
164                                 LEFT JOIN ( SELECT * FROM exif_info WHERE tag=\'Lens\' ) lens ON i.id=lens.image
165                                 LEFT JOIN ( SELECT * FROM exif_info WHERE tag=\'LensSpec\') lens_spec ON i.id=lens_spec.image
166                         WHERE event=? AND model.tag=\'Model\'
167                         GROUP BY 1,2
168                         ORDER BY 1,2')
169                         or die "Couldn't prepare to find equipment: $!";
170                 $eq->execute($event)
171                         or die "Couldn't find equipment: $!";
172
173                 my @equipment = ();
174                 my %cameras_seen = ();
175                 while (my $ref = $eq->fetchrow_hashref) {
176                         if (!defined($ref->{'lens'}) && exists($cameras_seen{$ref->{'model'}})) {
177                                 #
178                                 # Some compact cameras seem to add lens info sometimes and not at other
179                                 # times; if we have seen a camera with at least one specific lens earlier,
180                                 # just combine entries without a lens with the previous one.
181                                 #
182                                 $equipment[$#equipment]->{'num'} += $ref->{'num'};
183                                 next;
184                         }
185                         push @equipment, $ref;
186                         $cameras_seen{$ref->{'model'}} = 1;
187                 }
188                 $eq->finish;
189
190                 if (scalar @equipment > 0) {
191                         Sesse::pr0n::Templates::print_template($r, "equipment-start");
192                         for my $e (@equipment) {
193                                 my $eqspec = $e->{'model'};
194                                 $eqspec .= ', ' . $e->{'lens'} if (defined($e->{'lens'}));
195
196                                 # This isn't correct for all languages. Fix if we ever need to care. :-)
197                                 if ($e->{'num'} == 1) {
198                                         Sesse::pr0n::Templates::print_template($r, "equipment-item-singular", { eqspec => $eqspec });
199                                 } else {
200                                         Sesse::pr0n::Templates::print_template($r, "equipment-item", { eqspec => $eqspec, num => $e->{'num'} });
201                                 }
202                         }
203                         Sesse::pr0n::Templates::print_template($r, "equipment-end");
204                 }
205
206
207                 my $toclose = 0;
208                 my $lastupl = "";
209                 my $img_num = $start;
210                 
211                 # Print out all thumbnails
212                 if ($rot == 1) {
213                         $r->print("    <form method=\"post\" action=\"/rotate\">\n");
214                         $r->print("      <input type=\"hidden\" name=\"event\" value=\"$event\" />\n");
215         
216                         while (my $ref = $q->fetchrow_hashref()) {
217                                 my $imgsz = "";
218                                 my $takenby = $ref->{'takenby'};
219                                 if (defined($ref->{'day'})) {
220                                          $takenby .= ", " . $ref->{'day'};
221                                 }
222
223                                 if ($takenby ne $lastupl) {
224                                         $lastupl = $takenby;
225                                         $r->print("    <h2>");
226                                         Sesse::pr0n::Templates::print_template($r, "submittedby", { author => $lastupl });
227                                         print_fullscreen_fromhere($r, $event, \%settings, \%defsettings, $img_num);
228                                         $r->print("</h2>\n");
229                                 }
230                                 if ($ref->{'width'} != -1 && $ref->{'height'} != -1) {
231                                         my $width = $ref->{'width'};
232                                         my $height = $ref->{'height'};
233                                                 
234                                         ($width, $height) = Sesse::pr0n::Common::scale_aspect($width, $height, $thumbxres, $thumbyres);
235                                         $imgsz = " width=\"$width\" height=\"$height\"";
236                                 }
237
238                                 my $filename = $ref->{'filename'};
239                                 my $uri = $infobox . $filename;
240                                 if (defined($xres) && defined($yres) && $xres != -1) {
241                                         $uri = "${xres}x$yres/$infobox$filename";
242                                 } elsif (defined($xres) && $xres == -1) {
243                                         $uri = "original/$infobox$filename";
244                                 }
245
246                                 $r->print("    <p><a href=\"$uri\"><img src=\"${thumbxres}x${thumbyres}/$filename\" alt=\"\"$imgsz /></a>\n");
247                                 $r->print("      90 <input type=\"checkbox\" name=\"rot-" .
248                                         $ref->{'id'} . "-90\" />\n");
249                                 $r->print("      180 <input type=\"checkbox\" name=\"rot-" .
250                                         $ref->{'id'} . "-180\" />\n");
251                                 $r->print("      270 <input type=\"checkbox\" name=\"rot-" .
252                                         $ref->{'id'} . "-270\" />\n");
253                                 $r->print("      &nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;" .
254                                         "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;Del <input type=\"checkbox\" name=\"del-" . $ref->{'id'} . "\" /></p>\n");
255                         
256                                 ++$img_num;
257                         }
258                         $r->print("      <input type=\"submit\" value=\"Rotate\" />\n");
259                         $r->print("    </form>\n");
260                 } elsif ($sel == 1) {
261                         $r->print("    <form method=\"post\" action=\"/select\">\n");
262                         $r->print("      <input type=\"hidden\" name=\"event\" value=\"$event\" />\n");
263                         
264                         while (my $ref = $q->fetchrow_hashref()) {
265                                 my $imgsz = "";
266                                 my $takenby = $ref->{'takenby'};
267                                 if (defined($ref->{'day'})) {
268                                          $takenby .= ", " . $ref->{'day'};
269                                 }
270
271                                 if ($takenby ne $lastupl) {
272                                         $lastupl = $takenby;
273                                         $r->print("    <h2>");
274                                         Sesse::pr0n::Templates::print_template($r, "submittedby", { author => $lastupl });
275                                         print_fullscreen_fromhere($r, $event, \%settings, \%defsettings, $img_num);
276                                         $r->print("</h2>\n");
277                                 }
278                                 if ($ref->{'width'} != -1 && $ref->{'height'} != -1) {
279                                         my $width = $ref->{'width'};
280                                         my $height = $ref->{'height'};
281                                                 
282                                         ($width, $height) = Sesse::pr0n::Common::scale_aspect($width, $height, $thumbxres, $thumbyres);
283                                         $imgsz = " width=\"$width\" height=\"$height\"";
284                                 }
285
286                                 my $filename = $ref->{'filename'};
287                                 my $uri = $infobox . $filename;
288                                 if (defined($xres) && defined($yres) && $xres != -1) {
289                                         $uri = "${xres}x$yres/$infobox$filename";
290                                 } elsif (defined($xres) && $xres == -1) {
291                                         $uri = "original/$infobox$filename";
292                                 }
293
294                                 my $selected = $ref->{'selected'} ? ' checked="checked"' : '';
295
296                                 $r->print("    <p><a href=\"$uri\"><img src=\"${thumbxres}x${thumbyres}/$filename\" alt=\"\"$imgsz /></a>\n");
297                                 $r->print("      <input type=\"checkbox\" name=\"sel-" .
298                                         $ref->{'id'} . "\"$selected /></p>\n");
299
300                                 ++$img_num;
301                         }
302                         $r->print("      <input type=\"submit\" value=\"Select\" />\n");
303                         $r->print("    </form>\n");
304                 } else {
305                         while (my $ref = $q->fetchrow_hashref()) {
306                                 my $imgsz = "";
307                                 my $takenby = $ref->{'takenby'};
308                                 if (defined($ref->{'day'})) {
309                                          $takenby .= ", " . $ref->{'day'};
310                                 }
311
312                                 if ($takenby ne $lastupl) {
313                                         $r->print("    </p>\n\n") if ($lastupl ne "");
314                                         $lastupl = $takenby;
315                                         $r->print("    <h2>");
316                                         Sesse::pr0n::Templates::print_template($r, "submittedby", { author => $lastupl });
317                                         print_fullscreen_fromhere($r, $event, \%settings, \%defsettings, $img_num);
318                                         $r->print("</h2>\n");
319                                         $r->print("    <p class=\"photos\">\n");
320                                 }
321                                 if ($ref->{'width'} != -1 && $ref->{'height'} != -1) {
322                                         my $width = $ref->{'width'};
323                                         my $height = $ref->{'height'};
324                                                 
325                                         ($width, $height) = Sesse::pr0n::Common::scale_aspect($width, $height, $thumbxres, $thumbyres);
326                                         $imgsz = " width=\"$width\" height=\"$height\"";
327                                 }
328
329                                 my $filename = $ref->{'filename'};
330                                 my $uri = $infobox . $filename;
331                                 if (defined($xres) && defined($yres) && $xres != -1) {
332                                         $uri = "${xres}x$yres/$infobox$filename";
333                                 } elsif (defined($xres) && $xres == -1) {
334                                         $uri = "original/$infobox$filename";
335                                 }
336                                 
337                                 $r->print("      <a href=\"$uri\"><img src=\"${thumbxres}x${thumbyres}/$filename\" alt=\"\"$imgsz /></a>\n");
338                                 
339                                 ++$img_num;
340                         }
341                         $r->print("    </p>\n");
342                 }
343
344                 print_nextprev($r, $event, \%settings, \%defsettings);
345                 Sesse::pr0n::Common::footer($r);
346         }
347
348         return Apache2::Const::OK;
349 }
350
351 sub eq_with_undef {
352         my ($a, $b) = @_;
353         
354         return 1 if (!defined($a) && !defined($b));
355         return 0 unless (defined($a) && defined($b));
356         return ($a eq $b);
357 }
358
359 sub print_changes {
360         my ($r, $event, $template, $settings, $defsettings, $var1, $var2, $alternatives) = @_;
361
362         my $title = Sesse::pr0n::Templates::fetch_template($r, $template);
363         chomp $title;
364         $r->print("    <p>$title:\n");
365
366         for my $a (@$alternatives) {
367                 my $text;
368                 my %newsettings = %$settings;
369
370                 if (ref $a) {
371                         my ($v1, $v2);
372                         ($text, $v1, $v2) = @$a;
373                         
374                         $newsettings{$var1} = $v1;
375                         $newsettings{$var2} = $v2;
376                 } else {
377                         $text = $a;
378
379                         # Parse the current alternative
380                         my ($v1, $v2) = split /x/, $a;
381
382                         $newsettings{$var1} = $v1;
383                         $newsettings{$var2} = $v2;
384                 }
385
386                 $r->print("      ");
387
388                 # Check if these settings are current (print only label)
389                 if (eq_with_undef($settings->{$var1}, $newsettings{$var1}) &&
390                     eq_with_undef($settings->{$var2}, $newsettings{$var2})) {
391                         $r->print($text);
392                 } else {
393                         Sesse::pr0n::Common::print_link($r, $text, "/$event/", \%newsettings, $defsettings);
394                 }
395                 $r->print("\n");
396         }
397         $r->print("    </p>\n");
398 }
399
400 sub print_thumbsize {
401         my ($r, $event, $settings, $defsettings) = @_;
402         my @alternatives = qw(80x64 120x96 160x128 240x192 320x256);
403
404         print_changes($r, $event, 'thumbsize', $settings, $defsettings,
405                       'thumbxres', 'thumbyres', \@alternatives);
406 }
407 sub print_viewres {
408         my ($r, $event, $settings, $defsettings) = @_;
409         my @alternatives = qw(320x256 512x384 640x480 800x600 1024x768 1280x960);
410         chomp (my $unlimited = Sesse::pr0n::Templates::fetch_template($r, 'viewres-unlimited'));
411         chomp (my $original = Sesse::pr0n::Templates::fetch_template($r, 'viewres-original'));
412         push @alternatives, [ $unlimited, undef, undef ];
413         push @alternatives, [ $original, -1, -1 ];
414
415         print_changes($r, $event, 'viewres', $settings, $defsettings,
416                       'xres', 'yres', \@alternatives);
417 }
418
419 sub print_pagelimit {
420         my ($r, $event, $settings, $defsettings) = @_;
421         
422         my $title = Sesse::pr0n::Templates::fetch_template($r, 'imgsperpage');
423         chomp $title;
424         $r->print("    <p>$title:\n");
425         
426         # Get choices
427         chomp (my $unlimited = Sesse::pr0n::Templates::fetch_template($r, 'imgsperpage-unlimited'));
428         my @alternatives = qw(10 50 100 500);
429         push @alternatives, $unlimited;
430         
431         for my $num (@alternatives) {
432                 my %newsettings = %$settings;
433
434                 if ($num !~ /^\d+$/) { # unlimited
435                         $newsettings{'num'} = -1;
436                 } else {
437                         $newsettings{'num'} = $num;
438                 }
439
440                 $r->print("      ");
441                 if (eq_with_undef($settings->{'num'}, $newsettings{'num'})) {
442                         $r->print($num);
443                 } else {
444                         Sesse::pr0n::Common::print_link($r, $num, "/$event/", \%newsettings, $defsettings);
445                 }
446                 $r->print("\n");
447         }
448         $r->print("    </p>\n");
449 }
450
451 sub print_infobox {
452         my ($r, $event, $settings, $defsettings) = @_;
453
454         chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'infobox'));
455         chomp (my $on = Sesse::pr0n::Templates::fetch_template($r, 'infobox-on'));
456         chomp (my $off = Sesse::pr0n::Templates::fetch_template($r, 'infobox-off'));
457
458         $r->print("    <p>$title:\n");
459
460         my %newsettings = %$settings;
461
462         if ($settings->{'infobox'} == 1) {
463                 $r->print($on);
464         } else {
465                 $newsettings{'infobox'} = 1;
466                 Sesse::pr0n::Common::print_link($r, $on, "/$event/", \%newsettings, $defsettings);
467         }
468
469         $r->print(' ');
470
471         if ($settings->{'infobox'} == 0) {
472                 $r->print($off);
473         } else {
474                 $newsettings{'infobox'} = 0;
475                 Sesse::pr0n::Common::print_link($r, $off, "/$event/", \%newsettings, $defsettings);
476         }
477         
478         $r->print('</p>');
479 }
480
481 sub print_nextprev {
482         my ($r, $event, $settings, $defsettings) = @_;
483         my $start = $settings->{'start'};
484         my $num = $settings->{'num'};
485         my $dbh = Sesse::pr0n::Common::get_dbh();
486
487         $num = undef if (defined($num) && $num == -1);
488         return unless (defined($start) && defined($num));
489
490         # determine total number
491         my $ref = $dbh->selectrow_hashref('SELECT count(*) AS num_images FROM images WHERE event=?',
492                 undef, $event)
493                 or dberror($r, "image enumeration");
494         my $num_images = $ref->{'num_images'};
495
496         return if ($start == 1 && $start + $num >= $num_images);
497
498         my $end = $start + $num - 1;
499         if ($end > $num_images) {
500                 $end = $num_images;
501         }
502
503         $r->print("    <p>\n");
504
505         # Previous
506         if ($start > 1) {
507                 my $newstart = $start - $num;
508                 if ($newstart < 1) {
509                         $newstart = 1;
510                 }
511                 my $newend = $newstart + $num - 1;
512                 if ($newend > $num_images) {
513                         $newend = $num_images;
514                 }
515
516                 my %newsettings = %$settings;
517                 $newsettings{'start'} = $newstart;
518                 chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'prevpage'));
519                 chomp (my $accesskey = Sesse::pr0n::Templates::fetch_template($r, 'prevaccesskey'));
520                 Sesse::pr0n::Common::print_link($r, "$title ($newstart-$newend)\n", "/$event/", \%newsettings, $defsettings, $accesskey);
521         }
522
523         # This
524         chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'thispage'));
525         $r->print("    $title ($start-$end)\n");
526
527         # Next
528         if ($end < $num_images) {
529                 my $newstart = $start + $num;
530                 my $newend = $newstart + $num - 1;
531                 if ($newend > $num_images) {
532                         $newend = $num_images;
533                 }
534                 
535                 my %newsettings = %$settings;
536                 $newsettings{'start'} = $newstart;
537                 chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'nextpage'));
538                 chomp (my $accesskey = Sesse::pr0n::Templates::fetch_template($r, 'nextaccesskey'));
539                 Sesse::pr0n::Common::print_link($r, "$title ($newstart-$newend)", "/$event/", \%newsettings, $defsettings, $accesskey);
540         }
541
542         $r->print("    </p>\n");
543 }
544
545 sub print_selected {
546         my ($r, $event, $settings, $defsettings) = @_;
547
548         chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'show'));
549         chomp (my $all = Sesse::pr0n::Templates::fetch_template($r, 'show-all'));
550         chomp (my $sel = Sesse::pr0n::Templates::fetch_template($r, 'show-selected'));
551
552         $r->print("    <p>$title:\n");
553
554         my %newsettings = %$settings;
555
556         if ($settings->{'all'} == 0) {
557                 $r->print($sel);
558         } else {
559                 $newsettings{'all'} = 0;
560                 Sesse::pr0n::Common::print_link($r, $sel, "/$event/", \%newsettings, $defsettings);
561         }
562
563         $r->print(' ');
564
565         if ($settings->{'all'} == 1) {
566                 $r->print($all);
567         } else {
568                 $newsettings{'all'} = 1;
569                 Sesse::pr0n::Common::print_link($r, $all, "/$event/", \%newsettings, $defsettings);
570         }
571         
572         $r->print('</p>');
573 }
574
575 sub print_fullscreen {
576         my ($r, $event, $settings, $defsettings) = @_;
577
578         chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'fullscreen'));
579
580         my %newsettings = %$settings;
581         $newsettings{'fullscreen'} = 1;
582
583         $r->print("    <p>");
584         Sesse::pr0n::Common::print_link($r, $title, "/$event/", \%newsettings, $defsettings);
585         $r->print("</p>\n");
586 }
587
588 sub print_fullscreen_fromhere {
589         my ($r, $event, $settings, $defsettings, $start) = @_;
590
591         chomp (my $title = Sesse::pr0n::Templates::fetch_template($r, 'fullscreen-fromhere'));
592
593         my %newsettings = %$settings;
594         $newsettings{'fullscreen'} = 1;
595         $newsettings{'start'} = $start;
596
597         $r->print("    <p class=\"fsfromhere\">");
598         Sesse::pr0n::Common::print_link($r, $title, "/$event/", \%newsettings, $defsettings);
599         $r->print("</p>\n");
600 }
601         
602 1;
603
604