git.sesse.net Git - remoteglot/blob - remoteglot.pl

   1 #! /usr/bin/perl
   2
   3 #
   4 # remoteglot - Connects an abitrary UCI-speaking engine to ICS for easier post-game
   5 #              analysis, or for live analysis of relayed games. (Do not use for
   6 #              cheating! Cheating is bad for your karma, and your abuser flag.)
   7 #
   8 # Copyright 2007 Steinar H. Gunderson <steinar+remoteglot@gunderson.no>
   9 # Licensed under the GNU General Public License, version 2.
  10 #
  11
  12 use AnyEvent;
  13 use AnyEvent::Handle;
  14 use AnyEvent::HTTP;
  15 use Chess::PGN::Parse;
  16 use EV;
  17 use Net::Telnet;
  18 use File::Slurp;
  19 use IPC::Open2;
  20 use Time::HiRes;
  21 use JSON::XS;
  22 use URI::Escape;
  23 use DBI;
  24 use DBD::Pg;
  25 require 'Position.pm';
  26 require 'Engine.pm';
  27 require 'config.pm';
  28 use strict;
  29 use warnings;
  30 no warnings qw(once);
  31
  32 # Program starts here
  33 my $latest_update = undef;
  34 my $output_timer = undef;
  35 my $http_timer = undef;
  36 my $stop_pgn_fetch = 0;
  37 my $tb_retry_timer = undef;
  38 my %tb_cache = ();
  39 my $tb_lookup_running = 0;
  40 my $last_written_json = undef;
  41
  42 # Persisted so we can restart.
  43 # TODO: Figure out an appropriate way to deal with database restarts
  44 # and/or Postgres going away entirely.
  45 my $dbh = DBI->connect($remoteglotconf::dbistr, $remoteglotconf::dbiuser, $remoteglotconf::dbipass)
  46         or die DBI->errstr;
  47 $dbh->{RaiseError} = 1;
  48
  49 $| = 1;
  50
  51 open(FICSLOG, ">ficslog.txt")
  52         or die "ficslog.txt: $!";
  53 print FICSLOG "Log starting.\n";
  54 select(FICSLOG);
  55 $| = 1;
  56
  57 open(UCILOG, ">ucilog.txt")
  58         or die "ucilog.txt: $!";
  59 print UCILOG "Log starting.\n";
  60 select(UCILOG);
  61 $| = 1;
  62
  63 open(TBLOG, ">tblog.txt")
  64         or die "tblog.txt: $!";
  65 print TBLOG "Log starting.\n";
  66 select(TBLOG);
  67 $| = 1;
  68
  69 select(STDOUT);
  70 umask 0022;
  71
  72 # open the chess engine
  73 my $engine = open_engine($remoteglotconf::engine_cmdline, 'E1', sub { handle_uci(@_, 1); });
  74 my $engine2 = open_engine($remoteglotconf::engine2_cmdline, 'E2', sub { handle_uci(@_, 0); });
  75 my $last_move;
  76 my $last_text = '';
  77 my ($pos_waiting, $pos_calculating, $pos_calculating_second_engine);
  78
  79 uciprint($engine, "setoption name UCI_AnalyseMode value true");
  80 while (my ($key, $value) = each %remoteglotconf::engine_config) {
  81         uciprint($engine, "setoption name $key value $value");
  82 }
  83 uciprint($engine, "ucinewgame");
  84
  85 if (defined($engine2)) {
  86         uciprint($engine2, "setoption name UCI_AnalyseMode value true");
  87         while (my ($key, $value) = each %remoteglotconf::engine2_config) {
  88                 uciprint($engine2, "setoption name $key value $value");
  89         }
  90         uciprint($engine2, "setoption name MultiPV value 500");
  91         uciprint($engine2, "ucinewgame");
  92 }
  93
  94 print "Chess engine ready.\n";
  95
  96 # now talk to FICS
  97 my $t = Net::Telnet->new(Timeout => 10, Prompt => '/fics% /');
  98 $t->input_log(\*FICSLOG);
  99 $t->open($remoteglotconf::server);
 100 $t->print($remoteglotconf::nick);
 101 $t->waitfor('/Press return to enter the server/');
 102 $t->cmd("");
 103
 104 # set some options
 105 $t->cmd("set shout 0");
 106 $t->cmd("set seek 0");
 107 $t->cmd("set style 12");
 108
 109 my $ev1 = AnyEvent->io(
 110         fh => fileno($t),
 111         poll => 'r',
 112         cb => sub {    # what callback to execute
 113                 while (1) {
 114                         my $line = $t->getline(Timeout => 0, errmode => 'return');
 115                         return if (!defined($line));
 116
 117                         chomp $line;
 118                         $line =~ tr/\r//d;
 119                         handle_fics($line);
 120                 }
 121         }
 122 );
 123 if (defined($remoteglotconf::target)) {
 124         if ($remoteglotconf::target =~ /^http:/) {
 125                 fetch_pgn($remoteglotconf::target);
 126         } else {
 127                 $t->cmd("observe $remoteglotconf::target");
 128         }
 129 }
 130 print "FICS ready.\n";
 131
 132 # Engine events have already been set up by Engine.pm.
 133 EV::run;
 134
 135 sub handle_uci {
 136         my ($engine, $line, $primary) = @_;
 137
 138         return if $line =~ /(upper|lower)bound/;
 139
 140         $line =~ s/  / /g;  # Sometimes needed for Zappa Mexico
 141         print UCILOG localtime() . " $engine->{'tag'} <= $line\n";
 142         if ($line =~ /^info/) {
 143                 my (@infos) = split / /, $line;
 144                 shift @infos;
 145
 146                 parse_infos($engine, @infos);
 147         }
 148         if ($line =~ /^id/) {
 149                 my (@ids) = split / /, $line;
 150                 shift @ids;
 151
 152                 parse_ids($engine, @ids);
 153         }
 154         if ($line =~ /^bestmove/) {
 155                 if ($primary) {
 156                         return if (!$remoteglotconf::uci_assume_full_compliance);
 157                         if (defined($pos_waiting)) {
 158                                 uciprint($engine, "position fen " . $pos_waiting->fen());
 159                                 uciprint($engine, "go infinite");
 160
 161                                 $pos_calculating = $pos_waiting;
 162                                 $pos_waiting = undef;
 163                         }
 164                 } else {
 165                         $engine2->{'info'} = {};
 166                         my $pos = $pos_waiting // $pos_calculating;
 167                         uciprint($engine2, "position fen " . $pos->fen());
 168                         uciprint($engine2, "go infinite");
 169                         $pos_calculating_second_engine = $pos;
 170                 }
 171         }
 172         output();
 173 }
 174
 175 my $getting_movelist = 0;
 176 my $pos_for_movelist = undef;
 177 my @uci_movelist = ();
 178 my @pretty_movelist = ();
 179
 180 sub handle_fics {
 181         my $line = shift;
 182         if ($line =~ /^<12> /) {
 183                 handle_position(Position->new($line));
 184                 $t->cmd("moves");
 185         }
 186         if ($line =~ /^Movelist for game /) {
 187                 my $pos = $pos_waiting // $pos_calculating;
 188                 if (defined($pos)) {
 189                         @uci_movelist = ();
 190                         @pretty_movelist = ();
 191                         $pos_for_movelist = Position->start_pos($pos->{'player_w'}, $pos->{'player_b'});
 192                         $getting_movelist = 1;
 193                 }
 194         }
 195         if ($getting_movelist &&
 196             $line =~ /^\s* \d+\. \s+                     # move number
 197                        (\S+) \s+ \( [\d:.]+ \) \s*       # first move, then time
 198                        (?: (\S+) \s+ \( [\d:.]+ \) )?    # second move, then time
 199                      /x) {
 200                 eval {
 201                         my $uci_move;
 202                         ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($1);
 203                         push @uci_movelist, $uci_move;
 204                         push @pretty_movelist, $1;
 205
 206                         if (defined($2)) {
 207                                 ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($2);
 208                                 push @uci_movelist, $uci_move;
 209                                 push @pretty_movelist, $2;
 210                         }
 211                 };
 212                 if ($@) {
 213                         warn "Error when getting FICS move history: $@";
 214                         $getting_movelist = 0;
 215                 }
 216         }
 217         if ($getting_movelist &&
 218             $line =~ /^\s+ \{.*\} \s+ (?: \* | 1\/2-1\/2 | 0-1 | 1-0 )/x) {
 219                 # End of movelist.
 220                 for my $pos ($pos_waiting, $pos_calculating) {
 221                         next if (!defined($pos));
 222                         if ($pos->fen() eq $pos_for_movelist->fen()) {
 223                                 $pos->{'history'} = \@pretty_movelist;
 224                         }
 225                 }
 226                 $getting_movelist = 0;
 227         }
 228         if ($line =~ /^([A-Za-z]+)(?:\([A-Z]+\))* tells you: (.*)$/) {
 229                 my ($who, $msg) = ($1, $2);
 230
 231                 next if (grep { $_ eq $who } (@remoteglotconf::masters) == 0);
 232
 233                 if ($msg =~ /^fics (.*?)$/) {
 234                         $t->cmd("tell $who Executing '$1' on FICS.");
 235                         $t->cmd($1);
 236                 } elsif ($msg =~ /^uci (.*?)$/) {
 237                         $t->cmd("tell $who Sending '$1' to the engine.");
 238                         print { $engine->{'write'} } "$1\n";
 239                 } elsif ($msg =~ /^pgn (.*?)$/) {
 240                         my $url = $1;
 241                         $t->cmd("tell $who Starting to poll '$url'.");
 242                         fetch_pgn($url);
 243                 } elsif ($msg =~ /^stoppgn$/) {
 244                         $t->cmd("tell $who Stopping poll.");
 245                         $stop_pgn_fetch = 1;
 246                         $http_timer = undef;
 247                 } elsif ($msg =~ /^quit$/) {
 248                         $t->cmd("tell $who Bye bye.");
 249                         exit;
 250                 } else {
 251                         $t->cmd("tell $who Couldn't understand '$msg', sorry.");
 252                 }
 253         }
 254         #print "FICS: [$line]\n";
 255 }
 256
 257 # Starts periodic fetching of PGNs from the given URL.
 258 sub fetch_pgn {
 259         my ($url) = @_;
 260         AnyEvent::HTTP::http_get($url, sub {
 261                 handle_pgn(@_, $url);
 262         });
 263 }
 264
 265 my ($last_pgn_white, $last_pgn_black);
 266 my @last_pgn_uci_moves = ();
 267 my $pgn_hysteresis_counter = 0;
 268
 269 sub handle_pgn {
 270         my ($body, $header, $url) = @_;
 271
 272         if ($stop_pgn_fetch) {
 273                 $stop_pgn_fetch = 0;
 274                 $http_timer = undef;
 275                 return;
 276         }
 277
 278         my $pgn = Chess::PGN::Parse->new(undef, $body);
 279         if (!defined($pgn)) {
 280                 warn "Error in parsing PGN from $url [body='$body']\n";
 281         } elsif (!$pgn->read_game()) {
 282                 warn "Error in reading PGN game from $url [body='$body']\n";
 283         } elsif ($body !~ /^\[/) {
 284                 warn "Malformed PGN from $url [body='$body']\n";
 285         } else {
 286                 eval {
 287                         # Skip to the right game.
 288                         while (defined($remoteglotconf::pgn_filter) &&
 289                                !&$remoteglotconf::pgn_filter($pgn)) {
 290                                 $pgn->read_game() or die "Out of games during filtering";
 291                         }
 292
 293                         $pgn->parse_game({ save_comments => 'yes' });
 294                         my $white = $pgn->white;
 295                         my $black = $pgn->black;
 296                         $white =~ s/,.*//;  # Remove first name.
 297                         $black =~ s/,.*//;  # Remove first name.
 298                         my $pos = Position->start_pos($white, $black);
 299                         my $moves = $pgn->moves;
 300                         my @uci_moves = ();
 301                         my @repretty_moves = ();
 302                         for my $move (@$moves) {
 303                                 my ($npos, $uci_move) = $pos->make_pretty_move($move);
 304                                 push @uci_moves, $uci_move;
 305
 306                                 # Re-prettyprint the move.
 307                                 my ($from_row, $from_col, $to_row, $to_col, $promo) = parse_uci_move($uci_move);
 308                                 my ($pretty, undef) = $pos->{'board'}->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
 309                                 push @repretty_moves, $pretty;
 310                                 $pos = $npos;
 311                         }
 312                         if ($pgn->result eq '1-0' || $pgn->result eq '1/2-1/2' || $pgn->result eq '0-1') {
 313                                 $pos->{'result'} = $pgn->result;
 314                         }
 315                         $pos->{'history'} = \@repretty_moves;
 316
 317                         extract_clock($pgn, $pos);
 318
 319                         # Sometimes, PGNs lose a move or two for a short while,
 320                         # or people push out new ones non-atomically.
 321                         # Thus, if we PGN doesn't change names but becomes
 322                         # shorter, we mistrust it for a few seconds.
 323                         my $trust_pgn = 1;
 324                         if (defined($last_pgn_white) && defined($last_pgn_black) &&
 325                             $last_pgn_white eq $pgn->white &&
 326                             $last_pgn_black eq $pgn->black &&
 327                             scalar(@uci_moves) < scalar(@last_pgn_uci_moves)) {
 328                                 if (++$pgn_hysteresis_counter < 3) {
 329                                         $trust_pgn = 0;
 330                                 }
 331                         }
 332                         if ($trust_pgn) {
 333                                 $last_pgn_white = $pgn->white;
 334                                 $last_pgn_black = $pgn->black;
 335                                 @last_pgn_uci_moves = @uci_moves;
 336                                 $pgn_hysteresis_counter = 0;
 337                                 handle_position($pos);
 338                         }
 339                 };
 340                 if ($@) {
 341                         warn "Error in parsing moves from $url: $@\n";
 342                 }
 343         }
 344
 345         $http_timer = AnyEvent->timer(after => 1.0, cb => sub {
 346                 fetch_pgn($url);
 347         });
 348 }
 349
 350 sub handle_position {
 351         my ($pos) = @_;
 352         find_clock_start($pos, $pos_calculating);
 353
 354         # if this is already in the queue, ignore it (just update the result)
 355         if (defined($pos_waiting) && $pos->fen() eq $pos_waiting->fen()) {
 356                 $pos_waiting->{'result'} = $pos->{'result'};
 357                 return;
 358         }
 359
 360         # if we're already chewing on this and there's nothing else in the queue,
 361         # also ignore it
 362         if (!defined($pos_waiting) && defined($pos_calculating) &&
 363             $pos->fen() eq $pos_calculating->fen()) {
 364                 $pos_calculating->{'result'} = $pos->{'result'};
 365                 return;
 366         }
 367
 368         # if we're already thinking on something, stop and wait for the engine
 369         # to approve
 370         if (defined($pos_calculating)) {
 371                 # Store the final data we have for this position in the history,
 372                 # with the precise clock information we just got from the new
 373                 # position. (Historic positions store the clock at the end of
 374                 # the position.)
 375                 #
 376                 # Do not output anything new to the main analysis; that's
 377                 # going to be obsolete really soon.
 378                 $pos_calculating->{'white_clock'} = $pos->{'white_clock'};
 379                 $pos_calculating->{'black_clock'} = $pos->{'black_clock'};
 380                 delete $pos_calculating->{'white_clock_target'};
 381                 delete $pos_calculating->{'black_clock_target'};
 382                 output_json(1);
 383
 384                 if (!defined($pos_waiting)) {
 385                         uciprint($engine, "stop");
 386                 }
 387                 if ($remoteglotconf::uci_assume_full_compliance) {
 388                         $pos_waiting = $pos;
 389                 } else {
 390                         uciprint($engine, "position fen " . $pos->fen());
 391                         uciprint($engine, "go infinite");
 392                         $pos_calculating = $pos;
 393                 }
 394         } else {
 395                 # it's wrong just to give the FEN (the move history is useful,
 396                 # and per the UCI spec, we should really have sent "ucinewgame"),
 397                 # but it's easier
 398                 uciprint($engine, "position fen " . $pos->fen());
 399                 uciprint($engine, "go infinite");
 400                 $pos_calculating = $pos;
 401         }
 402
 403         if (defined($engine2)) {
 404                 if (defined($pos_calculating_second_engine)) {
 405                         uciprint($engine2, "stop");
 406                 } else {
 407                         uciprint($engine2, "position fen " . $pos->fen());
 408                         uciprint($engine2, "go infinite");
 409                         $pos_calculating_second_engine = $pos;
 410                 }
 411                 $engine2->{'info'} = {};
 412         }
 413
 414         $engine->{'info'} = {};
 415         $last_move = time;
 416
 417         schedule_tb_lookup();
 418
 419         #
 420         # Output a command every move to note that we're
 421         # still paying attention -- this is a good tradeoff,
 422         # since if no move has happened in the last half
 423         # hour, the analysis/relay has most likely stopped
 424         # and we should stop hogging server resources.
 425         #
 426         $t->cmd("date");
 427 }
 428
 429 sub parse_infos {
 430         my ($engine, @x) = @_;
 431         my $mpv = '';
 432
 433         my $info = $engine->{'info'};
 434
 435         # Search for "multipv" first of all, since e.g. Stockfish doesn't put it first.
 436         for my $i (0..$#x - 1) {
 437                 if ($x[$i] eq 'multipv') {
 438                         $mpv = $x[$i + 1];
 439                         next;
 440                 }
 441         }
 442
 443         while (scalar @x > 0) {
 444                 if ($x[0] eq 'multipv') {
 445                         # Dealt with above
 446                         shift @x;
 447                         shift @x;
 448                         next;
 449                 }
 450                 if ($x[0] eq 'currmove' || $x[0] eq 'currmovenumber' || $x[0] eq 'cpuload') {
 451                         my $key = shift @x;
 452                         my $value = shift @x;
 453                         $info->{$key} = $value;
 454                         next;
 455                 }
 456                 if ($x[0] eq 'depth' || $x[0] eq 'seldepth' || $x[0] eq 'hashfull' ||
 457                     $x[0] eq 'time' || $x[0] eq 'nodes' || $x[0] eq 'nps' ||
 458                     $x[0] eq 'tbhits') {
 459                         my $key = shift @x;
 460                         my $value = shift @x;
 461                         $info->{$key . $mpv} = $value;
 462                         next;
 463                 }
 464                 if ($x[0] eq 'score') {
 465                         shift @x;
 466
 467                         delete $info->{'score_cp' . $mpv};
 468                         delete $info->{'score_mate' . $mpv};
 469
 470                         while ($x[0] eq 'cp' || $x[0] eq 'mate') {
 471                                 if ($x[0] eq 'cp') {
 472                                         shift @x;
 473                                         $info->{'score_cp' . $mpv} = shift @x;
 474                                 } elsif ($x[0] eq 'mate') {
 475                                         shift @x;
 476                                         $info->{'score_mate' . $mpv} = shift @x;
 477                                 } else {
 478                                         shift @x;
 479                                 }
 480                         }
 481                         next;
 482                 }
 483                 if ($x[0] eq 'pv') {
 484                         $info->{'pv' . $mpv} = [ @x[1..$#x] ];
 485                         last;
 486                 }
 487                 if ($x[0] eq 'string' || $x[0] eq 'UCI_AnalyseMode' || $x[0] eq 'setting' || $x[0] eq 'contempt') {
 488                         last;
 489                 }
 490
 491                 #print "unknown info '$x[0]', trying to recover...\n";
 492                 #shift @x;
 493                 die "Unknown info '" . join(',', @x) . "'";
 494
 495         }
 496 }
 497
 498 sub parse_ids {
 499         my ($engine, @x) = @_;
 500
 501         while (scalar @x > 0) {
 502                 if ($x[0] eq 'name') {
 503                         my $value = join(' ', @x);
 504                         $engine->{'id'}{'author'} = $value;
 505                         last;
 506                 }
 507
 508                 # unknown
 509                 shift @x;
 510         }
 511 }
 512
 513 sub prettyprint_pv_no_cache {
 514         my ($board, @pvs) = @_;
 515
 516         if (scalar @pvs == 0 || !defined($pvs[0])) {
 517                 return ();
 518         }
 519
 520         my $pv = shift @pvs;
 521         my ($from_row, $from_col, $to_row, $to_col, $promo) = parse_uci_move($pv);
 522         my ($pretty, $nb) = $board->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
 523         return ( $pretty, prettyprint_pv_no_cache($nb, @pvs) );
 524 }
 525
 526 sub prettyprint_pv {
 527         my ($pos, @pvs) = @_;
 528
 529         my $cachekey = join('', @pvs);
 530         if (exists($pos->{'prettyprint_cache'}{$cachekey})) {
 531                 return @{$pos->{'prettyprint_cache'}{$cachekey}};
 532         } else {
 533                 my @res = prettyprint_pv_no_cache($pos->{'board'}, @pvs);
 534                 $pos->{'prettyprint_cache'}{$cachekey} = \@res;
 535                 return @res;
 536         }
 537 }
 538
 539 sub complete_using_tbprobe {
 540         my ($pos, $info, $mpv) = @_;
 541
 542         # We need Fathom installed to do standalone TB probes.
 543         return if (!defined($remoteglotconf::fathom_cmdline));
 544
 545         # If we already have a mate, don't bother; in some cases, it would even be
 546         # better than a tablebase score.
 547         return if defined($info->{'score_mate' . $mpv});
 548
 549         # If we have a draw or near-draw score, there's also not much interesting
 550         # we could add from a tablebase. We only really want mates.
 551         return if ($info->{'score_cp' . $mpv} >= -12250 && $info->{'score_cp' . $mpv} <= 12250);
 552
 553         # Run through the PV until we are at a 6-man position.
 554         # TODO: We could in theory only have 5-man data.
 555         my @pv = @{$info->{'pv' . $mpv}};
 556         my $key = join('', @pv);
 557         my @moves = ();
 558         if (exists($pos->{'tbprobe_cache'}{$key})) {
 559                 @moves = $pos->{'tbprobe_cache'}{$key};
 560         } else {
 561                 if ($mpv ne '') {
 562                         # Force doing at least one move of the PV.
 563                         my $move = shift @pv;
 564                         push @moves, $move;
 565                         $pos = $pos->make_move(parse_uci_move($move));
 566                 }
 567
 568                 while ($pos->num_pieces() > 6 && $#pv > -1) {
 569                         my $move = shift @pv;
 570                         push @moves, $move;
 571                         $pos = $pos->make_move(parse_uci_move($move));
 572                 }
 573
 574                 return if ($pos->num_pieces() > 6);
 575
 576                 my $fen = $pos->fen();
 577                 my $pgn_text = `fathom --path=/srv/syzygy "$fen"`;
 578                 my $pgn = Chess::PGN::Parse->new(undef, $pgn_text);
 579                 return if (!defined($pgn) || !$pgn->read_game() || ($pgn->result ne '0-1' && $pgn->result ne '1-0'));
 580                 $pgn->quick_parse_game;
 581                 $info->{'pv' . $mpv} = \@moves;
 582
 583                 # Splice the PV from the tablebase onto what we have so far.
 584                 for my $move (@{$pgn->moves}) {
 585                         my $uci_move;
 586                         ($pos, $uci_move) = $pos->make_pretty_move($move);
 587                         push @moves, $uci_move;
 588                 }
 589         }
 590
 591         $info->{'pv' . $mpv} = \@moves;
 592
 593         my $matelen = int((1 + scalar @moves) / 2);
 594         if ((scalar @moves) % 2 == 0) {
 595                 $info->{'score_mate' . $mpv} = -$matelen;
 596         } else {
 597                 $info->{'score_mate' . $mpv} = $matelen;
 598         }
 599 }
 600
 601 sub output {
 602         #return;
 603
 604         return if (!defined($pos_calculating));
 605
 606         # Don't update too often.
 607         my $age = Time::HiRes::tv_interval($latest_update);
 608         if ($age < $remoteglotconf::update_max_interval) {
 609                 my $wait = $remoteglotconf::update_max_interval + 0.01 - $age;
 610                 $output_timer = AnyEvent->timer(after => $wait, cb => \&output);
 611                 return;
 612         }
 613
 614         my $info = $engine->{'info'};
 615
 616         #
 617         # If we have tablebase data from a previous lookup, replace the
 618         # engine data with the data from the tablebase.
 619         #
 620         my $fen = $pos_calculating->fen();
 621         if (exists($tb_cache{$fen})) {
 622                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
 623                         delete $info->{$key . '1'};
 624                         delete $info->{$key};
 625                 }
 626                 $info->{'nodes'} = 0;
 627                 $info->{'nps'} = 0;
 628                 $info->{'depth'} = 0;
 629                 $info->{'seldepth'} = 0;
 630                 $info->{'tbhits'} = 0;
 631
 632                 my $t = $tb_cache{$fen};
 633                 my $pv = $t->{'pv'};
 634                 my $matelen = int((1 + $t->{'score'}) / 2);
 635                 if ($t->{'result'} eq '1/2-1/2') {
 636                         $info->{'score_cp'} = 0;
 637                 } elsif ($t->{'result'} eq '1-0') {
 638                         if ($pos_calculating->{'toplay'} eq 'B') {
 639                                 $info->{'score_mate'} = -$matelen;
 640                         } else {
 641                                 $info->{'score_mate'} = $matelen;
 642                         }
 643                 } else {
 644                         if ($pos_calculating->{'toplay'} eq 'B') {
 645                                 $info->{'score_mate'} = $matelen;
 646                         } else {
 647                                 $info->{'score_mate'} = -$matelen;
 648                         }
 649                 }
 650                 $info->{'pv'} = $pv;
 651                 $info->{'tablebase'} = 1;
 652         } else {
 653                 $info->{'tablebase'} = 0;
 654         }
 655
 656         #
 657         # Some programs _always_ report MultiPV, even with only one PV.
 658         # In this case, we simply use that data as if MultiPV was never
 659         # specified.
 660         #
 661         if (exists($info->{'pv1'}) && !exists($info->{'pv2'})) {
 662                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
 663                         if (exists($info->{$key . '1'})) {
 664                                 $info->{$key} = $info->{$key . '1'};
 665                         } else {
 666                                 delete $info->{$key};
 667                         }
 668                 }
 669         }
 670
 671         #
 672         # Check the PVs first. if they're invalid, just wait, as our data
 673         # is most likely out of sync. This isn't a very good solution, as
 674         # it can frequently miss stuff, but it's good enough for most users.
 675         #
 676         eval {
 677                 my $dummy;
 678                 if (exists($info->{'pv'})) {
 679                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv'}});
 680                 }
 681
 682                 my $mpv = 1;
 683                 while (exists($info->{'pv' . $mpv})) {
 684                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}});
 685                         ++$mpv;
 686                 }
 687         };
 688         if ($@) {
 689                 $engine->{'info'} = {};
 690                 return;
 691         }
 692
 693         # Now do our own Syzygy tablebase probes to convert scores like +123.45 to mate.
 694         if (exists($info->{'pv'})) {
 695                 complete_using_tbprobe($pos_calculating, $info, '');
 696         }
 697
 698         my $mpv = 1;
 699         while (exists($info->{'pv' . $mpv})) {
 700                 complete_using_tbprobe($pos_calculating, $info, $mpv);
 701                 ++$mpv;
 702         }
 703
 704         output_screen();
 705         output_json(0);
 706         $latest_update = [Time::HiRes::gettimeofday];
 707 }
 708
 709 sub output_screen {
 710         my $info = $engine->{'info'};
 711         my $id = $engine->{'id'};
 712
 713         my $text = 'Analysis';
 714         if ($pos_calculating->{'last_move'} ne 'none') {
 715                 if ($pos_calculating->{'toplay'} eq 'W') {
 716                         $text .= sprintf ' after %u. ... %s', ($pos_calculating->{'move_num'}-1), $pos_calculating->{'last_move'};
 717                 } else {
 718                         $text .= sprintf ' after %u. %s', $pos_calculating->{'move_num'}, $pos_calculating->{'last_move'};
 719                 }
 720                 if (exists($id->{'name'})) {
 721                         $text .= ',';
 722                 }
 723         }
 724
 725         if (exists($id->{'name'})) {
 726                 $text .= " by $id->{'name'}:\n\n";
 727         } else {
 728                 $text .= ":\n\n";
 729         }
 730
 731         return unless (exists($pos_calculating->{'board'}));
 732
 733         if (exists($info->{'pv1'}) && exists($info->{'pv2'})) {
 734                 # multi-PV
 735                 my $mpv = 1;
 736                 while (exists($info->{'pv' . $mpv})) {
 737                         $text .= sprintf "  PV%2u", $mpv;
 738                         my $score = short_score($info, $pos_calculating, $mpv);
 739                         $text .= "  ($score)" if (defined($score));
 740
 741                         my $tbhits = '';
 742                         if (exists($info->{'tbhits' . $mpv}) && $info->{'tbhits' . $mpv} > 0) {
 743                                 if ($info->{'tbhits' . $mpv} == 1) {
 744                                         $tbhits = ", 1 tbhit";
 745                                 } else {
 746                                         $tbhits = sprintf ", %u tbhits", $info->{'tbhits' . $mpv};
 747                                 }
 748                         }
 749
 750                         if (exists($info->{'nodes' . $mpv}) && exists($info->{'nps' . $mpv}) && exists($info->{'depth' . $mpv})) {
 751                                 $text .= sprintf " (%5u kn, %3u kn/s, %2u ply$tbhits)",
 752                                         $info->{'nodes' . $mpv} / 1000, $info->{'nps' . $mpv} / 1000, $info->{'depth' . $mpv};
 753                         }
 754
 755                         $text .= ":\n";
 756                         $text .= "  " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}})) . "\n";
 757                         $text .= "\n";
 758                         ++$mpv;
 759                 }
 760         } else {
 761                 # single-PV
 762                 my $score = long_score($info, $pos_calculating, '');
 763                 $text .= "  $score\n" if defined($score);
 764                 $text .=  "  PV: " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv'}}));
 765                 $text .=  "\n";
 766
 767                 if (exists($info->{'nodes'}) && exists($info->{'nps'}) && exists($info->{'depth'})) {
 768                         $text .= sprintf "  %u nodes, %7u nodes/sec, depth %u ply",
 769                                 $info->{'nodes'}, $info->{'nps'}, $info->{'depth'};
 770                 }
 771                 if (exists($info->{'seldepth'})) {
 772                         $text .= sprintf " (%u selective)", $info->{'seldepth'};
 773                 }
 774                 if (exists($info->{'tbhits'}) && $info->{'tbhits'} > 0) {
 775                         if ($info->{'tbhits'} == 1) {
 776                                 $text .= ", one Syzygy hit";
 777                         } else {
 778                                 $text .= sprintf ", %u Syzygy hits", $info->{'tbhits'};
 779                         }
 780                 }
 781                 $text .= "\n\n";
 782         }
 783
 784         #$text .= book_info($pos_calculating->fen(), $pos_calculating->{'board'}, $pos_calculating->{'toplay'});
 785
 786         my @refutation_lines = ();
 787         if (defined($engine2)) {
 788                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
 789                         my $info = $engine2->{'info'};
 790                         last if (!exists($info->{'pv' . $mpv}));
 791                         eval {
 792                                 complete_using_tbprobe($pos_calculating_second_engine, $info, $mpv);
 793                                 my $pv = $info->{'pv' . $mpv};
 794                                 my $pretty_move = join('', prettyprint_pv($pos_calculating_second_engine, $pv->[0]));
 795                                 my @pretty_pv = prettyprint_pv($pos_calculating_second_engine, @$pv);
 796                                 if (scalar @pretty_pv > 5) {
 797                                         @pretty_pv = @pretty_pv[0..4];
 798                                         push @pretty_pv, "...";
 799                                 }
 800                                 my $key = $pretty_move;
 801                                 my $line = sprintf("  %-6s %6s %3s  %s",
 802                                         $pretty_move,
 803                                         short_score($info, $pos_calculating_second_engine, $mpv),
 804                                         "d" . $info->{'depth' . $mpv},
 805                                         join(', ', @pretty_pv));
 806                                 push @refutation_lines, [ $key, $line ];
 807                         };
 808                 }
 809         }
 810
 811         if ($#refutation_lines >= 0) {
 812                 $text .= "Shallow search of all legal moves:\n\n";
 813                 for my $line (sort { $a->[0] cmp $b->[0] } @refutation_lines) {
 814                         $text .= $line->[1] . "\n";
 815                 }
 816                 $text .= "\n\n";
 817         }
 818
 819         if ($last_text ne $text) {
 820                 print "\e[H\e[2J"; # clear the screen
 821                 print $text;
 822                 $last_text = $text;
 823         }
 824 }
 825
 826 sub output_json {
 827         my $historic_json_only = shift;
 828         my $info = $engine->{'info'};
 829
 830         my $json = {};
 831         $json->{'position'} = $pos_calculating->to_json_hash();
 832         $json->{'engine'} = $engine->{'id'};
 833         if (defined($remoteglotconf::engine_url)) {
 834                 $json->{'engine'}{'url'} = $remoteglotconf::engine_url;
 835         }
 836         if (defined($remoteglotconf::engine_details)) {
 837                 $json->{'engine'}{'details'} = $remoteglotconf::engine_details;
 838         }
 839         if (defined($remoteglotconf::move_source)) {
 840                 $json->{'move_source'} = $remoteglotconf::move_source;
 841         }
 842         if (defined($remoteglotconf::move_source_url)) {
 843                 $json->{'move_source_url'} = $remoteglotconf::move_source_url;
 844         }
 845         $json->{'score'} = score_digest($info, $pos_calculating, '');
 846         $json->{'using_lomonosov'} = defined($remoteglotconf::tb_serial_key);
 847
 848         $json->{'nodes'} = $info->{'nodes'};
 849         $json->{'nps'} = $info->{'nps'};
 850         $json->{'depth'} = $info->{'depth'};
 851         $json->{'tbhits'} = $info->{'tbhits'};
 852         $json->{'seldepth'} = $info->{'seldepth'};
 853         $json->{'tablebase'} = $info->{'tablebase'};
 854         $json->{'pv'} = [ prettyprint_pv($pos_calculating, @{$info->{'pv'}}) ];
 855
 856         my %refutation_lines = ();
 857         my @refutation_lines = ();
 858         if (defined($engine2)) {
 859                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
 860                         my $info = $engine2->{'info'};
 861                         my $pretty_move = "";
 862                         my @pretty_pv = ();
 863                         last if (!exists($info->{'pv' . $mpv}));
 864
 865                         eval {
 866                                 complete_using_tbprobe($pos_calculating, $info, $mpv);
 867                                 my $pv = $info->{'pv' . $mpv};
 868                                 my $pretty_move = join('', prettyprint_pv($pos_calculating, $pv->[0]));
 869                                 my @pretty_pv = prettyprint_pv($pos_calculating, @$pv);
 870                                 $refutation_lines{$pretty_move} = {
 871                                         depth => $info->{'depth' . $mpv},
 872                                         score => score_digest($info, $pos_calculating, $mpv),
 873                                         move => $pretty_move,
 874                                         pv => \@pretty_pv,
 875                                 };
 876                         };
 877                 }
 878         }
 879         $json->{'refutation_lines'} = \%refutation_lines;
 880
 881         # Piece together historic score information, to the degree we have it.
 882         if (!$historic_json_only && exists($pos_calculating->{'history'})) {
 883                 my %score_history = ();
 884
 885                 my $q = $dbh->prepare('SELECT * FROM scores WHERE id=?');
 886                 my $pos = Position->start_pos('white', 'black');
 887                 my $halfmove_num = 0;
 888                 for my $move (@{$pos_calculating->{'history'}}) {
 889                         my $id = id_for_pos($pos, $halfmove_num);
 890                         my $ref = $dbh->selectrow_hashref($q, undef, $id);
 891                         if (defined($ref)) {
 892                                 $score_history{$halfmove_num} = [
 893                                         $ref->{'score_type'},
 894                                         $ref->{'score_value'}
 895                                 ];
 896                         }
 897                         ++$halfmove_num;
 898                         ($pos) = $pos->make_pretty_move($move);
 899                 }
 900                 $q->finish;
 901
 902                 # If at any point we are missing 10 consecutive moves,
 903                 # truncate the history there. This is so we don't get into
 904                 # a situation where we e.g. start analyzing at move 45,
 905                 # but we have analysis for 1. e4 from some completely different game
 906                 # and thus show a huge hole.
 907                 my $consecutive_missing = 0;
 908                 my $truncate_until = 0;
 909                 for (my $i = $halfmove_num; $i --> 0; ) {
 910                         if ($consecutive_missing >= 10) {
 911                                 delete $score_history{$i};
 912                                 next;
 913                         }
 914                         if (exists($score_history{$i})) {
 915                                 $consecutive_missing = 0;
 916                         } else {
 917                                 ++$consecutive_missing;
 918                         }
 919                 }
 920
 921                 $json->{'score_history'} = \%score_history;
 922         }
 923
 924         # Give out a list of other games going on. (Empty is fine.)
 925         # TODO: Don't bother reading our own file, the data will be stale anyway.
 926         if (!$historic_json_only) {
 927                 my @games = ();
 928
 929                 my $q = $dbh->prepare('SELECT * FROM current_games ORDER BY priority DESC, id');
 930                 $q->execute;
 931                 while (my $ref = $q->fetchrow_hashref) {
 932                         eval {
 933                                 my $other_game_contents = File::Slurp::read_file($ref->{'json_path'});
 934                                 my $other_game_json = JSON::XS::decode_json($other_game_contents);
 935
 936                                 die "Missing position" if (!exists($other_game_json->{'position'}));
 937                                 my $white = $other_game_json->{'position'}{'player_w'} // die 'Missing white';
 938                                 my $black = $other_game_json->{'position'}{'player_b'} // die 'Missing black';
 939
 940                                 my $game = {
 941                                         id => $ref->{'id'},
 942                                         name => "$white–$black",
 943                                         url => $ref->{'url'},
 944                                         hashurl => $ref->{'hash_url'},
 945                                 };
 946                                 if (defined($other_game_json->{'position'}{'result'})) {
 947                                         $game->{'result'} = $other_game_json->{'position'}{'result'};
 948                                 } else {
 949                                         $game->{'score'} = $other_game_json->{'score'};
 950                                 }
 951                                 push @games, $game;
 952                         };
 953                         if ($@) {
 954                                 warn "Could not add external game " . $ref->{'json_path'} . ": $@";
 955                         }
 956                 }
 957
 958                 if (scalar @games > 0) {
 959                         $json->{'games'} = \@games;
 960                 }
 961         }
 962
 963         my $json_enc = JSON::XS->new;
 964         $json_enc->canonical(1);
 965         my $encoded = $json_enc->encode($json);
 966         unless ($historic_json_only || !defined($remoteglotconf::json_output) ||
 967                 (defined($last_written_json) && $last_written_json eq $encoded)) {
 968                 atomic_set_contents($remoteglotconf::json_output, $encoded);
 969                 $last_written_json = $encoded;
 970         }
 971
 972         if (exists($pos_calculating->{'history'}) &&
 973             defined($remoteglotconf::json_history_dir)) {
 974                 my $id = id_for_pos($pos_calculating);
 975                 my $filename = $remoteglotconf::json_history_dir . "/" . $id . ".json";
 976
 977                 # Overwrite old analysis (assuming it exists at all) if we're
 978                 # using a different engine, or if we've calculated deeper.
 979                 # nodes is used as a tiebreaker. Don't bother about Multi-PV
 980                 # data; it's not that important.
 981                 my ($old_engine, $old_depth, $old_nodes) = get_json_analysis_stats($id);
 982                 my $new_depth = $json->{'depth'} // 0;
 983                 my $new_nodes = $json->{'nodes'} // 0;
 984                 if (!defined($old_engine) ||
 985                     $old_engine ne $json->{'engine'}{'name'} ||
 986                     $new_depth > $old_depth ||
 987                     ($new_depth == $old_depth && $new_nodes >= $old_nodes)) {
 988                         atomic_set_contents($filename, $encoded);
 989                         if (defined($json->{'score'})) {
 990                                 $dbh->do('INSERT INTO scores (id, score_type, score_value, engine, depth, nodes) VALUES (?,?,?,?,?,?) ' .
 991                                          '    ON CONFLICT (id) DO UPDATE SET ' .
 992                                          '        score_type=EXCLUDED.score_type, ' .
 993                                          '        score_value=EXCLUDED.score_value, ' .
 994                                          '        engine=EXCLUDED.engine, ' .
 995                                          '        depth=EXCLUDED.depth, ' .
 996                                          '        nodes=EXCLUDED.nodes',
 997                                         undef,
 998                                         $id, $json->{'score'}[0], $json->{'score'}[1],
 999                                         $json->{'engine'}{'name'}, $new_depth, $new_nodes);
1000                         }
1001                 }
1002         }
1003 }
1004
1005 sub atomic_set_contents {
1006         my ($filename, $contents) = @_;
1007
1008         open my $fh, ">", $filename . ".tmp"
1009                 or return;
1010         print $fh $contents;
1011         close $fh;
1012         rename($filename . ".tmp", $filename);
1013 }
1014
1015 sub id_for_pos {
1016         my ($pos, $halfmove_num) = @_;
1017
1018         $halfmove_num //= scalar @{$pos->{'history'}};
1019         (my $fen = $pos->fen()) =~ tr,/ ,-_,;
1020         return "move$halfmove_num-$fen";
1021 }
1022
1023 sub get_json_analysis_stats {
1024         my $id = shift;
1025         my $ref = $dbh->selectrow_hashref('SELECT * FROM scores WHERE id=?', undef, $id);
1026         if (defined($ref)) {
1027                 return ($ref->{'engine'}, $ref->{'depth'}, $ref->{'nodes'});
1028         } else {
1029                 return ('', 0, 0);
1030         }
1031 }
1032
1033 sub uciprint {
1034         my ($engine, $msg) = @_;
1035         $engine->print($msg);
1036         print UCILOG localtime() . " $engine->{'tag'} => $msg\n";
1037 }
1038
1039 sub short_score {
1040         my ($info, $pos, $mpv) = @_;
1041
1042         my $invert = ($pos->{'toplay'} eq 'B');
1043         if (defined($info->{'score_mate' . $mpv})) {
1044                 if ($invert) {
1045                         return sprintf "M%3d", -$info->{'score_mate' . $mpv};
1046                 } else {
1047                         return sprintf "M%3d", $info->{'score_mate' . $mpv};
1048                 }
1049         } else {
1050                 if (exists($info->{'score_cp' . $mpv})) {
1051                         my $score = $info->{'score_cp' . $mpv} * 0.01;
1052                         if ($score == 0) {
1053                                 if ($info->{'tablebase'}) {
1054                                         return "TB draw";
1055                                 } else {
1056                                         return " 0.00";
1057                                 }
1058                         }
1059                         if ($invert) {
1060                                 $score = -$score;
1061                         }
1062                         return sprintf "%+5.2f", $score;
1063                 }
1064         }
1065
1066         return undef;
1067 }
1068
1069 # Sufficient for computing long_score, short_score, plot_score and
1070 # (with side-to-play information) score_sort_key.
1071 sub score_digest {
1072         my ($info, $pos, $mpv) = @_;
1073
1074         if (defined($info->{'score_mate' . $mpv})) {
1075                 my $mate = $info->{'score_mate' . $mpv};
1076                 if ($pos->{'toplay'} eq 'B') {
1077                         $mate = -$mate;
1078                 }
1079                 return ['m', $mate];
1080         } else {
1081                 if (exists($info->{'score_cp' . $mpv})) {
1082                         my $score = $info->{'score_cp' . $mpv};
1083                         if ($pos->{'toplay'} eq 'B') {
1084                                 $score = -$score;
1085                         }
1086                         if ($score == 0 && $info->{'tablebase'}) {
1087                                 return ['d', undef];
1088                         } else {
1089                                 return ['cp', $score];
1090                         }
1091                 }
1092         }
1093
1094         return undef;
1095 }
1096
1097 sub long_score {
1098         my ($info, $pos, $mpv) = @_;
1099
1100         if (defined($info->{'score_mate' . $mpv})) {
1101                 my $mate = $info->{'score_mate' . $mpv};
1102                 if ($pos->{'toplay'} eq 'B') {
1103                         $mate = -$mate;
1104                 }
1105                 if ($mate > 0) {
1106                         return sprintf "White mates in %u", $mate;
1107                 } else {
1108                         return sprintf "Black mates in %u", -$mate;
1109                 }
1110         } else {
1111                 if (exists($info->{'score_cp' . $mpv})) {
1112                         my $score = $info->{'score_cp' . $mpv} * 0.01;
1113                         if ($score == 0) {
1114                                 if ($info->{'tablebase'}) {
1115                                         return "Theoretical draw";
1116                                 } else {
1117                                         return "Score:  0.00";
1118                                 }
1119                         }
1120                         if ($pos->{'toplay'} eq 'B') {
1121                                 $score = -$score;
1122                         }
1123                         return sprintf "Score: %+5.2f", $score;
1124                 }
1125         }
1126
1127         return undef;
1128 }
1129
1130 # For graphs; a single number in centipawns, capped at +/- 500.
1131 sub plot_score {
1132         my ($info, $pos, $mpv) = @_;
1133
1134         my $invert = ($pos->{'toplay'} eq 'B');
1135         if (defined($info->{'score_mate' . $mpv})) {
1136                 my $mate = $info->{'score_mate' . $mpv};
1137                 if ($invert) {
1138                         $mate = -$mate;
1139                 }
1140                 if ($mate > 0) {
1141                         return 500;
1142                 } else {
1143                         return -500;
1144                 }
1145         } else {
1146                 if (exists($info->{'score_cp' . $mpv})) {
1147                         my $score = $info->{'score_cp' . $mpv};
1148                         if ($invert) {
1149                                 $score = -$score;
1150                         }
1151                         $score = 500 if ($score > 500);
1152                         $score = -500 if ($score < -500);
1153                         return int($score);
1154                 }
1155         }
1156
1157         return undef;
1158 }
1159
1160 my %book_cache = ();
1161 sub book_info {
1162         my ($fen, $board, $toplay) = @_;
1163
1164         if (exists($book_cache{$fen})) {
1165                 return $book_cache{$fen};
1166         }
1167
1168         my $ret = `./booklook $fen`;
1169         return "" if ($ret =~ /Not found/ || $ret eq '');
1170
1171         my @moves = ();
1172
1173         for my $m (split /\n/, $ret) {
1174                 my ($move, $annotation, $win, $draw, $lose, $rating, $rating_div) = split /,/, $m;
1175
1176                 my $pmove;
1177                 if ($move eq '')  {
1178                         $pmove = '(current)';
1179                 } else {
1180                         ($pmove) = prettyprint_pv_no_cache($board, $move);
1181                         $pmove .= $annotation;
1182                 }
1183
1184                 my $score;
1185                 if ($toplay eq 'W') {
1186                         $score = 1.0 * $win + 0.5 * $draw + 0.0 * $lose;
1187                 } else {
1188                         $score = 0.0 * $win + 0.5 * $draw + 1.0 * $lose;
1189                 }
1190                 my $n = $win + $draw + $lose;
1191
1192                 my $percent;
1193                 if ($n == 0) {
1194                         $percent = "     ";
1195                 } else {
1196                         $percent = sprintf "%4u%%", int(100.0 * $score / $n + 0.5);
1197                 }
1198
1199                 push @moves, [ $pmove, $n, $percent, $rating ];
1200         }
1201
1202         @moves[1..$#moves] = sort { $b->[2] cmp $a->[2] } @moves[1..$#moves];
1203
1204         my $text = "Book moves:\n\n              Perf.     N     Rating\n\n";
1205         for my $m (@moves) {
1206                 $text .= sprintf "  %-10s %s   %6u    %4s\n", $m->[0], $m->[2], $m->[1], $m->[3]
1207         }
1208
1209         return $text;
1210 }
1211
1212 sub extract_clock {
1213         my ($pgn, $pos) = @_;
1214
1215         # Look for extended PGN clock tags.
1216         my $tags = $pgn->tags;
1217         if (exists($tags->{'WhiteClock'}) && exists($tags->{'BlackClock'})) {
1218                 $pos->{'white_clock'} = hms_to_sec($tags->{'WhiteClock'});
1219                 $pos->{'black_clock'} = hms_to_sec($tags->{'BlackClock'});
1220                 return;
1221         }
1222
1223         # Look for TCEC-style time comments.
1224         my $moves = $pgn->moves;
1225         my $comments = $pgn->comments;
1226         my $last_black_move = int((scalar @$moves) / 2);
1227         my $last_white_move = int((1 + scalar @$moves) / 2);
1228
1229         my $black_key = $last_black_move . "b";
1230         my $white_key = $last_white_move . "w";
1231
1232         if (exists($comments->{$white_key}) &&
1233             exists($comments->{$black_key}) &&
1234             $comments->{$white_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/ &&
1235             $comments->{$black_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/) {
1236                 $comments->{$white_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/;
1237                 $pos->{'white_clock'} = hms_to_sec($1);
1238                 $comments->{$black_key} =~ /(?:tl=|clk )(\d+:\d+:\d+)/;
1239                 $pos->{'black_clock'} = hms_to_sec($1);
1240                 return;
1241         }
1242
1243         delete $pos->{'white_clock'};
1244         delete $pos->{'black_clock'};
1245 }
1246
1247 sub hms_to_sec {
1248         my $hms = shift;
1249         return undef if (!defined($hms));
1250         $hms =~ /(\d+):(\d+):(\d+)/;
1251         return $1 * 3600 + $2 * 60 + $3;
1252 }
1253
1254 sub find_clock_start {
1255         my ($pos, $prev_pos) = @_;
1256
1257         # If the game is over, the clock is stopped.
1258         if (exists($pos->{'result'}) &&
1259             ($pos->{'result'} eq '1-0' ||
1260              $pos->{'result'} eq '1/2-1/2' ||
1261              $pos->{'result'} eq '0-1')) {
1262                 return;
1263         }
1264
1265         # When we don't have any moves, we assume the clock hasn't started yet.
1266         if ($pos->{'move_num'} == 1 && $pos->{'toplay'} eq 'W') {
1267                 if (defined($remoteglotconf::adjust_clocks_before_move)) {
1268                         &$remoteglotconf::adjust_clocks_before_move(\$pos->{'white_clock'}, \$pos->{'black_clock'}, 1, 'W');
1269                 }
1270                 return;
1271         }
1272
1273         # TODO(sesse): Maybe we can get the number of moves somehow else for FICS games.
1274         # The history is needed for id_for_pos.
1275         if (!exists($pos->{'history'})) {
1276                 return;
1277         }
1278
1279         my $id = id_for_pos($pos);
1280         my $clock_info = $dbh->selectrow_hashref('SELECT * FROM clock_info WHERE id=?', undef, $id);
1281         if (defined($clock_info)) {
1282                 $pos->{'white_clock'} //= $clock_info->{'white_clock'};
1283                 $pos->{'black_clock'} //= $clock_info->{'black_clock'};
1284                 if ($pos->{'toplay'} eq 'W') {
1285                         $pos->{'white_clock_target'} = $clock_info->{'white_clock_target'};
1286                 } else {
1287                         $pos->{'black_clock_target'} = $clock_info->{'black_clock_target'};
1288                 }
1289                 return;
1290         }
1291
1292         # OK, we haven't seen this position before, so we assume the move
1293         # happened right now.
1294
1295         # See if we should do our own clock management (ie., clock information
1296         # is spurious or non-existent).
1297         if (defined($remoteglotconf::adjust_clocks_before_move)) {
1298                 my $wc = $pos->{'white_clock'} // $prev_pos->{'white_clock'};
1299                 my $bc = $pos->{'black_clock'} // $prev_pos->{'black_clock'};
1300                 if (defined($prev_pos->{'white_clock_target'})) {
1301                         $wc = $prev_pos->{'white_clock_target'} - time;
1302                 }
1303                 if (defined($prev_pos->{'black_clock_target'})) {
1304                         $bc = $prev_pos->{'black_clock_target'} - time;
1305                 }
1306                 &$remoteglotconf::adjust_clocks_before_move(\$wc, \$bc, $pos->{'move_num'}, $pos->{'toplay'});
1307                 $pos->{'white_clock'} = $wc;
1308                 $pos->{'black_clock'} = $bc;
1309         }
1310
1311         my $key = ($pos->{'toplay'} eq 'W') ? 'white_clock' : 'black_clock';
1312         if (!exists($pos->{$key})) {
1313                 # No clock information.
1314                 return;
1315         }
1316         my $time_left = $pos->{$key};
1317         my ($white_clock_target, $black_clock_target);
1318         if ($pos->{'toplay'} eq 'W') {
1319                 $white_clock_target = $pos->{'white_clock_target'} = time + $time_left;
1320         } else {
1321                 $black_clock_target = $pos->{'black_clock_target'} = time + $time_left;
1322         }
1323         local $dbh->{AutoCommit} = 0;
1324         $dbh->do('DELETE FROM clock_info WHERE id=?', undef, $id);
1325         $dbh->do('INSERT INTO clock_info (id, white_clock, black_clock, white_clock_target, black_clock_target) VALUES (?, ?, ?, ?, ?)', undef,
1326                 $id, $pos->{'white_clock'}, $pos->{'black_clock'}, $white_clock_target, $black_clock_target);
1327         $dbh->commit;
1328 }
1329
1330 sub schedule_tb_lookup {
1331         return if (!defined($remoteglotconf::tb_serial_key));
1332         my $pos = $pos_waiting // $pos_calculating;
1333         return if (exists($tb_cache{$pos->fen()}));
1334
1335         # If there's more than seven pieces, there's not going to be an answer,
1336         # so don't bother.
1337         return if ($pos->num_pieces() > 7);
1338
1339         # Max one at a time. If it's still relevant when it returns,
1340         # schedule_tb_lookup() will be called again.
1341         return if ($tb_lookup_running);
1342
1343         $tb_lookup_running = 1;
1344         my $url = 'http://158.250.18.203:6904/tasks/addtask?auth.login=' .
1345                 $remoteglotconf::tb_serial_key .
1346                 '&auth.password=aquarium&type=0&fen=' .
1347                 URI::Escape::uri_escape($pos->fen());
1348         print TBLOG "Downloading $url...\n";
1349         AnyEvent::HTTP::http_get($url, sub {
1350                 handle_tb_lookup_return(@_, $pos, $pos->fen());
1351         });
1352 }
1353
1354 sub handle_tb_lookup_return {
1355         my ($body, $header, $pos, $fen) = @_;
1356         print TBLOG "Response for [$fen]:\n";
1357         print TBLOG $header . "\n\n";
1358         print TBLOG $body . "\n\n";
1359         eval {
1360                 my $response = JSON::XS::decode_json($body);
1361                 if ($response->{'ErrorCode'} != 0) {
1362                         die "Unknown tablebase server error: " . $response->{'ErrorDesc'};
1363                 }
1364                 my $state = $response->{'Response'}{'StateString'};
1365                 if ($state eq 'COMPLETE') {
1366                         my $pgn = Chess::PGN::Parse->new(undef, $response->{'Response'}{'Moves'});
1367                         if (!defined($pgn) || !$pgn->read_game()) {
1368                                 warn "Error in parsing PGN\n";
1369                         } else {
1370                                 $pgn->quick_parse_game;
1371                                 my $pvpos = $pos;
1372                                 my $moves = $pgn->moves;
1373                                 my @uci_moves = ();
1374                                 for my $move (@$moves) {
1375                                         my $uci_move;
1376                                         ($pvpos, $uci_move) = $pvpos->make_pretty_move($move);
1377                                         push @uci_moves, $uci_move;
1378                                 }
1379                                 $tb_cache{$fen} = {
1380                                         result => $pgn->result,
1381                                         pv => \@uci_moves,
1382                                         score => $response->{'Response'}{'Score'},
1383                                 };
1384                                 output();
1385                         }
1386                 } elsif ($state =~ /QUEUED/ || $state =~ /PROCESSING/) {
1387                         # Try again in a second. Note that if we have changed
1388                         # position in the meantime, we might query a completely
1389                         # different position! But that's fine.
1390                 } else {
1391                         die "Unknown response state " . $state;
1392                 }
1393
1394                 # Wait a second before we schedule another one.
1395                 $tb_retry_timer = AnyEvent->timer(after => 1.0, cb => sub {
1396                         $tb_lookup_running = 0;
1397                         schedule_tb_lookup();
1398                 });
1399         };
1400         if ($@) {
1401                 warn "Error in tablebase lookup: $@";
1402
1403                 # Don't try this one again, but don't block new lookups either.
1404                 $tb_lookup_running = 0;
1405         }
1406 }
1407
1408 sub open_engine {
1409         my ($cmdline, $tag, $cb) = @_;
1410         return undef if (!defined($cmdline));
1411         return Engine->open($cmdline, $tag, $cb);
1412 }
1413
1414 sub col_letter_to_num {
1415         return ord(shift) - ord('a');
1416 }
1417
1418 sub row_letter_to_num {
1419         return 7 - (ord(shift) - ord('1'));
1420 }
1421
1422 sub parse_uci_move {
1423         my $move = shift;
1424         my $from_col = col_letter_to_num(substr($move, 0, 1));
1425         my $from_row = row_letter_to_num(substr($move, 1, 1));
1426         my $to_col   = col_letter_to_num(substr($move, 2, 1));
1427         my $to_row   = row_letter_to_num(substr($move, 3, 1));
1428         my $promo    = substr($move, 4, 1);
1429         return ($from_row, $from_col, $to_row, $to_col, $promo);
1430 }