git.sesse.net Git - pr0n/blob - perl/Sesse/pr0n/WebDAV.pm

   1 package Sesse::pr0n::WebDAV;
   2 use strict;
   3 use warnings;
   4
   5 use Sesse::pr0n::Common qw(error dberror);
   6 use Digest::SHA1;
   7 use MIME::Base64;
   8 use Apache2::Request;
   9 use Apache2::Upload;
  10
  11 sub handler {
  12         my $r = shift;
  13         my $dbh = Sesse::pr0n::Common::get_dbh();
  14
  15         $r->headers_out->{'DAV'} = "1,2";
  16
  17         # We only handle depth=0, depth=1 (cf. the RFC)
  18         my $depth = $r->headers_in->{'depth'};
  19         $depth = 0 if (!defined($depth));
  20         if (defined($depth) && $depth ne "0" && $depth ne "1") {
  21                 $r->content_type('text/plain; charset="utf-8"');
  22                 $r->status(403);
  23                 $r->print("Invalid depth setting");
  24                 return Apache2::Const::OK;
  25         }
  26
  27         my ($user,$takenby) = Sesse::pr0n::Common::check_access($r);
  28         if (!defined($user)) {
  29                 return Apache2::Const::OK;
  30         }
  31
  32         # Just "ping, are you alive and do you speak WebDAV"
  33         if ($r->method eq "OPTIONS") {
  34                 $r->content_type('text/plain; charset="utf-8"');
  35                 $r->status(200);
  36                 $r->headers_out->{'allow'} = 'OPTIONS,PUT';
  37                 $r->headers_out->{'ms-author-via'} = 'DAV';
  38                 return Apache2::Const::OK;
  39         }
  40
  41         # Directory listings et al
  42         if ($r->method eq "PROPFIND") {
  43                 # We ignore the body, but we _must_ consume it fully before
  44                 # we output anything, or Squid will get seriously confused
  45                 $r->discard_request_body;
  46
  47                 $r->content_type('text/xml; charset="utf-8"');
  48                 $r->status(207);
  49
  50                 if ($r->uri =~ m#^/webdav/?$#) {
  51                         $r->headers_out->{'content-location'} = "/webdav/";
  52
  53                         # Root directory
  54                         $r->print(<<"EOF");
  55 <?xml version="1.0" encoding="utf-8"?>
  56 <multistatus xmlns="DAV:">
  57   <response>
  58      <href>/webdav/</href>
  59      <propstat>
  60         <prop>
  61           <resourcetype><collection/></resourcetype>
  62           <getcontenttype>text/xml</getcontenttype>
  63         </prop>
  64         <status>HTTP/1.1 200 OK</status>
  65      </propstat>
  66   </response>
  67 EOF
  68
  69                         # Optionally list the upload/ dir
  70                         if ($depth >= 1) {
  71                                 $r->print(<<"EOF");
  72   <response>
  73      <href>/webdav/upload/</href>
  74      <propstat>
  75         <prop>
  76           <resourcetype><collection/></resourcetype>
  77           <getcontenttype>text/xml</getcontenttype>
  78         </prop>
  79         <status>HTTP/1.1 200 OK</status>
  80      </propstat>
  81   </response>
  82 EOF
  83                         }
  84                         $r->print("</multistatus>\n");
  85                  } elsif ($r->uri =~ m#^/webdav/upload/?$#) {
  86                         $r->headers_out->{'content-location'} = "/webdav/upload/";
  87
  88                         # Upload root directory
  89                         $r->print(<<"EOF");
  90 <?xml version="1.0" encoding="utf-8"?>
  91 <multistatus xmlns="DAV:">
  92   <response>
  93      <href>/webdav/upload/</href>
  94      <propstat>
  95         <prop>
  96           <resourcetype><collection/></resourcetype>
  97           <getcontenttype>text/xml</getcontenttype>
  98         </prop>
  99         <status>HTTP/1.1 200 OK</status>
 100      </propstat>
 101   </response>
 102 EOF
 103
 104                         # Optionally list all events
 105                         if ($depth >= 1) {
 106                                 my $q = $dbh->prepare('SELECT * FROM events WHERE vhost=?') or
 107                                         dberror($r, "Couldn't list events");
 108                                 $q->execute($r->get_server_name) or
 109                                         dberror($r, "Couldn't get events");
 110
 111                                 while (my $ref = $q->fetchrow_hashref()) {
 112                                         my $id = $ref->{'event'};
 113                                         my $name = $ref->{'name'};
 114
 115                                         $name =~ s/&/\&amp;/g;  # hack :-)
 116                                         $r->print(<<"EOF");
 117   <response>
 118      <href>/webdav/upload/$id/</href>
 119      <propstat>
 120         <prop>
 121           <resourcetype><collection/></resourcetype>
 122           <getcontenttype>text/xml</getcontenttype>
 123           <displayname>$name</displayname>
 124         </prop>
 125         <status>HTTP/1.1 200 OK</status>
 126      </propstat>
 127   </response>
 128 EOF
 129                                 }
 130                                 $q->finish;
 131                         }
 132
 133                         $r->print("</multistatus>\n");
 134                 } elsif ($r->uri =~ m#^/webdav/upload/([a-zA-Z0-9-]+)/?$#) {
 135                         my $event = $1;
 136
 137                         $r->headers_out->{'content-location'} = "/webdav/upload/$event/";
 138
 139                         # Check that we do indeed exist
 140                         my $ref = $dbh->selectrow_hashref('SELECT count(*) AS numev FROM events WHERE vhost=? AND event=?',
 141                                 undef, $r->get_server_name, $event);
 142                         if ($ref->{'numev'} != 1) {
 143                                 $r->status(404);
 144                                 $r->content_type('text/plain; charset=utf-8');
 145                                 $r->print("Couldn't find event in database");
 146                                 return Apache2::Const::OK;
 147                         }
 148
 149                         # OK, list the directory
 150                         $r->print(<<"EOF");
 151 <?xml version="1.0" encoding="utf-8"?>
 152 <multistatus xmlns="DAV:">
 153   <response>
 154      <href>/webdav/upload/$event/</href>
 155      <propstat>
 156         <prop>
 157           <resourcetype><collection/></resourcetype>
 158           <getcontenttype>text/xml</getcontenttype>
 159         </prop>
 160         <status>HTTP/1.1 200 OK</status>
 161      </propstat>
 162   </response>
 163 EOF
 164
 165                         # List all the files within too, of course :-)
 166                         if ($depth >= 1) {
 167                                 my $q = $dbh->prepare('SELECT * FROM images WHERE vhost=? AND event=?') or
 168                                         dberror($r, "Couldn't list images");
 169                                 $q->execute($r->get_server_name, $event) or
 170                                         dberror($r, "Couldn't get events");
 171
 172                                 while (my $ref = $q->fetchrow_hashref()) {
 173                                         my $id = $ref->{'id'};
 174                                         my $filename = $ref->{'filename'};
 175                                         my $fname = Sesse::pr0n::Common::get_disk_location($r, $id);
 176                                         my (undef, undef, undef, undef, undef, undef, undef, $size, undef, $mtime) = stat($fname)
 177                                                 or next;
 178                                         $mtime = POSIX::strftime("%a, %d %b %Y %H:%M:%S GMT", gmtime($mtime));
 179                                         my $mime_type = Sesse::pr0n::Common::get_mimetype_from_filename($filename);
 180
 181                                         $r->print(<<"EOF");
 182   <response>
 183      <href>/webdav/upload/$event/$filename</href>
 184      <propstat>
 185         <prop>
 186           <resourcetype/>
 187           <getcontenttype>$mime_type</getcontenttype>
 188           <getcontentlength>$size</getcontentlength>
 189           <getlastmodified>$mtime</getlastmodified>
 190         </prop>
 191         <status>HTTP/1.1 200 OK</status>
 192      </propstat>
 193   </response>
 194 EOF
 195                                 }
 196                                 $q->finish;
 197
 198                                 # And the magical autorename folder
 199                                 $r->print(<<"EOF");
 200   <response>
 201      <href>/webdav/upload/$event/autorename/</href>
 202      <propstat>
 203         <prop>
 204           <resourcetype><collection/></resourcetype>
 205           <getcontenttype>text/xml</getcontenttype>
 206         </prop>
 207         <status>HTTP/1.1 200 OK</status>
 208      </propstat>
 209   </response>
 210 EOF
 211                         }
 212
 213                         $r->print("</multistatus>\n");
 214
 215                         return Apache2::Const::OK;
 216                 } elsif ($r->uri =~ m#^/webdav/upload/([a-zA-Z0-9-]+)/autorename/?$#) {
 217                         # The autorename folder is always empty
 218                         my $event = $1;
 219
 220                         $r->headers_out->{'content-location'} = "/webdav/upload/$event/autorename/";
 221
 222                         # Check that we do indeed exist
 223                         my $ref = $dbh->selectrow_hashref('SELECT count(*) AS numev FROM events WHERE vhost=? AND event=?',
 224                                 undef, $r->get_server_name, $event);
 225                         if ($ref->{'numev'} != 1) {
 226                                 $r->status(404);
 227                                 $r->content_type('text/plain; charset=utf-8');
 228                                 $r->print("Couldn't find event in database");
 229                                 return Apache2::Const::OK;
 230                         }
 231
 232                         # OK, list the (empty) directory
 233                         $r->print(<<"EOF");
 234 <?xml version="1.0" encoding="utf-8"?>
 235 <multistatus xmlns="DAV:">
 236   <response>
 237      <href>/webdav/upload/$event/autorename/</href>
 238      <propstat>
 239         <prop>
 240           <resourcetype><collection/></resourcetype>
 241           <getcontenttype>text/xml</getcontenttype>
 242         </prop>
 243         <status>HTTP/1.1 200 OK</status>
 244      </propstat>
 245   </response>
 246 </multistatus>
 247 EOF
 248
 249                         return Apache2::Const::OK;
 250                 } elsif ($r->uri =~ m#^/webdav/upload/([a-zA-Z0-9-]+)/([a-zA-Z0-9._()-]+)$#) {
 251                         # stat a single file
 252                         my ($event, $filename) = ($1, $2);
 253                         my ($fname, $size, $mtime);
 254
 255                         # check if we have a pending fake file for this
 256                         my $ref = $dbh->selectrow_hashref('SELECT count(*) AS numfiles FROM fake_files WHERE event=? AND vhost=? AND filename=? AND expires_at > now()',
 257                                 undef, $event, $r->get_server_name, $filename);
 258                         if ($ref->{'numfiles'} == 1) {
 259                                 $fname = "/dev/null";
 260                                 $size = 0;
 261                                 $mtime = time;
 262                         } else {
 263                                 ($fname, $size, $mtime) = Sesse::pr0n::Common::stat_image($r, $event, $filename);
 264                         }
 265
 266                         if (!defined($fname)) {
 267                                 $r->status(404);
 268                                 $r->content_type('text/plain; charset=utf-8');
 269                                 $r->print("Couldn't find file");
 270                                 return Apache2::Const::OK;
 271                         }
 272                         my $mime_type = Sesse::pr0n::Common::get_mimetype_from_filename($filename);
 273
 274                         $mtime = POSIX::strftime("%a, %d %b %Y %H:%M:%S GMT", gmtime($mtime));
 275                         $r->print(<<"EOF");
 276 <?xml version="1.0" encoding="utf-8"?>
 277 <multistatus xmlns="DAV:">
 278   <response>
 279     <href>/webdav/upload/$event/$filename</href>
 280     <propstat>
 281       <prop>
 282         <resourcetype/>
 283         <getcontenttype>$mime_type</getcontenttype>
 284         <getcontentlength>$size</getcontentlength>
 285         <getlastmodified>$mtime</getlastmodified>
 286       </prop>
 287       <status>HTTP/1.1 200 OK</status>
 288     </propstat>
 289   </response>
 290 </multistatus>
 291 EOF
 292                         return Apache2::Const::OK;
 293                 } elsif ($r->uri =~ m#^/webdav/upload/([a-zA-Z0-9-]+)/autorename/(.{1,250})$#) {
 294                         # stat a single file in autorename
 295                         my ($event, $filename) = ($1, $2);
 296                         my ($fname, $size, $mtime);
 297
 298                         # check if we have a pending fake file for this
 299                         my $ref = $dbh->selectrow_hashref('SELECT count(*) AS numfiles FROM fake_files WHERE event=? AND vhost=? AND filename=? AND expires_at > now()',
 300                                 undef, $event, $r->get_server_name, $filename);
 301                         if ($ref->{'numfiles'} == 1) {
 302                                 $fname = "/dev/null";
 303                                 $size = 0;
 304                                 $mtime = time;
 305                         } else {
 306                                 # check if we have a "shadow file" for this
 307                                 my $ref = $dbh->selectrow_hashref('SELECT id FROM shadow_files WHERE vhost=? AND event=? AND filename=? AND expires_at > now()',
 308                                         undef, $r->get_server_name, $event, $filename);
 309                                 if (defined($ref)) {
 310                                         ($fname, $size, $mtime) = Sesse::pr0n::Common::stat_image_from_id($r, $ref->{'id'});
 311                                 }
 312                         }
 313
 314                         if (!defined($fname)) {
 315                                 $r->status(404);
 316                                 $r->content_type('text/plain; charset=utf-8');
 317                                 $r->print("Couldn't find file");
 318                                 return Apache2::Const::OK;
 319                         }
 320                         my $mime_type = Sesse::pr0n::Common::get_mimetype_from_filename($filename);
 321
 322                         $mtime = POSIX::strftime("%a, %d %b %Y %H:%M:%S GMT", gmtime($mtime));
 323                         $r->print(<<"EOF");
 324 <?xml version="1.0" encoding="utf-8"?>
 325 <multistatus xmlns="DAV:">
 326   <response>
 327     <href>/webdav/upload/$event/autorename/$filename</href>
 328     <propstat>
 329       <prop>
 330         <resourcetype/>
 331         <getcontenttype>$mime_type</getcontenttype>
 332         <getcontentlength>$size</getcontentlength>
 333         <getlastmodified>$mtime</getlastmodified>
 334       </prop>
 335       <status>HTTP/1.1 200 OK</status>
 336     </propstat>
 337   </response>
 338 </multistatus>
 339 EOF
 340                 } else {
 341                         $r->status(404);
 342                         $r->content_type('text/plain; charset=utf-8');
 343                         $r->print("Couldn't find file");
 344                 }
 345                 return Apache2::Const::OK;
 346         }
 347
 348         if ($r->method eq "HEAD" or $r->method eq "GET") {
 349                 if ($r->uri !~ m#^/webdav/upload/([a-zA-Z0-9-]+)/(autorename/)?(.{1,250})$#) {
 350                         $r->status(404);
 351                         $r->content_type('text/xml; charset=utf-8');
 352                         $r->print("<?xml version=\"1.0\"?>\n<p>Couldn't find file</p>");
 353                         return Apache2::Const::OK;
 354                 }
 355
 356                 my ($event, $autorename, $filename) = ($1, $2, $3);
 357
 358                 # Check if this file really exists
 359                 my ($fname, $size, $mtime);
 360
 361                 # check if we have a pending fake file for this
 362                 my $ref = $dbh->selectrow_hashref('SELECT count(*) AS numfiles FROM fake_files WHERE event=? AND vhost=? AND filename=? AND expires_at > now()',
 363                         undef, $event, $r->get_server_name, $filename);
 364                 if ($ref->{'numfiles'} == 1) {
 365                         $fname = "/dev/null";
 366                         $size = 0;
 367                         $mtime = time;
 368                 } else {
 369                         # check if we have a "shadow file" for this
 370                         if (defined($autorename) && $autorename eq "autorename/") {
 371                                 my $ref = $dbh->selectrow_hashref('SELECT id FROM shadow_files WHERE host=? AND event=? AND filename=? AND expires_at > now()',
 372                                         undef, $r->get_server_name, $event, $filename);
 373                                 if (defined($ref)) {
 374                                         ($fname, $size, $mtime) = Sesse::pr0n::Common::stat_image_from_id($r, $ref->{'id'});
 375                                 }
 376                         } elsif (!defined($fname)) {
 377                                 ($fname, $size, $mtime) = Sesse::pr0n::Common::stat_image($r, $event, $filename);
 378                         }
 379                 }
 380
 381                 if (!defined($fname)) {
 382                         $r->status(404);
 383                         $r->content_type('text/plain; charset=utf-8');
 384                         $r->print("Couldn't find file");
 385                         return Apache2::Const::OK;
 386                 }
 387
 388                 $r->status(200);
 389                 $r->set_content_length($size);
 390                 $r->set_last_modified($mtime);
 391
 392                 if ($r->method eq "GET") {
 393                         $r->sendfile($fname);
 394                 }
 395                 return Apache2::Const::OK;
 396         }
 397
 398         if ($r->method eq "PUT") {
 399                 if ($r->uri !~ m#^/webdav/upload/([a-zA-Z0-9-]+)/(autorename/)?(.{1,250})$#) {
 400                         $r->status(403);
 401                         $r->content_type('text/plain; charset=utf-8');
 402                         $r->print("No access");
 403                         return Apache2::Const::OK;
 404                 }
 405
 406                 my ($event, $autorename, $filename) = ($1, $2, $3);
 407                 my $size = $r->headers_in->{'content-length'};
 408                 my $orig_filename = $filename;
 409
 410                 # Remove evil characters
 411                 if ($filename =~ /[^a-zA-Z0-9._()-]/) {
 412                         if (defined($autorename) && $autorename eq "autorename/") {
 413                                 $filename =~ tr/a-zA-Z0-9.()-/_/c;
 414                         } else {
 415                                 $r->status(403);
 416                                 $r->content_type('text/plain; charset=utf-8');
 417                                 $r->print("Illegal characters in filename");
 418                                 return Apache2::Const::OK;
 419                         }
 420                 }
 421
 422                 #
 423                 # gnome-vfs and mac os x love to make zero-byte files,
 424                 # make them happy
 425                 #
 426                 if ($r->headers_in->{'content-length'} == 0) {
 427                         $dbh->do('DELETE FROM fake_files WHERE expires_at <= now() OR (event=? AND vhost=? AND filename=?);',
 428                                 undef, $event, $r->get_server_name, $filename)
 429                                 or dberror($r, "Couldn't prune fake_files");
 430                         $dbh->do('INSERT INTO fake_files (vhost,event,filename,expires_at) VALUES (?,?,?,now() + interval \'30 seconds\');',
 431                                 undef, $r->get_server_name, $event, $filename)
 432                                 or dberror($r, "Couldn't add file");
 433                         $r->content_type('text/plain; charset="utf-8"');
 434                         $r->status(201);
 435                         $r->print("OK");
 436                         $r->log->info("Fake upload of $event/$filename");
 437                         return Apache2::Const::OK;
 438                 }
 439
 440                 # Get the new ID
 441                 my $ref = $dbh->selectrow_hashref("SELECT NEXTVAL('imageid_seq') AS id;");
 442                 my $newid = $ref->{'id'};
 443                 if (!defined($newid)) {
 444                         dberror($r, "Couldn't get new ID");
 445                 }
 446
 447                 # Autorename if we need to
 448                 if (defined($autorename) && $autorename eq "autorename/") {
 449                         my $ref = $dbh->selectrow_hashref("SELECT COUNT(*) AS numfiles FROM images WHERE vhost=? AND event=? AND filename=?",
 450                                 undef, $r->get_server_name, $event, $filename)
 451                                 or dberror($r, "Couldn't check for existing files");
 452                         if ($ref->{'numfiles'} > 0) {
 453                                 $r->log->info("Renaming $filename to $newid.jpeg");
 454                                 $filename = "$newid.jpeg";
 455                         }
 456                 }
 457
 458                 {
 459                         # Enable transactions and error raising temporarily
 460                         local $dbh->{AutoCommit} = 0;
 461                         local $dbh->{RaiseError} = 1;
 462                         my $fname;
 463
 464                         # Try to insert this new file
 465                         eval {
 466                                 $dbh->do('DELETE FROM fake_files WHERE vhost=? AND event=? AND filename=?',
 467                                         undef, $r->get_server_name, $event, $filename);
 468
 469                                 $dbh->do('INSERT INTO images (id,vhost,event,uploadedby,takenby,filename) VALUES (?,?,?,?,?,?)',
 470                                         undef, $newid, $r->get_server_name, $event, $user, $takenby, $filename);
 471                                 $dbh->do('UPDATE events SET last_update=CURRENT_TIMESTAMP WHERE vhost=? AND event=?',
 472                                         undef, $r->get_server_name, $event);
 473
 474                                 # Now save the file to disk
 475                                 $fname = Sesse::pr0n::Common::get_disk_location($r, $newid);
 476                                 open NEWFILE, ">$fname"
 477                                         or die "$fname: $!";
 478
 479                                 my $buf;
 480                                 my $content_length = $r->headers_in->{'content-length'};
 481                                 if ($r->read($buf, $content_length)) {
 482                                         print NEWFILE $buf or die "write($fname): $!";
 483                                 }
 484
 485                                 close NEWFILE or die "close($fname): $!";
 486
 487                                 # Orient stuff correctly
 488                                 system("/usr/bin/exifautotran", $fname) == 0
 489                                         or die "/usr/bin/exifautotran: $!";
 490
 491                                 # Make cache while we're at it.
 492                                 # Don't do it for the resource forks Mac OS X loves to upload :-(
 493                                 if ($filename !~ /^\._/) {
 494                                         Sesse::pr0n::Common::ensure_cached($r, $filename, $newid, -1, -1, 1, 80, 64, 320, 256, -1, -1);
 495                                 }
 496
 497                                 # OK, we got this far, commit
 498                                 $dbh->commit;
 499
 500                                 $r->log->notice("Successfully wrote $event/$filename to $fname");
 501                         };
 502                         if ($@) {
 503                                 # Some error occurred, rollback and bomb out
 504                                 $dbh->rollback;
 505                                 error($r, "Transaction aborted because $@");
 506                                 unlink($fname);
 507                         }
 508                 }
 509
 510                 # Insert a `shadow file' we can stat the next 30 secs
 511                 if (defined($autorename) && $autorename eq "autorename/") {
 512                         $dbh->do('DELETE FROM shadow_files WHERE expires_at <= now() OR (vhost=? AND event=? AND filename=?);',
 513                                 undef, $r->get_server_name, $event, $filename)
 514                                 or dberror($r, "Couldn't prune shadow_files");
 515                         $dbh->do('INSERT INTO shadow_files (vhost,event,filename,id,expires_at) VALUES (?,?,?,?,now() + interval \'30 seconds\');',
 516                                 undef, $r->get_server_name, $event, $orig_filename, $newid)
 517                                 or dberror($r, "Couldn't add shadow file");
 518                         $r->log->info("Added shadow entry for $event/$filename");
 519                 }
 520
 521                 $r->content_type('text/plain; charset="utf-8"');
 522                 $r->status(201);
 523                 $r->print("OK");
 524
 525                 return Apache2::Const::OK;
 526         }
 527
 528         # Used by the XP publishing wizard -- largely the same as the code above
 529         # but vastly simplified. Should we refactor?
 530         if ($r->method eq "POST") {
 531                 my $apr = Apache2::Request->new($r);
 532                 my $client_size = $apr->param('size');
 533                 my $event = $apr->param('event');
 534
 535                 my $file = $apr->upload('image');
 536                 my $filename = $file->filename();
 537                 if ($client_size != $file->size()) {
 538                         $r->content_type('text/plain; charset="utf-8"');
 539                         $r->status(403);
 540                         $r->print("Client-size resizing detected; refusing automatically");
 541
 542                         $r->log->info("Client-size resized upload of $event/$filename detected");
 543                         return Apache2::Const::OK;
 544                 }
 545
 546                 # Ugh, Windows XP seems to be sending this in... something that's not UTF-8, at least
 547                 my $takenby_given = Sesse::pr0n::Common::guess_charset($apr->param('takenby'));
 548
 549                 if (defined($takenby_given) && $takenby_given !~ /^\s*$/ && $takenby_given !~ /[<>&]/ && length($takenby_given) <= 100) {
 550                         $takenby = $takenby_given;
 551                 }
 552
 553                 my $ne_id = Sesse::pr0n::Common::guess_charset($apr->param('neweventid'));
 554                 my $ne_date = Sesse::pr0n::Common::guess_charset($apr->param('neweventdate'));
 555                 my $ne_desc = Sesse::pr0n::Common::guess_charset($apr->param('neweventdesc'));
 556                 if (defined($ne_id)) {
 557                         # Trying to add a new event, let's see if it already exists
 558                         my $q = $dbh->prepare('SELECT COUNT(*) AS cnt FROM events WHERE event=? AND vhost=?')
 559                                 or dberror($r, "Couldn't prepare event count");
 560                         $q->execute($ne_id, $r->get_server_name)
 561                                 or dberror($r, "Couldn't execute event count");
 562                         my $ref = $q->fetchrow_hashref;
 563
 564                         if ($ref->{'cnt'} == 0) {
 565                                 my @errors = Sesse::pr0n::Common::add_new_event($dbh, $ne_id, $ne_date, $ne_desc, $r->get_server_name);
 566                                 if (scalar @errors > 0) {
 567                                         die "Couldn't add new event $ne_id: " . join(', ', @errors);
 568                                 }
 569                         }
 570
 571                         $event = $ne_id;
 572                 }
 573
 574                 # Remove evil characters
 575                 if ($filename =~ /[^a-zA-Z0-9._-]/) {
 576                         $filename =~ tr/a-zA-Z0-9.-/_/c;
 577                 }
 578
 579                 # Get the new ID
 580                 my $ref = $dbh->selectrow_hashref("SELECT NEXTVAL('imageid_seq') AS id;");
 581                 my $newid = $ref->{'id'};
 582                 if (!defined($newid)) {
 583                         dberror($r, "Couldn't get new ID");
 584                 }
 585
 586                 # Autorename if we need to
 587                 {
 588                         my $ref = $dbh->selectrow_hashref("SELECT COUNT(*) AS numfiles FROM images WHERE vhost=? AND event=? AND filename=?",
 589                                 undef, $r->get_server_name, $event, $filename)
 590                                 or dberror($r, "Couldn't check for existing files");
 591                         if ($ref->{'numfiles'} > 0) {
 592                                 $r->log->info("Renaming $filename to $newid.jpeg");
 593                                 $filename = "$newid.jpeg";
 594                         }
 595                 }
 596
 597                 {
 598                         # Enable transactions and error raising temporarily
 599                         local $dbh->{AutoCommit} = 0;
 600                         local $dbh->{RaiseError} = 1;
 601                         my $fname;
 602
 603                         # Try to insert this new file
 604                         eval {
 605                                 $dbh->do('INSERT INTO images (id,vhost,event,uploadedby,takenby,filename) VALUES (?,?,?,?,?,?)',
 606                                         undef, $newid, $r->get_server_name, $event, $user, $takenby, $filename);
 607                                 $dbh->do('UPDATE events SET last_update=CURRENT_TIMESTAMP WHERE vhost=? AND event=?',
 608                                         undef, $r->get_server_name, $event);
 609
 610                                 # Now save the file to disk
 611                                 $fname = Sesse::pr0n::Common::get_disk_location($r, $newid);
 612                                 open NEWFILE, ">$fname"
 613                                         or die "$fname: $!";
 614
 615                                 my $buf;
 616                                 $file->slurp($buf);
 617                                 print NEWFILE $buf or die "write($fname): $!";
 618                                 close NEWFILE or die "close($fname): $!";
 619
 620                                 # Orient stuff correctly
 621                                 system("/usr/bin/exifautotran", $fname) == 0
 622                                         or die "/usr/bin/exifautotran: $!";
 623
 624                                 # Make cache while we're at it.
 625                                 Sesse::pr0n::Common::ensure_cached($r, $filename, $newid, -1, -1, 1, 80, 64, 320, 256, -1, -1);
 626
 627                                 # OK, we got this far, commit
 628                                 $dbh->commit;
 629
 630                                 $r->log->notice("Successfully wrote $event/$filename to $fname");
 631                         };
 632                         if ($@) {
 633                                 # Some error occurred, rollback and bomb out
 634                                 $dbh->rollback;
 635                                 error($r, "Transaction aborted because $@");
 636                                 unlink($fname);
 637
 638                                 $r->content_type('text/plain; charset="utf-8"');
 639                                 $r->status(500);
 640                                 $r->print("Error: $@");
 641                         }
 642                 }
 643
 644                 $r->content_type('text/plain; charset="utf-8"');
 645                 $r->status(201);
 646                 $r->print("OK");
 647
 648                 return Apache2::Const::OK;
 649         }
 650
 651         # Yes, we fake locks. :-)
 652         if ($r->method eq "LOCK") {
 653                 if ($r->uri !~ m#^/webdav/upload/([a-zA-Z0-9-]+)/(autorename/)?([a-zA-Z0-9._-]+)$#) {
 654                         $r->status(403);
 655                         $r->content_type('text/plain; charset=utf-8');
 656                         $r->print("No access");
 657                         return Apache2::Const::OK;
 658                 }
 659
 660                 my ($event, $autorename, $filename) = ($1, $2, $3);
 661                 my $sha1 = Digest::SHA1::sha1_base64("/$event/$autorename/$filename");
 662
 663                 $r->status(200);
 664                 $r->content_type('text/xml; charset=utf-8');
 665
 666                 $r->print(<<"EOF");
 667 <?xml version="1.0" encoding="utf-8"?>
 668 <prop xmlns="DAV:">
 669   <lockdiscovery>
 670     <activelock>
 671       <locktype><write/></locktype>
 672       <lockscope><exclusive/></lockscope>
 673       <depth>0</depth>
 674       <owner>
 675         <href>/webdav/upload/$event/$autorename$filename</href>
 676       </owner>
 677       <timeout>Second-3600</timeout>
 678       <locktoken>
 679         <href>opaquelocktoken:$sha1</href>
 680       </locktoken>
 681     </activelock>
 682   </lockdiscovery>
 683 </prop>
 684 EOF
 685                 return Apache2::Const::OK;
 686         }
 687
 688         if ($r->method eq "UNLOCK") {
 689                 $r->content_type('text/plain; charset="utf-8"');
 690                 $r->status(200);
 691                 $r->print("OK");
 692
 693                 return Apache2::Const::OK;
 694         }
 695
 696         if ($r->method eq "DELETE") {
 697                 if ($r->uri !~ m#^/webdav/upload/([a-zA-Z0-9-]+)/(autorename/)?(\._[a-zA-Z0-9._-]+)$#) {
 698                         $r->status(403);
 699                         $r->content_type('text/plain; charset=utf-8');
 700                         $r->print("No access");
 701                         return Apache2::Const::OK;
 702                 }
 703
 704                 my ($event, $autorename, $filename) = ($1, $2, $3);
 705                 $dbh->do('DELETE FROM images WHERE vhost=? AND event=? AND filename=?',
 706                         undef, $r->get_server_name, $event, $filename)
 707                         or dberror($r, "Couldn't remove file");
 708                 $dbh->do('UPDATE events SET last_update=CURRENT_TIMESTAMP WHERE vhost=? AND event=?',
 709                         undef, $r->get_server_name, $event)
 710                         or dberror($r, "Couldn't invalidate cache");
 711                 $r->status(200);
 712                 $r->print("OK");
 713
 714                 $r->log->info("deleted $event/$filename");
 715
 716                 return Apache2::Const::OK;
 717         }
 718
 719         if ($r->method eq "MOVE" or
 720             $r->method eq "MKCOL" or
 721             $r->method eq "RMCOL" or
 722             $r->method eq "RENAME" or
 723             $r->method eq "COPY") {
 724                 $r->content_type('text/plain; charset="utf-8"');
 725                 $r->status(403);
 726                 $r->print("Sorry, you do not have access to that feature.");
 727                 return Apache2::Const::OK;
 728         }
 729
 730         $r->content_type('text/plain; charset=utf-8');
 731         $r->log->error("unknown method " . $r->method);
 732         $r->status(500);
 733         $r->print("Unknown method");
 734
 735         return Apache2::Const::OK;
 736 }
 737
 738 1;
 739
 740