Move most configuration into a separate file.
[remoteglot] / remoteglot.pl
1 #! /usr/bin/perl
2
3 #
4 # remoteglot - Connects an abitrary UCI-speaking engine to ICS for easier post-game
5 #              analysis, or for live analysis of relayed games. (Do not use for
6 #              cheating! Cheating is bad for your karma, and your abuser flag.)
7 #
8 # Copyright 2007 Steinar H. Gunderson <sgunderson@bigfoot.com>
9 # Licensed under the GNU General Public License, version 2.
10 #
11
12 use AnyEvent;
13 use AnyEvent::Handle;
14 use AnyEvent::HTTP;
15 use Chess::PGN::Parse;
16 use EV;
17 use Net::Telnet;
18 use FileHandle;
19 use IPC::Open2;
20 use Time::HiRes;
21 use JSON::XS;
22 require 'Position.pm';
23 require 'Engine.pm';
24 require 'config.pm';
25 use strict;
26 use warnings;
27 no warnings qw(once);
28
29 # Program starts here
30 $SIG{ALRM} = sub { output(); };
31 my $latest_update = undef;
32 my $http_timer = undef;
33
34 $| = 1;
35
36 open(FICSLOG, ">ficslog.txt")
37         or die "ficslog.txt: $!";
38 print FICSLOG "Log starting.\n";
39 select(FICSLOG);
40 $| = 1;
41
42 open(UCILOG, ">ucilog.txt")
43         or die "ucilog.txt: $!";
44 print UCILOG "Log starting.\n";
45 select(UCILOG);
46 $| = 1;
47 select(STDOUT);
48
49 # open the chess engine
50 my $engine = open_engine($remoteglotconf::engine_cmdline, 'E1', sub { handle_uci(@_, 1); });
51 my $engine2 = open_engine($remoteglotconf::engine2_cmdline, 'E2', sub { handle_uci(@_, 0); });
52 my $last_move;
53 my $last_text = '';
54 my ($pos_waiting, $pos_calculating, $pos_calculating_second_engine);
55
56 uciprint($engine, "setoption name UCI_AnalyseMode value true");
57 while (my ($key, $value) = each %remoteglotconf::engine_config) {
58         uciprint($engine, "setoption name $key value $value");
59 }
60 uciprint($engine, "ucinewgame");
61
62 if (defined($engine2)) {
63         uciprint($engine2, "setoption name UCI_AnalyseMode value true");
64         while (my ($key, $value) = each %remoteglotconf::engine2_config) {
65                 uciprint($engine2, "setoption name $key value $value");
66         }
67         uciprint($engine2, "setoption name MultiPV value 500");
68         uciprint($engine2, "ucinewgame");
69 }
70
71 print "Chess engine ready.\n";
72
73 # now talk to FICS
74 my $t = Net::Telnet->new(Timeout => 10, Prompt => '/fics% /');
75 $t->input_log(\*FICSLOG);
76 $t->open($remoteglotconf::server);
77 $t->print($remoteglotconf::nick);
78 $t->waitfor('/Press return to enter the server/');
79 $t->cmd("");
80
81 # set some options
82 $t->cmd("set shout 0");
83 $t->cmd("set seek 0");
84 $t->cmd("set style 12");
85 $t->cmd("observe $remoteglotconf::target");
86 print "FICS ready.\n";
87
88 my $ev1 = AnyEvent->io(
89         fh => fileno($t),
90         poll => 'r',
91         cb => sub {    # what callback to execute
92                 while (1) {
93                         my $line = $t->getline(Timeout => 0, errmode => 'return');
94                         return if (!defined($line));
95
96                         chomp $line;
97                         $line =~ tr/\r//d;
98                         handle_fics($line);
99                 }
100         }
101 );
102 # Engine events have already been set up by Engine.pm.
103 EV::run;
104
105 sub handle_uci {
106         my ($engine, $line, $primary) = @_;
107
108         $line =~ s/  / /g;  # Sometimes needed for Zappa Mexico
109         print UCILOG localtime() . " $engine->{'tag'} <= $line\n";
110         if ($line =~ /^info/) {
111                 my (@infos) = split / /, $line;
112                 shift @infos;
113
114                 parse_infos($engine, @infos);
115         }
116         if ($line =~ /^id/) {
117                 my (@ids) = split / /, $line;
118                 shift @ids;
119
120                 parse_ids($engine, @ids);
121         }
122         if ($line =~ /^bestmove/) {
123                 if ($primary) {
124                         return if (!$remoteglotconf::uci_assume_full_compliance);
125                         if (defined($pos_waiting)) {
126                                 uciprint($engine, "position fen " . $pos_waiting->fen());
127                                 uciprint($engine, "go infinite");
128
129                                 $pos_calculating = $pos_waiting;
130                                 $pos_waiting = undef;
131                         }
132                 } else {
133                         $engine2->{'info'} = {};
134                         my $pos = $pos_waiting // $pos_calculating;
135                         uciprint($engine2, "position fen " . $pos->fen());
136                         uciprint($engine2, "go infinite");
137                         $pos_calculating_second_engine = $pos;
138                 }
139         }
140         output();
141 }
142
143 sub handle_fics {
144         my $line = shift;
145         if ($line =~ /^<12> /) {
146                 handle_position(Position->new($line));
147         }
148         if ($line =~ /^([A-Za-z]+)(?:\([A-Z]+\))* tells you: (.*)$/) {
149                 my ($who, $msg) = ($1, $2);
150
151                 next if (grep { $_ eq $who } (@remoteglotconf::masters) == 0);
152
153                 if ($msg =~ /^fics (.*?)$/) {
154                         $t->cmd("tell $who Executing '$1' on FICS.");
155                         $t->cmd($1);
156                 } elsif ($msg =~ /^uci (.*?)$/) {
157                         $t->cmd("tell $who Sending '$1' to the engine.");
158                         print { $engine->{'write'} } "$1\n";
159                 } elsif ($msg =~ /^pgn (.*?)$/) {
160                         my $url = $1;
161                         $t->cmd("tell $who Starting to poll '$url'.");
162                         AnyEvent::HTTP::http_get($url, sub {
163                                 handle_pgn(@_, $url);
164                         });
165                 } elsif ($msg =~ /^stoppgn$/) {
166                         $t->cmd("tell $who Stopping poll.");
167                         $http_timer = undef;
168                 } elsif ($msg =~ /^quit$/) {
169                         $t->cmd("tell $who Bye bye.");
170                         exit;
171                 } else {
172                         $t->cmd("tell $who Couldn't understand '$msg', sorry.");
173                 }
174         }
175         #print "FICS: [$line]\n";
176 }
177
178 sub handle_pgn {
179         my ($body, $header, $url) = @_;
180         my $pgn = Chess::PGN::Parse->new(undef, $body);
181         if (!defined($pgn) || !$pgn->read_game()) {
182                 warn "Error in parsing PGN from $url\n";
183         } else {
184                 $pgn->quick_parse_game;
185                 my $pos = Position->start_pos($pgn->white, $pgn->black);
186                 my $moves = $pgn->moves;
187                 for my $move (@$moves) {
188                         my ($from_row, $from_col, $to_row, $to_col, $promo) = $pos->parse_pretty_move($move);
189                         $pos = $pos->make_move($from_row, $from_col, $to_row, $to_col, $promo);
190                 }
191                 handle_position($pos);
192         }
193         
194         $http_timer = AnyEvent->timer(after => 1.0, cb => sub {
195                 AnyEvent::HTTP::http_get($url, sub {
196                         handle_pgn(@_, $url);
197                 });
198         });
199 }
200
201 sub handle_position {
202         my ($pos) = @_;
203                 
204         # if this is already in the queue, ignore it
205         return if (defined($pos_waiting) && $pos->fen() eq $pos_waiting->fen());
206
207         # if we're already chewing on this and there's nothing else in the queue,
208         # also ignore it
209         return if (!defined($pos_waiting) && defined($pos_calculating) &&
210                  $pos->fen() eq $pos_calculating->fen());
211
212         # if we're already thinking on something, stop and wait for the engine
213         # to approve
214         if (defined($pos_calculating)) {
215                 if (!defined($pos_waiting)) {
216                         uciprint($engine, "stop");
217                 }
218                 if ($remoteglotconf::uci_assume_full_compliance) {
219                         $pos_waiting = $pos;
220                 } else {
221                         uciprint($engine, "position fen " . $pos->fen());
222                         uciprint($engine, "go infinite");
223                         $pos_calculating = $pos;
224                 }
225         } else {
226                 # it's wrong just to give the FEN (the move history is useful,
227                 # and per the UCI spec, we should really have sent "ucinewgame"),
228                 # but it's easier
229                 uciprint($engine, "position fen " . $pos->fen());
230                 uciprint($engine, "go infinite");
231                 $pos_calculating = $pos;
232         }
233
234         if (defined($engine2)) {
235                 if (defined($pos_calculating_second_engine)) {
236                         uciprint($engine2, "stop");
237                 } else {
238                         uciprint($engine2, "position fen " . $pos->fen());
239                         uciprint($engine2, "go infinite");
240                         $pos_calculating_second_engine = $pos;
241                 }
242                 $engine2->{'info'} = {};
243         }
244
245         $engine->{'info'} = {};
246         $last_move = time;
247
248         # 
249         # Output a command every move to note that we're
250         # still paying attention -- this is a good tradeoff,
251         # since if no move has happened in the last half
252         # hour, the analysis/relay has most likely stopped
253         # and we should stop hogging server resources.
254         #
255         $t->cmd("date");
256 }
257
258 sub parse_infos {
259         my ($engine, @x) = @_;
260         my $mpv = '';
261
262         my $info = $engine->{'info'};
263
264         # Search for "multipv" first of all, since e.g. Stockfish doesn't put it first.
265         for my $i (0..$#x - 1) {
266                 if ($x[$i] eq 'multipv') {
267                         $mpv = $x[$i + 1];
268                         next;
269                 }
270         }
271
272         while (scalar @x > 0) {
273                 if ($x[0] eq 'multipv') {
274                         # Dealt with above
275                         shift @x;
276                         shift @x;
277                         next;
278                 }
279                 if ($x[0] eq 'currmove' || $x[0] eq 'currmovenumber' || $x[0] eq 'cpuload') {
280                         my $key = shift @x;
281                         my $value = shift @x;
282                         $info->{$key} = $value;
283                         next;
284                 }
285                 if ($x[0] eq 'depth' || $x[0] eq 'seldepth' || $x[0] eq 'hashfull' ||
286                     $x[0] eq 'time' || $x[0] eq 'nodes' || $x[0] eq 'nps' ||
287                     $x[0] eq 'tbhits') {
288                         my $key = shift @x;
289                         my $value = shift @x;
290                         $info->{$key . $mpv} = $value;
291                         next;
292                 }
293                 if ($x[0] eq 'score') {
294                         shift @x;
295
296                         delete $info->{'score_cp' . $mpv};
297                         delete $info->{'score_mate' . $mpv};
298
299                         while ($x[0] eq 'cp' || $x[0] eq 'mate' || $x[0] eq 'lowerbound' || $x[0] eq 'upperbound') {
300                                 if ($x[0] eq 'cp') {
301                                         shift @x;
302                                         $info->{'score_cp' . $mpv} = shift @x;
303                                 } elsif ($x[0] eq 'mate') {
304                                         shift @x;
305                                         $info->{'score_mate' . $mpv} = shift @x;
306                                 } else {
307                                         shift @x;
308                                 }
309                         }
310                         next;
311                 }
312                 if ($x[0] eq 'pv') {
313                         $info->{'pv' . $mpv} = [ @x[1..$#x] ];
314                         last;
315                 }
316                 if ($x[0] eq 'string' || $x[0] eq 'UCI_AnalyseMode' || $x[0] eq 'setting' || $x[0] eq 'contempt') {
317                         last;
318                 }
319
320                 #print "unknown info '$x[0]', trying to recover...\n";
321                 #shift @x;
322                 die "Unknown info '" . join(',', @x) . "'";
323
324         }
325 }
326
327 sub parse_ids {
328         my ($engine, @x) = @_;
329
330         while (scalar @x > 0) {
331                 if ($x[0] =~ /^(name|author)$/) {
332                         my $key = shift @x;
333                         my $value = join(' ', @x);
334                         $engine->{'id'}{$key} = $value;
335                         last;
336                 }
337
338                 # unknown
339                 shift @x;
340         }
341 }
342
343 sub prettyprint_pv_no_cache {
344         my ($board, @pvs) = @_;
345
346         if (scalar @pvs == 0 || !defined($pvs[0])) {
347                 return ();
348         }
349
350         my $pv = shift @pvs;
351         my ($from_col, $from_row, $to_col, $to_row, $promo) = parse_uci_move($pv);
352         my ($pretty, $nb) = $board->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
353         return ( $pretty, prettyprint_pv_no_cache($nb, @pvs) );
354 }
355
356 sub prettyprint_pv {
357         my ($pos, @pvs) = @_;
358
359         my $cachekey = join('', @pvs);
360         if (exists($pos->{'prettyprint_cache'}{$cachekey})) {
361                 return @{$pos->{'prettyprint_cache'}{$cachekey}};
362         } else {
363                 my @res = prettyprint_pv_no_cache($pos->{'board'}, @pvs);
364                 $pos->{'prettyprint_cache'}{$cachekey} = \@res;
365                 return @res;
366         }
367 }
368
369 sub output {
370         #return;
371
372         return if (!defined($pos_calculating));
373
374         # Don't update too often.
375         my $age = Time::HiRes::tv_interval($latest_update);
376         if ($age < $remoteglotconf::update_max_interval) {
377                 Time::HiRes::alarm($remoteglotconf::update_max_interval + 0.01 - $age);
378                 return;
379         }
380         
381         my $info = $engine->{'info'};
382         
383         #
384         # Some programs _always_ report MultiPV, even with only one PV.
385         # In this case, we simply use that data as if MultiPV was never
386         # specified.
387         #
388         if (exists($info->{'pv1'}) && !exists($info->{'pv2'})) {
389                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
390                         if (exists($info->{$key . '1'})) {
391                                 $info->{$key} = $info->{$key . '1'};
392                         }
393                 }
394         }
395         
396         #
397         # Check the PVs first. if they're invalid, just wait, as our data
398         # is most likely out of sync. This isn't a very good solution, as
399         # it can frequently miss stuff, but it's good enough for most users.
400         #
401         eval {
402                 my $dummy;
403                 if (exists($info->{'pv'})) {
404                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv'}});
405                 }
406         
407                 my $mpv = 1;
408                 while (exists($info->{'pv' . $mpv})) {
409                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}});
410                         ++$mpv;
411                 }
412         };
413         if ($@) {
414                 $engine->{'info'} = {};
415                 return;
416         }
417
418         output_screen();
419         output_json();
420         $latest_update = [Time::HiRes::gettimeofday];
421 }
422
423 sub output_screen {
424         my $info = $engine->{'info'};
425         my $id = $engine->{'id'};
426
427         my $text = 'Analysis';
428         if ($pos_calculating->{'last_move'} ne 'none') {
429                 if ($pos_calculating->{'toplay'} eq 'W') {
430                         $text .= sprintf ' after %u. ... %s', ($pos_calculating->{'move_num'}-1), $pos_calculating->{'last_move'};
431                 } else {
432                         $text .= sprintf ' after %u. %s', $pos_calculating->{'move_num'}, $pos_calculating->{'last_move'};
433                 }
434                 if (exists($id->{'name'})) {
435                         $text .= ',';
436                 }
437         }
438
439         if (exists($id->{'name'})) {
440                 $text .= " by $id->{'name'}:\n\n";
441         } else {
442                 $text .= ":\n\n";
443         }
444
445         return unless (exists($pos_calculating->{'board'}));
446                 
447         if (exists($info->{'pv1'}) && exists($info->{'pv2'})) {
448                 # multi-PV
449                 my $mpv = 1;
450                 while (exists($info->{'pv' . $mpv})) {
451                         $text .= sprintf "  PV%2u", $mpv;
452                         my $score = short_score($info, $pos_calculating, $mpv);
453                         $text .= "  ($score)" if (defined($score));
454
455                         my $tbhits = '';
456                         if (exists($info->{'tbhits' . $mpv}) && $info->{'tbhits' . $mpv} > 0) {
457                                 if ($info->{'tbhits' . $mpv} == 1) {
458                                         $tbhits = ", 1 tbhit";
459                                 } else {
460                                         $tbhits = sprintf ", %u tbhits", $info->{'tbhits' . $mpv};
461                                 }
462                         }
463
464                         if (exists($info->{'nodes' . $mpv}) && exists($info->{'nps' . $mpv}) && exists($info->{'depth' . $mpv})) {
465                                 $text .= sprintf " (%5u kn, %3u kn/s, %2u ply$tbhits)",
466                                         $info->{'nodes' . $mpv} / 1000, $info->{'nps' . $mpv} / 1000, $info->{'depth' . $mpv};
467                         }
468
469                         $text .= ":\n";
470                         $text .= "  " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}})) . "\n";
471                         $text .= "\n";
472                         ++$mpv;
473                 }
474         } else {
475                 # single-PV
476                 my $score = long_score($info, $pos_calculating, '');
477                 $text .= "  $score\n" if defined($score);
478                 $text .=  "  PV: " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv'}}));
479                 $text .=  "\n";
480
481                 if (exists($info->{'nodes'}) && exists($info->{'nps'}) && exists($info->{'depth'})) {
482                         $text .= sprintf "  %u nodes, %7u nodes/sec, depth %u ply",
483                                 $info->{'nodes'}, $info->{'nps'}, $info->{'depth'};
484                 }
485                 if (exists($info->{'seldepth'})) {
486                         $text .= sprintf " (%u selective)", $info->{'seldepth'};
487                 }
488                 if (exists($info->{'tbhits'}) && $info->{'tbhits'} > 0) {
489                         if ($info->{'tbhits'} == 1) {
490                                 $text .= ", one Syzygy hit";
491                         } else {
492                                 $text .= sprintf ", %u Syzygy hits", $info->{'tbhits'};
493                         }
494                 }
495                 $text .= "\n\n";
496         }
497
498         #$text .= book_info($pos_calculating->fen(), $pos_calculating->{'board'}, $pos_calculating->{'toplay'});
499
500         my @refutation_lines = ();
501         if (defined($engine2)) {
502                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
503                         my $info = $engine2->{'info'};
504                         last if (!exists($info->{'pv' . $mpv}));
505                         eval {
506                                 my $pv = $info->{'pv' . $mpv};
507
508                                 my $pretty_move = join('', prettyprint_pv($pos_calculating_second_engine, $pv->[0]));
509                                 my @pretty_pv = prettyprint_pv($pos_calculating_second_engine, @$pv);
510                                 if (scalar @pretty_pv > 5) {
511                                         @pretty_pv = @pretty_pv[0..4];
512                                         push @pretty_pv, "...";
513                                 }
514                                 my $key = $pretty_move;
515                                 my $line = sprintf("  %-6s %6s %3s  %s",
516                                         $pretty_move,
517                                         short_score($info, $pos_calculating_second_engine, $mpv, 0),
518                                         "d" . $info->{'depth' . $mpv},
519                                         join(', ', @pretty_pv));
520                                 push @refutation_lines, [ $key, $line ];
521                         };
522                 }
523         }
524
525         if ($#refutation_lines >= 0) {
526                 $text .= "Shallow search of all legal moves:\n\n";
527                 for my $line (sort { $a->[0] cmp $b->[0] } @refutation_lines) {
528                         $text .= $line->[1] . "\n";
529                 }
530                 $text .= "\n\n";        
531         }       
532
533         if ($last_text ne $text) {
534                 print "\e[H\e[2J"; # clear the screen
535                 print $text;
536                 $last_text = $text;
537         }
538 }
539
540 sub output_json {
541         my $info = $engine->{'info'};
542
543         my $json = {};
544         $json->{'position'} = $pos_calculating->to_json_hash();
545         $json->{'id'} = $engine->{'id'};
546         $json->{'score'} = long_score($info, $pos_calculating, '');
547
548         $json->{'nodes'} = $info->{'nodes'};
549         $json->{'nps'} = $info->{'nps'};
550         $json->{'depth'} = $info->{'depth'};
551         $json->{'tbhits'} = $info->{'tbhits'};
552         $json->{'seldepth'} = $info->{'seldepth'};
553
554         # single-PV only for now
555         $json->{'pv_uci'} = $info->{'pv'};
556         $json->{'pv_pretty'} = [ prettyprint_pv($pos_calculating, @{$info->{'pv'}}) ];
557
558         my %refutation_lines = ();
559         my @refutation_lines = ();
560         if (defined($engine2)) {
561                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
562                         my $info = $engine2->{'info'};
563                         my $pretty_move = "";
564                         my @pretty_pv = ();
565                         last if (!exists($info->{'pv' . $mpv}));
566
567                         eval {
568                                 my $pv = $info->{'pv' . $mpv};
569                                 my $pretty_move = join('', prettyprint_pv($pos_calculating, $pv->[0]));
570                                 my @pretty_pv = prettyprint_pv($pos_calculating, @$pv);
571                                 $refutation_lines{$pv->[0]} = {
572                                         sort_key => $pretty_move,
573                                         depth => $info->{'depth' . $mpv},
574                                         score_sort_key => score_sort_key($info, $pos_calculating, $mpv, 0),
575                                         pretty_score => short_score($info, $pos_calculating, $mpv, 0),
576                                         pretty_move => $pretty_move,
577                                         pv_pretty => \@pretty_pv,
578                                 };
579                                 $refutation_lines{$pv->[0]}->{'pv_uci'} = $pv;
580                         };
581                 }
582         }
583         $json->{'refutation_lines'} = \%refutation_lines;
584
585         open my $fh, ">/srv/analysis.sesse.net/www/analysis.json.tmp"
586                 or return;
587         print $fh JSON::XS::encode_json($json);
588         close $fh;
589         rename("/srv/analysis.sesse.net/www/analysis.json.tmp", "/srv/analysis.sesse.net/www/analysis.json");
590 }
591
592 sub uciprint {
593         my ($engine, $msg) = @_;
594         $engine->print($msg);
595         print UCILOG localtime() . " $engine->{'tag'} => $msg\n";
596 }
597
598 sub short_score {
599         my ($info, $pos, $mpv, $invert) = @_;
600
601         $invert //= 0;
602         if ($pos->{'toplay'} eq 'B') {
603                 $invert = !$invert;
604         }
605
606         if (defined($info->{'score_mate' . $mpv})) {
607                 if ($invert) {
608                         return sprintf "M%3d", -$info->{'score_mate' . $mpv};
609                 } else {
610                         return sprintf "M%3d", $info->{'score_mate' . $mpv};
611                 }
612         } else {
613                 if (exists($info->{'score_cp' . $mpv})) {
614                         my $score = $info->{'score_cp' . $mpv} * 0.01;
615                         if ($score == 0) {
616                                 return " 0.00";
617                         }
618                         if ($invert) {
619                                 $score = -$score;
620                         }
621                         return sprintf "%+5.2f", $score;
622                 }
623         }
624
625         return undef;
626 }
627
628 sub score_sort_key {
629         my ($info, $pos, $mpv, $invert) = @_;
630
631         if (defined($info->{'score_mate' . $mpv})) {
632                 if ($invert) {
633                         return 99999 - $info->{'score_mate' . $mpv};
634                 } else {
635                         return -(99999 - $info->{'score_mate' . $mpv});
636                 }
637         } else {
638                 if (exists($info->{'score_cp' . $mpv})) {
639                         my $score = $info->{'score_cp' . $mpv};
640                         if ($invert) {
641                                 $score = -$score;
642                         }
643                         return $score;
644                 }
645         }
646
647         return undef;
648 }
649
650 sub long_score {
651         my ($info, $pos, $mpv) = @_;
652
653         if (defined($info->{'score_mate' . $mpv})) {
654                 my $mate = $info->{'score_mate' . $mpv};
655                 if ($pos->{'toplay'} eq 'B') {
656                         $mate = -$mate;
657                 }
658                 if ($mate > 0) {
659                         return sprintf "White mates in %u", $mate;
660                 } else {
661                         return sprintf "Black mates in %u", -$mate;
662                 }
663         } else {
664                 if (exists($info->{'score_cp' . $mpv})) {
665                         my $score = $info->{'score_cp' . $mpv} * 0.01;
666                         if ($score == 0) {
667                                 return "Score:  0.00";
668                         }
669                         if ($pos->{'toplay'} eq 'B') {
670                                 $score = -$score;
671                         }
672                         return sprintf "Score: %+5.2f", $score;
673                 }
674         }
675
676         return undef;
677 }
678
679 my %book_cache = ();
680 sub book_info {
681         my ($fen, $board, $toplay) = @_;
682
683         if (exists($book_cache{$fen})) {
684                 return $book_cache{$fen};
685         }
686
687         my $ret = `./booklook $fen`;
688         return "" if ($ret =~ /Not found/ || $ret eq '');
689
690         my @moves = ();
691
692         for my $m (split /\n/, $ret) {
693                 my ($move, $annotation, $win, $draw, $lose, $rating, $rating_div) = split /,/, $m;
694
695                 my $pmove;
696                 if ($move eq '')  {
697                         $pmove = '(current)';
698                 } else {
699                         ($pmove) = prettyprint_pv_no_cache($board, $move);
700                         $pmove .= $annotation;
701                 }
702
703                 my $score;
704                 if ($toplay eq 'W') {
705                         $score = 1.0 * $win + 0.5 * $draw + 0.0 * $lose;
706                 } else {
707                         $score = 0.0 * $win + 0.5 * $draw + 1.0 * $lose;
708                 }
709                 my $n = $win + $draw + $lose;
710                 
711                 my $percent;
712                 if ($n == 0) {
713                         $percent = "     ";
714                 } else {
715                         $percent = sprintf "%4u%%", int(100.0 * $score / $n + 0.5);
716                 }
717
718                 push @moves, [ $pmove, $n, $percent, $rating ];
719         }
720
721         @moves[1..$#moves] = sort { $b->[2] cmp $a->[2] } @moves[1..$#moves];
722         
723         my $text = "Book moves:\n\n              Perf.     N     Rating\n\n";
724         for my $m (@moves) {
725                 $text .= sprintf "  %-10s %s   %6u    %4s\n", $m->[0], $m->[2], $m->[1], $m->[3]
726         }
727
728         return $text;
729 }
730
731 sub open_engine {
732         my ($cmdline, $tag, $cb) = @_;
733         return undef if (!defined($cmdline));
734         return Engine->open($cmdline, $tag, $cb);
735 }
736
737 sub col_letter_to_num {
738         return ord(shift) - ord('a');
739 }
740
741 sub row_letter_to_num {
742         return 7 - (ord(shift) - ord('1'));
743 }
744
745 sub parse_uci_move {
746         my $move = shift;
747         my $from_col = col_letter_to_num(substr($move, 0, 1));
748         my $from_row = row_letter_to_num(substr($move, 1, 1));
749         my $to_col   = col_letter_to_num(substr($move, 2, 1));
750         my $to_row   = row_letter_to_num(substr($move, 3, 1));
751         my $promo    = substr($move, 4, 1);
752         return ($from_col, $from_row, $to_col, $to_row, $promo);
753 }