git.sesse.net Git - remoteglot/blob - remoteglot.pl

   1 #! /usr/bin/perl
   2
   3 #
   4 # remoteglot - Connects an abitrary UCI-speaking engine to ICS for easier post-game
   5 #              analysis, or for live analysis of relayed games. (Do not use for
   6 #              cheating! Cheating is bad for your karma, and your abuser flag.)
   7 #
   8 # Copyright 2007 Steinar H. Gunderson <steinar+remoteglot@gunderson.no>
   9 # Licensed under the GNU General Public License, version 2.
  10 #
  11
  12 use AnyEvent;
  13 use AnyEvent::Handle;
  14 use AnyEvent::HTTP;
  15 use Chess::PGN::Parse;
  16 use EV;
  17 use Net::Telnet;
  18 use File::Slurp;
  19 use IPC::Open2;
  20 use Time::HiRes;
  21 use JSON::XS;
  22 use URI::Escape;
  23 use DBI;
  24 use DBD::Pg;
  25 require 'Position.pm';
  26 require 'Engine.pm';
  27 require 'config.pm';
  28 use strict;
  29 use warnings;
  30 no warnings qw(once);
  31
  32 # Program starts here
  33 my $latest_update = undef;
  34 my $output_timer = undef;
  35 my $http_timer = undef;
  36 my $stop_pgn_fetch = 0;
  37 my $tb_retry_timer = undef;
  38 my %tb_cache = ();
  39 my $tb_lookup_running = 0;
  40 my $last_written_json = undef;
  41
  42 # Persisted so we can restart.
  43 # TODO: Figure out an appropriate way to deal with database restarts
  44 # and/or Postgres going away entirely.
  45 my $dbh = DBI->connect($remoteglotconf::dbistr, $remoteglotconf::dbiuser, $remoteglotconf::dbipass)
  46         or die DBI->errstr;
  47 $dbh->{RaiseError} = 1;
  48
  49 $| = 1;
  50
  51 open(FICSLOG, ">ficslog.txt")
  52         or die "ficslog.txt: $!";
  53 print FICSLOG "Log starting.\n";
  54 select(FICSLOG);
  55 $| = 1;
  56
  57 open(UCILOG, ">ucilog.txt")
  58         or die "ucilog.txt: $!";
  59 print UCILOG "Log starting.\n";
  60 select(UCILOG);
  61 $| = 1;
  62
  63 open(TBLOG, ">tblog.txt")
  64         or die "tblog.txt: $!";
  65 print TBLOG "Log starting.\n";
  66 select(TBLOG);
  67 $| = 1;
  68
  69 select(STDOUT);
  70 umask 0022;
  71
  72 # open the chess engine
  73 my $engine = open_engine($remoteglotconf::engine_cmdline, 'E1', sub { handle_uci(@_, 1); });
  74 my $engine2 = open_engine($remoteglotconf::engine2_cmdline, 'E2', sub { handle_uci(@_, 0); });
  75 my $last_move;
  76 my $last_text = '';
  77 my ($pos_waiting, $pos_calculating, $pos_calculating_second_engine);
  78
  79 uciprint($engine, "setoption name UCI_AnalyseMode value true");
  80 while (my ($key, $value) = each %remoteglotconf::engine_config) {
  81         uciprint($engine, "setoption name $key value $value");
  82 }
  83 uciprint($engine, "ucinewgame");
  84
  85 if (defined($engine2)) {
  86         uciprint($engine2, "setoption name UCI_AnalyseMode value true");
  87         while (my ($key, $value) = each %remoteglotconf::engine2_config) {
  88                 uciprint($engine2, "setoption name $key value $value");
  89         }
  90         uciprint($engine2, "setoption name MultiPV value 500");
  91         uciprint($engine2, "ucinewgame");
  92 }
  93
  94 print "Chess engine ready.\n";
  95
  96 # now talk to FICS
  97 my $t = Net::Telnet->new(Timeout => 10, Prompt => '/fics% /');
  98 $t->input_log(\*FICSLOG);
  99 $t->open($remoteglotconf::server);
 100 $t->print($remoteglotconf::nick);
 101 $t->waitfor('/Press return to enter the server/');
 102 $t->cmd("");
 103
 104 # set some options
 105 $t->cmd("set shout 0");
 106 $t->cmd("set seek 0");
 107 $t->cmd("set style 12");
 108
 109 my $ev1 = AnyEvent->io(
 110         fh => fileno($t),
 111         poll => 'r',
 112         cb => sub {    # what callback to execute
 113                 while (1) {
 114                         my $line = $t->getline(Timeout => 0, errmode => 'return');
 115                         return if (!defined($line));
 116
 117                         chomp $line;
 118                         $line =~ tr/\r//d;
 119                         handle_fics($line);
 120                 }
 121         }
 122 );
 123 if (defined($remoteglotconf::target)) {
 124         if ($remoteglotconf::target =~ /^http:/) {
 125                 fetch_pgn($remoteglotconf::target);
 126         } else {
 127                 $t->cmd("observe $remoteglotconf::target");
 128         }
 129 }
 130 print "FICS ready.\n";
 131
 132 # Engine events have already been set up by Engine.pm.
 133 EV::run;
 134
 135 sub handle_uci {
 136         my ($engine, $line, $primary) = @_;
 137
 138         return if $line =~ /(upper|lower)bound/;
 139
 140         $line =~ s/  / /g;  # Sometimes needed for Zappa Mexico
 141         print UCILOG localtime() . " $engine->{'tag'} <= $line\n";
 142         if ($line =~ /^info/) {
 143                 my (@infos) = split / /, $line;
 144                 shift @infos;
 145
 146                 parse_infos($engine, @infos);
 147         }
 148         if ($line =~ /^id/) {
 149                 my (@ids) = split / /, $line;
 150                 shift @ids;
 151
 152                 parse_ids($engine, @ids);
 153         }
 154         if ($line =~ /^bestmove/) {
 155                 if ($primary) {
 156                         return if (!$remoteglotconf::uci_assume_full_compliance);
 157                         if (defined($pos_waiting)) {
 158                                 uciprint($engine, "position fen " . $pos_waiting->fen());
 159                                 uciprint($engine, "go infinite");
 160
 161                                 $pos_calculating = $pos_waiting;
 162                                 $pos_waiting = undef;
 163                         }
 164                 } else {
 165                         $engine2->{'info'} = {};
 166                         my $pos = $pos_waiting // $pos_calculating;
 167                         uciprint($engine2, "position fen " . $pos->fen());
 168                         uciprint($engine2, "go infinite");
 169                         $pos_calculating_second_engine = $pos;
 170                 }
 171         }
 172         output();
 173 }
 174
 175 my $getting_movelist = 0;
 176 my $pos_for_movelist = undef;
 177 my @uci_movelist = ();
 178 my @pretty_movelist = ();
 179
 180 sub handle_fics {
 181         my $line = shift;
 182         if ($line =~ /^<12> /) {
 183                 handle_position(Position->new($line));
 184                 $t->cmd("moves");
 185         }
 186         if ($line =~ /^Movelist for game /) {
 187                 my $pos = $pos_waiting // $pos_calculating;
 188                 if (defined($pos)) {
 189                         @uci_movelist = ();
 190                         @pretty_movelist = ();
 191                         $pos_for_movelist = Position->start_pos($pos->{'player_w'}, $pos->{'player_b'});
 192                         $getting_movelist = 1;
 193                 }
 194         }
 195         if ($getting_movelist &&
 196             $line =~ /^\s* \d+\. \s+                     # move number
 197                        (\S+) \s+ \( [\d:.]+ \) \s*       # first move, then time
 198                        (?: (\S+) \s+ \( [\d:.]+ \) )?    # second move, then time
 199                      /x) {
 200                 eval {
 201                         my $uci_move;
 202                         ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($1);
 203                         push @uci_movelist, $uci_move;
 204                         push @pretty_movelist, $1;
 205
 206                         if (defined($2)) {
 207                                 ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($2);
 208                                 push @uci_movelist, $uci_move;
 209                                 push @pretty_movelist, $2;
 210                         }
 211                 };
 212                 if ($@) {
 213                         warn "Error when getting FICS move history: $@";
 214                         $getting_movelist = 0;
 215                 }
 216         }
 217         if ($getting_movelist &&
 218             $line =~ /^\s+ \{.*\} \s+ (?: \* | 1\/2-1\/2 | 0-1 | 1-0 )/x) {
 219                 # End of movelist.
 220                 for my $pos ($pos_waiting, $pos_calculating) {
 221                         next if (!defined($pos));
 222                         if ($pos->fen() eq $pos_for_movelist->fen()) {
 223                                 $pos->{'pretty_history'} = \@pretty_movelist;
 224                         }
 225                 }
 226                 $getting_movelist = 0;
 227         }
 228         if ($line =~ /^([A-Za-z]+)(?:\([A-Z]+\))* tells you: (.*)$/) {
 229                 my ($who, $msg) = ($1, $2);
 230
 231                 next if (grep { $_ eq $who } (@remoteglotconf::masters) == 0);
 232
 233                 if ($msg =~ /^fics (.*?)$/) {
 234                         $t->cmd("tell $who Executing '$1' on FICS.");
 235                         $t->cmd($1);
 236                 } elsif ($msg =~ /^uci (.*?)$/) {
 237                         $t->cmd("tell $who Sending '$1' to the engine.");
 238                         print { $engine->{'write'} } "$1\n";
 239                 } elsif ($msg =~ /^pgn (.*?)$/) {
 240                         my $url = $1;
 241                         $t->cmd("tell $who Starting to poll '$url'.");
 242                         fetch_pgn($url);
 243                 } elsif ($msg =~ /^stoppgn$/) {
 244                         $t->cmd("tell $who Stopping poll.");
 245                         $stop_pgn_fetch = 1;
 246                         $http_timer = undef;
 247                 } elsif ($msg =~ /^quit$/) {
 248                         $t->cmd("tell $who Bye bye.");
 249                         exit;
 250                 } else {
 251                         $t->cmd("tell $who Couldn't understand '$msg', sorry.");
 252                 }
 253         }
 254         #print "FICS: [$line]\n";
 255 }
 256
 257 # Starts periodic fetching of PGNs from the given URL.
 258 sub fetch_pgn {
 259         my ($url) = @_;
 260         AnyEvent::HTTP::http_get($url, sub {
 261                 handle_pgn(@_, $url);
 262         });
 263 }
 264
 265 my ($last_pgn_white, $last_pgn_black);
 266 my @last_pgn_uci_moves = ();
 267 my $pgn_hysteresis_counter = 0;
 268
 269 sub handle_pgn {
 270         my ($body, $header, $url) = @_;
 271
 272         if ($stop_pgn_fetch) {
 273                 $stop_pgn_fetch = 0;
 274                 $http_timer = undef;
 275                 return;
 276         }
 277
 278         my $pgn = Chess::PGN::Parse->new(undef, $body);
 279         if (!defined($pgn)) {
 280                 warn "Error in parsing PGN from $url [body='$body']\n";
 281         } elsif (!$pgn->read_game()) {
 282                 warn "Error in reading PGN game from $url [body='$body']\n";
 283         } elsif ($body !~ /^\[/) {
 284                 warn "Malformed PGN from $url [body='$body']\n";
 285         } else {
 286                 eval {
 287                         # Skip to the right game.
 288                         while (defined($remoteglotconf::pgn_filter) &&
 289                                !&$remoteglotconf::pgn_filter($pgn)) {
 290                                 $pgn->read_game() or die "Out of games during filtering";
 291                         }
 292
 293                         $pgn->parse_game({ save_comments => 'yes' });
 294                         my $white = $pgn->white;
 295                         my $black = $pgn->black;
 296                         $white =~ s/,.*//;  # Remove first name.
 297                         $black =~ s/,.*//;  # Remove first name.
 298                         my $pos = Position->start_pos($white, $black);
 299                         my $moves = $pgn->moves;
 300                         my @uci_moves = ();
 301                         my @repretty_moves = ();
 302                         for my $move (@$moves) {
 303                                 my ($npos, $uci_move) = $pos->make_pretty_move($move);
 304                                 push @uci_moves, $uci_move;
 305
 306                                 # Re-prettyprint the move.
 307                                 my ($from_row, $from_col, $to_row, $to_col, $promo) = parse_uci_move($uci_move);
 308                                 my ($pretty, undef) = $pos->{'board'}->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
 309                                 push @repretty_moves, $pretty;
 310                                 $pos = $npos;
 311                         }
 312                         if ($pgn->result eq '1-0' || $pgn->result eq '1/2-1/2' || $pgn->result eq '0-1') {
 313                                 $pos->{'result'} = $pgn->result;
 314                         }
 315                         $pos->{'pretty_history'} = \@repretty_moves;
 316
 317                         extract_clock($pgn, $pos);
 318
 319                         # Sometimes, PGNs lose a move or two for a short while,
 320                         # or people push out new ones non-atomically.
 321                         # Thus, if we PGN doesn't change names but becomes
 322                         # shorter, we mistrust it for a few seconds.
 323                         my $trust_pgn = 1;
 324                         if (defined($last_pgn_white) && defined($last_pgn_black) &&
 325                             $last_pgn_white eq $pgn->white &&
 326                             $last_pgn_black eq $pgn->black &&
 327                             scalar(@uci_moves) < scalar(@last_pgn_uci_moves)) {
 328                                 if (++$pgn_hysteresis_counter < 3) {
 329                                         $trust_pgn = 0;
 330                                 }
 331                         }
 332                         if ($trust_pgn) {
 333                                 $last_pgn_white = $pgn->white;
 334                                 $last_pgn_black = $pgn->black;
 335                                 @last_pgn_uci_moves = @uci_moves;
 336                                 $pgn_hysteresis_counter = 0;
 337                                 handle_position($pos);
 338                         }
 339                 };
 340                 if ($@) {
 341                         warn "Error in parsing moves from $url: $@\n";
 342                 }
 343         }
 344
 345         $http_timer = AnyEvent->timer(after => 1.0, cb => sub {
 346                 fetch_pgn($url);
 347         });
 348 }
 349
 350 sub handle_position {
 351         my ($pos) = @_;
 352         find_clock_start($pos, $pos_calculating);
 353
 354         # if this is already in the queue, ignore it (just update the result)
 355         if (defined($pos_waiting) && $pos->fen() eq $pos_waiting->fen()) {
 356                 $pos_waiting->{'result'} = $pos->{'result'};
 357                 return;
 358         }
 359
 360         # if we're already chewing on this and there's nothing else in the queue,
 361         # also ignore it
 362         if (!defined($pos_waiting) && defined($pos_calculating) &&
 363             $pos->fen() eq $pos_calculating->fen()) {
 364                 $pos_calculating->{'result'} = $pos->{'result'};
 365                 return;
 366         }
 367
 368         # if we're already thinking on something, stop and wait for the engine
 369         # to approve
 370         if (defined($pos_calculating)) {
 371                 # Store the final data we have for this position in the history,
 372                 # with the precise clock information we just got from the new
 373                 # position. (Historic positions store the clock at the end of
 374                 # the position.)
 375                 #
 376                 # Do not output anything new to the main analysis; that's
 377                 # going to be obsolete really soon.
 378                 $pos_calculating->{'white_clock'} = $pos->{'white_clock'};
 379                 $pos_calculating->{'black_clock'} = $pos->{'black_clock'};
 380                 delete $pos_calculating->{'white_clock_target'};
 381                 delete $pos_calculating->{'black_clock_target'};
 382                 output_json(1);
 383
 384                 if (!defined($pos_waiting)) {
 385                         uciprint($engine, "stop");
 386                 }
 387                 if ($remoteglotconf::uci_assume_full_compliance) {
 388                         $pos_waiting = $pos;
 389                 } else {
 390                         uciprint($engine, "position fen " . $pos->fen());
 391                         uciprint($engine, "go infinite");
 392                         $pos_calculating = $pos;
 393                 }
 394         } else {
 395                 # it's wrong just to give the FEN (the move history is useful,
 396                 # and per the UCI spec, we should really have sent "ucinewgame"),
 397                 # but it's easier
 398                 uciprint($engine, "position fen " . $pos->fen());
 399                 uciprint($engine, "go infinite");
 400                 $pos_calculating = $pos;
 401         }
 402
 403         if (defined($engine2)) {
 404                 if (defined($pos_calculating_second_engine)) {
 405                         uciprint($engine2, "stop");
 406                 } else {
 407                         uciprint($engine2, "position fen " . $pos->fen());
 408                         uciprint($engine2, "go infinite");
 409                         $pos_calculating_second_engine = $pos;
 410                 }
 411                 $engine2->{'info'} = {};
 412         }
 413
 414         $engine->{'info'} = {};
 415         $last_move = time;
 416
 417         schedule_tb_lookup();
 418
 419         #
 420         # Output a command every move to note that we're
 421         # still paying attention -- this is a good tradeoff,
 422         # since if no move has happened in the last half
 423         # hour, the analysis/relay has most likely stopped
 424         # and we should stop hogging server resources.
 425         #
 426         $t->cmd("date");
 427 }
 428
 429 sub parse_infos {
 430         my ($engine, @x) = @_;
 431         my $mpv = '';
 432
 433         my $info = $engine->{'info'};
 434
 435         # Search for "multipv" first of all, since e.g. Stockfish doesn't put it first.
 436         for my $i (0..$#x - 1) {
 437                 if ($x[$i] eq 'multipv') {
 438                         $mpv = $x[$i + 1];
 439                         next;
 440                 }
 441         }
 442
 443         while (scalar @x > 0) {
 444                 if ($x[0] eq 'multipv') {
 445                         # Dealt with above
 446                         shift @x;
 447                         shift @x;
 448                         next;
 449                 }
 450                 if ($x[0] eq 'currmove' || $x[0] eq 'currmovenumber' || $x[0] eq 'cpuload') {
 451                         my $key = shift @x;
 452                         my $value = shift @x;
 453                         $info->{$key} = $value;
 454                         next;
 455                 }
 456                 if ($x[0] eq 'depth' || $x[0] eq 'seldepth' || $x[0] eq 'hashfull' ||
 457                     $x[0] eq 'time' || $x[0] eq 'nodes' || $x[0] eq 'nps' ||
 458                     $x[0] eq 'tbhits') {
 459                         my $key = shift @x;
 460                         my $value = shift @x;
 461                         $info->{$key . $mpv} = $value;
 462                         next;
 463                 }
 464                 if ($x[0] eq 'score') {
 465                         shift @x;
 466
 467                         delete $info->{'score_cp' . $mpv};
 468                         delete $info->{'score_mate' . $mpv};
 469
 470                         while ($x[0] eq 'cp' || $x[0] eq 'mate') {
 471                                 if ($x[0] eq 'cp') {
 472                                         shift @x;
 473                                         $info->{'score_cp' . $mpv} = shift @x;
 474                                 } elsif ($x[0] eq 'mate') {
 475                                         shift @x;
 476                                         $info->{'score_mate' . $mpv} = shift @x;
 477                                 } else {
 478                                         shift @x;
 479                                 }
 480                         }
 481                         next;
 482                 }
 483                 if ($x[0] eq 'pv') {
 484                         $info->{'pv' . $mpv} = [ @x[1..$#x] ];
 485                         last;
 486                 }
 487                 if ($x[0] eq 'string' || $x[0] eq 'UCI_AnalyseMode' || $x[0] eq 'setting' || $x[0] eq 'contempt') {
 488                         last;
 489                 }
 490
 491                 #print "unknown info '$x[0]', trying to recover...\n";
 492                 #shift @x;
 493                 die "Unknown info '" . join(',', @x) . "'";
 494
 495         }
 496 }
 497
 498 sub parse_ids {
 499         my ($engine, @x) = @_;
 500
 501         while (scalar @x > 0) {
 502                 if ($x[0] eq 'name') {
 503                         my $value = join(' ', @x);
 504                         $engine->{'id'}{'author'} = $value;
 505                         last;
 506                 }
 507
 508                 # unknown
 509                 shift @x;
 510         }
 511 }
 512
 513 sub prettyprint_pv_no_cache {
 514         my ($board, @pvs) = @_;
 515
 516         if (scalar @pvs == 0 || !defined($pvs[0])) {
 517                 return ();
 518         }
 519
 520         my $pv = shift @pvs;
 521         my ($from_row, $from_col, $to_row, $to_col, $promo) = parse_uci_move($pv);
 522         my ($pretty, $nb) = $board->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
 523         return ( $pretty, prettyprint_pv_no_cache($nb, @pvs) );
 524 }
 525
 526 sub prettyprint_pv {
 527         my ($pos, @pvs) = @_;
 528
 529         my $cachekey = join('', @pvs);
 530         if (exists($pos->{'prettyprint_cache'}{$cachekey})) {
 531                 return @{$pos->{'prettyprint_cache'}{$cachekey}};
 532         } else {
 533                 my @res = prettyprint_pv_no_cache($pos->{'board'}, @pvs);
 534                 $pos->{'prettyprint_cache'}{$cachekey} = \@res;
 535                 return @res;
 536         }
 537 }
 538
 539 sub complete_using_tbprobe {
 540         my ($pos, $info, $mpv) = @_;
 541
 542         # We need Fathom installed to do standalone TB probes.
 543         return if (!defined($remoteglotconf::fathom_cmdline));
 544
 545         # If we already have a mate, don't bother; in some cases, it would even be
 546         # better than a tablebase score.
 547         return if defined($info->{'score_mate' . $mpv});
 548
 549         # If we have a draw or near-draw score, there's also not much interesting
 550         # we could add from a tablebase. We only really want mates.
 551         return if ($info->{'score_cp' . $mpv} >= -12250 && $info->{'score_cp' . $mpv} <= 12250);
 552
 553         # Run through the PV until we are at a 6-man position.
 554         # TODO: We could in theory only have 5-man data.
 555         my @pv = @{$info->{'pv' . $mpv}};
 556         my $key = join('', @pv);
 557         my @moves = ();
 558         if (exists($pos->{'tbprobe_cache'}{$key})) {
 559                 @moves = $pos->{'tbprobe_cache'}{$key};
 560         } else {
 561                 while ($pos->num_pieces() > 6 && $#pv > -1) {
 562                         my $move = shift @pv;
 563                         push @moves, $move;
 564                         $pos = $pos->make_move(parse_uci_move($move));
 565                 }
 566
 567                 return if ($pos->num_pieces() > 6);
 568
 569                 my $fen = $pos->fen();
 570                 my $pgn_text = `fathom --path=/srv/syzygy "$fen"`;
 571                 my $pgn = Chess::PGN::Parse->new(undef, $pgn_text);
 572                 return if (!defined($pgn) || !$pgn->read_game() || ($pgn->result ne '0-1' && $pgn->result ne '1-0'));
 573                 $pgn->quick_parse_game;
 574                 $info->{'pv' . $mpv} = \@moves;
 575
 576                 # Splice the PV from the tablebase onto what we have so far.
 577                 for my $move (@{$pgn->moves}) {
 578                         my $uci_move;
 579                         ($pos, $uci_move) = $pos->make_pretty_move($move);
 580                         push @moves, $uci_move;
 581                 }
 582         }
 583
 584         $info->{'pv' . $mpv} = \@moves;
 585
 586         my $matelen = int((1 + scalar @moves) / 2);
 587         if ((scalar @moves) % 2 == 0) {
 588                 $info->{'score_mate' . $mpv} = -$matelen;
 589         } else {
 590                 $info->{'score_mate' . $mpv} = $matelen;
 591         }
 592 }
 593
 594 sub output {
 595         #return;
 596
 597         return if (!defined($pos_calculating));
 598
 599         # Don't update too often.
 600         my $age = Time::HiRes::tv_interval($latest_update);
 601         if ($age < $remoteglotconf::update_max_interval) {
 602                 my $wait = $remoteglotconf::update_max_interval + 0.01 - $age;
 603                 $output_timer = AnyEvent->timer(after => $wait, cb => \&output);
 604                 return;
 605         }
 606
 607         my $info = $engine->{'info'};
 608
 609         #
 610         # If we have tablebase data from a previous lookup, replace the
 611         # engine data with the data from the tablebase.
 612         #
 613         my $fen = $pos_calculating->fen();
 614         if (exists($tb_cache{$fen})) {
 615                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
 616                         delete $info->{$key . '1'};
 617                         delete $info->{$key};
 618                 }
 619                 $info->{'nodes'} = 0;
 620                 $info->{'nps'} = 0;
 621                 $info->{'depth'} = 0;
 622                 $info->{'seldepth'} = 0;
 623                 $info->{'tbhits'} = 0;
 624
 625                 my $t = $tb_cache{$fen};
 626                 my $pv = $t->{'pv'};
 627                 my $matelen = int((1 + $t->{'score'}) / 2);
 628                 if ($t->{'result'} eq '1/2-1/2') {
 629                         $info->{'score_cp'} = 0;
 630                 } elsif ($t->{'result'} eq '1-0') {
 631                         if ($pos_calculating->{'toplay'} eq 'B') {
 632                                 $info->{'score_mate'} = -$matelen;
 633                         } else {
 634                                 $info->{'score_mate'} = $matelen;
 635                         }
 636                 } else {
 637                         if ($pos_calculating->{'toplay'} eq 'B') {
 638                                 $info->{'score_mate'} = $matelen;
 639                         } else {
 640                                 $info->{'score_mate'} = -$matelen;
 641                         }
 642                 }
 643                 $info->{'pv'} = $pv;
 644                 $info->{'tablebase'} = 1;
 645         } else {
 646                 $info->{'tablebase'} = 0;
 647         }
 648
 649         #
 650         # Some programs _always_ report MultiPV, even with only one PV.
 651         # In this case, we simply use that data as if MultiPV was never
 652         # specified.
 653         #
 654         if (exists($info->{'pv1'}) && !exists($info->{'pv2'})) {
 655                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
 656                         if (exists($info->{$key . '1'})) {
 657                                 $info->{$key} = $info->{$key . '1'};
 658                         } else {
 659                                 delete $info->{$key};
 660                         }
 661                 }
 662         }
 663
 664         #
 665         # Check the PVs first. if they're invalid, just wait, as our data
 666         # is most likely out of sync. This isn't a very good solution, as
 667         # it can frequently miss stuff, but it's good enough for most users.
 668         #
 669         eval {
 670                 my $dummy;
 671                 if (exists($info->{'pv'})) {
 672                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv'}});
 673                 }
 674
 675                 my $mpv = 1;
 676                 while (exists($info->{'pv' . $mpv})) {
 677                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}});
 678                         ++$mpv;
 679                 }
 680         };
 681         if ($@) {
 682                 $engine->{'info'} = {};
 683                 return;
 684         }
 685
 686         # Now do our own Syzygy tablebase probes to convert scores like +123.45 to mate.
 687         if (exists($info->{'pv'})) {
 688                 complete_using_tbprobe($pos_calculating, $info, '');
 689         }
 690
 691         my $mpv = 1;
 692         while (exists($info->{'pv' . $mpv})) {
 693                 complete_using_tbprobe($pos_calculating, $info, $mpv);
 694                 ++$mpv;
 695         }
 696
 697         output_screen();
 698         output_json(0);
 699         $latest_update = [Time::HiRes::gettimeofday];
 700 }
 701
 702 sub output_screen {
 703         my $info = $engine->{'info'};
 704         my $id = $engine->{'id'};
 705
 706         my $text = 'Analysis';
 707         if ($pos_calculating->{'last_move'} ne 'none') {
 708                 if ($pos_calculating->{'toplay'} eq 'W') {
 709                         $text .= sprintf ' after %u. ... %s', ($pos_calculating->{'move_num'}-1), $pos_calculating->{'last_move'};
 710                 } else {
 711                         $text .= sprintf ' after %u. %s', $pos_calculating->{'move_num'}, $pos_calculating->{'last_move'};
 712                 }
 713                 if (exists($id->{'name'})) {
 714                         $text .= ',';
 715                 }
 716         }
 717
 718         if (exists($id->{'name'})) {
 719                 $text .= " by $id->{'name'}:\n\n";
 720         } else {
 721                 $text .= ":\n\n";
 722         }
 723
 724         return unless (exists($pos_calculating->{'board'}));
 725
 726         if (exists($info->{'pv1'}) && exists($info->{'pv2'})) {
 727                 # multi-PV
 728                 my $mpv = 1;
 729                 while (exists($info->{'pv' . $mpv})) {
 730                         $text .= sprintf "  PV%2u", $mpv;
 731                         my $score = short_score($info, $pos_calculating, $mpv);
 732                         $text .= "  ($score)" if (defined($score));
 733
 734                         my $tbhits = '';
 735                         if (exists($info->{'tbhits' . $mpv}) && $info->{'tbhits' . $mpv} > 0) {
 736                                 if ($info->{'tbhits' . $mpv} == 1) {
 737                                         $tbhits = ", 1 tbhit";
 738                                 } else {
 739                                         $tbhits = sprintf ", %u tbhits", $info->{'tbhits' . $mpv};
 740                                 }
 741                         }
 742
 743                         if (exists($info->{'nodes' . $mpv}) && exists($info->{'nps' . $mpv}) && exists($info->{'depth' . $mpv})) {
 744                                 $text .= sprintf " (%5u kn, %3u kn/s, %2u ply$tbhits)",
 745                                         $info->{'nodes' . $mpv} / 1000, $info->{'nps' . $mpv} / 1000, $info->{'depth' . $mpv};
 746                         }
 747
 748                         $text .= ":\n";
 749                         $text .= "  " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}})) . "\n";
 750                         $text .= "\n";
 751                         ++$mpv;
 752                 }
 753         } else {
 754                 # single-PV
 755                 my $score = long_score($info, $pos_calculating, '');
 756                 $text .= "  $score\n" if defined($score);
 757                 $text .=  "  PV: " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv'}}));
 758                 $text .=  "\n";
 759
 760                 if (exists($info->{'nodes'}) && exists($info->{'nps'}) && exists($info->{'depth'})) {
 761                         $text .= sprintf "  %u nodes, %7u nodes/sec, depth %u ply",
 762                                 $info->{'nodes'}, $info->{'nps'}, $info->{'depth'};
 763                 }
 764                 if (exists($info->{'seldepth'})) {
 765                         $text .= sprintf " (%u selective)", $info->{'seldepth'};
 766                 }
 767                 if (exists($info->{'tbhits'}) && $info->{'tbhits'} > 0) {
 768                         if ($info->{'tbhits'} == 1) {
 769                                 $text .= ", one Syzygy hit";
 770                         } else {
 771                                 $text .= sprintf ", %u Syzygy hits", $info->{'tbhits'};
 772                         }
 773                 }
 774                 $text .= "\n\n";
 775         }
 776
 777         #$text .= book_info($pos_calculating->fen(), $pos_calculating->{'board'}, $pos_calculating->{'toplay'});
 778
 779         my @refutation_lines = ();
 780         if (defined($engine2)) {
 781                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
 782                         my $info = $engine2->{'info'};
 783                         last if (!exists($info->{'pv' . $mpv}));
 784                         eval {
 785                                 complete_using_tbprobe($pos_calculating_second_engine, $info, $mpv);
 786                                 my $pv = $info->{'pv' . $mpv};
 787                                 my $pretty_move = join('', prettyprint_pv($pos_calculating_second_engine, $pv->[0]));
 788                                 my @pretty_pv = prettyprint_pv($pos_calculating_second_engine, @$pv);
 789                                 if (scalar @pretty_pv > 5) {
 790                                         @pretty_pv = @pretty_pv[0..4];
 791                                         push @pretty_pv, "...";
 792                                 }
 793                                 my $key = $pretty_move;
 794                                 my $line = sprintf("  %-6s %6s %3s  %s",
 795                                         $pretty_move,
 796                                         short_score($info, $pos_calculating_second_engine, $mpv),
 797                                         "d" . $info->{'depth' . $mpv},
 798                                         join(', ', @pretty_pv));
 799                                 push @refutation_lines, [ $key, $line ];
 800                         };
 801                 }
 802         }
 803
 804         if ($#refutation_lines >= 0) {
 805                 $text .= "Shallow search of all legal moves:\n\n";
 806                 for my $line (sort { $a->[0] cmp $b->[0] } @refutation_lines) {
 807                         $text .= $line->[1] . "\n";
 808                 }
 809                 $text .= "\n\n";
 810         }
 811
 812         if ($last_text ne $text) {
 813                 print "\e[H\e[2J"; # clear the screen
 814                 print $text;
 815                 $last_text = $text;
 816         }
 817 }
 818
 819 sub output_json {
 820         my $historic_json_only = shift;
 821         my $info = $engine->{'info'};
 822
 823         my $json = {};
 824         $json->{'position'} = $pos_calculating->to_json_hash();
 825         $json->{'engine'} = $engine->{'id'};
 826         if (defined($remoteglotconf::engine_url)) {
 827                 $json->{'engine'}{'url'} = $remoteglotconf::engine_url;
 828         }
 829         if (defined($remoteglotconf::engine_details)) {
 830                 $json->{'engine'}{'details'} = $remoteglotconf::engine_details;
 831         }
 832         if (defined($remoteglotconf::move_source)) {
 833                 $json->{'move_source'} = $remoteglotconf::move_source;
 834         }
 835         if (defined($remoteglotconf::move_source_url)) {
 836                 $json->{'move_source_url'} = $remoteglotconf::move_source_url;
 837         }
 838         $json->{'score'} = score_digest($info, $pos_calculating, '');
 839         $json->{'using_lomonosov'} = defined($remoteglotconf::tb_serial_key);
 840
 841         $json->{'nodes'} = $info->{'nodes'};
 842         $json->{'nps'} = $info->{'nps'};
 843         $json->{'depth'} = $info->{'depth'};
 844         $json->{'tbhits'} = $info->{'tbhits'};
 845         $json->{'seldepth'} = $info->{'seldepth'};
 846         $json->{'tablebase'} = $info->{'tablebase'};
 847
 848         $json->{'pv_uci'} = $info->{'pv'};  # Still needs to be there for the JS to calculate arrows; only for the primary PV, though!
 849         $json->{'pv_pretty'} = [ prettyprint_pv($pos_calculating, @{$info->{'pv'}}) ];
 850
 851         my %refutation_lines = ();
 852         my @refutation_lines = ();
 853         if (defined($engine2)) {
 854                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
 855                         my $info = $engine2->{'info'};
 856                         my $pretty_move = "";
 857                         my @pretty_pv = ();
 858                         last if (!exists($info->{'pv' . $mpv}));
 859
 860                         eval {
 861                                 complete_using_tbprobe($pos_calculating, $info, $mpv);
 862                                 my $pv = $info->{'pv' . $mpv};
 863                                 my $pretty_move = join('', prettyprint_pv($pos_calculating, $pv->[0]));
 864                                 my @pretty_pv = prettyprint_pv($pos_calculating, @$pv);
 865                                 $refutation_lines{$pv->[0]} = {
 866                                         sort_key => $pretty_move,
 867                                         depth => $info->{'depth' . $mpv},
 868                                         score => score_digest($info, $pos_calculating, $mpv),
 869                                         pretty_move => $pretty_move,
 870                                         pv_pretty => \@pretty_pv,
 871                                 };
 872                         };
 873                 }
 874         }
 875         $json->{'refutation_lines'} = \%refutation_lines;
 876
 877         # Piece together historic score information, to the degree we have it.
 878         if (!$historic_json_only && exists($pos_calculating->{'pretty_history'})) {
 879                 my %score_history = ();
 880
 881                 my $q = $dbh->prepare('SELECT * FROM scores WHERE id=?');
 882                 my $pos = Position->start_pos('white', 'black');
 883                 my $halfmove_num = 0;
 884                 for my $move (@{$pos_calculating->{'pretty_history'}}) {
 885                         my $id = id_for_pos($pos, $halfmove_num);
 886                         my $ref = $dbh->selectrow_hashref($q, undef, $id);
 887                         if (defined($ref)) {
 888                                 $score_history{$halfmove_num} = [
 889                                         $ref->{'score_type'},
 890                                         $ref->{'score_value'}
 891                                 ];
 892                         }
 893                         ++$halfmove_num;
 894                         ($pos) = $pos->make_pretty_move($move);
 895                 }
 896                 $q->finish;
 897
 898                 # If at any point we are missing 10 consecutive moves,
 899                 # truncate the history there. This is so we don't get into
 900                 # a situation where we e.g. start analyzing at move 45,
 901                 # but we have analysis for 1. e4 from some completely different game
 902                 # and thus show a huge hole.
 903                 my $consecutive_missing = 0;
 904                 my $truncate_until = 0;
 905                 for (my $i = $halfmove_num; $i --> 0; ) {
 906                         if ($consecutive_missing >= 10) {
 907                                 delete $score_history{$i};
 908                                 next;
 909                         }
 910                         if (exists($score_history{$i})) {
 911                                 $consecutive_missing = 0;
 912                         } else {
 913                                 ++$consecutive_missing;
 914                         }
 915                 }
 916
 917                 $json->{'score_history'} = \%score_history;
 918         }
 919
 920         # Give out a list of other games going on. (Empty is fine.)
 921         if (!$historic_json_only) {
 922                 my @games = ();
 923
 924                 my $q = $dbh->prepare('SELECT * FROM current_games ORDER BY priority DESC, id');
 925                 $q->execute;
 926                 while (my $ref = $q->fetchrow_hashref) {
 927                         eval {
 928                                 my $other_game_contents = File::Slurp::read_file($ref->{'json_path'});
 929                                 my $other_game_json = JSON::XS::decode_json($other_game_contents);
 930
 931                                 die "Missing position" if (!exists($other_game_json->{'position'}));
 932                                 my $white = $other_game_json->{'position'}{'player_w'} // die 'Missing white';
 933                                 my $black = $other_game_json->{'position'}{'player_b'} // die 'Missing black';
 934
 935                                 my $game = {
 936                                         id => $ref->{'id'},
 937                                         name => "$white–$black",
 938                                         url => $ref->{'url'},
 939                                         hashurl => $ref->{'hash_url'},
 940                                 };
 941                                 if (defined($other_game_json->{'position'}{'result'})) {
 942                                         $game->{'result'} = $other_game_json->{'position'}{'result'};
 943                                 } else {
 944                                         $game->{'score'} = $other_game_json->{'score'};
 945                                 }
 946                                 push @games, $game;
 947                         };
 948                         if ($@) {
 949                                 warn "Could not add external game " . $ref->{'json_path'} . ": $@";
 950                         }
 951                 }
 952
 953                 if (scalar @games > 0) {
 954                         $json->{'games'} = \@games;
 955                 }
 956         }
 957
 958         my $json_enc = JSON::XS->new;
 959         $json_enc->canonical(1);
 960         my $encoded = $json_enc->encode($json);
 961         unless ($historic_json_only || !defined($remoteglotconf::json_output) ||
 962                 (defined($last_written_json) && $last_written_json eq $encoded)) {
 963                 atomic_set_contents($remoteglotconf::json_output, $encoded);
 964                 $last_written_json = $encoded;
 965         }
 966
 967         if (exists($pos_calculating->{'pretty_history'}) &&
 968             defined($remoteglotconf::json_history_dir)) {
 969                 my $id = id_for_pos($pos_calculating);
 970                 my $filename = $remoteglotconf::json_history_dir . "/" . $id . ".json";
 971
 972                 # Overwrite old analysis (assuming it exists at all) if we're
 973                 # using a different engine, or if we've calculated deeper.
 974                 # nodes is used as a tiebreaker. Don't bother about Multi-PV
 975                 # data; it's not that important.
 976                 my ($old_engine, $old_depth, $old_nodes) = get_json_analysis_stats($id);
 977                 my $new_depth = $json->{'depth'} // 0;
 978                 my $new_nodes = $json->{'nodes'} // 0;
 979                 if (!defined($old_engine) ||
 980                     $old_engine ne $json->{'engine'}{'name'} ||
 981                     $new_depth > $old_depth ||
 982                     ($new_depth == $old_depth && $new_nodes >= $old_nodes)) {
 983                         atomic_set_contents($filename, $encoded);
 984                         if (defined($json->{'score'})) {
 985                                 $dbh->do('INSERT INTO scores (id, score_type, score_value, engine, depth, nodes) VALUES (?,?,?,?,?,?) ' .
 986                                          '    ON CONFLICT (id) DO UPDATE SET ' .
 987                                          '        score_type=EXCLUDED.score_type, ' .
 988                                          '        score_value=EXCLUDED.score_value, ' .
 989                                          '        engine=EXCLUDED.engine, ' .
 990                                          '        depth=EXCLUDED.depth, ' .
 991                                          '        nodes=EXCLUDED.nodes',
 992                                         undef,
 993                                         $id, $json->{'score'}[0], $json->{'score'}[1],
 994                                         $json->{'engine'}{'name'}, $new_depth, $new_nodes);
 995                         }
 996                 }
 997         }
 998 }
 999
