package Sesse::pr0n::Image;
use strict;
use warnings;

use Sesse::pr0n::Common qw(error dberror);
use POSIX;

sub handler {
	my $r = shift;
	my $dbh = Sesse::pr0n::Common::get_dbh();

#	if ($r->connection->remote_ip() eq '80.212.251.227') {
#		die "Har du lest FAQen?";
#	}

	# Find the event and file name (nobox/ is for compatibility with legacy URLs).
	my ($event,$filename,$xres,$yres,$dpr);
	if ($r->path_info =~ m#^/([a-zA-Z0-9-]+)/original/?([a-zA-Z0-9._()-]+)$#) {
		$event = $1;
		$filename = $2;
	} elsif ($r->path_info =~ m#^/([a-zA-Z0-9-]+)/(\d+)x(\d+)(?:\@(\d+(?:\.\d+)?))?/([a-zA-Z0-9._()-]+)$#) {
		$event = $1;
		$filename = $5;
		$xres = $2;
		$yres = $3;
		$dpr = $4;
	} elsif ($r->path_info =~ m#^/([a-zA-Z0-9-]+)/([a-zA-Z0-9._()-]+)$#) {
		$event = $1;
		$filename = $2;
		$xres = -1;
		$yres = -1;
	}
	$dpr //= 1;

	my ($id, $dbwidth, $dbheight);
	#if ($event eq 'single' && $filename =~ /^(\d+)\.jpeg$/) {
	#	$id = $1;
	#} else {
	
	# Look it up in the database
	my $ref = $dbh->selectrow_hashref('SELECT id,render_id,width,height FROM images WHERE event=? AND vhost=? AND filename=?',
		undef, $event, Sesse::pr0n::Common::get_server_name($r), $filename);
	return error($r, "Could not find $event/$filename", 404, "File not found") unless (defined($ref));

	if (defined($xres) && defined($yres) && defined($ref->{'render_id'})) {
		# We have a render, and we're not asked for the original.
		$ref = $dbh->selectrow_hashref('SELECT id,filename,width,height FROM images WHERE id=?', 
			undef, $ref->{'render_id'});
		return error($r, "Could not find render of $event/$filename", 404, "File not found") unless (defined($ref));
		$filename = $ref->{'filename'};
	}

	$id = $ref->{'id'};
	$dbwidth = $ref->{'width'};
	$dbheight = $ref->{'height'};

	my $res = Plack::Response->new(200);

	# Scale if we need to do so
	my ($fname, $mime_type);
	my $accept = $r->header('Accept');
	my $avif_ok = (defined($accept) && $accept =~ /(^|,)image\/avif($|,|;)/);
	my $jxl_ok = (defined($accept) && $accept =~ /(^|,)image\/jxl($|,|;)/);
	($fname, $mime_type) = Sesse::pr0n::Common::ensure_cached($r, $avif_ok, $jxl_ok, $filename, $id, $dbwidth, $dbheight, $xres, $yres);
	$res->header('Vary' => 'Accept');

	# Output the image to the user

	if (!defined($mime_type)) {
		$mime_type = Sesse::pr0n::Common::get_mimetype_from_filename($filename);
	}
	$res->content_type($mime_type);
	
	my (undef, undef, undef, undef, undef, undef, undef, $size, undef, $mtime) = stat($fname)
                or return error($r, "stat of $fname: $!");
		
	$res->content_length($size);
	Sesse::pr0n::Common::set_last_modified($res, $mtime);

	# # If the client can use cache, by all means do so
	#if ((my $rc = $r->meets_conditions) != Apache2::Const::OK) {
	#	return $rc;
	#}

	$res->content(IO::File::WithPath->new($fname));
	return $res;
}

1;


