git.sesse.net Git - remoteglot/blob - Board.pm

   1 #! /usr/bin/perl
   2 #
   3 # There are too many chess modules on CPAN already, so here's another one...
   4 #
   5 use strict;
   6 use warnings;
   7
   8 package Board;
   9
  10 sub new {
  11         my ($class, @rows) = @_;
  12         my $board = [];
  13
  14         for my $row (0..7) {
  15                 for my $col (0..7) {
  16                         $board->[$row][$col] = substr($rows[$row], $col, 1);
  17                 }
  18         }
  19
  20         return bless $board;
  21 }
  22
  23 sub clone {
  24         my ($board) = shift;
  25         my $nb = [];
  26
  27         for my $row (0..7) {
  28                 $nb->[$row] = [ @{$board->[$row]} ];
  29         }
  30
  31         return bless $nb;
  32 }
  33
  34 # Returns a new board.
  35 sub make_move {
  36         my ($board, $from_row, $from_col, $to_row, $to_col, $promo) = @_;
  37         my $move = move_to_uci_notation($from_row, $from_col, $to_row, $to_col, $promo);
  38         my $piece = $board->[$from_row][$from_col];
  39         my $nb = $board->clone();
  40
  41         if ($piece eq '-') {
  42                 die "Invalid move $move";
  43         }
  44
  45         # white short castling
  46         if ($move eq 'e1g1' && $piece eq 'K') {
  47                 # king
  48                 $nb->[7][4] = '-';
  49                 $nb->[7][6] = $piece;
  50
  51                 # rook
  52                 $nb->[7][7] = '-';
  53                 $nb->[7][5] = 'R';
  54
  55                 return $nb;
  56         }
  57
  58         # white long castling
  59         if ($move eq 'e1c1' && $piece eq 'K') {
  60                 # king
  61                 $nb->[7][4] = '-';
  62                 $nb->[7][2] = $piece;
  63
  64                 # rook
  65                 $nb->[7][0] = '-';
  66                 $nb->[7][3] = 'R';
  67
  68                 return $nb;
  69         }
  70
  71         # black short castling
  72         if ($move eq 'e8g8' && $piece eq 'k') {
  73                 # king
  74                 $nb->[0][4] = '-';
  75                 $nb->[0][6] = $piece;
  76
  77                 # rook
  78                 $nb->[0][7] = '-';
  79                 $nb->[0][5] = 'r';
  80
  81                 return $nb;
  82         }
  83
  84         # black long castling
  85         if ($move eq 'e8c8' && $piece eq 'k') {
  86                 # king
  87                 $nb->[0][4] = '-';
  88                 $nb->[0][2] = $piece;
  89
  90                 # rook
  91                 $nb->[0][0] = '-';
  92                 $nb->[0][3] = 'r';
  93
  94                 return $nb;
  95         }
  96
  97         # check if the from-piece is a pawn
  98         if (lc($piece) eq 'p') {
  99                 # attack?
 100                 if ($from_col != $to_col) {
 101                         # en passant?
 102                         if ($board->[$to_row][$to_col] eq '-') {
 103                                 if ($piece eq 'p') {
 104                                         $nb->[$to_row - 1][$to_col] = '-';
 105                                 } else {
 106                                         $nb->[$to_row + 1][$to_col] = '-';
 107                                 }
 108                         }
 109                 }
 110                 if (defined($promo) && $promo ne '') {
 111                         if ($piece eq 'p') {
 112                                 $piece = lc($promo);
 113                         } else {
 114                                 $piece = uc($promo);
 115                         }
 116                 }
 117         }
 118
 119         # update the board
 120         $nb->[$from_row][$from_col] = '-';
 121         $nb->[$to_row][$to_col] = $piece;
 122
 123         return $nb;
 124 }
 125
 126 sub _pos_to_square {
 127         my ($row, $col) = @_;
 128         return sprintf("%c%d", ord('a') + $col, 8 - $row);
 129 }
 130
 131 sub _col_letter_to_num {
 132         return ord(shift) - ord('a');
 133 }
 134
 135 sub _row_letter_to_num {
 136         return 7 - (ord(shift) - ord('1'));
 137 }
 138
 139 sub _square_to_pos {
 140         my ($square) = @_;
 141         $square =~ /^([a-h])([1-8])$/ or die "Invalid square $square";
 142         return (_row_letter_to_num($2), _col_letter_to_num($1));
 143 }
 144
 145 sub move_to_uci_notation {
 146         my ($from_row, $from_col, $to_row, $to_col, $promo) = @_;
 147         $promo //= "";
 148         return _pos_to_square($from_row, $from_col) . _pos_to_square($to_row, $to_col) . $promo;
 149 }
 150
 151 # Note: This is in general not a validation that the move is actually allowed
 152 # (e.g. you can castle even though you're in check).
 153 sub parse_pretty_move {
 154         my ($board, $move, $toplay) = @_;
 155
 156         # Strip check or mate
 157         $move =~ s/[+#]$//;
 158
 159         if ($move eq '0-0' or $move eq 'O-O') {
 160                 if ($toplay eq 'W') {
 161                         return (_square_to_pos('e1'), _square_to_pos('g1'));
 162                 } else {
 163                         return (_square_to_pos('e8'), _square_to_pos('g8'));
 164                 }
 165         } elsif ($move eq '0-0-0' or $move eq 'O-O-O') {
 166                 if ($toplay eq 'W') {
 167                         return (_square_to_pos('e1'), _square_to_pos('c1'));
 168                 } else {
 169                         return (_square_to_pos('e8'), _square_to_pos('c8'));
 170                 }
 171         }
 172
 173         # Parse promo
 174         my $promo;
 175         if ($move =~ s/=?([QRNB])$//) {
 176                 $promo = $1;
 177         }
 178
 179         $move =~ /^([KQRBN])?([a-h])?([1-8])?x?([a-h][1-8])$/ or die "Invalid move $move";
 180         my $piece = $1;
 181         my $from_col = defined($2) ? _col_letter_to_num($2) : undef;
 182         my $from_row = defined($3) ? _row_letter_to_num($3) : undef;
 183         if (!defined($piece) && (!defined($from_col) || !defined($from_row))) {
 184                 $piece = 'P';
 185         }
 186         my ($to_row, $to_col) = _square_to_pos($4);
 187
 188         # Find all possible from-squares that could have been meant.
 189         my @squares = ();
 190         my $side = 'K';
 191         if ($toplay eq 'B') {
 192                 $piece = lc($piece) if defined($piece);
 193                 $side = 'k';
 194         }
 195         for my $row (0..7) {
 196                 next if (defined($from_row) && $from_row != $row);
 197                 for my $col (0..7) {
 198                         next if (defined($from_col) && $from_col != $col);
 199                         next if (defined($piece) && $board->[$row][$col] ne $piece);
 200                         push @squares, [ $row, $col ];
 201                 }
 202         }
 203         if (scalar @squares > 1) {
 204                 # Filter out pieces which cannot reach this square.
 205                 @squares = grep { $board->can_reach($piece, $_->[0], $_->[1], $to_row, $to_col) } @squares;
 206         }
 207         if (scalar @squares > 1) {
 208                 # See if doing this move would put us in check
 209                 # (yes, there are clients that expect us to do this).
 210                 @squares = grep { !$board->make_move($_->[0], $_->[1], $to_row, $to_col, $promo)->in_check($side) } @squares;
 211         }
 212         if (scalar @squares == 0) {
 213                 die "Impossible move $move";
 214         }
 215         if (scalar @squares != 1) {
 216                 die "Ambigious move $move";
 217         }
 218         return (@{$squares[0]}, $to_row, $to_col, $promo);
 219 }
 220
 221 sub fen {
 222         my ($board) = @_;
 223         my @rows = ();
 224         for my $row (0..7) {
 225                 my $str = join('', @{$board->[$row]});
 226                 $str =~ s/(-+)/length($1)/ge;
 227                 push @rows, $str;
 228         }
 229
 230         return join('/', @rows);
 231 }
 232
 233 sub can_reach {
 234         my ($board, $piece, $from_row, $from_col, $to_row, $to_col) = @_;
 235
 236         # can't eat your own piece
 237         my $dest_piece = $board->[$to_row][$to_col];
 238         if ($dest_piece ne '-') {
 239                 return 0 if (($piece eq lc($piece)) == ($dest_piece eq lc($dest_piece)));
 240         }
 241
 242         if ($piece eq 'p') {
 243                 # black pawn
 244                 if ($to_col == $from_col && $to_row == $from_row + 1) {
 245                         return ($dest_piece eq '-');
 246                 }
 247                 if ($to_col == $from_col && $from_row == 1 && $to_row == 3) {
 248                         my $middle_piece = $board->[2][$to_col];
 249                         return ($dest_piece eq '-' && $middle_piece eq '-');
 250                 }
 251                 if (abs($to_col - $from_col) == 1 && $to_row == $from_row + 1) {
 252                         if ($dest_piece eq '-') {
 253                                 # En passant. TODO: check that the last move was indeed an EP move
 254                                 return ($to_row == 5 && $board->[4][$to_col] eq 'P');
 255                         } else {
 256                                 return 1;
 257                         }
 258                 }
 259                 return 0;
 260         }
 261         if ($piece eq 'P') {
 262                 # white pawn
 263                 if ($to_col == $from_col && $to_row == $from_row - 1) {
 264                         return ($dest_piece eq '-');
 265                 }
 266                 if ($to_col == $from_col && $from_row == 6 && $to_row == 4) {
 267                         my $middle_piece = $board->[5][$to_col];
 268                         return ($dest_piece eq '-' && $middle_piece eq '-');
 269                 }
 270                 if (abs($to_col - $from_col) == 1 && $to_row == $from_row - 1) {
 271                         if ($dest_piece eq '-') {
 272                                 # En passant. TODO: check that the last move was indeed an EP move
 273                                 return ($to_row == 2 && $board->[3][$to_col] eq 'p');
 274                         } else {
 275                                 return 1;
 276                         }
 277                 }
 278                 return 0;
 279         }
 280
 281         if (lc($piece) eq 'r') {
 282                 return 0 unless ($from_row == $to_row || $from_col == $to_col);
 283
 284                 # check that there's a clear passage
 285                 if ($from_row == $to_row) {
 286                         if ($from_col > $to_col) {
 287                                 ($to_col, $from_col) = ($from_col, $to_col);
 288                         }
 289
 290                         for my $c (($from_col+1)..($to_col-1)) {
 291                                 my $middle_piece = $board->[$to_row][$c];
 292                                 return 0 if ($middle_piece ne '-');
 293                         }
 294
 295                         return 1;
 296                 } else {
 297                         if ($from_row > $to_row) {
 298                                 ($to_row, $from_row) = ($from_row, $to_row);
 299                         }
 300
 301                         for my $r (($from_row+1)..($to_row-1)) {
 302                                 my $middle_piece = $board->[$r][$to_col];
 303                                 return 0 if ($middle_piece ne '-');
 304                         }
 305
 306                         return 1;
 307                 }
 308         }
 309         if (lc($piece) eq 'b') {
 310                 return 0 unless (abs($from_row - $to_row) == abs($from_col - $to_col));
 311
 312                 my $dr = ($to_row - $from_row) / abs($to_row - $from_row);
 313                 my $dc = ($to_col - $from_col) / abs($to_col - $from_col);
 314
 315                 my $r = $from_row + $dr;
 316                 my $c = $from_col + $dc;
 317
 318                 while ($r != $to_row) {
 319                         my $middle_piece = $board->[$r][$c];
 320                         return 0 if ($middle_piece ne '-');
 321
 322                         $r += $dr;
 323                         $c += $dc;
 324                 }
 325
 326                 return 1;
 327         }
 328         if (lc($piece) eq 'n') {
 329                 my $diff_r = abs($from_row - $to_row);
 330                 my $diff_c = abs($from_col - $to_col);
 331                 return 1 if ($diff_r == 2 && $diff_c == 1);
 332                 return 1 if ($diff_r == 1 && $diff_c == 2);
 333                 return 0;
 334         }
 335         if ($piece eq 'q') {
 336                 return (can_reach($board, 'r', $from_row, $from_col, $to_row, $to_col) ||
 337                         can_reach($board, 'b', $from_row, $from_col, $to_row, $to_col));
 338         }
 339         if ($piece eq 'Q') {
 340                 return (can_reach($board, 'R', $from_row, $from_col, $to_row, $to_col) ||
 341                         can_reach($board, 'B', $from_row, $from_col, $to_row, $to_col));
 342         }
 343         if (lc($piece) eq 'k') {
 344                 return (abs($from_row - $to_row) <= 1 && abs($from_col - $to_col) <= 1);
 345         }
 346
 347         # unknown piece
 348         return 0;
 349 }
 350
 351 # Like can_reach, but also checks the move doesn't put the side in check.
 352 # We use this in prettyprint_move to reduce the disambiguation, because Chess.js
 353 # needs moves to be in minimally disambiguated form.
 354 sub can_legally_reach {
 355         my ($board, $piece, $from_row, $from_col, $to_row, $to_col) = @_;
 356
 357         return 0 if (!can_reach($board, $piece, $from_row, $from_col, $to_row, $to_col));
 358
 359         my $nb = $board->make_move($from_row, $from_col, $to_row, $to_col);
 360         my $side = ($piece eq lc($piece)) ? 'k' : 'K';
 361
 362         return !in_check($nb, $side);
 363 }
 364
 365 my %pieces_against_side = (
 366         k => { K => 1, Q => 1, R => 1, N => 1, B => 1, P => 1 },
 367         K => { k => 1, q => 1, r => 1, n => 1, b => 1, p => 1 },
 368 );
 369
 370 # Returns whether the given side (given as k or K for black and white) is in check.
 371 sub in_check {
 372         my ($board, $side) = @_;
 373         my ($kr, $kc) = _find_piece($board, $side);
 374
 375         # check all pieces for the possibility of threatening this king
 376         for my $row (0..7) {
 377                 next unless grep { exists($pieces_against_side{$side}{$_}) } @{$board->[$row]};
 378                 for my $col (0..7) {
 379                         my $piece = $board->[$row][$col];
 380                         next if ($piece eq '-');
 381                         return 1 if ($board->can_reach($piece, $row, $col, $kr, $kc));
 382                 }
 383         }
 384
 385         return 0;
 386 }
 387
 388 sub _find_piece {
 389         my ($board, $piece) = @_;
 390
 391         for my $row (0..7) {
 392                 next unless grep { $_ eq $piece } @{$board->[$row]};
 393                 for my $col (0..7) {
 394                         if ($board->[$row][$col] eq $piece) {
 395                                 return ($row, $col);
 396                         }
 397                 }
 398         }
 399
 400         return (undef, undef);
 401 }
 402
 403 # Returns if the given side (given as k or K) is in mate.
 404 sub in_mate {
 405         my ($board, $side, $in_check) = @_;
 406         return 0 if (!$in_check);
 407
 408         # try all possible moves for the side in check
 409         for my $row (0..7) {
 410                 for my $col (0..7) {
 411                         my $piece = $board->[$row][$col];
 412                         next if ($piece eq '-');
 413
 414                         if ($side eq 'K') {
 415                                 next if ($piece eq lc($piece));
 416                         } else {
 417                                 next if ($piece eq uc($piece));
 418                         }
 419
 420                         for my $dest_row (0..7) {
 421                                 for my $dest_col (0..7) {
 422                                         next if ($row == $dest_row && $col == $dest_col);
 423                                         next unless ($board->can_reach($piece, $row, $col, $dest_row, $dest_col));
 424
 425                                         my $nb = $board->make_move($row, $col, $dest_row, $dest_col);
 426                                         return 0 if (!$nb->in_check($side));
 427                                 }
 428                         }
 429                 }
 430         }
 431
 432         # nothing to do; mate
 433         return 1;
 434 }
 435
 436 # Returns the short algebraic form of the move, as well as the new position.
 437 sub prettyprint_move {
 438         my ($board, $from_row, $from_col, $to_row, $to_col, $promo) = @_;
 439         my $pretty = $board->_prettyprint_move_no_check_or_mate($from_row, $from_col, $to_row, $to_col, $promo);
 440
 441         my $nb = $board->make_move($from_row, $from_col, $to_row, $to_col, $promo);
 442
 443         my $piece = $board->[$from_row][$from_col];
 444         my $other_side = (uc($piece) eq $piece) ? 'k' : 'K';
 445         my $in_check = $nb->in_check($other_side);
 446         if ($nb->in_mate($other_side, $in_check)) {
 447                 $pretty .= '#';
 448         } elsif ($in_check) {
 449                 $pretty .= '+';
 450         }
 451         return ($pretty, $nb);
 452 }
 453
 454 sub num_pieces {
 455         my ($board) = @_;
 456
 457         my $num = 0;
 458         for my $row (0..7) {
 459                 for my $col (0..7) {
 460                         my $piece = $board->[$row][$col];
 461                         ++$num if ($piece ne '-');
 462                 }
 463         }
 464         return $num;
 465 }
 466
 467 sub _prettyprint_move_no_check_or_mate {
 468         my ($board, $from_row, $from_col, $to_row, $to_col, $promo) = @_;
 469         my $piece = $board->[$from_row][$from_col];
 470         my $move = move_to_uci_notation($from_row, $from_col, $to_row, $to_col, $promo);
 471
 472         if ($piece eq '-') {
 473                 die "Invalid move $move";
 474         }
 475
 476         # white short castling
 477         if ($move eq 'e1g1' && $piece eq 'K') {
 478                 return 'O-O';
 479         }
 480
 481         # white long castling
 482         if ($move eq 'e1c1' && $piece eq 'K') {
 483                 return 'O-O-O';
 484         }
 485
 486         # black short castling
 487         if ($move eq 'e8g8' && $piece eq 'k') {
 488                 return 'O-O';
 489         }
 490
 491         # black long castling
 492         if ($move eq 'e8c8' && $piece eq 'k') {
 493                 return 'O-O-O';
 494         }
 495
 496         my $pretty;
 497
 498         # check if the from-piece is a pawn
 499         if (lc($piece) eq 'p') {
 500                 # attack?
 501                 if ($from_col != $to_col) {
 502                         $pretty = substr($move, 0, 1) . 'x' . _pos_to_square($to_row, $to_col);
 503                 } else {
 504                         $pretty = _pos_to_square($to_row, $to_col);
 505                 }
 506
 507                 if (defined($promo) && $promo ne '') {
 508                         # promotion
 509                         $pretty .= "=";
 510                         $pretty .= uc($promo);
 511                 }
 512                 return $pretty;
 513         }
 514
 515         $pretty = uc($piece);
 516
 517         # see how many of these pieces could go here, in all
 518         my $num_total = 0;
 519         for my $col (0..7) {
 520                 for my $row (0..7) {
 521                         next unless ($board->[$row][$col] eq $piece);
 522                         ++$num_total if ($board->can_legally_reach($piece, $row, $col, $to_row, $to_col));
 523                 }
 524         }
 525
 526         # see how many of these pieces from the given row could go here
 527         my $num_row = 0;
 528         for my $col (0..7) {
 529                 next unless ($board->[$from_row][$col] eq $piece);
 530                 ++$num_row if ($board->can_legally_reach($piece, $from_row, $col, $to_row, $to_col));
 531         }
 532
 533         # and same for columns
 534         my $num_col = 0;
 535         for my $row (0..7) {
 536                 next unless ($board->[$row][$from_col] eq $piece);
 537                 ++$num_col if ($board->can_legally_reach($piece, $row, $from_col, $to_row, $to_col));
 538         }
 539
 540         # see if we need to disambiguate
 541         if ($num_total > 1) {
 542                 if ($num_col == 1) {
 543                         $pretty .= substr($move, 0, 1);
 544                 } elsif ($num_row == 1) {
 545                         $pretty .= substr($move, 1, 1);
 546                 } else {
 547                         $pretty .= substr($move, 0, 2);
 548                 }
 549         }
 550
 551         # attack?
 552         if ($board->[$to_row][$to_col] ne '-') {
 553                 $pretty .= 'x';
 554         }
 555
 556         $pretty .= _pos_to_square($to_row, $to_col);
 557         return $pretty;
 558 }
 559
 560 1;