1000 sub atomic_set_contents {
1001         my ($filename, $contents) = @_;
1002
1003         open my $fh, ">", $filename . ".tmp"
1004                 or return;
1005         print $fh $contents;
1006         close $fh;
1007         rename($filename . ".tmp", $filename);
1008 }
1009
1010 sub id_for_pos {
1011         my ($pos, $halfmove_num) = @_;
1012
1013         $halfmove_num //= scalar @{$pos->{'pretty_history'}};
1014         (my $fen = $pos->fen()) =~ tr,/ ,-_,;
1015         return "move$halfmove_num-$fen";
1016 }
1017
1018 sub get_json_analysis_stats {
1019         my $id = shift;
1020         my $ref = $dbh->selectrow_hashref('SELECT * FROM scores WHERE id=?', undef, $id);
1021         if (defined($ref)) {
1022                 return ($ref->{'engine'}, $ref->{'depth'}, $ref->{'nodes'});
1023         } else {
1024                 return ('', 0, 0);
1025         }
1026 }
1027
1028 sub uciprint {
1029         my ($engine, $msg) = @_;
1030         $engine->print($msg);
1031         print UCILOG localtime() . " $engine->{'tag'} => $msg\n";
1032 }
1033
1034 sub short_score {
1035         my ($info, $pos, $mpv) = @_;
1036
1037         my $invert = ($pos->{'toplay'} eq 'B');
1038         if (defined($info->{'score_mate' . $mpv})) {
1039                 if ($invert) {
1040                         return sprintf "M%3d", -$info->{'score_mate' . $mpv};
1041                 } else {
1042                         return sprintf "M%3d", $info->{'score_mate' . $mpv};
1043                 }
1044         } else {
1045                 if (exists($info->{'score_cp' . $mpv})) {
1046                         my $score = $info->{'score_cp' . $mpv} * 0.01;
1047                         if ($score == 0) {
1048                                 if ($info->{'tablebase'}) {
1049                                         return "TB draw";
1050                                 } else {
1051                                         return " 0.00";
1052                                 }
1053                         }
1054                         if ($invert) {
1055                                 $score = -$score;
1056                         }
1057                         return sprintf "%+5.2f", $score;
1058                 }
1059         }
1060
1061         return undef;
1062 }
1063
1064 # Sufficient for computing long_score, short_score, plot_score and
1065 # (with side-to-play information) score_sort_key.
1066 sub score_digest {
1067         my ($info, $pos, $mpv) = @_;
1068
1069         if (defined($info->{'score_mate' . $mpv})) {
1070                 my $mate = $info->{'score_mate' . $mpv};
1071                 if ($pos->{'toplay'} eq 'B') {
1072                         $mate = -$mate;
1073                 }
1074                 return ['m', $mate];
1075         } else {
1076                 if (exists($info->{'score_cp' . $mpv})) {
1077                         my $score = $info->{'score_cp' . $mpv};
1078                         if ($pos->{'toplay'} eq 'B') {
1079                                 $score = -$score;
1080                         }
1081                         if ($score == 0 && $info->{'tablebase'}) {
1082                                 return ['d', undef];
1083                         } else {
1084                                 return ['cp', $score];
1085                         }
1086                 }
1087         }
1088
1089         return undef;
1090 }
1091
1092 sub long_score {
1093         my ($info, $pos, $mpv) = @_;
1094
1095         if (defined($info->{'score_mate' . $mpv})) {
1096                 my $mate = $info->{'score_mate' . $mpv};
1097                 if ($pos->{'toplay'} eq 'B') {
1098                         $mate = -$mate;
1099                 }
1100                 if ($mate > 0) {
1101                         return sprintf "White mates in %u", $mate;
1102                 } else {
1103                         return sprintf "Black mates in %u", -$mate;
1104                 }
1105         } else {
1106                 if (exists($info->{'score_cp' . $mpv})) {
1107                         my $score = $info->{'score_cp' . $mpv} * 0.01;
1108                         if ($score == 0) {
1109                                 if ($info->{'tablebase'}) {
1110                                         return "Theoretical draw";
1111                                 } else {
1112                                         return "Score:  0.00";
1113                                 }
1114                         }
1115                         if ($pos->{'toplay'} eq 'B') {
1116                                 $score = -$score;
1117                         }
1118                         return sprintf "Score: %+5.2f", $score;
1119                 }
1120         }
1121
1122         return undef;
1123 }
1124
1125 # For graphs; a single number in centipawns, capped at +/- 500.
1126 sub plot_score {
1127         my ($info, $pos, $mpv) = @_;
1128
1129         my $invert = ($pos->{'toplay'} eq 'B');
1130         if (defined($info->{'score_mate' . $mpv})) {
1131                 my $mate = $info->{'score_mate' . $mpv};
1132                 if ($invert) {
1133                         $mate = -$mate;
1134                 }
1135                 if ($mate > 0) {
1136                         return 500;
1137                 } else {
1138                         return -500;
1139                 }
1140         } else {
1141                 if (exists($info->{'score_cp' . $mpv})) {
1142                         my $score = $info->{'score_cp' . $mpv};
1143                         if ($invert) {
1144                                 $score = -$score;
1145                         }
1146                         $score = 500 if ($score > 500);
1147                         $score = -500 if ($score < -500);
1148                         return int($score);
1149                 }
1150         }
1151
1152         return undef;
1153 }
1154
1155 my %book_cache = ();
1156 sub book_info {
1157         my ($fen, $board, $toplay) = @_;
1158
1159         if (exists($book_cache{$fen})) {
1160                 return $book_cache{$fen};
1161         }
1162
1163         my $ret = `./booklook $fen`;
1164         return "" if ($ret =~ /Not found/ || $ret eq '');
1165
1166         my @moves = ();
1167
1168         for my $m (split /\n/, $ret) {
1169                 my ($move, $annotation, $win, $draw, $lose, $rating, $rating_div) = split /,/, $m;
1170
1171                 my $pmove;
1172                 if ($move eq '')  {
1173                         $pmove = '(current)';
1174                 } else {
1175                         ($pmove) = prettyprint_pv_no_cache($board, $move);
1176                         $pmove .= $annotation;
1177                 }
1178
1179                 my $score;
1180                 if ($toplay eq 'W') {
1181                         $score = 1.0 * $win + 0.5 * $draw + 0.0 * $lose;
1182                 } else {
1183                         $score = 0.0 * $win + 0.5 * $draw + 1.0 * $lose;
1184                 }
1185                 my $n = $win + $draw + $lose;
1186
1187                 my $percent;
1188                 if ($n == 0) {
1189                         $percent = "     ";
1190                 } else {
1191                         $percent = sprintf "%4u%%", int(100.0 * $score / $n + 0.5);
1192                 }
1193
1194                 push @moves, [ $pmove, $n, $percent, $rating ];
1195         }
1196
1197         @moves[1..$#moves] = sort { $b->[2] cmp $a->[2] } @moves[1..$#moves];
1198
1199         my $text = "Book moves:\n\n              Perf.     N     Rating\n\n";
1200         for my $m (@moves) {
1201                 $text .= sprintf "  %-10s %s   %6u    %4s\n", $m->[0], $m->[2], $m->[1], $m->[3]
1202         }
1203
1204         return $text;
1205 }
1206
1207 sub extract_clock {
1208         my ($pgn, $pos) = @_;
1209
1210         # Look for extended PGN clock tags.
1211         my $tags = $pgn->tags;
1212         if (exists($tags->{'WhiteClock'}) && exists($tags->{'BlackClock'})) {
1213                 $pos->{'white_clock'} = hms_to_sec($tags->{'WhiteClock'});
1214                 $pos->{'black_clock'} = hms_to_sec($tags->{'BlackClock'});
1215                 return;
1216         }
1217
1218         # Look for TCEC-style time comments.
1219         my $moves = $pgn->moves;
1220         my $comments = $pgn->comments;
1221         my $last_black_move = int((scalar @$moves) / 2);
1222         my $last_white_move = int((1 + scalar @$moves) / 2);
1223
1224         my $black_key = $last_black_move . "b";
1225         my $white_key = $last_white_move . "w";
1226
1227         if (exists($comments->{$white_key}) &&
1228             exists($comments->{$black_key}) &&
1229             $comments->{$white_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/ &&
1230             $comments->{$black_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/) {
1231                 $comments->{$white_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/;
1232                 $pos->{'white_clock'} = hms_to_sec($1);
1233                 $comments->{$black_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/;
1234                 $pos->{'black_clock'} = hms_to_sec($1);
1235                 return;
1236         }
1237
1238         delete $pos->{'white_clock'};
1239         delete $pos->{'black_clock'};
1240 }
1241
1242 sub hms_to_sec {
1243         my $hms = shift;
1244         return undef if (!defined($hms));
1245         $hms =~ /(\d+):(\d+):(\d+)/;
1246         return $1 * 3600 + $2 * 60 + $3;
1247 }
1248
1249 sub find_clock_start {
1250         my ($pos, $prev_pos) = @_;
1251
1252         # If the game is over, the clock is stopped.
1253         if (exists($pos->{'result'}) &&
1254             ($pos->{'result'} eq '1-0' ||
1255              $pos->{'result'} eq '1/2-1/2' ||
1256              $pos->{'result'} eq '0-1')) {
1257                 return;
1258         }
1259
1260         # When we don't have any moves, we assume the clock hasn't started yet.
1261         if ($pos->{'move_num'} == 1 && $pos->{'toplay'} eq 'W') {
1262                 if (defined($remoteglotconf::adjust_clocks_before_move)) {
1263                         &$remoteglotconf::adjust_clocks_before_move(\$pos->{'white_clock'}, \$pos->{'black_clock'}, 1, 'W');
1264                 }
1265                 return;
1266         }
1267
1268         # TODO(sesse): Maybe we can get the number of moves somehow else for FICS games.
1269         # The history is needed for id_for_pos.
1270         if (!exists($pos->{'pretty_history'})) {
1271                 return;
1272         }
1273
1274         my $id = id_for_pos($pos);
1275         my $clock_info = $dbh->selectrow_hashref('SELECT * FROM clock_info WHERE id=?', undef, $id);
1276         if (defined($clock_info)) {
1277                 $pos->{'white_clock'} //= $clock_info->{'white_clock'};
1278                 $pos->{'black_clock'} //= $clock_info->{'black_clock'};
1279                 if ($pos->{'toplay'} eq 'W') {
1280                         $pos->{'white_clock_target'} = $clock_info->{'white_clock_target'};
1281                 } else {
1282                         $pos->{'black_clock_target'} = $clock_info->{'black_clock_target'};
1283                 }
1284                 return;
1285         }
1286
1287         # OK, we haven't seen this position before, so we assume the move
1288         # happened right now.
1289
1290         # See if we should do our own clock management (ie., clock information
1291         # is spurious or non-existent).
1292         if (defined($remoteglotconf::adjust_clocks_before_move)) {
1293                 my $wc = $pos->{'white_clock'} // $prev_pos->{'white_clock'};
1294                 my $bc = $pos->{'black_clock'} // $prev_pos->{'black_clock'};
1295                 if (defined($prev_pos->{'white_clock_target'})) {
1296                         $wc = $prev_pos->{'white_clock_target'} - time;
1297                 }
1298                 if (defined($prev_pos->{'black_clock_target'})) {
1299                         $bc = $prev_pos->{'black_clock_target'} - time;
1300                 }
1301                 &$remoteglotconf::adjust_clocks_before_move(\$wc, \$bc, $pos->{'move_num'}, $pos->{'toplay'});
1302                 $pos->{'white_clock'} = $wc;
1303                 $pos->{'black_clock'} = $bc;
1304         }
1305
1306         my $key = ($pos->{'toplay'} eq 'W') ? 'white_clock' : 'black_clock';
1307         if (!exists($pos->{$key})) {
1308                 # No clock information.
1309                 return;
1310         }
1311         my $time_left = $pos->{$key};
1312         my ($white_clock_target, $black_clock_target);
1313         if ($pos->{'toplay'} eq 'W') {
1314                 $white_clock_target = $pos->{'white_clock_target'} = time + $time_left;
1315         } else {
1316                 $black_clock_target = $pos->{'black_clock_target'} = time + $time_left;
1317         }
1318         local $dbh->{AutoCommit} = 0;
1319         $dbh->do('DELETE FROM clock_info WHERE id=?', undef, $id);
1320         $dbh->do('INSERT INTO clock_info (id, white_clock, black_clock, white_clock_target, black_clock_target) VALUES (?, ?, ?, ?, ?)', undef,
1321                 $id, $pos->{'white_clock'}, $pos->{'black_clock'}, $white_clock_target, $black_clock_target);
1322         $dbh->commit;
1323 }
1324
1325 sub schedule_tb_lookup {
1326         return if (!defined($remoteglotconf::tb_serial_key));
1327         my $pos = $pos_waiting // $pos_calculating;
1328         return if (exists($tb_cache{$pos->fen()}));
1329
1330         # If there's more than seven pieces, there's not going to be an answer,
1331         # so don't bother.
1332         return if ($pos->num_pieces() > 7);
1333
1334         # Max one at a time. If it's still relevant when it returns,
1335         # schedule_tb_lookup() will be called again.
1336         return if ($tb_lookup_running);
1337
1338         $tb_lookup_running = 1;
1339         my $url = 'http://158.250.18.203:6904/tasks/addtask?auth.login=' .
1340                 $remoteglotconf::tb_serial_key .
1341                 '&auth.password=aquarium&type=0&fen=' .
1342                 URI::Escape::uri_escape($pos->fen());
1343         print TBLOG "Downloading $url...\n";
1344         AnyEvent::HTTP::http_get($url, sub {
1345                 handle_tb_lookup_return(@_, $pos, $pos->fen());
1346         });
1347 }
1348
1349 sub handle_tb_lookup_return {
1350         my ($body, $header, $pos, $fen) = @_;
1351         print TBLOG "Response for [$fen]:\n";
1352         print TBLOG $header . "\n\n";
1353         print TBLOG $body . "\n\n";
1354         eval {
1355                 my $response = JSON::XS::decode_json($body);
1356                 if ($response->{'ErrorCode'} != 0) {
1357                         die "Unknown tablebase server error: " . $response->{'ErrorDesc'};
1358                 }
1359                 my $state = $response->{'Response'}{'StateString'};
1360                 if ($state eq 'COMPLETE') {
1361                         my $pgn = Chess::PGN::Parse->new(undef, $response->{'Response'}{'Moves'});
1362                         if (!defined($pgn) || !$pgn->read_game()) {
1363                                 warn "Error in parsing PGN\n";
1364                         } else {
1365                                 $pgn->quick_parse_game;
1366                                 my $pvpos = $pos;
1367                                 my $moves = $pgn->moves;
1368                                 my @uci_moves = ();
1369                                 for my $move (@$moves) {
1370                                         my $uci_move;
1371                                         ($pvpos, $uci_move) = $pvpos->make_pretty_move($move);
1372                                         push @uci_moves, $uci_move;
1373                                 }
1374                                 $tb_cache{$fen} = {
1375                                         result => $pgn->result,
1376                                         pv => \@uci_moves,
1377                                         score => $response->{'Response'}{'Score'},
1378                                 };
1379                                 output();
1380                         }
1381                 } elsif ($state =~ /QUEUED/ || $state =~ /PROCESSING/) {
1382                         # Try again in a second. Note that if we have changed
1383                         # position in the meantime, we might query a completely
1384                         # different position! But that's fine.
1385                 } else {
1386                         die "Unknown response state " . $state;
1387                 }
1388
1389                 # Wait a second before we schedule another one.
1390                 $tb_retry_timer = AnyEvent->timer(after => 1.0, cb => sub {
1391                         $tb_lookup_running = 0;
1392                         schedule_tb_lookup();
1393                 });
1394         };
1395         if ($@) {
1396                 warn "Error in tablebase lookup: $@";
1397
1398                 # Don't try this one again, but don't block new lookups either.
1399                 $tb_lookup_running = 0;
1400         }
1401 }
1402
1403 sub open_engine {
1404         my ($cmdline, $tag, $cb) = @_;
1405         return undef if (!defined($cmdline));
1406         return Engine->open($cmdline, $tag, $cb);
1407 }
1408
1409 sub col_letter_to_num {
1410         return ord(shift) - ord('a');
1411 }
1412
1413 sub row_letter_to_num {
1414         return 7 - (ord(shift) - ord('1'));
1415 }
1416
1417 sub parse_uci_move {
1418         my $move = shift;
1419         my $from_col = col_letter_to_num(substr($move, 0, 1));
1420         my $from_row = row_letter_to_num(substr($move, 1, 1));
1421         my $to_col   = col_letter_to_num(substr($move, 2, 1));
1422         my $to_row   = row_letter_to_num(substr($move, 3, 1));
1423         my $promo    = substr($move, 4, 1);
1424         return ($from_row, $from_col, $to_row, $to_col, $promo);
1425 }