git.sesse.net Git - remoteglot/blob - Position.pm

   1 #! /usr/bin/perl
   2 #
   3 # There are too many chess modules on CPAN already, so here's another one...
   4 #
   5 use strict;
   6 use warnings;
   7 use MIME::Base64;
   8
   9 require 'Board.pm';
  10
  11 package Position;
  12
  13 # Takes in a FICS style 12-type position.
  14 sub new {
  15         my ($class, $str) = @_;
  16         my $pos = {};
  17         my (@x) = split / /, $str;
  18
  19         $pos->{'board'} = Board->new(@x[1..8]);
  20         $pos->{'toplay'} = $x[9];
  21         $pos->{'ep_file_num'} = $x[10];
  22         $pos->{'white_castle_k'} = $x[11];
  23         $pos->{'white_castle_q'} = $x[12];
  24         $pos->{'black_castle_k'} = $x[13];
  25         $pos->{'black_castle_q'} = $x[14];
  26         $pos->{'time_since_100move_rule_reset'} = $x[15];
  27         $pos->{'player_w'} = $x[17];
  28         $pos->{'player_b'} = $x[18];
  29         $pos->{'player_w'} =~ s/^W?[FCIG]M//;
  30         $pos->{'player_b'} =~ s/^W?[FCIG]M//;
  31         $pos->{'white_clock'} = $x[24];
  32         $pos->{'black_clock'} = $x[25];
  33         $pos->{'move_num'} = $x[26];
  34         if ($x[27] =~ /([a-h][1-8])-([a-h][1-8])/) {
  35                 $pos->{'last_move_uci'} = $1 . $2;
  36         } else {
  37                 $pos->{'last_move_uci'} = undef;
  38         }
  39         $pos->{'last_move'} = $x[29];
  40         $pos->{'prettyprint_cache'} = {};
  41
  42         bless $pos, $class;
  43         return $pos;
  44 }
  45
  46 sub start_pos {
  47         my ($class, $white, $black) = @_;
  48         $white = "base64:" . MIME::Base64::encode_base64($white);
  49         $black = "base64:" . MIME::Base64::encode_base64($black);
  50         return $class->new("<12> rnbqkbnr pppppppp -------- -------- -------- -------- PPPPPPPP RNBQKBNR W -1 1 1 1 1 0 dummygamenum $white $black -2 dummytime dummyincrement 39 39 dummytime dummytime 1 none (0:00) none 0 0 0");
  51 }
  52
  53 sub fen {
  54         my $pos = shift;
  55
  56         # the board itself
  57         my $fen = $pos->{'board'}->fen();
  58
  59         # white/black to move
  60         $fen .= " ";
  61         $fen .= lc($pos->{'toplay'});
  62
  63         # castling
  64         my $castling = "";
  65         $castling .= "K" if ($pos->{'white_castle_k'} == 1);
  66         $castling .= "Q" if ($pos->{'white_castle_q'} == 1);
  67         $castling .= "k" if ($pos->{'black_castle_k'} == 1);
  68         $castling .= "q" if ($pos->{'black_castle_q'} == 1);
  69         $castling = "-" if ($castling eq "");
  70         # $castling = "-"; # chess960
  71         $fen .= " ";
  72         $fen .= $castling;
  73
  74         # en passant
  75         my $ep = "-";
  76         if ($pos->{'ep_file_num'} != -1) {
  77                 my $col = $pos->{'ep_file_num'};
  78                 $ep = (qw(a b c d e f g h))[$col];
  79
  80                 if ($pos->{'toplay'} eq 'B') {
  81                         $ep .= "3";
  82                 } else {
  83                         $ep .= "6";
  84                 }
  85         }
  86         $fen .= " ";
  87         $fen .= $ep;
  88
  89         # half-move clock
  90         $fen .= " ";
  91         $fen .= $pos->{'time_since_100move_rule_reset'};
  92
  93         # full-move clock
  94         $fen .= " ";
  95         $fen .= $pos->{'move_num'};
  96
  97         return $fen;
  98 }
  99
 100 # Returns a compact bit string describing the same data as fen(),
 101 # except for the half-move and full-move clock.
 102 sub bitpacked_fen {
 103         my $pos = shift;
 104         my $board = $pos->{'board'}->bitpacked_fen();
 105
 106         my $bits = "";
 107         if ($pos->{'toplay'} eq 'W') {
 108                 $bits .= "0";
 109         } else {
 110                 $bits .= "1";
 111         }
 112
 113         $bits .= $pos->{'white_castle_k'};
 114         $bits .= $pos->{'white_castle_q'};
 115         $bits .= $pos->{'black_castle_k'};
 116         $bits .= $pos->{'black_castle_q'};
 117
 118         my $col = $pos->{'ep_file_num'};
 119         if ($col == -1) {
 120                 $bits .= "0";
 121         } else {
 122                 $bits .= "1";
 123                 $bits .= (qw(000 001 010 011 100 101 110 111))[$col];
 124         }
 125
 126         return $board . pack('b*', $bits);
 127 }
 128
 129 sub to_json_hash {
 130         my $pos = shift;
 131         my $json = { %$pos, fen => $pos->fen() };
 132         delete $json->{'board'};
 133         delete $json->{'prettyprint_cache'};
 134         delete $json->{'black_castle_k'};
 135         delete $json->{'black_castle_q'};
 136         delete $json->{'white_castle_k'};
 137         delete $json->{'white_castle_q'};
 138         delete $json->{'time_since_100move_rule_reset'};
 139         if ($json->{'player_w'} =~ /^base64:(.*)$/) {
 140                 $json->{'player_w'} = MIME::Base64::decode_base64($1);
 141         }
 142         if ($json->{'player_b'} =~ /^base64:(.*)$/) {
 143                 $json->{'player_b'} = MIME::Base64::decode_base64($1);
 144         }
 145         return $json;
 146 }
 147
 148 sub parse_pretty_move {
 149         my ($pos, $move) = @_;
 150         return $pos->{'board'}->parse_pretty_move($move, $pos->{'toplay'});
 151 }
 152
 153 sub num_pieces {
 154         my ($pos) = @_;
 155         return $pos->{'board'}->num_pieces();
 156 }
 157
 158 # Returns a new Position object.
 159 sub make_move {
 160         my ($pos, $from_row, $from_col, $to_row, $to_col, $promo) = @_;
 161
 162         my $from_square = _pos_to_square($from_row, $from_col);
 163         my $to_square = _pos_to_square($to_row, $to_col);
 164
 165         my $np = {};
 166         $np->{'board'} = $pos->{'board'}->make_move($from_row, $from_col, $to_row, $to_col, $promo);
 167         if ($pos->{'toplay'} eq 'W') {
 168                 $np->{'toplay'} = 'B';
 169                 $np->{'move_num'} = $pos->{'move_num'};
 170         } else {
 171                 $np->{'toplay'} = 'W';
 172                 $np->{'move_num'} = $pos->{'move_num'} + 1;
 173         }
 174
 175         my $piece = $pos->{'board'}[$from_row][$from_col];
 176         my $dest_piece = $pos->{'board'}[$to_row][$to_col];
 177
 178         # Find out if this was a two-step pawn move.
 179         if (lc($piece) eq 'p' && abs($from_row - $to_row) == 2) {
 180                 $np->{'ep_file_num'} = $from_col;
 181         } else {
 182                 $np->{'ep_file_num'} = -1;
 183         }
 184
 185         # Castling rights.
 186         $np->{'white_castle_k'} = $pos->{'white_castle_k'};
 187         $np->{'white_castle_q'} = $pos->{'white_castle_q'};
 188         $np->{'black_castle_k'} = $pos->{'black_castle_k'};
 189         $np->{'black_castle_q'} = $pos->{'black_castle_q'};
 190         if ($piece eq 'K') {
 191                 $np->{'white_castle_k'} = 0;
 192                 $np->{'white_castle_q'} = 0;
 193         } elsif ($piece eq 'k') {
 194                 $np->{'black_castle_k'} = 0;
 195                 $np->{'black_castle_q'} = 0;
 196         } elsif ($from_square eq 'a1' || $to_square eq 'a1') {
 197                 $np->{'white_castle_q'} = 0;
 198         } elsif ($from_square eq 'h1' || $to_square eq 'h1') {
 199                 $np->{'white_castle_k'} = 0;
 200         } elsif ($from_square eq 'a8' || $to_square eq 'a8') {
 201                 $np->{'black_castle_q'} = 0;
 202         } elsif ($from_square eq 'h8' || $to_square eq 'h8') {
 203                 $np->{'black_castle_k'} = 0;
 204         }
 205
 206         # 50-move rule.
 207         if (lc($piece) eq 'p' || $dest_piece ne '-') {
 208                 $np->{'time_since_100move_rule_reset'} = 0;
 209         } else {
 210                 $np->{'time_since_100move_rule_reset'} = $pos->{'time_since_100move_rule_reset'} + 1;
 211         }
 212         $np->{'player_w'} = $pos->{'player_w'};
 213         $np->{'player_b'} = $pos->{'player_b'};
 214         my ($move, $nb) = $pos->{'board'}->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
 215         $np->{'last_move'} = $move;
 216         $np->{'last_move_uci'} = Board::move_to_uci_notation($from_row, $from_col, $to_row, $to_col, $promo);
 217
 218         return bless $np;
 219 }
 220
 221 # Returns a new Position object, and the parsed UCI move.
 222 sub make_pretty_move {
 223         my ($pos, $move) = @_;
 224
 225         my ($from_row, $from_col, $to_row, $to_col, $promo) = $pos->parse_pretty_move($move);
 226         my $uci_move = Board::move_to_uci_notation($from_row, $from_col, $to_row, $to_col, $promo);
 227         $pos = $pos->make_move($from_row, $from_col, $to_row, $to_col, $promo);
 228         return ($pos, $uci_move);
 229 }
 230
 231 sub _pos_to_square {
 232         my ($row, $col) = @_;
 233         return sprintf("%c%d", ord('a') + $col, 8 - $row);
 234 }
 235
 236 sub apply_uci_pv {
 237         my ($pos, @pv) = @_;
 238
 239         my $pvpos = $pos;
 240         for my $pv_move (@pv) {
 241                 my ($from_row, $from_col, $to_row, $to_col, $promo) = _parse_uci_move($pv_move);
 242                 $pvpos = $pvpos->make_move($from_row, $from_col, $to_row, $to_col, $promo);
 243         }
 244
 245         return $pvpos;
 246 }
 247
 248 sub _col_letter_to_num {
 249         return ord(shift) - ord('a');
 250 }
 251
 252 sub _row_letter_to_num {
 253         return 7 - (ord(shift) - ord('1'));
 254 }
 255
 256 sub _parse_uci_move {
 257         my $move = shift;
 258         my $from_col = _col_letter_to_num(substr($move, 0, 1));
 259         my $from_row = _row_letter_to_num(substr($move, 1, 1));
 260         my $to_col   = _col_letter_to_num(substr($move, 2, 1));
 261         my $to_row   = _row_letter_to_num(substr($move, 3, 1));
 262         my $promo    = substr($move, 4, 1);
 263         return ($from_row, $from_col, $to_row, $to_col, $promo);
 264 }
 265
 266 1;