git.sesse.net Git - remoteglot/blob - remoteglot.pl

   1 #! /usr/bin/perl
   2
   3 #
   4 # remoteglot - Connects an abitrary UCI-speaking engine to ICS for easier post-game
   5 #              analysis, or for live analysis of relayed games. (Do not use for
   6 #              cheating! Cheating is bad for your karma, and your abuser flag.)
   7 #
   8 # Copyright 2007 Steinar H. Gunderson <sgunderson@bigfoot.com>
   9 # Licensed under the GNU General Public License, version 2.
  10 #
  11
  12 use Net::Telnet;
  13 use FileHandle;
  14 use IPC::Open2;
  15 use Time::HiRes;
  16 use strict;
  17 use warnings;
  18
  19 # Configuration
  20 my $server = "freechess.org";
  21 my $target = "GMCarlsen";
  22 my $engine_cmdline = "'./Deep Rybka 4 SSE42 x64'";
  23 my $telltarget = undef;   # undef to be silent
  24 my @tell_intervals = (5, 20, 60, 120, 240, 480, 960);  # after each move
  25 my $uci_assume_full_compliance = 0;                    # dangerous :-)
  26 my @masters = (
  27         'Sesse',
  28         'Sessse',
  29         'Sesssse',
  30         'greatestguns',
  31         'beuki'
  32 );
  33
  34 # Program starts here
  35 $SIG{ALRM} = sub { output_screen(); };
  36
  37 $| = 1;
  38
  39 open(FICSLOG, ">ficslog.txt")
  40         or die "ficslog.txt: $!";
  41 print FICSLOG "Log starting.\n";
  42 select(FICSLOG);
  43 $| = 1;
  44
  45 open(UCILOG, ">ucilog.txt")
  46         or die "ucilog.txt: $!";
  47 print UCILOG "Log starting.\n";
  48 select(UCILOG);
  49 $| = 1;
  50 select(STDOUT);
  51
  52 # open the chess engine
  53 my $engine = open_engine($engine_cmdline);
  54 my %uciinfo = ();
  55 my %uciid = ();
  56 my ($last_move, $last_tell);
  57 my $last_text = '';
  58 my $last_told_text = '';
  59 my ($pos_waiting, $pos_calculating);
  60
  61 uciprint($engine, "setoption name UCI_AnalyseMode value true");
  62 # uciprint($engine, "setoption name NalimovPath value /srv/tablebase");
  63 uciprint($engine, "setoption name NalimovUsage value Rarely");
  64 uciprint($engine, "setoption name Hash value 1024");
  65 # uciprint($engine, "setoption name MultiPV value 2");
  66 uciprint($engine, "ucinewgame");
  67
  68 print "Chess engine ready.\n";
  69
  70 # now talk to FICS
  71 my $t = Net::Telnet->new(Timeout => 10, Prompt => '/fics% /');
  72 $t->input_log(\*FICSLOG);
  73 $t->open($server);
  74 $t->print("SesseBOT");
  75 $t->waitfor('/Press return to enter the server/');
  76 $t->cmd("");
  77
  78 # set some options
  79 $t->cmd("set shout 0");
  80 $t->cmd("set seek 0");
  81 $t->cmd("set style 12");
  82 $t->cmd("observe $target");
  83
  84 # main loop
  85 print "FICS ready.\n";
  86 while (1) {
  87         my $rin = '';
  88         my $rout;
  89         vec($rin, fileno($engine->{'read'}), 1) = 1;
  90         vec($rin, fileno($t), 1) = 1;
  91
  92         my ($nfound, $timeleft) = select($rout=$rin, undef, undef, 5.0);
  93         my $sleep = 1.0;
  94
  95         while (1) {
  96                 my $line = $t->getline(Timeout => 0, errmode => 'return');
  97                 last if (!defined($line));
  98
  99                 chomp $line;
 100                 $line =~ tr/\r//d;
 101                 if ($line =~ /^<12> /) {
 102                         my $pos = style12_to_fen($line);
 103
 104                         # if this is already in the queue, ignore it
 105                         next if (defined($pos_waiting) && $pos->{'fen'} eq $pos_waiting->{'fen'});
 106
 107                         # if we're already chewing on this and there's nothing else in the queue,
 108                         # also ignore it
 109                         next if (!defined($pos_waiting) && defined($pos_calculating) &&
 110                                  $pos->{'fen'} eq $pos_calculating->{'fen'});
 111
 112                         # if we're already thinking on something, stop and wait for the engine
 113                         # to approve
 114                         if (defined($pos_calculating)) {
 115                                 if (!defined($pos_waiting)) {
 116                                         uciprint($engine, "stop");
 117                                 }
 118                                 if ($uci_assume_full_compliance) {
 119                                         $pos_waiting = $pos;
 120                                 } else {
 121                                         uciprint($engine, "position fen " . $pos->{'fen'});
 122                                         uciprint($engine, "go infinite");
 123                                         $pos_calculating = $pos;
 124                                 }
 125                         } else {
 126                                 # it's wrong just to give the FEN (the move history is useful,
 127                                 # and per the UCI spec, we should really have sent "ucinewgame"),
 128                                 # but it's easier
 129                                 uciprint($engine, "position fen " . $pos->{'fen'});
 130                                 uciprint($engine, "go infinite");
 131                                 $pos_calculating = $pos;
 132                         }
 133
 134                         %uciinfo = ();
 135                         $last_move = time;
 136
 137                         #
 138                         # Output a command every move to note that we're
 139                         # still paying attention -- this is a good tradeoff,
 140                         # since if no move has happened in the last half
 141                         # hour, the analysis/relay has most likely stopped
 142                         # and we should stop hogging server resources.
 143                         #
 144                         $t->cmd("date");
 145                 }
 146                 if ($line =~ /^([A-Za-z]+)(?:\([A-Z]+\))* tells you: (.*)$/) {
 147                         my ($who, $msg) = ($1, $2);
 148
 149                         next if (grep { $_ eq $who } (@masters) == 0);
 150
 151                         if ($msg =~ /^fics (.*?)$/) {
 152                                 $t->cmd("tell $who Executing '$1' on FICS.");
 153                                 $t->cmd($1);
 154                         } elsif ($msg =~ /^uci (.*?)$/) {
 155                                 $t->cmd("tell $who Sending '$1' to the engine.");
 156                                 print { $engine->{'write'} } "$1\n";
 157                         } else {
 158                                 $t->cmd("tell $who Couldn't understand '$msg', sorry.");
 159                         }
 160                 }
 161                 #print "FICS: [$line]\n";
 162                 $sleep = 0;
 163         }
 164
 165         # any fun on the UCI channel?
 166         if ($nfound > 0 && vec($rout, fileno($engine->{'read'}), 1) == 1) {
 167                 my $line = read_line($engine->{'read'});
 168                 handle_uci($line);
 169                 $sleep = 0;
 170
 171                 # don't update too often
 172                 Time::HiRes::alarm(0.2);
 173         }
 174
 175         sleep $sleep;
 176 }
 177
 178 sub handle_uci {
 179         my ($line) = @_;
 180
 181         chomp $line;
 182         $line =~ tr/\r//d;
 183         $line =~ s/  / /g;  # Sometimes needed for Zappa Mexico
 184         print UCILOG localtime() . " <= $line\n";
 185         if ($line =~ /^info/) {
 186                 my (@infos) = split / /, $line;
 187                 shift @infos;
 188
 189                 parse_infos(@infos);
 190         }
 191         if ($line =~ /^id/) {
 192                 my (@ids) = split / /, $line;
 193                 shift @ids;
 194
 195                 parse_ids(@ids);
 196         }
 197         if ($line =~ /^bestmove/ && $uci_assume_full_compliance) {
 198                 if (defined($pos_waiting)) {
 199                         uciprint($engine, "position fen " . $pos_waiting->{'fen'});
 200                         uciprint($engine, "go infinite");
 201
 202                         $pos_calculating = $pos_waiting;
 203                         $pos_waiting = undef;
 204                 }
 205         }
 206 }
 207
 208 sub parse_infos {
 209         my (@x) = @_;
 210         my $mpv = '';
 211
 212         while (scalar @x > 0) {
 213                 if ($x[0] =~ 'multipv') {
 214                         shift @x;
 215                         $mpv = shift @x;
 216                         next;
 217                 }
 218                 if ($x[0] =~ /^(currmove|currmovenumber|cpuload)$/) {
 219                         my $key = shift @x;
 220                         my $value = shift @x;
 221                         $uciinfo{$key} = $value;
 222                         next;
 223                 }
 224                 if ($x[0] =~ /^(depth|seldepth|hashfull|time|nodes|nps|tbhits)$/) {
 225                         my $key = shift @x;
 226                         my $value = shift @x;
 227                         $uciinfo{$key . $mpv} = $value;
 228                         next;
 229                 }
 230                 if ($x[0] eq 'score') {
 231                         shift @x;
 232
 233                         delete $uciinfo{'score_cp' . $mpv};
 234                         delete $uciinfo{'score_mate' . $mpv};
 235
 236                         while ($x[0] =~ /^(cp|mate|lowerbound|upperbound)$/) {
 237                                 if ($x[0] eq 'cp') {
 238                                         shift @x;
 239                                         $uciinfo{'score_cp' . $mpv} = shift @x;
 240                                 } elsif ($x[0] eq 'mate') {
 241                                         shift @x;
 242                                         $uciinfo{'score_mate' . $mpv} = shift @x;
 243                                 } else {
 244                                         shift @x;
 245                                 }
 246                         }
 247                         next;
 248                 }
 249                 if ($x[0] eq 'pv') {
 250                         $uciinfo{'pv' . $mpv} = [ @x[1..$#x] ];
 251                         last;
 252                 }
 253                 if ($x[0] eq 'string' || $x[0] eq 'UCI_AnalyseMode' || $x[0] eq 'setting' || $x[0] eq 'contempt') {
 254                         last;
 255                 }
 256
 257                 #print "unknown info '$x[0]', trying to recover...\n";
 258                 #shift @x;
 259                 die "Unknown info '" . join(',', @x) . "'";
 260
 261         }
 262 }
 263
 264 sub parse_ids {
 265         my (@x) = @_;
 266
 267         while (scalar @x > 0) {
 268                 if ($x[0] =~ /^(name|author)$/) {
 269                         my $key = shift @x;
 270                         my $value = join(' ', @x);
 271                         $uciid{$key} = $value;
 272                         last;
 273                 }
 274
 275                 # unknown
 276                 shift @x;
 277         }
 278 }
 279
 280 sub style12_to_fen {
 281         my $str = shift;
 282         my %pos = ();
 283         my (@x) = split / /, $str;
 284
 285         $pos{'board'} = [ @x[1..8] ];
 286         $pos{'toplay'} = $x[9];
 287
 288         # the board itself
 289         my (@board) = @x[1..8];
 290         for my $rank (0..7) {
 291                 $board[$rank] =~ s/(-+)/length($1)/ge;
 292         }
 293         my $fen = join('/', @board);
 294
 295         # white/black to move
 296         $fen .= " ";
 297         $fen .= lc($x[9]);
 298
 299         # castling
 300         my $castling = "";
 301         $castling .= "K" if ($x[11] == 1);
 302         $castling .= "Q" if ($x[12] == 1);
 303         $castling .= "k" if ($x[13] == 1);
 304         $castling .= "q" if ($x[14] == 1);
 305         $castling = "-" if ($castling eq "");
 306         # $castling = "-"; # chess960
 307         $fen .= " ";
 308         $fen .= $castling;
 309
 310         # en passant
 311         my $ep = "-";
 312         if ($x[10] != -1) {
 313                 my $col = $x[10];
 314                 my $nep = (qw(a b c d e f g h))[$col];
 315
 316                 if ($x[9] eq 'B') {
 317                         $nep .= "3";
 318                 } else {
 319                         $nep .= "6";
 320                 }
 321
 322                 #
 323                 # Showing the en passant square when actually no capture can be made
 324                 # seems to confuse at least Rybka. Thus, check if there's actually
 325                 # a pawn of the opposite side that can do the en passant move, and if
 326                 # not, just lie -- it doesn't matter anyway. I'm unsure what's the
 327                 # "right" thing as per the standard, though.
 328                 #
 329                 if ($x[9] eq 'B') {
 330                         $ep = $nep if ($col > 0 && substr($pos{'board'}[4], $col-1, 1) eq 'p');
 331                         $ep = $nep if ($col < 7 && substr($pos{'board'}[4], $col+1, 1) eq 'p');
 332                 } else {
 333                         $ep = $nep if ($col > 0 && substr($pos{'board'}[3], $col-1, 1) eq 'P');
 334                         $ep = $nep if ($col < 7 && substr($pos{'board'}[3], $col+1, 1) eq 'P');
 335                 }
 336         }
 337         $fen .= " ";
 338         $fen .= $ep;
 339
 340         # half-move clock
 341         $fen .= " ";
 342         $fen .= $x[15];
 343
 344         # full-move clock
 345         $fen .= " ";
 346         $fen .= $x[26];
 347
 348         $pos{'fen'} = $fen;
 349         $pos{'move_num'} = $x[26];
 350         $pos{'last_move'} = $x[29];
 351
 352         return \%pos;
 353 }
 354
 355 sub prettyprint_pv {
 356         my ($board, @pvs) = @_;
 357
 358         if (scalar @pvs == 0 || !defined($pvs[0])) {
 359                 return ();
 360         }
 361
 362         my @nb = @$board;
 363
 364         my $pv = shift @pvs;
 365         my $from_col = ord(substr($pv, 0, 1)) - ord('a');
 366         my $from_row = 7 - (ord(substr($pv, 1, 1)) - ord('1'));
 367         my $to_col   = ord(substr($pv, 2, 1)) - ord('a');
 368         my $to_row   = 7 - (ord(substr($pv, 3, 1)) - ord('1'));
 369
 370         my $pretty;
 371         my $piece = substr($board->[$from_row], $from_col, 1);
 372
 373         if ($piece eq '-') {
 374                 die "Invalid move $pv";
 375         }
 376
 377         # white short castling
 378         if ($pv eq 'e1g1' && $piece eq 'K') {
 379                 # king
 380                 substr($nb[7], 4, 1, '-');
 381                 substr($nb[7], 6, 1, $piece);
 382
 383                 # rook
 384                 substr($nb[7], 7, 1, '-');
 385                 substr($nb[7], 5, 1, 'R');
 386
 387                 return ('0-0', prettyprint_pv(\@nb, @pvs));
 388         }
 389
 390         # white long castling
 391         if ($pv eq 'e1c1' && $piece eq 'K') {
 392                 # king
 393                 substr($nb[7], 4, 1, '-');
 394                 substr($nb[7], 2, 1, $piece);
 395
 396                 # rook
 397                 substr($nb[7], 0, 1, '-');
 398                 substr($nb[7], 3, 1, 'R');
 399
 400                 return ('0-0-0', prettyprint_pv(\@nb, @pvs));
 401         }
 402
 403         # black short castling
 404         if ($pv eq 'e8g8' && $piece eq 'k') {
 405                 # king
 406                 substr($nb[0], 4, 1, '-');
 407                 substr($nb[0], 6, 1, $piece);
 408
 409                 # rook
 410                 substr($nb[0], 7, 1, '-');
 411                 substr($nb[0], 5, 1, 'r');
 412
 413                 return ('0-0', prettyprint_pv(\@nb, @pvs));
 414         }
 415
 416         # black long castling
 417         if ($pv eq 'e8c8' && $piece eq 'k') {
 418                 # king
 419                 substr($nb[0], 4, 1, '-');
 420                 substr($nb[0], 2, 1, $piece);
 421
 422                 # rook
 423                 substr($nb[0], 0, 1, '-');
 424                 substr($nb[0], 3, 1, 'r');
 425
 426                 return ('0-0-0', prettyprint_pv(\@nb, @pvs));
 427         }
 428
 429         # check if the from-piece is a pawn
 430         if (lc($piece) eq 'p') {
 431                 # attack?
 432                 if ($from_col != $to_col) {
 433                         $pretty = substr($pv, 0, 1) . 'x' . substr($pv, 2, 2);
 434
 435                         # en passant?
 436                         if (substr($board->[$to_row], $to_col, 1) eq '-') {
 437                                 if ($piece eq 'p') {
 438                                         substr($nb[$to_row + 1], $to_col, 1, '-');
 439                                 } else {
 440                                         substr($nb[$to_row - 1], $to_col, 1, '-');
 441                                 }
 442                         }
 443                 } else {
 444                         $pretty = substr($pv, 2, 2);
 445
 446                         if (length($pv) == 5) {
 447                                 # promotion
 448                                 $pretty .= "=";
 449                                 $pretty .= uc(substr($pv, 4, 1));
 450
 451                                 if ($piece eq 'p') {
 452                                         $piece = substr($pv, 4, 1);
 453                                 } else {
 454                                         $piece = uc(substr($pv, 4, 1));
 455                                 }
 456                         }
 457                 }
 458         } else {
 459                 $pretty = uc($piece);
 460
 461                 # see how many of these pieces could go here, in all
 462                 my $num_total = 0;
 463                 for my $col (0..7) {
 464                         for my $row (0..7) {
 465                                 next unless (substr($board->[$row], $col, 1) eq $piece);
 466                                 ++$num_total if (can_reach($board, $piece, $row, $col, $to_row, $to_col));
 467                         }
 468                 }
 469
 470                 # see how many of these pieces from the given row could go here
 471                 my $num_row = 0;
 472                 for my $col (0..7) {
 473                         next unless (substr($board->[$from_row], $col, 1) eq $piece);
 474                         ++$num_row if (can_reach($board, $piece, $from_row, $col, $to_row, $to_col));
 475                 }
 476
 477                 # and same for columns
 478                 my $num_col = 0;
 479                 for my $row (0..7) {
 480                         next unless (substr($board->[$row], $from_col, 1) eq $piece);
 481                         ++$num_col if (can_reach($board, $piece, $row, $from_col, $to_row, $to_col));
 482                 }
 483
 484                 # see if we need to disambiguate
 485                 if ($num_total > 1) {
 486                         if ($num_col == 1) {
 487                                 $pretty .= substr($pv, 0, 1);
 488                         } elsif ($num_row == 1) {
 489                                 $pretty .= substr($pv, 1, 1);
 490                         } else {
 491                                 $pretty .= substr($pv, 0, 2);
 492                         }
 493                 }
 494
 495                 # attack?
 496                 if (substr($board->[$to_row], $to_col, 1) ne '-') {
 497                         $pretty .= 'x';
 498                 }
 499
 500                 $pretty .= substr($pv, 2, 2);
 501         }
 502
 503         # update the board
 504         substr($nb[$from_row], $from_col, 1, '-');
 505         substr($nb[$to_row], $to_col, 1, $piece);
 506
 507         if (in_mate(\@nb)) {
 508                 $pretty .= '#';
 509         } elsif (in_check(\@nb) ne 'none') {
 510                 $pretty .= '+';
 511         }
 512
 513         return ($pretty, prettyprint_pv(\@nb, @pvs));
 514 }
 515
 516 sub output_screen {
 517         #return;
 518
 519         return if (!defined($pos_calculating));
 520
 521         #
 522         # Check the PVs first. if they're invalid, just wait, as our data
 523         # is most likely out of sync. This isn't a very good solution, as
 524         # it can frequently miss stuff, but it's good enough for most users.
 525         #
 526         eval {
 527                 my $dummy;
 528                 if (exists($uciinfo{'pv'})) {
 529                         $dummy = prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv'}});
 530                 }
 531
 532                 my $mpv = 1;
 533                 while (exists($uciinfo{'pv' . $mpv})) {
 534                         $dummy = prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv' . $mpv}});
 535                         ++$mpv;
 536                 }
 537         };
 538         if ($@) {
 539                 %uciinfo = ();
 540                 return;
 541         }
 542
 543         my $text = 'Analysis';
 544         if ($pos_calculating->{'last_move'} ne 'none') {
 545                 if ($pos_calculating->{'toplay'} eq 'W') {
 546                         $text .= sprintf ' after %u. ... %s', ($pos_calculating->{'move_num'}-1), $pos_calculating->{'last_move'};
 547                 } else {
 548                         $text .= sprintf ' after %u. %s', $pos_calculating->{'move_num'}, $pos_calculating->{'last_move'};
 549                 }
 550                 if (exists($uciid{'name'})) {
 551                         $text .= ',';
 552                 }
 553         }
 554
 555         if (exists($uciid{'name'})) {
 556                 $text .= " by $uciid{'name'}:\n\n";
 557         } else {
 558                 $text .= ":\n\n";
 559         }
 560
 561         return unless (exists($pos_calculating->{'board'}));
 562
 563         #
 564         # Some programs _always_ report MultiPV, even with only one PV.
 565         # In this case, we simply use that data as if MultiPV was never
 566         # specified.
 567         #
 568         if (exists($uciinfo{'pv1'}) && !exists($uciinfo{'pv2'})) {
 569                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
 570                         if (exists($uciinfo{$key . '1'}) && !exists($uciinfo{$key})) {
 571                                 $uciinfo{$key} = $uciinfo{$key . '1'};
 572                         }
 573                 }
 574         }
 575
 576         if (exists($uciinfo{'pv1'}) && exists($uciinfo{'pv2'})) {
 577                 # multi-PV
 578                 my $mpv = 1;
 579                 while (exists($uciinfo{'pv' . $mpv})) {
 580                         $text .= sprintf "  PV%2u", $mpv;
 581                         my $score = short_score(\%uciinfo, $pos_calculating, $mpv);
 582                         $text .= "  ($score)" if (defined($score));
 583
 584                         my $tbhits = '';
 585                         if (exists($uciinfo{'tbhits' . $mpv}) && $uciinfo{'tbhits' . $mpv} > 0) {
 586                                 if ($uciinfo{'tbhits' . $mpv} == 1) {
 587                                         $tbhits = ", 1 tbhit";
 588                                 } else {
 589                                         $tbhits = sprintf ", %u tbhits", $uciinfo{'tbhits' . $mpv};
 590                                 }
 591                         }
 592
 593                         if (exists($uciinfo{'nodes' . $mpv}) && exists($uciinfo{'nps' . $mpv}) && exists($uciinfo{'depth' . $mpv})) {
 594                                 $text .= sprintf " (%5u kn, %3u kn/s, %2u ply$tbhits)",
 595                                         $uciinfo{'nodes' . $mpv} / 1000, $uciinfo{'nps' . $mpv} / 1000, $uciinfo{'depth' . $mpv};
 596                         }
 597
 598                         $text .= ":\n";
 599                         $text .= "  " . join(', ', prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv' . $mpv}})) . "\n";
 600                         $text .= "\n";
 601                         ++$mpv;
 602                 }
 603         } else {
 604                 # single-PV
 605                 my $score = long_score(\%uciinfo, $pos_calculating, '');
 606                 $text .= "  $score\n" if defined($score);
 607                 $text .=  "  PV: " . join(', ', prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv'}}));
 608                 $text .=  "\n";
 609
 610                 if (exists($uciinfo{'nodes'}) && exists($uciinfo{'nps'}) && exists($uciinfo{'depth'})) {
 611                         $text .= sprintf "  %u nodes, %7u nodes/sec, depth %u ply",
 612                                 $uciinfo{'nodes'}, $uciinfo{'nps'}, $uciinfo{'depth'};
 613                 }
 614                 if (exists($uciinfo{'tbhits'}) && $uciinfo{'tbhits'} > 0) {
 615                         if ($uciinfo{'tbhits'} == 1) {
 616                                 $text .= ", one Nalimov hit";
 617                         } else {
 618                                 $text .= sprintf ", %u Nalimov hits", $uciinfo{'tbhits'};
 619                         }
 620                 }
 621                 if (exists($uciinfo{'seldepth'})) {
 622                         $text .= sprintf " (%u selective)", $uciinfo{'seldepth'};
 623                 }
 624                 $text .=  "\n\n";
 625         }
 626
 627         #$text .= book_info($pos_calculating->{'fen'}, $pos_calculating->{'board'}, $pos_calculating->{'toplay'});
 628
 629         if ($last_text ne $text) {
 630                 print "\e[H\e[2J"; # clear the screen
 631                 print $text;
 632                 $last_text = $text;
 633         }
 634
 635         # Now construct the tell text, if any
 636         return if (!defined($telltarget));
 637
 638         my $tell_text = '';
 639
 640         if (exists($uciid{'name'})) {
 641                 $tell_text .= "Analysis by $uciid{'name'} -- see http://analysis.sesse.net/ for more information\n";
 642         } else {
 643                 $tell_text .= "Computer analysis -- http://analysis.sesse.net/ for more information\n";
 644         }
 645
 646         if (exists($uciinfo{'pv1'}) && exists($uciinfo{'pv2'})) {
 647                 # multi-PV
 648                 my $mpv = 1;
 649                 while (exists($uciinfo{'pv' . $mpv})) {
 650                         $tell_text .= sprintf "  PV%2u", $mpv;
 651                         my $score = short_score(\%uciinfo, $pos_calculating, $mpv);
 652                         $tell_text .= "  ($score)" if (defined($score));
 653
 654                         if (exists($uciinfo{'depth' . $mpv})) {
 655                                 $tell_text .= sprintf " (%2u ply)", $uciinfo{'depth' . $mpv};
 656                         }
 657
 658                         $tell_text .= ": ";
 659                         $tell_text .= join(', ', prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv' . $mpv}}));
 660                         $tell_text .= "\n";
 661                         ++$mpv;
 662                 }
 663         } else {
 664                 # single-PV
 665                 my $score = long_score(\%uciinfo, $pos_calculating, '');
 666                 $tell_text .= "  $score\n" if defined($score);
 667                 $tell_text .= "  PV: " . join(', ', prettyprint_pv($pos_calculating->{'board'}, @{$uciinfo{'pv'}}));
 668                 if (exists($uciinfo{'depth'})) {
 669                         $tell_text .= sprintf " (depth %u ply)", $uciinfo{'depth'};
 670                 }
 671                 $tell_text .=  "\n";
 672         }
 673
 674         # see if a new tell is called for -- it is if the delay has expired _and_
 675         # this is not simply a repetition of the last one
 676         if ($last_told_text ne $tell_text) {
 677                 my $now = time;
 678                 for my $iv (@tell_intervals) {
 679                         last if ($now - $last_move < $iv);
 680                         next if ($last_tell - $last_move >= $iv);
 681
 682                         for my $line (split /\n/, $tell_text) {
 683                                 $t->print("tell $telltarget [$target] $line");
 684                         }
 685
 686                         $last_told_text = $text;
 687                         $last_tell = $now;
 688
 689                         last;
 690                 }
 691         }
 692 }
 693
 694 sub find_kings {
 695         my $board = shift;
 696         my ($wkr, $wkc, $bkr, $bkc);
 697
 698         for my $row (0..7) {
 699                 for my $col (0..7) {
 700                         my $piece = substr($board->[$row], $col, 1);
 701                         if ($piece eq 'K') {
 702                                 ($wkr, $wkc) = ($row, $col);
 703                         } elsif ($piece eq 'k') {
 704                                 ($bkr, $bkc) = ($row, $col);
 705                         }
 706                 }
 707         }
 708
 709         return ($wkr, $wkc, $bkr, $bkc);
 710 }
 711
 712 sub in_mate {
 713         my $board = shift;
 714         my $check = in_check($board);
 715         return 0 if ($check eq 'none');
 716
 717         # try all possible moves for the side in check
 718         for my $row (0..7) {
 719                 for my $col (0..7) {
 720                         my $piece = substr($board->[$row], $col, 1);
 721                         next if ($piece eq '-');
 722
 723                         if ($check eq 'white') {
 724                                 next if ($piece eq lc($piece));
 725                         } else {
 726                                 next if ($piece eq uc($piece));
 727                         }
 728
 729                         for my $dest_row (0..7) {
 730                                 for my $dest_col (0..7) {
 731                                         next if ($row == $dest_row && $col == $dest_col);
 732                                         next unless (can_reach($board, $piece, $row, $col, $dest_row, $dest_col));
 733
 734                                         my @nb = @$board;
 735                                         substr($nb[$row], $col, 1, '-');
 736                                         substr($nb[$dest_row], $dest_col, 1, $piece);
 737
 738                                         my $new_check = in_check(\@nb);
 739                                         return 0 if ($new_check ne $check && $new_check ne 'both');
 740                                 }
 741                         }
 742                 }
 743         }
 744
 745         # nothing to do; mate
 746         return 1;
 747 }
 748
 749 sub in_check {
 750         my $board = shift;
 751         my ($black_check, $white_check) = (0, 0);
 752
 753         my ($wkr, $wkc, $bkr, $bkc) = find_kings($board);
 754
 755         # check all pieces for the possibility of threatening the two kings
 756         for my $row (0..7) {
 757                 for my $col (0..7) {
 758                         my $piece = substr($board->[$row], $col, 1);
 759                         next if ($piece eq '-');
 760
 761                         if (uc($piece) eq $piece) {
 762                                 # white piece
 763                                 $black_check = 1 if (can_reach($board, $piece, $row, $col, $bkr, $bkc));
 764                         } else {
 765                                 # black piece
 766                                 $white_check = 1 if (can_reach($board, $piece, $row, $col, $wkr, $wkc));
 767                         }
 768                 }
 769         }
 770
 771         if ($black_check && $white_check) {
 772                 return 'both';
 773         } elsif ($black_check) {
 774                 return 'black';
 775         } elsif ($white_check) {
 776                 return 'white';
 777         } else {
 778                 return 'none';
 779         }
 780 }
 781
 782 sub can_reach {
 783         my ($board, $piece, $from_row, $from_col, $to_row, $to_col) = @_;
 784
 785         # can't eat your own piece
 786         my $dest_piece = substr($board->[$to_row], $to_col, 1);
 787         if ($dest_piece ne '-') {
 788                 return 0 if (($piece eq lc($piece)) == ($dest_piece eq lc($dest_piece)));
 789         }
 790
 791         if (lc($piece) eq 'k') {
 792                 return (abs($from_row - $to_row) <= 1 && abs($from_col - $to_col) <= 1);
 793         }
 794         if (lc($piece) eq 'r') {
 795                 return 0 unless ($from_row == $to_row || $from_col == $to_col);
 796
 797                 # check that there's a clear passage
 798                 if ($from_row == $to_row) {
 799                         if ($from_col > $to_col) {
 800                                 ($to_col, $from_col) = ($from_col, $to_col);
 801                         }
 802
 803                         for my $c (($from_col+1)..($to_col-1)) {
 804                                 my $middle_piece = substr($board->[$to_row], $c, 1);
 805                                 return 0 if ($middle_piece ne '-');
 806                         }
 807
 808                         return 1;
 809                 } else {
 810                         if ($from_row > $to_row) {
 811                                 ($to_row, $from_row) = ($from_row, $to_row);
 812                         }
 813
 814                         for my $r (($from_row+1)..($to_row-1)) {
 815                                 my $middle_piece = substr($board->[$r], $to_col, 1);
 816                                 return 0 if ($middle_piece ne '-');
 817                         }
 818
 819                         return 1;
 820                 }
 821         }
 822         if (lc($piece) eq 'b') {
 823                 return 0 unless (abs($from_row - $to_row) == abs($from_col - $to_col));
 824
 825                 my $dr = ($to_row - $from_row) / abs($to_row - $from_row);
 826                 my $dc = ($to_col - $from_col) / abs($to_col - $from_col);
 827
 828                 my $r = $from_row + $dr;
 829                 my $c = $from_col + $dc;
 830
 831                 while ($r != $to_row) {
 832                         my $middle_piece = substr($board->[$r], $c, 1);
 833                         return 0 if ($middle_piece ne '-');
 834
 835                         $r += $dr;
 836                         $c += $dc;
 837                 }
 838
 839                 return 1;
 840         }
 841         if (lc($piece) eq 'n') {
 842                 my $diff_r = abs($from_row - $to_row);
 843                 my $diff_c = abs($from_col - $to_col);
 844                 return 1 if ($diff_r == 2 && $diff_c == 1);
 845                 return 1 if ($diff_r == 1 && $diff_c == 2);
 846                 return 0;
 847         }
 848         if ($piece eq 'q') {
 849                 return (can_reach($board, 'r', $from_row, $from_col, $to_row, $to_col) ||
 850                         can_reach($board, 'b', $from_row, $from_col, $to_row, $to_col));
 851         }
 852         if ($piece eq 'Q') {
 853                 return (can_reach($board, 'R', $from_row, $from_col, $to_row, $to_col) ||
 854                         can_reach($board, 'B', $from_row, $from_col, $to_row, $to_col));
 855         }
 856
 857         # TODO: en passant
 858         if ($piece eq 'p') {
 859                 # black pawn
 860                 if ($to_col == $from_col && $to_row == $from_row + 1) {
 861                         return ($dest_piece eq '-');
 862                 }
 863                 if ($to_col == $from_col && $from_row == 1 && $to_row == 3) {
 864                         my $middle_piece = substr($board->[2], $to_col, 1);
 865                         return ($dest_piece eq '-' && $middle_piece eq '-');
 866                 }
 867                 if (abs($to_col - $from_col) == 1 && $to_row == $from_row + 1) {
 868                         return ($dest_piece ne '-');
 869                 }
 870                 return 0;
 871         }
 872         if ($piece eq 'P') {
 873                 # white pawn
 874                 if ($to_col == $from_col && $to_row == $from_row - 1) {
 875                         return ($dest_piece eq '-');
 876                 }
 877                 if ($to_col == $from_col && $from_row == 6 && $to_row == 4) {
 878                         my $middle_piece = substr($board->[5], $to_col, 1);
 879                         return ($dest_piece eq '-' && $middle_piece eq '-');
 880                 }
 881                 if (abs($to_col - $from_col) == 1 && $to_row == $from_row - 1) {
 882                         return ($dest_piece ne '-');
 883                 }
 884                 return 0;
 885         }
 886
 887         # unknown piece
 888         return 0;
 889 }
 890
 891 sub uciprint {
 892         my ($engine, $msg) = @_;
 893         print { $engine->{'write'} } "$msg\n";
 894         print UCILOG localtime() . " => $msg\n";
 895 }
 896
 897 sub short_score {
 898         my ($uciinfo, $pos, $mpv) = @_;
 899
 900         if (defined($uciinfo{'score_mate' . $mpv})) {
 901                 return sprintf "M%3d", $uciinfo{'score_mate' . $mpv};
 902         } else {
 903                 if (exists($uciinfo{'score_cp' . $mpv})) {
 904                         my $score = $uciinfo{'score_cp' . $mpv} * 0.01;
 905                         if ($pos->{'toplay'} eq 'B') {
 906                                 $score = -$score;
 907                         }
 908                         return sprintf "%+5.2f", $score;
 909                 }
 910         }
 911
 912         return undef;
 913 }
 914
 915 sub long_score {
 916         my ($uciinfo, $pos, $mpv) = @_;
 917
 918         if (defined($uciinfo{'score_mate' . $mpv})) {
 919                 my $mate = $uciinfo{'score_mate' . $mpv};
 920                 if ($pos->{'toplay'} eq 'B') {
 921                         $mate = -$mate;
 922                 }
 923                 if ($mate > 0) {
 924                         return sprintf "White mates in %u", $mate;
 925                 } else {
 926                         return sprintf "Black mates in %u", -$mate;
 927                 }
 928         } else {
 929                 if (exists($uciinfo{'score_cp' . $mpv})) {
 930                         my $score = $uciinfo{'score_cp' . $mpv} * 0.01;
 931                         if ($pos->{'toplay'} eq 'B') {
 932                                 $score = -$score;
 933                         }
 934                         return sprintf "Score: %+5.2f", $score;
 935                 }
 936         }
 937
 938         return undef;
 939 }
 940
 941 my %book_cache = ();
 942 sub book_info {
 943         my ($fen, $board, $toplay) = @_;
 944
 945         if (exists($book_cache{$fen})) {
 946                 return $book_cache{$fen};
 947         }
 948
 949         my $ret = `./booklook $fen`;
 950         return "" if ($ret =~ /Not found/ || $ret eq '');
 951
 952         my @moves = ();
 953
 954         for my $m (split /\n/, $ret) {
 955                 my ($move, $annotation, $win, $draw, $lose, $rating, $rating_div) = split /,/, $m;
 956
 957                 my $pmove;
 958                 if ($move eq '')  {
 959                         $pmove = '(current)';
 960                 } else {
 961                         ($pmove) = prettyprint_pv($board, $move);
 962                         $pmove .= $annotation;
 963                 }
 964
 965                 my $score;
 966                 if ($toplay eq 'W') {
 967                         $score = 1.0 * $win + 0.5 * $draw + 0.0 * $lose;
 968                 } else {
 969                         $score = 0.0 * $win + 0.5 * $draw + 1.0 * $lose;
 970                 }
 971                 my $n = $win + $draw + $lose;
 972
 973                 my $percent;
 974                 if ($n == 0) {
 975                         $percent = "     ";
 976                 } else {
 977                         $percent = sprintf "%4u%%", int(100.0 * $score / $n + 0.5);
 978                 }
 979
 980                 push @moves, [ $pmove, $n, $percent, $rating ];
 981         }
 982
 983         @moves[1..$#moves] = sort { $b->[2] cmp $a->[2] } @moves[1..$#moves];
 984
 985         my $text = "Book moves:\n\n              Perf.     N     Rating\n\n";
 986         for my $m (@moves) {
 987                 $text .= sprintf "  %-10s %s   %6u    %4s\n", $m->[0], $m->[2], $m->[1], $m->[3]
 988         }
 989
 990         return $text;
 991 }
 992
 993 sub open_engine {
 994         my $cmdline = shift;
 995         my ($uciread, $uciwrite);
 996         my $pid = IPC::Open2::open2($uciread, $uciwrite, $cmdline);
 997
 998         my $engine = {
 999                 pid => $pid,
1000                 read => $uciread,
1001                 write => $uciwrite
1002         };
1003
1004         uciprint($engine, "uci");
1005
1006         # gobble the options
1007         while (<$uciread>) {
1008                 /uciok/ && last;
1009                 handle_uci($_);
1010         }
1011
1012         return $engine;
1013 }
1014
1015 sub read_line {
1016         my $fh = shift;
1017
1018         #
1019         # Read until we've got a full line -- if the engine sends part of
1020         # a line and then stops we're pretty much hosed, but that should
1021         # never happen.
1022         #
1023         my $line = '';
1024         while ($line !~ /\n/) {
1025                 my $tmp;
1026                 my $ret = sysread $engine->{'read'}, $tmp, 1;
1027
1028                 if (!defined($ret)) {
1029                         next if ($!{EINTR});
1030                         die "error in reading from the UCI engine: $!";
1031                 } elsif ($ret == 0) {
1032                         die "EOF from UCI engine";
1033                 }
1034
1035                 $line .= $tmp;
1036         }
1037
1038         $line =~ tr/\r\n//d;
1039         return $line;
1040 }