50b3fba64f22689e6d8957a81e63639e2c21c094
[remoteglot] / remoteglot.pl
1 #! /usr/bin/perl
2
3 #
4 # remoteglot - Connects an abitrary UCI-speaking engine to ICS for easier post-game
5 #              analysis, or for live analysis of relayed games. (Do not use for
6 #              cheating! Cheating is bad for your karma, and your abuser flag.)
7 #
8 # Copyright 2007 Steinar H. Gunderson <sgunderson@bigfoot.com>
9 # Licensed under the GNU General Public License, version 2.
10 #
11
12 use Net::Telnet;
13 use FileHandle;
14 use IPC::Open2;
15 use Time::HiRes;
16 use strict;
17 use warnings;
18
19 $SIG{ALRM} = sub { output_screen(); };
20
21 $| = 1;
22
23 my $server = "freechess.org";
24 my $target = "Sesse";
25 # my $engine = "/usr/games/toga2";
26 my $engine = "wine Rybkav2.3.2a.mp.w32.exe";
27
28 open(FICSLOG, ">ficslog.txt")
29         or die "ficslog.txt: $!";
30 print FICSLOG "Log starting.\n";
31 select(FICSLOG);
32 $| = 1;
33
34 open(UCILOG, ">ucilog.txt")
35         or die "ucilog.txt: $!";
36 print UCILOG "Log starting.\n";
37 select(UCILOG);
38 $| = 1;
39 select(STDOUT);
40
41 # open the chess engine
42 my $pid = IPC::Open2::open2(*UCIREAD, *UCIWRITE, $engine);
43 my %uciinfo = ();
44 my %ficsinfo = ();
45
46 uciprint("uci");
47
48 # gobble the options
49 while (<UCIREAD>) {
50         /uciok/ && last;
51 }
52
53 uciprint("setoption name UCI_AnalyseMode value true");
54 uciprint("setoption name NalimovPath value c:\\nalimov");
55 uciprint("setoption name NalimovUsage value Rarely");
56 uciprint("setoption name Hash value 1024");
57 # uciprint("setoption name MultiPV value 3");
58 # uciprint("setoption name Contempt value 1000");
59 # uciprint("setoption name Outlook value Ultra Optimistic");
60 uciprint("ucinewgame");
61
62 print "Chess engine ready.\n";
63
64 # now talk to FICS
65 my $t = Net::Telnet->new(Timeout => 10, Prompt => '/fics% /');
66 $t->input_log(\*FICSLOG);
67 $t->open($server);
68 $t->print("guest");
69 $t->waitfor('/Press return to enter the server/');
70 $t->cmd("");
71
72 # set some options
73 $t->cmd("set shout 0");
74 $t->cmd("set seek 0");
75 $t->cmd("set style 12");
76 $t->cmd("observe $target");
77
78 # main loop
79 print "FICS ready.\n";
80 while (1) {
81         my $rin = '';
82         my $rout;
83         vec($rin, fileno(UCIREAD), 1) = 1;
84         vec($rin, fileno($t), 1) = 1;
85
86         my ($nfound, $timeleft) = select($rout=$rin, undef, undef, 5.0);
87         my $sleep = 1.0;
88
89         while (1) {
90                 my $line = $t->getline(Timeout => 0, errmode => 'return');
91                 last if (!defined($line));
92
93                 chomp $line;
94                 $line =~ tr/\r//d;
95                 if ($line =~ /^<12> /) {
96                         my $fen = style12_to_fen($line);
97                         uciprint("stop");
98                         uciprint("position fen $fen");
99                         uciprint("go infinite");
100                 }
101                 #print "FICS: [$line]\n";
102                 $sleep = 0;
103         }
104         
105         # any fun on the UCI channel?
106         if ($nfound > 0 && vec($rout, fileno(UCIREAD), 1) == 1) {
107                 my $line = <UCIREAD>;
108                 chomp $line;
109                 $line =~ tr/\r//d;
110                 print UCILOG "<= $line\n";
111                 if ($line =~ /^info/) {
112                         my (@infos) = split / /, $line;
113                         shift @infos;
114
115                         parse_infos(@infos);
116                 }
117                 $sleep = 0;
118
119                 # don't update too often
120                 Time::HiRes::alarm(0.2);
121         }
122
123         sleep $sleep;
124 }
125
126 sub parse_infos {
127         my (@x) = @_;
128         my $mpv = '';
129
130         while (scalar @x > 0) {
131                 if ($x[0] =~ 'multipv') {
132                         shift @x;
133                         $mpv = shift @x;
134                         next;
135                 }
136                 if ($x[0] =~ /^(currmove|currmovenumber|cpuload)$/) {
137                         my $key = shift @x;
138                         my $value = shift @x;
139                         $uciinfo{$key} = $value;
140                         next;
141                 }
142                 if ($x[0] =~ /^(depth|seldepth|hashfull|time|nodes|nps|tbhits)$/) {
143                         my $key = shift @x;
144                         my $value = shift @x;
145                         $uciinfo{$key . $mpv} = $value;
146                         next;
147                 }
148                 if ($x[0] eq 'score') {
149                         shift @x;
150
151                         delete $uciinfo{'score_cp' . $mpv};
152                         delete $uciinfo{'score_mate' . $mpv};
153
154                         while ($x[0] =~ /^(cp|mate|lowerbound|upperbound)$/) {
155                                 if ($x[0] eq 'cp') {
156                                         shift @x;
157                                         $uciinfo{'score_cp' . $mpv} = shift @x;
158                                 } elsif ($x[0] eq 'mate') {
159                                         shift @x;
160                                         $uciinfo{'score_mate' . $mpv} = shift @x;
161                                 } else {
162                                         shift @x;
163                                 }
164                         }
165                         next;
166                 }
167                 if ($x[0] eq 'pv') {
168                         $uciinfo{'pv' . $mpv} = [ @x[1..$#x] ];
169                         last;
170                 }
171                 if ($x[0] eq 'string' || $x[0] eq 'UCI_AnalyseMode' || $x[0] eq 'setting' || $x[0] eq 'contempt') {
172                         last;
173                 }
174
175                 #print "unknown info '$x[0]', trying to recover...\n";
176                 #shift @x;
177                 die "Unknown info '" . join(',', @x) . "'";
178
179         }
180 }
181
182 sub style12_to_fen {
183         my $str = shift; 
184         my (@x) = split / /, $str;
185         
186         $ficsinfo{'board'} = [ @x[1..8] ];
187         $ficsinfo{'toplay'} = $x[9];
188         
189         # the board itself
190         my (@board) = @x[1..8];
191         for my $rank (0..7) {
192                 $board[$rank] =~ s/(-+)/length($1)/ge;
193         }
194         my $fen = join('/', @board);
195
196         # white/black to move
197         $fen .= " ";
198         $fen .= lc($x[9]);
199
200         # castling
201         my $castling = "";
202         $castling .= "K" if ($x[11] == 1);
203         $castling .= "Q" if ($x[12] == 1);
204         $castling .= "k" if ($x[13] == 1);
205         $castling .= "q" if ($x[14] == 1);
206         $castling = "-" if ($castling eq "");
207         $fen .= " ";
208         $fen .= $castling;
209
210         # en passant
211         my $ep = "-";
212         if ($x[10] != -1) {
213                 my $col = $x[10];
214                 my $nep = (qw(a b c d e f g h))[$col];
215
216                 if ($x[9] eq 'B') {
217                         $nep .= "3";
218                 } else {
219                         $nep .= "6";
220                 }
221                 
222                 #
223                 # Showing the en passant square when actually no capture can be made
224                 # seems to confuse at least Rybka. Thus, check if there's actually
225                 # a pawn of the opposite side that can do the en passant move, and if
226                 # not, just lie -- it doesn't matter anyway. I'm unsure what's the
227                 # "right" thing as per the standard, though.
228                 #
229                 if ($x[9] eq 'B') {
230                         $ep = $nep if ($col > 0 && substr($board[4], $col-1, 1) eq 'p');
231                         $ep = $nep if ($col < 7 && substr($board[4], $col+1, 1) eq 'p');
232                 } else {
233                         $ep = $nep if ($col > 0 && substr($board[3], $col-1, 1) eq 'P');
234                         $ep = $nep if ($col < 7 && substr($board[3], $col+1, 1) eq 'P');
235                 }
236         }
237         $fen .= " ";
238         $fen .= $ep;
239
240         # half-move clock
241         $fen .= " ";
242         $fen .= $x[15];
243
244         # full-move clock
245         $fen .= " ";
246         $fen .= $x[26];
247
248         return $fen;
249 }
250
251 sub prettyprint_pv {
252         my ($board, @pvs) = @_;
253         
254         if (scalar @pvs == 0 || !defined($pvs[0])) {
255                 return ();
256         }
257
258         my $pv = shift @pvs;
259         my $from_col = ord(substr($pv, 0, 1)) - ord('a');
260         my $from_row = 7 - (ord(substr($pv, 1, 1)) - ord('1'));
261         my $to_col   = ord(substr($pv, 2, 1)) - ord('a');
262         my $to_row   = 7 - (ord(substr($pv, 3, 1)) - ord('1'));
263
264         my $pretty;
265         my $piece = substr($board->[$from_row], $from_col, 1);
266
267         if ($piece eq '-') {
268                 die "Invalid move";
269         }
270
271         # white short castling
272         if ($pv eq 'e1g1' && $piece eq 'K') {
273                 my @nb = @$board;
274
275                 # king
276                 substr($nb[7], 4, 1, '-');
277                 substr($nb[7], 6, 1, $piece);
278                 
279                 # rook
280                 substr($nb[7], 7, 1, '-');
281                 substr($nb[7], 5, 1, 'R');
282                                 
283                 return ('0-0', prettyprint_pv(\@nb, @pvs));
284         }
285
286         # white long castling
287         if ($pv eq 'e1c1' && $piece eq 'K') {
288                 my @nb = @$board;
289
290                 # king
291                 substr($nb[7], 4, 1, '-');
292                 substr($nb[7], 2, 1, $piece);
293                 
294                 # rook
295                 substr($nb[7], 0, 1, '-');
296                 substr($nb[7], 3, 1, 'R');
297                                 
298                 return ('0-0-0', prettyprint_pv(\@nb, @pvs));
299         }
300
301         # black short castling
302         if ($pv eq 'e8g8' && $piece eq 'k') {
303                 my @nb = @$board;
304
305                 # king
306                 substr($nb[0], 4, 1, '-');
307                 substr($nb[0], 6, 1, $piece);
308                 
309                 # rook
310                 substr($nb[0], 7, 1, '-');
311                 substr($nb[0], 5, 1, 'r');
312                                 
313                 return ('0-0', prettyprint_pv(\@nb, @pvs));
314         }
315
316         # black long castling
317         if ($pv eq 'e8c8' && $piece eq 'k') {
318                 my @nb = @$board;
319
320                 # king
321                 substr($nb[0], 4, 1, '-');
322                 substr($nb[0], 2, 1, $piece);
323                 
324                 # rook
325                 substr($nb[0], 0, 1, '-');
326                 substr($nb[0], 3, 1, 'r');
327                                 
328                 return ('0-0-0', prettyprint_pv(\@nb, @pvs));
329         }
330
331         # check if the from-piece is a pawn
332         if (lc($piece) eq 'p') {
333                 # attack?
334                 if (substr($board->[$to_row], $to_col, 1) ne '-') {
335                         $pretty = substr($pv, 0, 1) . 'x' . substr($pv, 2, 2);
336                 } else {
337                         $pretty = substr($pv, 2, 2);
338
339                         if (length($pv) == 5) {
340                                 # promotion
341                                 $pretty .= "=";
342                                 $pretty .= uc(substr($pv, 4, 1));
343
344                                 if ($piece eq 'p') {
345                                         $piece = substr($pv, 4, 1);
346                                 } else {
347                                         $piece = uc(substr($pv, 4, 1));
348                                 }
349                         }
350                 }
351         } else {
352                 $pretty = uc($piece);
353
354                 # see how many of these pieces could go here, in all
355                 my $num_total = 0;
356                 for my $col (0..7) {
357                         for my $row (0..7) {
358                                 next unless (substr($board->[$row], $col, 1) eq $piece);
359                                 ++$num_total if (can_reach($board, $piece, $row, $col, $to_row, $to_col));
360                         }
361                 }
362
363                 # see how many of these pieces from the given row could go here
364                 my $num_row = 0;
365                 for my $col (0..7) {
366                         next unless (substr($board->[$from_row], $col, 1) eq $piece);
367                         ++$num_row if (can_reach($board, $piece, $from_row, $col, $to_row, $to_col));
368                 }
369                 
370                 # and same for columns
371                 my $num_col = 0;
372                 for my $row (0..7) {
373                         next unless (substr($board->[$row], $from_col, 1) eq $piece);
374                         ++$num_col if (can_reach($board, $piece, $row, $from_col, $to_row, $to_col));
375                 }
376                 
377                 # see if we need to disambiguate
378                 if ($num_total > 1) {
379                         if ($num_col == 1) {
380                                 $pretty .= substr($pv, 0, 1);
381                         } elsif ($num_row == 1) {
382                                 $pretty .= substr($pv, 1, 1);
383                         } else {
384                                 $pretty .= substr($pv, 0, 2);
385                         }
386                 }
387
388                 # attack?
389                 if (substr($board->[$to_row], $to_col, 1) ne '-') {
390                         $pretty .= 'x';
391                 }
392
393                 $pretty .= substr($pv, 2, 2);
394         }
395
396         # update the board
397         my @nb = @$board;
398         substr($nb[$from_row], $from_col, 1, '-');
399         substr($nb[$to_row], $to_col, 1, $piece);
400
401         if (in_mate(\@nb)) {
402                 $pretty .= '#';
403         } elsif (in_check(\@nb) ne 'none') {
404                 $pretty .= '+';
405         }
406
407         return ($pretty, prettyprint_pv(\@nb, @pvs));
408 }
409
410 sub output_screen {
411         #return;
412
413         #
414         # Check the PVs first. if they're invalid, just wait, as our data
415         # is most likely out of sync. This isn't a very good solution, as
416         # it can frequently miss stuff, but it's good enough for most users.
417         #
418         eval {
419                 my $dummy;
420                 if (exists($uciinfo{'pv'})) {
421                         $dummy = prettyprint_pv($ficsinfo{'board'}, @{$uciinfo{'pv'}});
422                 }
423         
424                 my $mpv = 1;
425                 while (exists($uciinfo{'pv' . $mpv})) {
426                         $dummy = prettyprint_pv($ficsinfo{'board'}, @{$uciinfo{'pv' . $mpv}});
427                         ++$mpv;
428                 }
429         };
430         if ($@) {
431                 return;
432         }
433
434         print  "\ecAnalysis:\n";
435
436         return unless (exists($ficsinfo{'board'}));
437
438         if (exists($uciinfo{'pv1'})) {
439                 # multi-PV
440                 my $mpv = 1;
441                 while (exists($uciinfo{'pv' . $mpv})) {
442                         printf "  PV%2u", $mpv;
443
444                         if (defined($uciinfo{'score_mate' . $mpv})) {
445                                 printf " (M%3d)", $uciinfo{'score_mate' . $mpv};
446                         } else {
447                                 if (exists($uciinfo{'score_cp' . $mpv})) {
448                                         my $score = $uciinfo{'score_cp' . $mpv} * 0.01;
449                                         if ($ficsinfo{'toplay'} eq 'B') {
450                                                 $score = -$score;
451                                         }
452                                         printf " (%+5.2f)", $score;
453                                 }
454                         }
455                         
456                         if (exists($uciinfo{'nodes' . $mpv}) && exists($uciinfo{'nps' . $mpv}) && exists($uciinfo{'depth' . $mpv})) {
457                                 printf " (%5u kn, %3u kn/s, %2u ply)",
458                                         $uciinfo{'nodes' . $mpv} / 1000, $uciinfo{'nps' . $mpv} / 1000, $uciinfo{'depth' . $mpv};
459                         }
460
461                         print ":\n";
462                         print "  ", join(', ', prettyprint_pv($ficsinfo{'board'}, @{$uciinfo{'pv' . $mpv}})), "\n";
463                         print "\n";
464                         ++$mpv;
465                 }
466         } else {
467                 # single-PV
468                 if (defined($uciinfo{'score_mate'})) {
469                         my $mate = $uciinfo{'score_mate'};
470                         if ($ficsinfo{'toplay'} eq 'B') {
471                                 $mate = -$mate;
472                         }
473                         if ($mate > 0) {
474                                 printf "  White mates in %u\n", $mate;
475                         } else {
476                                 printf "  Black mates in %u\n", -$mate;
477                         }
478                 } else {
479                         if (exists($uciinfo{'score_cp'})) {
480                                 my $score = $uciinfo{'score_cp'} * 0.01;
481                                 if ($ficsinfo{'toplay'} eq 'B') {
482                                         $score = -$score;
483                                 }
484                                 printf "  Score: %+5.2f\n", $score;
485                         }
486                 }
487
488                 print  "  PV: ", join(', ', prettyprint_pv($ficsinfo{'board'}, @{$uciinfo{'pv'}}));
489                 print  "\n";
490
491                 if (exists($uciinfo{'nodes'}) && exists($uciinfo{'nps'}) && exists($uciinfo{'depth'})) {
492                         printf "  %u nodes, %7u nodes/sec, depth %u ply",
493                                 $uciinfo{'nodes'}, $uciinfo{'nps'}, $uciinfo{'depth'};
494                 }
495                 if (exists($uciinfo{'tbhits'})) {
496                         printf ", %u Nalimov hits", $uciinfo{'tbhits'};
497                 }
498                 if (exists($uciinfo{'seldepth'})) {
499                         printf " (%u selective)", $uciinfo{'seldepth'};
500                 }
501                 print  "\n\n";
502         }
503 }
504
505 sub find_kings {
506         my $board = shift;
507         my ($wkr, $wkc, $bkr, $bkc);
508
509         for my $row (0..7) {
510                 for my $col (0..7) {
511                         my $piece = substr($board->[$row], $col, 1);
512                         if ($piece eq 'K') {
513                                 ($wkr, $wkc) = ($row, $col);
514                         } elsif ($piece eq 'k') {
515                                 ($bkr, $bkc) = ($row, $col);
516                         }
517                 }
518         }
519
520         return ($wkr, $wkc, $bkr, $bkc);
521 }
522
523 sub in_mate {
524         my $board = shift;
525         my $check = in_check($board);
526         return 0 if ($check eq 'none');
527
528         # try all possible moves for the side in check
529         for my $row (0..7) {
530                 for my $col (0..7) {
531                         my $piece = substr($board->[$row], $col, 1);
532                         next if ($piece eq '-');
533
534                         if ($check eq 'white') {
535                                 next if ($piece eq lc($piece));
536                         } else {
537                                 next if ($piece eq uc($piece));
538                         }
539
540                         for my $dest_row (0..7) {
541                                 for my $dest_col (0..7) {
542                                         next if ($row == $dest_row && $col == $dest_col);
543                                         next unless (can_reach($board, $piece, $row, $col, $dest_row, $dest_col));
544
545                                         my @nb = @$board;
546                                         substr($nb[$row], $col, 1, '-');
547                                         substr($nb[$dest_row], $dest_col, 1, $piece);
548
549                                         my $new_check = in_check(\@nb);
550                                         return 0 if ($new_check ne $check && $new_check ne 'both');
551                                 }
552                         }
553                 }
554         }
555
556         # nothing to do; mate
557         return 1;
558 }
559
560 sub in_check {
561         my $board = shift;
562         my ($black_check, $white_check) = (0, 0);
563
564         my ($wkr, $wkc, $bkr, $bkc) = find_kings($board);
565
566         # check all pieces for the possibility of threatening the two kings
567         for my $row (0..7) {
568                 for my $col (0..7) {
569                         my $piece = substr($board->[$row], $col, 1);
570                         next if ($piece eq '-');
571                 
572                         if (uc($piece) eq $piece) {
573                                 # white piece
574                                 $black_check = 1 if (can_reach($board, $piece, $row, $col, $bkr, $bkc));
575                         } else {
576                                 # black piece
577                                 $white_check = 1 if (can_reach($board, $piece, $row, $col, $wkr, $wkc));
578                         }
579                 }
580         }
581
582         if ($black_check && $white_check) {
583                 return 'both';
584         } elsif ($black_check) {
585                 return 'black';
586         } elsif ($white_check) {
587                 return 'white';
588         } else {
589                 return 'none';
590         }
591 }
592
593 sub can_reach {
594         my ($board, $piece, $from_row, $from_col, $to_row, $to_col) = @_;
595         
596         # can't eat your own piece
597         my $dest_piece = substr($board->[$to_row], $to_col, 1);
598         if ($dest_piece ne '-') {
599                 return 0 if (($piece eq lc($piece)) == ($dest_piece eq lc($dest_piece)));
600         }
601
602         if (lc($piece) eq 'k') {
603                 return (abs($from_row - $to_row) <= 1 && abs($from_col - $to_col) <= 1);
604         }
605         if (lc($piece) eq 'r') {
606                 return 0 unless ($from_row == $to_row || $from_col == $to_col);
607
608                 # check that there's a clear passage
609                 if ($from_row == $to_row) {
610                         if ($from_col > $to_col) {
611                                 ($to_col, $from_col) = ($from_col, $to_col);
612                         }
613
614                         for my $c (($from_col+1)..($to_col-1)) {
615                                 my $middle_piece = substr($board->[$to_row], $c, 1);
616                                 return 0 if ($middle_piece ne '-');     
617                         }
618
619                         return 1;
620                 } else {
621                         if ($from_row > $to_row) {
622                                 ($to_row, $from_row) = ($from_row, $to_row);
623                         }
624
625                         for my $r (($from_row+1)..($to_row-1)) {
626                                 my $middle_piece = substr($board->[$r], $to_col, 1);
627                                 return 0 if ($middle_piece ne '-');     
628                         }
629
630                         return 1;
631                 }
632         }
633         if (lc($piece) eq 'b') {
634                 return 0 unless (abs($from_row - $to_row) == abs($from_col - $to_col));
635
636                 my $dr = ($to_row - $from_row) / abs($to_row - $from_row);
637                 my $dc = ($to_col - $from_col) / abs($to_col - $from_col);
638
639                 my $r = $from_row + $dr;
640                 my $c = $from_col + $dc;
641
642                 while ($r != $to_row) {
643                         my $middle_piece = substr($board->[$r], $c, 1);
644                         return 0 if ($middle_piece ne '-');
645                         
646                         $r += $dr;
647                         $c += $dc;
648                 }
649
650                 return 1;
651         }
652         if (lc($piece) eq 'n') {
653                 my $diff_r = abs($from_row - $to_row);
654                 my $diff_c = abs($from_col - $to_col);
655                 return 1 if ($diff_r == 2 && $diff_c == 1);
656                 return 1 if ($diff_r == 1 && $diff_c == 2);
657                 return 0;
658         }
659         if ($piece eq 'q') {
660                 return (can_reach($board, 'r', $from_row, $from_col, $to_row, $to_col) ||
661                         can_reach($board, 'b', $from_row, $from_col, $to_row, $to_col));
662         }
663         if ($piece eq 'Q') {
664                 return (can_reach($board, 'R', $from_row, $from_col, $to_row, $to_col) ||
665                         can_reach($board, 'B', $from_row, $from_col, $to_row, $to_col));
666         }
667         if ($piece eq 'p') {
668                 # black pawn
669                 if ($to_col == $from_col && $to_row == $from_row + 1) {
670                         return ($dest_piece eq '-');
671                 }
672                 if (abs($to_col - $from_col) == 1 && $to_row == $from_row + 1) {
673                         return ($dest_piece ne '-');
674                 }
675                 return 0;
676         }
677         if ($piece eq 'P') {
678                 # white pawn
679                 if ($to_col == $from_col && $to_row == $from_row - 1) {
680                         return ($dest_piece eq '-');
681                 }
682                 if (abs($to_col - $from_col) == 1 && $to_row == $from_row - 1) {
683                         return ($dest_piece ne '-');
684                 }
685                 return 0;
686         }
687         
688         # unknown piece
689         return 0;
690 }
691
692 sub uciprint {
693         my $msg = shift;
694         print UCIWRITE "$msg\n";
695         print UCILOG "=> $msg\n";
696 }