git.sesse.net Git - remoteglot/blob - remoteglot.pl

   1 #! /usr/bin/perl
   2
   3 #
   4 # remoteglot - Connects an abitrary UCI-speaking engine to ICS for easier post-game
   5 #              analysis, or for live analysis of relayed games. (Do not use for
   6 #              cheating! Cheating is bad for your karma, and your abuser flag.)
   7 #
   8 # Copyright 2007 Steinar H. Gunderson <sgunderson@bigfoot.com>
   9 # Licensed under the GNU General Public License, version 2.
  10 #
  11
  12 use Net::Telnet;
  13 use FileHandle;
  14 use IPC::Open2;
  15 use Time::HiRes;
  16 use strict;
  17 use warnings;
  18
  19 # Configuration
  20 my $server = "freechess.org";
  21 my $target = "22";
  22 # my $engine = "/usr/games/toga2";
  23 my $engine = "wine Rybkav2.3.2a.mp.w32.exe";
  24 my $telltarget = undef;   # undef to be silent
  25 my @tell_intervals = (5, 20, 60, 120, 240, 480, 960);  # after each move
  26 my $uci_assume_full_compliance = 1;                    # dangerous :-)
  27 my @masters = (
  28         'Sesse',
  29         'Sessse',
  30         'Sesssse'
  31 );
  32
  33 # Program starts here
  34 $SIG{ALRM} = sub { output_screen(); };
  35
  36 $| = 1;
  37
  38 open(FICSLOG, ">ficslog.txt")
  39         or die "ficslog.txt: $!";
  40 print FICSLOG "Log starting.\n";
  41 select(FICSLOG);
  42 $| = 1;
  43
  44 open(UCILOG, ">ucilog.txt")
  45         or die "ucilog.txt: $!";
  46 print UCILOG "Log starting.\n";
  47 select(UCILOG);
  48 $| = 1;
  49 select(STDOUT);
  50
  51 # open the chess engine
  52 my $pid = IPC::Open2::open2(*UCIREAD, *UCIWRITE, $engine);
  53 my %uciinfo = ();
  54 my %uciid = ();
  55 my ($last_move, $last_tell);
  56 my $last_text = '';
  57 my $last_told_text = '';
  58 my ($pos_waiting, $pos_calculating);
  59
  60 uciprint("uci");
  61
  62 # gobble the options
  63 while (<UCIREAD>) {
  64         /uciok/ && last;
  65         handle_uci($_);
  66 }
  67
  68 uciprint("setoption name UCI_AnalyseMode value true");
  69 # uciprint("setoption name Preserve Analysis value true");
  70 uciprint("setoption name NalimovPath value c:\\nalimov");
  71 uciprint("setoption name NalimovUsage value Rarely");
  72 uciprint("setoption name Hash value 1024");
  73 uciprint("setoption name MultiPV value 3");
  74 # uciprint("setoption name Contempt value 1000");
  75 # uciprint("setoption name Outlook value Ultra Optimistic");
  76 uciprint("ucinewgame");
  77
  78 print "Chess engine ready.\n";
  79
  80 # now talk to FICS
  81 my $t = Net::Telnet->new(Timeout => 10, Prompt => '/fics% /');
  82 $t->input_log(\*FICSLOG);
  83 $t->open($server);
  84 $t->print("guest");
  85 $t->waitfor('/Press return to enter the server/');
  86 $t->cmd("");
  87
  88 # set some options
  89 $t->cmd("set shout 0");
  90 $t->cmd("set seek 0");
  91 $t->cmd("set style 12");
  92 $t->cmd("observe $target");
  93
  94 # main loop
  95 print "FICS ready.\n";
  96 while (1) {
  97         my $rin = '';
  98         my $rout;
  99         vec($rin, fileno(UCIREAD), 1) = 1;
 100         vec($rin, fileno($t), 1) = 1;
 101
 102         my ($nfound, $timeleft) = select($rout=$rin, undef, undef, 5.0);
 103         my $sleep = 1.0;
 104
 105         while (1) {
 106                 my $line = $t->getline(Timeout => 0, errmode => 'return');
 107                 last if (!defined($line));
 108
 109                 chomp $line;
 110                 $line =~ tr/\r//d;
 111                 if ($line =~ /^<12> /) {
 112                         my $pos = style12_to_fen($line);
 113
 114                         # if this is already in the queue, ignore it
 115                         next if (defined($pos_waiting) && $pos->{'fen'} eq $pos_waiting->{'fen'});
 116
 117                         # if we're already chewing on this and there's nothing else in the queue,
 118                         # also ignore it
 119                         next if (!defined($pos_waiting) && defined($pos_calculating) &&
 120                                  $pos->{'fen'} eq $pos_calculating->{'fen'});
 121
 122                         # if we're already thinking on something, stop and wait for the engine
 123                         # to approve
 124                         if (defined($pos_calculating)) {
 125                                 if (!defined($pos_waiting)) {
 126                                         uciprint("stop");
 127                                 }
 128                                 if ($uci_assume_full_compliance) {
 129                                         $pos_waiting = $pos;
 130                                 } else {
 131                                         uciprint("position fen " . $pos->{'fen'});
 132                                         uciprint("go infinite");
 133                                         $pos_calculating = $pos;
 134                                 }
 135                         } else {
 136                                 # it's wrong just to give the FEN (the move history is useful,
 137                                 # and per the UCI spec, we should really have sent "ucinewgame"),
 138                                 # but it's easier
 139                                 uciprint("position fen " . $pos->{'fen'});
 140                                 uciprint("go infinite");
 141                                 $pos_calculating = $pos;
 142                         }
 143
 144                         %uciinfo = ();
 145                         $last_move = time;
 146
 147                         #
 148                         # Output a command every move to note that we're
 149                         # still paying attention -- this is a good tradeoff,
 150                         # since if no move has happened in the last half
 151                         # hour, the analysis/relay has most likely stopped
 152                         # and we should stop hogging server resources.
 153                         #
 154                         $t->cmd("date");
 155                 }
 156                 if ($line =~ /^([A-Za-z]+)(?:\([A-Z]+\))* tells you: (.*)$/) {
 157                         my ($who, $msg) = ($1, $2);
 158
 159                         next if (grep { $_ eq $who } (@masters) == 0);
 160
 161                         if ($msg =~ /^fics (.*?)$/) {
 162                                 $t->cmd("tell $who Executing '$1' on FICS.");
 163                                 $t->cmd($1);
 164                         } elsif ($msg =~ /^uci (.*?)$/) {
 165                                 $t->cmd("tell $who Sending '$1' to the engine.");
 166                                 print UCIWRITE "$1\n";
 167                         } else {
 168                                 $t->cmd("tell $who Couldn't understand '$msg', sorry.");
 169                         }
 170                 }
 171                 #print "FICS: [$line]\n";
 172                 $sleep = 0;
 173         }
 174
 175         # any fun on the UCI channel?
 176         if ($nfound > 0 && vec($rout, fileno(UCIREAD), 1) == 1) {
 177                 #
 178                 # Read until we've got a full line -- if the engine sends part of
 179                 # a line and then stops we're pretty much hosed, but that should
 180                 # never happen.
 181                 #
 182                 my $line = '';
 183                 while ($line !~ /\n/) {
 184                         my $tmp;
 185                         my $ret = sysread UCIREAD, $tmp, 1;
 186
 187                         if (!defined($ret)) {
 188                                 next if ($!{EINTR});
 189                                 die "error in reading from the UCI engine: $!";
 190                         } elsif ($ret == 0) {
 191                                 die "EOF from UCI engine";
 192                         }
 193
 194                         $line .= $tmp;
 195                 }
 196
 197                 $line =~ tr/\r\n//d;
 198                 handle_uci($line);
 199                 $sleep = 0;
 200
 201                 # don't update too often
 202                 Time::HiRes::alarm(0.2);
 203         }
 204
 205         sleep $sleep;
 206 }
 207
 208 sub handle_uci {
 209         my ($line) = @_;
 210
 211         chomp $line;
 212         $line =~ tr/\r//d;
 213         print UCILOG localtime() . " <= $line\n";
 214         if ($line =~ /^info/) {
 215                 my (@infos) = split / /, $line;
 216                 shift @infos;
 217
 218                 parse_infos(@infos);
 219         }
 220         if ($line =~ /^id/) {
 221                 my (@ids) = split / /, $line;
 222                 shift @ids;
 223
 224                 parse_ids(@ids);
 225         }
 226         if ($line =~ /^bestmove/ && $uci_assume_full_compliance) {
 227                 if (defined($pos_waiting)) {
 228                         uciprint("position fen " . $pos_waiting->{'fen'});
 229                         uciprint("go infinite");
 230
 231                         $pos_calculating = $pos_waiting;
 232                         $pos_waiting = undef;
 233                 }
 234         }
 235 }
 236
 237 sub parse_infos {
 238         my (@x) = @_;
 239         my $mpv = '';
 240
 241         while (scalar @x > 0) {
 242                 if ($x[0] =~ 'multipv') {
 243                         shift @x;
 244                         $mpv = shift @x;
 245                         next;
 246                 }
 247                 if ($x[0] =~ /^(currmove|currmovenumber|cpuload)$/) {
 248                         my $key = shift @x;
 249                         my $value = shift @x;
 250                         $uciinfo{$key} = $value;
 251                         next;
 252                 }
 253                 if ($x[0] =~ /^(depth|seldepth|hashfull|time|nodes|nps|tbhits)$/) {
 254                         my $key = shift @x;
 255                         my $value = shift @x;
 256                         $uciinfo{$key . $mpv} = $value;
 257                         next;
 258                 }
 259                 if ($x[0] eq 'score') {
 260                         shift @x;
 261
 262                         delete $uciinfo{'score_cp' . $mpv};
 263                         delete $uciinfo{'score_mate' . $mpv};
 264
 265                         while ($x[0] =~ /^(cp|mate|lowerbound|upperbound)$/) {
 266                                 if ($x[0] eq 'cp') {
 267                                         shift @x;
 268                                         $uciinfo{'score_cp' . $mpv} = shift @x;
 269                                 } elsif ($x[0] eq 'mate') {
 270                                         shift @x;
 271                                         $uciinfo{'score_mate' . $mpv} = shift @x;
 272                                 } else {
 273                                         shift @x;
 274                                 }
 275                         }
 276                         next;
 277                 }
 278                 if ($x[0] eq 'pv') {
 279                         $uciinfo{'pv' . $mpv} = [ @x[1..$#x] ];
 280                         last;
 281                 }
 282                 if ($x[0] eq 'string' || $x[0] eq 'UCI_AnalyseMode' || $x[0] eq 'setting' || $x[0] eq 'contempt') {
 283                         last;
 284                 }
 285
 286                 #print "unknown info '$x[0]', trying to recover...\n";
 287                 #shift @x;
 288                 die "Unknown info '" . join(',', @x) . "'";
 289
 290         }
 291 }
 292
 293 sub parse_ids {
 294         my (@x) = @_;
 295
 296         while (scalar @x > 0) {
 297                 if ($x[0] =~ /^(name|author)$/) {
 298                         my $key = shift @x;
 299                         my $value = join(' ', @x);
 300                         $uciid{$key} = $value;
 301                         last;
 302                 }
 303
 304                 # unknown
 305                 shift @x;
 306         }
 307 }
 308
 309 sub style12_to_fen {
 310         my $str = shift;
 311         my %pos = ();
 312         my (@x) = split / /, $str;
 313
 314         $pos{'board'} = [ @x[1..8] ];
 315         $pos{'toplay'} = $x[9];
 316
 317         # the board itself
 318         my (@board) = @x[1..8];
 319         for my $rank (0..7) {
 320                 $board[$rank] =~ s/(-+)/length($1)/ge;
 321         }
 322         my $fen = join('/', @board);
 323
 324         # white/black to move
 325         $fen .= " ";
 326         $fen .= lc($x[9]);
 327
 328         # castling
 329         my $castling = "";
 330         $castling .= "K" if ($x[11] == 1);
 331         $castling .= "Q" if ($x[12] == 1);
 332         $castling .= "k" if ($x[13] == 1);
 333         $castling .= "q" if ($x[14] == 1);
 334         $castling = "-" if ($castling eq "");
 335         $fen .= " ";
 336         $fen .= $castling;
 337
 338         # en passant
 339         my $ep = "-";
 340         if ($x[10] != -1) {
 341                 my $col = $x[10];
 342                 my $nep = (qw(a b c d e f g h))[$col];
 343
 344                 if ($x[9] eq 'B') {
 345                         $nep .= "3";
 346                 } else {
 347                         $nep .= "6";
 348                 }
 349
 350                 #
 351                 # Showing the en passant square when actually no capture can be made
 352                 # seems to confuse at least Rybka. Thus, check if there's actually
 353                 # a pawn of the opposite side that can do the en passant move, and if
 354                 # not, just lie -- it doesn't matter anyway. I'm unsure what's the
 355                 # "right" thing as per the standard, though.
 356                 #
 357                 if ($x[9] eq 'B') {
 358                         $ep = $nep if ($col > 0 && substr($pos{'board'}[4], $col-1, 1) eq 'p');
 359                         $ep = $nep if ($col < 7 && substr($pos{'board'}[4], $col+1, 1) eq 'p');
 360                 } else {
 361                         $ep = $nep if ($col > 0 && substr($pos{'board'}[3], $col-1, 1) eq 'P');
 362                         $ep = $nep if ($col < 7 && substr($pos{'board'}[3], $col+1, 1) eq 'P');
 363                 }
 364         }
 365         $fen .= " ";
 366         $fen .= $ep;
 367
 368         # half-move clock
 369         $fen .= " ";
 370         $fen .= $x[15];
 371
 372         # full-move clock
 373         $fen .= " ";
 374         $fen .= $x[26];
 375
 376         $pos{'fen'} = $fen;
 377
 378         return \%pos;
 379 }
 380
 381 sub prettyprint_pv {
 382         my ($board, @pvs) = @_;
 383
 384         if (scalar @pvs == 0 || !defined($pvs[0])) {
 385                 return ();
 386         }
 387
 388         my @nb = @$board;
 389
 390         my $pv = shift @pvs;
 391         my $from_col = ord(substr($pv, 0, 1)) - ord('a');
 392         my $from_row = 7 - (ord(substr($pv, 1, 1)) - ord('1'));
 393         my $to_col   = ord(substr($pv, 2, 1)) - ord('a');
 394         my $to_row   = 7 - (ord(substr($pv, 3, 1)) - ord('1'));
 395
 396         my $pretty;
 397         my $piece = substr($board->[$from_row], $from_col, 1);
 398
 399         if ($piece eq '-') {
 400                 die "Invalid move";
 401         }
 402
 403         # white short castling
 404         if ($pv eq 'e1g1' && $piece eq 'K') {
 405                 # king
 406                 substr($nb[7], 4, 1, '-');
 407                 substr($nb[7], 6, 1, $piece);
 408
 409                 # rook
 410                 substr($nb[7], 7, 1, '-');
 411                 substr($nb[7], 5, 1, 'R');
 412
 413                 return ('0-0', prettyprint_pv(\@nb, @pvs));
 414         }
 415
 416         # white long castling
 417         if ($pv eq 'e1c1' && $piece eq 'K') {
 418                 # king
 419                 substr($nb[7], 4, 1, '-');
 420                 substr($nb[7], 2, 1, $piece);
 421
 422                 # rook
 423                 substr($nb[7], 0, 1, '-');
 424                 substr($nb[7], 3, 1, 'R');
 425
 426                 return ('0-0-0', prettyprint_pv(\@nb, @pvs));
 427         }
 428
 429         # black short castling
 430         if ($pv eq 'e8g8' && $piece eq 'k') {
 431                 # king
 432                 substr($nb[0], 4, 1, '-');
 433                 substr($nb[0], 6, 1, $piece);
 434
 435                 # rook
 436                 substr($nb[0], 7, 1, '-');
 437                 substr($nb[0], 5, 1, 'r');
 438
 439                 return ('0-0', prettyprint_pv(\@nb, @pvs));
 440         }
 441
 442         # black long castling
 443         if ($pv eq 'e8c8' && $piece eq 'k') {
 444                 # king
 445                 substr($nb[0], 4, 1, '-');
 446                 substr($nb[0], 2, 1, $piece);
 447
 448                 # rook
 449                 substr($nb[0], 0, 1, '-');
 450                 substr($nb[0], 3, 1, 'r');
 451
 452                 return ('0-0-0', prettyprint_pv(\@nb, @pvs));
 453         }
 454
 455         # check if the from-piece is a pawn
 456         if (lc($piece) eq 'p') {
 457                 # attack?
 458                 if ($from_col != $to_col) {
 459                         $pretty = substr($pv, 0, 1) . 'x' . substr($pv, 2, 2);
 460
 461                         # en passant?
 462                         if (substr($board->[$to_row], $to_col, 1) eq '-') {
 463                                 if ($piece eq 'p') {
 464                                         substr($nb[$to_row + 1], $to_col, 1, '-');
 465                                 } else {
 466                                         substr($nb[$to_row - 1], $to_col, 1, '-');
 467                                 }
 468                         }
 469                 } else {
 470                         $pretty = substr($pv, 2, 2);
 471
 472                         if (length($pv) == 5) {
 473                                 # promotion
 474                                 $pretty .= "=";
 475                                 $pretty .= uc(substr($pv, 4, 1));
 476
 477                                 if ($piece eq 'p') {
 478                                         $piece = substr($pv, 4, 1);
 479                                 } else {
 480                                         $piece = uc(substr($pv, 4, 1));
 481                                 }
 482                         }
 483                 }
 484         } else {
 485                 $pretty = uc($piece);
 486
 487                 # see how many of these pieces could go here, in all
 488                 my $num_total = 0;
 489                 for my $col (0..7) {
 490                         for my $row (0..7) {
 491                                 next unless (substr($board->[$row], $col, 1) eq $piece);
 492                                 ++$num_total if (can_reach($board, $piece, $row, $col, $to_row, $to_col));
 493                         }
 494                 }
 495
 496                 # see how many of these pieces from the given row could go here
 497                 my $num_row = 0;
 498                 for my $col (0..7) {
 499                         next unless (substr($board->[$from_row], $col, 1) eq $piece);
 500                         ++$num_row if (can_reach($board, $piece, $from_row, $col, $to_row, $to_col));
 501                 }
 502
 503                 # and same for columns
 504                 my $num_col = 0;
 505                 for my $row (0..7) {
 506                         next unless (substr($board->[$row], $from_col, 1) eq $piece);
 507                         ++$num_col if (can_reach($board, $piece, $row, $from_col, $to_row, $to_col));
 508                 }
 509
 510                 # see if we need to disambiguate
 511                 if ($num_total > 1) {
 512                         if ($num_col == 1) {
 513                                 $pretty .= substr($pv, 0, 1);
 514                         } elsif ($num_row == 1) {
 515                                 $pretty .= substr($pv, 1, 1);
 516                         } else {
 517                                 $pretty .= substr($pv, 0, 2);
 518                         }
 519                 }
 520
 521                 # attack?
 522                 if (substr($board->[$to_row], $to_col, 1) ne '-') {
 523                         $pretty .= 'x';
 524                 }
 525
 526                 $pretty .= substr($pv, 2, 2);
 527         }
 528
 529         # update the board
 530         substr($nb[$from_row], $from_col, 1, '-');
 531         substr($nb[$to_row], $to_col, 1, $piece);
 532
 533         if (in_mate(\@nb)) {
 534                 $pretty .= '#';
 535         } elsif (in_check(\@nb) ne 'none') {
 536                 $pretty .= '+';
 537         }
 538
 539         return ($pretty, prettyprint_pv(\@nb, @pvs));
 540 }
 541
 542 sub output_screen {
 543         #return;
 544
 545         return if (!defined($pos_calculating));
 546
 547         #
 548         # Check the PVs first. if they're invalid, just wait, as our data
 549         # is most likely out of sync. This isn't a very good solution, as
 550         # it can frequently miss stuff, but it's good enough for most users.
 551         #
 552         eval {
 553                 my $dummy;
 554                 if (exists($uciinfo{'pv'})) {
 555                         $dummy = prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv'}});
 556                 }
 557
 558                 my $mpv = 1;
 559                 while (exists($uciinfo{'pv' . $mpv})) {
 560                         $dummy = prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv' . $mpv}});
 561                         ++$mpv;
 562                 }
 563         };
 564         if ($@) {
 565                 %uciinfo = ();
 566                 return;
 567         }
 568
 569         my $text = '';
 570
 571         if (exists($uciid{'name'})) {
 572                 $text .= "Analysis by $uciid{'name'}:\n\n";
 573         } else {
 574                 $text .= "Analysis:\n\n";
 575         }
 576
 577         return unless (exists($pos_calculating->{'board'}));
 578
 579         #
 580         # Some programs _always_ report MultiPV, even with only one PV.
 581         # In this case, we simply use that data as if MultiPV was never
 582         # specified.
 583         #
 584         if (exists($uciinfo{'pv1'}) && !exists($uciinfo{'pv2'})) {
 585                 for my $key qw(pv score_cp score_mate nodes nps depth seldepth tbhits) {
 586                         if (exists($uciinfo{$key . '1'}) && !exists($uciinfo{$key})) {
 587                                 $uciinfo{$key} = $uciinfo{$key . '1'};
 588                         }
 589                 }
 590         }
 591
 592         if (exists($uciinfo{'pv1'}) && exists($uciinfo{'pv2'})) {
 593                 # multi-PV
 594                 my $mpv = 1;
 595                 while (exists($uciinfo{'pv' . $mpv})) {
 596                         $text .= sprintf "  PV%2u", $mpv;
 597                         my $score = short_score(\%uciinfo, $pos_calculating, $mpv);
 598                         $text .= "  ($score)" if (defined($score));
 599
 600                         my $tbhits = '';
 601                         if (exists($uciinfo{'tbhits' . $mpv})) {
 602                                 $tbhits = sprintf ", %u tbhits", $uciinfo{'tbhits' . $mpv};
 603                         }
 604
 605                         if (exists($uciinfo{'nodes' . $mpv}) && exists($uciinfo{'nps' . $mpv}) && exists($uciinfo{'depth' . $mpv})) {
 606                                 $text .= sprintf " (%5u kn, %3u kn/s, %2u ply$tbhits)",
 607                                         $uciinfo{'nodes' . $mpv} / 1000, $uciinfo{'nps' . $mpv} / 1000, $uciinfo{'depth' . $mpv};
 608                         }
 609
 610                         $text .= ":\n";
 611                         $text .= "  " . join(', ', prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv' . $mpv}})) . "\n";
 612                         $text .= "\n";
 613                         ++$mpv;
 614                 }
 615         } else {
 616                 # single-PV
 617                 my $score = long_score(\%uciinfo, $pos_calculating, '');
 618                 $text .= "  $score\n" if defined($score);
 619                 $text .=  "  PV: " . join(', ', prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv'}}));
 620                 $text .=  "\n";
 621
 622                 if (exists($uciinfo{'nodes'}) && exists($uciinfo{'nps'}) && exists($uciinfo{'depth'})) {
 623                         $text .= sprintf "  %u nodes, %7u nodes/sec, depth %u ply",
 624                                 $uciinfo{'nodes'}, $uciinfo{'nps'}, $uciinfo{'depth'};
 625                 }
 626                 if (exists($uciinfo{'tbhits'})) {
 627                         $text .= sprintf ", %u Nalimov hits", $uciinfo{'tbhits'};
 628                 }
 629                 if (exists($uciinfo{'seldepth'})) {
 630                         $text .= sprintf " (%u selective)", $uciinfo{'seldepth'};
 631                 }
 632                 $text .=  "\n\n";
 633         }
 634
 635         if ($last_text ne $text) {
 636                 print "\e[H\e[2J"; # clear the screen
 637                 print $text;
 638                 $last_text = $text;
 639         }
 640
 641         # Now construct the tell text, if any
 642         return if (!defined($telltarget));
 643
 644         my $tell_text = '';
 645
 646         if (exists($uciid{'name'})) {
 647                 $tell_text .= "Analysis by $uciid{'name'} -- see http://analysis.sesse.net/ for more information\n";
 648         } else {
 649                 $tell_text .= "Computer analysis -- http://analysis.sesse.net/ for more information\n";
 650         }
 651
 652         if (exists($uciinfo{'pv1'}) && exists($uciinfo{'pv2'})) {
 653                 # multi-PV
 654                 my $mpv = 1;
 655                 while (exists($uciinfo{'pv' . $mpv})) {
 656                         $tell_text .= sprintf "  PV%2u", $mpv;
 657                         my $score = short_score(\%uciinfo, $pos_calculating, $mpv);
 658                         $tell_text .= "  ($score)" if (defined($score));
 659
 660                         if (exists($uciinfo{'depth' . $mpv})) {
 661                                 $tell_text .= sprintf " (%2u ply)", $uciinfo{'depth' . $mpv};
 662                         }
 663
 664                         $tell_text .= ": ";
 665                         $tell_text .= join(', ', prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv' . $mpv}}));
 666                         $tell_text .= "\n";
 667                         ++$mpv;
 668                 }
 669         } else {
 670                 # single-PV
 671                 my $score = long_score(\%uciinfo, $pos_calculating, '');
 672                 $tell_text .= "  $score\n" if defined($score);
 673                 $tell_text .= "  PV: " . join(', ', prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv'}}));
 674                 if (exists($uciinfo{'depth'})) {
 675                         $tell_text .= sprintf " (depth %u ply)", $uciinfo{'depth'};
 676                 }
 677                 $tell_text .=  "\n";
 678         }
 679
 680         # see if a new tell is called for -- it is if the delay has expired _and_
 681         # this is not simply a repetition of the last one
 682         if ($last_told_text ne $tell_text) {
 683                 my $now = time;
 684                 for my $iv (@tell_intervals) {
 685                         last if ($now - $last_move < $iv);
 686                         next if ($last_tell - $last_move >= $iv);
 687
 688                         for my $line (split /\n/, $tell_text) {
 689                                 $t->print("tell $telltarget [$target] $line");
 690                         }
 691
 692                         $last_told_text = $text;
 693                         $last_tell = $now;
 694
 695                         last;
 696                 }
 697         }
 698 }
 699
 700 sub find_kings {
 701         my $board = shift;
 702         my ($wkr, $wkc, $bkr, $bkc);
 703
 704         for my $row (0..7) {
 705                 for my $col (0..7) {
 706                         my $piece = substr($board->[$row], $col, 1);
 707                         if ($piece eq 'K') {
 708                                 ($wkr, $wkc) = ($row, $col);
 709                         } elsif ($piece eq 'k') {
 710                                 ($bkr, $bkc) = ($row, $col);
 711                         }
 712                 }
 713         }
 714
 715         return ($wkr, $wkc, $bkr, $bkc);
 716 }
 717
 718 sub in_mate {
 719         my $board = shift;
 720         my $check = in_check($board);
 721         return 0 if ($check eq 'none');
 722
 723         # try all possible moves for the side in check
 724         for my $row (0..7) {
 725                 for my $col (0..7) {
 726                         my $piece = substr($board->[$row], $col, 1);
 727                         next if ($piece eq '-');
 728
 729                         if ($check eq 'white') {
 730                                 next if ($piece eq lc($piece));
 731                         } else {
 732                                 next if ($piece eq uc($piece));
 733                         }
 734
 735                         for my $dest_row (0..7) {
 736                                 for my $dest_col (0..7) {
 737                                         next if ($row == $dest_row && $col == $dest_col);
 738                                         next unless (can_reach($board, $piece, $row, $col, $dest_row, $dest_col));
 739
 740                                         my @nb = @$board;
 741                                         substr($nb[$row], $col, 1, '-');
 742                                         substr($nb[$dest_row], $dest_col, 1, $piece);
 743
 744                                         my $new_check = in_check(\@nb);
 745                                         return 0 if ($new_check ne $check && $new_check ne 'both');
 746                                 }
 747                         }
 748                 }
 749         }
 750
 751         # nothing to do; mate
 752         return 1;
 753 }
 754
 755 sub in_check {
 756         my $board = shift;
 757         my ($black_check, $white_check) = (0, 0);
 758
 759         my ($wkr, $wkc, $bkr, $bkc) = find_kings($board);
 760
 761         # check all pieces for the possibility of threatening the two kings
 762         for my $row (0..7) {
 763                 for my $col (0..7) {
 764                         my $piece = substr($board->[$row], $col, 1);
 765                         next if ($piece eq '-');
 766
 767                         if (uc($piece) eq $piece) {
 768                                 # white piece
 769                                 $black_check = 1 if (can_reach($board, $piece, $row, $col, $bkr, $bkc));
 770                         } else {
 771                                 # black piece
 772                                 $white_check = 1 if (can_reach($board, $piece, $row, $col, $wkr, $wkc));
 773                         }
 774                 }
 775         }
 776
 777         if ($black_check && $white_check) {
 778                 return 'both';
 779         } elsif ($black_check) {
 780                 return 'black';
 781         } elsif ($white_check) {
 782                 return 'white';
 783         } else {
 784                 return 'none';
 785         }
 786 }
 787
 788 sub can_reach {
 789         my ($board, $piece, $from_row, $from_col, $to_row, $to_col) = @_;
 790
 791         # can't eat your own piece
 792         my $dest_piece = substr($board->[$to_row], $to_col, 1);
 793         if ($dest_piece ne '-') {
 794                 return 0 if (($piece eq lc($piece)) == ($dest_piece eq lc($dest_piece)));
 795         }
 796
 797         if (lc($piece) eq 'k') {
 798                 return (abs($from_row - $to_row) <= 1 && abs($from_col - $to_col) <= 1);
 799         }
 800         if (lc($piece) eq 'r') {
 801                 return 0 unless ($from_row == $to_row || $from_col == $to_col);
 802
 803                 # check that there's a clear passage
 804                 if ($from_row == $to_row) {
 805                         if ($from_col > $to_col) {
 806                                 ($to_col, $from_col) = ($from_col, $to_col);
 807                         }
 808
 809                         for my $c (($from_col+1)..($to_col-1)) {
 810                                 my $middle_piece = substr($board->[$to_row], $c, 1);
 811                                 return 0 if ($middle_piece ne '-');
 812                         }
 813
 814                         return 1;
 815                 } else {
 816                         if ($from_row > $to_row) {
 817                                 ($to_row, $from_row) = ($from_row, $to_row);
 818                         }
 819
 820                         for my $r (($from_row+1)..($to_row-1)) {
 821                                 my $middle_piece = substr($board->[$r], $to_col, 1);
 822                                 return 0 if ($middle_piece ne '-');
 823                         }
 824
 825                         return 1;
 826                 }
 827         }
 828         if (lc($piece) eq 'b') {
 829                 return 0 unless (abs($from_row - $to_row) == abs($from_col - $to_col));
 830
 831                 my $dr = ($to_row - $from_row) / abs($to_row - $from_row);
 832                 my $dc = ($to_col - $from_col) / abs($to_col - $from_col);
 833
 834                 my $r = $from_row + $dr;
 835                 my $c = $from_col + $dc;
 836
 837                 while ($r != $to_row) {
 838                         my $middle_piece = substr($board->[$r], $c, 1);
 839                         return 0 if ($middle_piece ne '-');
 840
 841                         $r += $dr;
 842                         $c += $dc;
 843                 }
 844
 845                 return 1;
 846         }
 847         if (lc($piece) eq 'n') {
 848                 my $diff_r = abs($from_row - $to_row);
 849                 my $diff_c = abs($from_col - $to_col);
 850                 return 1 if ($diff_r == 2 && $diff_c == 1);
 851                 return 1 if ($diff_r == 1 && $diff_c == 2);
 852                 return 0;
 853         }
 854         if ($piece eq 'q') {
 855                 return (can_reach($board, 'r', $from_row, $from_col, $to_row, $to_col) ||
 856                         can_reach($board, 'b', $from_row, $from_col, $to_row, $to_col));
 857         }
 858         if ($piece eq 'Q') {
 859                 return (can_reach($board, 'R', $from_row, $from_col, $to_row, $to_col) ||
 860                         can_reach($board, 'B', $from_row, $from_col, $to_row, $to_col));
 861         }
 862         if ($piece eq 'p') {
 863                 # black pawn
 864                 if ($to_col == $from_col && $to_row == $from_row + 1) {
 865                         return ($dest_piece eq '-');
 866                 }
 867                 if (abs($to_col - $from_col) == 1 && $to_row == $from_row + 1) {
 868                         return ($dest_piece ne '-');
 869                 }
 870                 return 0;
 871         }
 872         if ($piece eq 'P') {
 873                 # white pawn
 874                 if ($to_col == $from_col && $to_row == $from_row - 1) {
 875                         return ($dest_piece eq '-');
 876                 }
 877                 if (abs($to_col - $from_col) == 1 && $to_row == $from_row - 1) {
 878                         return ($dest_piece ne '-');
 879                 }
 880                 return 0;
 881         }
 882
 883         # unknown piece
 884         return 0;
 885 }
 886
 887 sub uciprint {
 888         my $msg = shift;
 889         print UCIWRITE "$msg\n";
 890         print UCILOG localtime() . " => $msg\n";
 891 }
 892
 893 sub short_score {
 894         my ($uciinfo, $pos, $mpv) = @_;
 895
 896         if (defined($uciinfo{'score_mate' . $mpv})) {
 897                 return sprintf "M%3d", $uciinfo{'score_mate' . $mpv};
 898         } else {
 899                 if (exists($uciinfo{'score_cp' . $mpv})) {
 900                         my $score = $uciinfo{'score_cp' . $mpv} * 0.01;
 901                         if ($pos->{'toplay'} eq 'B') {
 902                                 $score = -$score;
 903                         }
 904                         return sprintf "%+5.2f", $score;
 905                 }
 906         }
 907
 908         return undef;
 909 }
 910
 911 sub long_score {
 912         my ($uciinfo, $pos, $mpv) = @_;
 913
 914         if (defined($uciinfo{'score_mate' . $mpv})) {
 915                 my $mate = $uciinfo{'score_mate' . $mpv};
 916                 if ($pos->{'toplay'} eq 'B') {
 917                         $mate = -$mate;
 918                 }
 919                 if ($mate > 0) {
 920                         return sprintf "White mates in %u", $mate;
 921                 } else {
 922                         return sprintf "Black mates in %u", -$mate;
 923                 }
 924         } else {
 925                 if (exists($uciinfo{'score_cp' . $mpv})) {
 926                         my $score = $uciinfo{'score_cp' . $mpv} * 0.01;
 927                         if ($pos->{'toplay'} eq 'B') {
 928                                 $score = -$score;
 929                         }
 930                         return sprintf "Score: %+5.2f", $score;
 931                 }
 932         }
 933
 934         return undef;
 935 }