git.sesse.net Git - remoteglot/blob - remoteglot.pl

   1 #! /usr/bin/perl
   2
   3 #
   4 # remoteglot - Connects an abitrary UCI-speaking engine to ICS for easier post-game
   5 #              analysis, or for live analysis of relayed games. (Do not use for
   6 #              cheating! Cheating is bad for your karma, and your abuser flag.)
   7 #
   8 # Copyright 2007 Steinar H. Gunderson <sgunderson@bigfoot.com>
   9 # Licensed under the GNU General Public License, version 2.
  10 #
  11
  12 use AnyEvent;
  13 use AnyEvent::Handle;
  14 use AnyEvent::HTTP;
  15 use Chess::PGN::Parse;
  16 use EV;
  17 use Net::Telnet;
  18 use FileHandle;
  19 use IPC::Open2;
  20 use Time::HiRes;
  21 use JSON::XS;
  22 use URI::Escape;
  23 require 'Position.pm';
  24 require 'Engine.pm';
  25 require 'config.pm';
  26 use strict;
  27 use warnings;
  28 no warnings qw(once);
  29
  30 # Program starts here
  31 $SIG{ALRM} = sub { output(); };
  32 my $latest_update = undef;
  33 my $http_timer = undef;
  34 my $tb_retry_timer = undef;
  35 my %tb_cache = ();
  36 my $tb_lookup_running = 0;
  37
  38 $| = 1;
  39
  40 open(FICSLOG, ">ficslog.txt")
  41         or die "ficslog.txt: $!";
  42 print FICSLOG "Log starting.\n";
  43 select(FICSLOG);
  44 $| = 1;
  45
  46 open(UCILOG, ">ucilog.txt")
  47         or die "ucilog.txt: $!";
  48 print UCILOG "Log starting.\n";
  49 select(UCILOG);
  50 $| = 1;
  51
  52 open(TBLOG, ">tblog.txt")
  53         or die "tblog.txt: $!";
  54 print TBLOG "Log starting.\n";
  55 select(TBLOG);
  56 $| = 1;
  57
  58 select(STDOUT);
  59
  60 # open the chess engine
  61 my $engine = open_engine($remoteglotconf::engine_cmdline, 'E1', sub { handle_uci(@_, 1); });
  62 my $engine2 = open_engine($remoteglotconf::engine2_cmdline, 'E2', sub { handle_uci(@_, 0); });
  63 my $last_move;
  64 my $last_text = '';
  65 my ($pos_waiting, $pos_calculating, $pos_calculating_second_engine);
  66
  67 uciprint($engine, "setoption name UCI_AnalyseMode value true");
  68 while (my ($key, $value) = each %remoteglotconf::engine_config) {
  69         uciprint($engine, "setoption name $key value $value");
  70 }
  71 uciprint($engine, "ucinewgame");
  72
  73 if (defined($engine2)) {
  74         uciprint($engine2, "setoption name UCI_AnalyseMode value true");
  75         while (my ($key, $value) = each %remoteglotconf::engine2_config) {
  76                 uciprint($engine2, "setoption name $key value $value");
  77         }
  78         uciprint($engine2, "setoption name MultiPV value 500");
  79         uciprint($engine2, "ucinewgame");
  80 }
  81
  82 print "Chess engine ready.\n";
  83
  84 # now talk to FICS
  85 my $t = Net::Telnet->new(Timeout => 10, Prompt => '/fics% /');
  86 $t->input_log(\*FICSLOG);
  87 $t->open($remoteglotconf::server);
  88 $t->print($remoteglotconf::nick);
  89 $t->waitfor('/Press return to enter the server/');
  90 $t->cmd("");
  91
  92 # set some options
  93 $t->cmd("set shout 0");
  94 $t->cmd("set seek 0");
  95 $t->cmd("set style 12");
  96
  97 my $ev1 = AnyEvent->io(
  98         fh => fileno($t),
  99         poll => 'r',
 100         cb => sub {    # what callback to execute
 101                 while (1) {
 102                         my $line = $t->getline(Timeout => 0, errmode => 'return');
 103                         return if (!defined($line));
 104
 105                         chomp $line;
 106                         $line =~ tr/\r//d;
 107                         handle_fics($line);
 108                 }
 109         }
 110 );
 111 if (defined($remoteglotconf::target)) {
 112         if ($remoteglotconf::target =~ /^http:/) {
 113                 fetch_pgn($remoteglotconf::target);
 114         } else {
 115                 $t->cmd("observe $remoteglotconf::target");
 116         }
 117 }
 118 print "FICS ready.\n";
 119
 120 # Engine events have already been set up by Engine.pm.
 121 EV::run;
 122
 123 sub handle_uci {
 124         my ($engine, $line, $primary) = @_;
 125
 126         return if $line =~ /(upper|lower)bound/;
 127
 128         $line =~ s/  / /g;  # Sometimes needed for Zappa Mexico
 129         print UCILOG localtime() . " $engine->{'tag'} <= $line\n";
 130         if ($line =~ /^info/) {
 131                 my (@infos) = split / /, $line;
 132                 shift @infos;
 133
 134                 parse_infos($engine, @infos);
 135         }
 136         if ($line =~ /^id/) {
 137                 my (@ids) = split / /, $line;
 138                 shift @ids;
 139
 140                 parse_ids($engine, @ids);
 141         }
 142         if ($line =~ /^bestmove/) {
 143                 if ($primary) {
 144                         return if (!$remoteglotconf::uci_assume_full_compliance);
 145                         if (defined($pos_waiting)) {
 146                                 uciprint($engine, "position fen " . $pos_waiting->fen());
 147                                 uciprint($engine, "go infinite");
 148
 149                                 $pos_calculating = $pos_waiting;
 150                                 $pos_waiting = undef;
 151                         }
 152                 } else {
 153                         $engine2->{'info'} = {};
 154                         my $pos = $pos_waiting // $pos_calculating;
 155                         uciprint($engine2, "position fen " . $pos->fen());
 156                         uciprint($engine2, "go infinite");
 157                         $pos_calculating_second_engine = $pos;
 158                 }
 159         }
 160         output();
 161 }
 162
 163 my $getting_movelist = 0;
 164 my $pos_for_movelist = undef;
 165 my @uci_movelist = ();
 166 my @pretty_movelist = ();
 167
 168 sub handle_fics {
 169         my $line = shift;
 170         if ($line =~ /^<12> /) {
 171                 handle_position(Position->new($line));
 172                 $t->cmd("moves");
 173         }
 174         if ($line =~ /^Movelist for game /) {
 175                 my $pos = $pos_waiting // $pos_calculating;
 176                 if (defined($pos)) {
 177                         @uci_movelist = ();
 178                         @pretty_movelist = ();
 179                         $pos_for_movelist = Position->start_pos($pos->{'player_w'}, $pos->{'player_b'});
 180                         $getting_movelist = 1;
 181                 }
 182         }
 183         if ($getting_movelist &&
 184             $line =~ /^\s* \d+\. \s+                     # move number
 185                        (\S+) \s+ \( [\d:.]+ \) \s*       # first move, then time
 186                        (?: (\S+) \s+ \( [\d:.]+ \) )?    # second move, then time
 187                      /x) {
 188                 eval {
 189                         my $uci_move;
 190                         ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($1);
 191                         push @uci_movelist, $uci_move;
 192                         push @pretty_movelist, $1;
 193
 194                         if (defined($2)) {
 195                                 ($pos_for_movelist, $uci_move) = $pos_for_movelist->make_pretty_move($2);
 196                                 push @uci_movelist, $uci_move;
 197                                 push @pretty_movelist, $2;
 198                         }
 199                 };
 200                 if ($@) {
 201                         warn "Error when getting FICS move history: $@";
 202                         exit;
 203                         $getting_movelist = 0;
 204                 }
 205         }
 206         if ($getting_movelist &&
 207             $line =~ /^\s+ \{.*\} \s+ (?: \* | 1\/2-1\/2 | 0-1 | 1-0 )/x) {
 208                 # End of movelist.
 209                 for my $pos ($pos_waiting, $pos_calculating) {
 210                         next if (!defined($pos));
 211                         if ($pos->fen() eq $pos_for_movelist->fen()) {
 212                                 $pos->{'history'} = \@uci_movelist;
 213                                 $pos->{'pretty_history'} = \@pretty_movelist;
 214                         }
 215                 }
 216                 $getting_movelist = 0;
 217         }
 218         if ($line =~ /^([A-Za-z]+)(?:\([A-Z]+\))* tells you: (.*)$/) {
 219                 my ($who, $msg) = ($1, $2);
 220
 221                 next if (grep { $_ eq $who } (@remoteglotconf::masters) == 0);
 222
 223                 if ($msg =~ /^fics (.*?)$/) {
 224                         $t->cmd("tell $who Executing '$1' on FICS.");
 225                         $t->cmd($1);
 226                 } elsif ($msg =~ /^uci (.*?)$/) {
 227                         $t->cmd("tell $who Sending '$1' to the engine.");
 228                         print { $engine->{'write'} } "$1\n";
 229                 } elsif ($msg =~ /^pgn (.*?)$/) {
 230                         my $url = $1;
 231                         $t->cmd("tell $who Starting to poll '$url'.");
 232                         fetch_pgn($url);
 233                 } elsif ($msg =~ /^stoppgn$/) {
 234                         $t->cmd("tell $who Stopping poll.");
 235                         $http_timer = undef;
 236                 } elsif ($msg =~ /^quit$/) {
 237                         $t->cmd("tell $who Bye bye.");
 238                         exit;
 239                 } else {
 240                         $t->cmd("tell $who Couldn't understand '$msg', sorry.");
 241                 }
 242         }
 243         #print "FICS: [$line]\n";
 244 }
 245
 246 # Starts periodic fetching of PGNs from the given URL.
 247 sub fetch_pgn {
 248         my ($url) = @_;
 249         AnyEvent::HTTP::http_get($url, sub {
 250                 handle_pgn(@_, $url);
 251         });
 252 }
 253
 254 my ($last_pgn_white, $last_pgn_black);
 255 my @last_pgn_uci_moves = ();
 256 my $pgn_hysteresis_counter = 0;
 257
 258 sub handle_pgn {
 259         my ($body, $header, $url) = @_;
 260         my $pgn = Chess::PGN::Parse->new(undef, $body);
 261         if (!defined($pgn) || !$pgn->read_game()) {
 262                 warn "Error in parsing PGN from $url\n";
 263         } else {
 264                 $pgn->quick_parse_game;
 265                 my $pos = Position->start_pos($pgn->white, $pgn->black);
 266                 my $moves = $pgn->moves;
 267                 my @uci_moves = ();
 268                 for my $move (@$moves) {
 269                         my $uci_move;
 270                         ($pos, $uci_move) = $pos->make_pretty_move($move);
 271                         push @uci_moves, $uci_move;
 272                 }
 273                 $pos->{'history'} = \@uci_moves;
 274                 $pos->{'pretty_history'} = $moves;
 275
 276                 # Sometimes, PGNs lose a move or two for a short while,
 277                 # or people push out new ones non-atomically.
 278                 # Thus, if we PGN doesn't change names but becomes
 279                 # shorter, we mistrust it for a few seconds.
 280                 my $trust_pgn = 1;
 281                 if (defined($last_pgn_white) && defined($last_pgn_black) &&
 282                     $last_pgn_white eq $pgn->white &&
 283                     $last_pgn_black eq $pgn->black &&
 284                     scalar(@uci_moves) < scalar(@last_pgn_uci_moves)) {
 285                         if (++$pgn_hysteresis_counter < 3) {
 286                                 $trust_pgn = 0;
 287                         }
 288                 }
 289                 if ($trust_pgn) {
 290                         $last_pgn_white = $pgn->white;
 291                         $last_pgn_black = $pgn->black;
 292                         @last_pgn_uci_moves = @uci_moves;
 293                         $pgn_hysteresis_counter = 0;
 294                         handle_position($pos);
 295                 }
 296         }
 297
 298         $http_timer = AnyEvent->timer(after => 1.0, cb => sub {
 299                 fetch_pgn($url);
 300         });
 301 }
 302
 303 sub handle_position {
 304         my ($pos) = @_;
 305
 306         # if this is already in the queue, ignore it
 307         return if (defined($pos_waiting) && $pos->fen() eq $pos_waiting->fen());
 308
 309         # if we're already chewing on this and there's nothing else in the queue,
 310         # also ignore it
 311         return if (!defined($pos_waiting) && defined($pos_calculating) &&
 312                  $pos->fen() eq $pos_calculating->fen());
 313
 314         # if we're already thinking on something, stop and wait for the engine
 315         # to approve
 316         if (defined($pos_calculating)) {
 317                 if (!defined($pos_waiting)) {
 318                         uciprint($engine, "stop");
 319                 }
 320                 if ($remoteglotconf::uci_assume_full_compliance) {
 321                         $pos_waiting = $pos;
 322                 } else {
 323                         uciprint($engine, "position fen " . $pos->fen());
 324                         uciprint($engine, "go infinite");
 325                         $pos_calculating = $pos;
 326                 }
 327         } else {
 328                 # it's wrong just to give the FEN (the move history is useful,
 329                 # and per the UCI spec, we should really have sent "ucinewgame"),
 330                 # but it's easier
 331                 uciprint($engine, "position fen " . $pos->fen());
 332                 uciprint($engine, "go infinite");
 333                 $pos_calculating = $pos;
 334         }
 335
 336         if (defined($engine2)) {
 337                 if (defined($pos_calculating_second_engine)) {
 338                         uciprint($engine2, "stop");
 339                 } else {
 340                         uciprint($engine2, "position fen " . $pos->fen());
 341                         uciprint($engine2, "go infinite");
 342                         $pos_calculating_second_engine = $pos;
 343                 }
 344                 $engine2->{'info'} = {};
 345         }
 346
 347         $engine->{'info'} = {};
 348         $last_move = time;
 349
 350         schedule_tb_lookup();
 351
 352         #
 353         # Output a command every move to note that we're
 354         # still paying attention -- this is a good tradeoff,
 355         # since if no move has happened in the last half
 356         # hour, the analysis/relay has most likely stopped
 357         # and we should stop hogging server resources.
 358         #
 359         $t->cmd("date");
 360 }
 361
 362 sub parse_infos {
 363         my ($engine, @x) = @_;
 364         my $mpv = '';
 365
 366         my $info = $engine->{'info'};
 367
 368         # Search for "multipv" first of all, since e.g. Stockfish doesn't put it first.
 369         for my $i (0..$#x - 1) {
 370                 if ($x[$i] eq 'multipv') {
 371                         $mpv = $x[$i + 1];
 372                         next;
 373                 }
 374         }
 375
 376         while (scalar @x > 0) {
 377                 if ($x[0] eq 'multipv') {
 378                         # Dealt with above
 379                         shift @x;
 380                         shift @x;
 381                         next;
 382                 }
 383                 if ($x[0] eq 'currmove' || $x[0] eq 'currmovenumber' || $x[0] eq 'cpuload') {
 384                         my $key = shift @x;
 385                         my $value = shift @x;
 386                         $info->{$key} = $value;
 387                         next;
 388                 }
 389                 if ($x[0] eq 'depth' || $x[0] eq 'seldepth' || $x[0] eq 'hashfull' ||
 390                     $x[0] eq 'time' || $x[0] eq 'nodes' || $x[0] eq 'nps' ||
 391                     $x[0] eq 'tbhits') {
 392                         my $key = shift @x;
 393                         my $value = shift @x;
 394                         $info->{$key . $mpv} = $value;
 395                         next;
 396                 }
 397                 if ($x[0] eq 'score') {
 398                         shift @x;
 399
 400                         delete $info->{'score_cp' . $mpv};
 401                         delete $info->{'score_mate' . $mpv};
 402
 403                         while ($x[0] eq 'cp' || $x[0] eq 'mate') {
 404                                 if ($x[0] eq 'cp') {
 405                                         shift @x;
 406                                         $info->{'score_cp' . $mpv} = shift @x;
 407                                 } elsif ($x[0] eq 'mate') {
 408                                         shift @x;
 409                                         $info->{'score_mate' . $mpv} = shift @x;
 410                                 } else {
 411                                         shift @x;
 412                                 }
 413                         }
 414                         next;
 415                 }
 416                 if ($x[0] eq 'pv') {
 417                         $info->{'pv' . $mpv} = [ @x[1..$#x] ];
 418                         last;
 419                 }
 420                 if ($x[0] eq 'string' || $x[0] eq 'UCI_AnalyseMode' || $x[0] eq 'setting' || $x[0] eq 'contempt') {
 421                         last;
 422                 }
 423
 424                 #print "unknown info '$x[0]', trying to recover...\n";
 425                 #shift @x;
 426                 die "Unknown info '" . join(',', @x) . "'";
 427
 428         }
 429 }
 430
 431 sub parse_ids {
 432         my ($engine, @x) = @_;
 433
 434         while (scalar @x > 0) {
 435                 if ($x[0] =~ /^(name|author)$/) {
 436                         my $key = shift @x;
 437                         my $value = join(' ', @x);
 438                         $engine->{'id'}{$key} = $value;
 439                         last;
 440                 }
 441
 442                 # unknown
 443                 shift @x;
 444         }
 445 }
 446
 447 sub prettyprint_pv_no_cache {
 448         my ($board, @pvs) = @_;
 449
 450         if (scalar @pvs == 0 || !defined($pvs[0])) {
 451                 return ();
 452         }
 453
 454         my $pv = shift @pvs;
 455         my ($from_col, $from_row, $to_col, $to_row, $promo) = parse_uci_move($pv);
 456         my ($pretty, $nb) = $board->prettyprint_move($from_row, $from_col, $to_row, $to_col, $promo);
 457         return ( $pretty, prettyprint_pv_no_cache($nb, @pvs) );
 458 }
 459
 460 sub prettyprint_pv {
 461         my ($pos, @pvs) = @_;
 462
 463         my $cachekey = join('', @pvs);
 464         if (exists($pos->{'prettyprint_cache'}{$cachekey})) {
 465                 return @{$pos->{'prettyprint_cache'}{$cachekey}};
 466         } else {
 467                 my @res = prettyprint_pv_no_cache($pos->{'board'}, @pvs);
 468                 $pos->{'prettyprint_cache'}{$cachekey} = \@res;
 469                 return @res;
 470         }
 471 }
 472
 473 sub output {
 474         #return;
 475
 476         return if (!defined($pos_calculating));
 477
 478         # Don't update too often.
 479         my $age = Time::HiRes::tv_interval($latest_update);
 480         if ($age < $remoteglotconf::update_max_interval) {
 481                 Time::HiRes::alarm($remoteglotconf::update_max_interval + 0.01 - $age);
 482                 return;
 483         }
 484
 485         my $info = $engine->{'info'};
 486
 487         #
 488         # If we have tablebase data from a previous lookup, replace the
 489         # engine data with the data from the tablebase.
 490         #
 491         my $fen = $pos_calculating->fen();
 492         if (exists($tb_cache{$fen})) {
 493                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
 494                         delete $info->{$key . '1'};
 495                         delete $info->{$key};
 496                 }
 497                 $info->{'nodes'} = 0;
 498                 $info->{'nps'} = 0;
 499                 $info->{'depth'} = 0;
 500                 $info->{'seldepth'} = 0;
 501                 $info->{'tbhits'} = 0;
 502
 503                 my $t = $tb_cache{$fen};
 504                 my $pv = $t->{'pv'};
 505                 my $matelen = int((1 + scalar @$pv) / 2);
 506                 if ($t->{'result'} eq '1/2-1/2') {
 507                         $info->{'score_cp'} = 0;
 508                 } elsif ($t->{'result'} eq '1-0') {
 509                         if ($pos_calculating->{'toplay'} eq 'B') {
 510                                 $info->{'score_mate'} = -$matelen;
 511                         } else {
 512                                 $info->{'score_mate'} = $matelen;
 513                         }
 514                 } else {
 515                         if ($pos_calculating->{'toplay'} eq 'B') {
 516                                 $info->{'score_mate'} = $matelen;
 517                         } else {
 518                                 $info->{'score_mate'} = -$matelen;
 519                         }
 520                 }
 521                 $info->{'pv'} = $pv;
 522                 $info->{'tablebase'} = 1;
 523         } else {
 524                 $info->{'tablebase'} = 0;
 525         }
 526
 527         #
 528         # Some programs _always_ report MultiPV, even with only one PV.
 529         # In this case, we simply use that data as if MultiPV was never
 530         # specified.
 531         #
 532         if (exists($info->{'pv1'}) && !exists($info->{'pv2'})) {
 533                 for my $key (qw(pv score_cp score_mate nodes nps depth seldepth tbhits)) {
 534                         if (exists($info->{$key . '1'})) {
 535                                 $info->{$key} = $info->{$key . '1'};
 536                         }
 537                 }
 538         }
 539
 540         #
 541         # Check the PVs first. if they're invalid, just wait, as our data
 542         # is most likely out of sync. This isn't a very good solution, as
 543         # it can frequently miss stuff, but it's good enough for most users.
 544         #
 545         eval {
 546                 my $dummy;
 547                 if (exists($info->{'pv'})) {
 548                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv'}});
 549                 }
 550
 551                 my $mpv = 1;
 552                 while (exists($info->{'pv' . $mpv})) {
 553                         $dummy = prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}});
 554                         ++$mpv;
 555                 }
 556         };
 557         if ($@) {
 558                 $engine->{'info'} = {};
 559                 return;
 560         }
 561
 562         output_screen();
 563         output_json();
 564         $latest_update = [Time::HiRes::gettimeofday];
 565 }
 566
 567 sub output_screen {
 568         my $info = $engine->{'info'};
 569         my $id = $engine->{'id'};
 570
 571         my $text = 'Analysis';
 572         if ($pos_calculating->{'last_move'} ne 'none') {
 573                 if ($pos_calculating->{'toplay'} eq 'W') {
 574                         $text .= sprintf ' after %u. ... %s', ($pos_calculating->{'move_num'}-1), $pos_calculating->{'last_move'};
 575                 } else {
 576                         $text .= sprintf ' after %u. %s', $pos_calculating->{'move_num'}, $pos_calculating->{'last_move'};
 577                 }
 578                 if (exists($id->{'name'})) {
 579                         $text .= ',';
 580                 }
 581         }
 582
 583         if (exists($id->{'name'})) {
 584                 $text .= " by $id->{'name'}:\n\n";
 585         } else {
 586                 $text .= ":\n\n";
 587         }
 588
 589         return unless (exists($pos_calculating->{'board'}));
 590
 591         if (exists($info->{'pv1'}) && exists($info->{'pv2'})) {
 592                 # multi-PV
 593                 my $mpv = 1;
 594                 while (exists($info->{'pv' . $mpv})) {
 595                         $text .= sprintf "  PV%2u", $mpv;
 596                         my $score = short_score($info, $pos_calculating, $mpv);
 597                         $text .= "  ($score)" if (defined($score));
 598
 599                         my $tbhits = '';
 600                         if (exists($info->{'tbhits' . $mpv}) && $info->{'tbhits' . $mpv} > 0) {
 601                                 if ($info->{'tbhits' . $mpv} == 1) {
 602                                         $tbhits = ", 1 tbhit";
 603                                 } else {
 604                                         $tbhits = sprintf ", %u tbhits", $info->{'tbhits' . $mpv};
 605                                 }
 606                         }
 607
 608                         if (exists($info->{'nodes' . $mpv}) && exists($info->{'nps' . $mpv}) && exists($info->{'depth' . $mpv})) {
 609                                 $text .= sprintf " (%5u kn, %3u kn/s, %2u ply$tbhits)",
 610                                         $info->{'nodes' . $mpv} / 1000, $info->{'nps' . $mpv} / 1000, $info->{'depth' . $mpv};
 611                         }
 612
 613                         $text .= ":\n";
 614                         $text .= "  " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv' . $mpv}})) . "\n";
 615                         $text .= "\n";
 616                         ++$mpv;
 617                 }
 618         } else {
 619                 # single-PV
 620                 my $score = long_score($info, $pos_calculating, '');
 621                 $text .= "  $score\n" if defined($score);
 622                 $text .=  "  PV: " . join(', ', prettyprint_pv($pos_calculating, @{$info->{'pv'}}));
 623                 $text .=  "\n";
 624
 625                 if (exists($info->{'nodes'}) && exists($info->{'nps'}) && exists($info->{'depth'})) {
 626                         $text .= sprintf "  %u nodes, %7u nodes/sec, depth %u ply",
 627                                 $info->{'nodes'}, $info->{'nps'}, $info->{'depth'};
 628                 }
 629                 if (exists($info->{'seldepth'})) {
 630                         $text .= sprintf " (%u selective)", $info->{'seldepth'};
 631                 }
 632                 if (exists($info->{'tbhits'}) && $info->{'tbhits'} > 0) {
 633                         if ($info->{'tbhits'} == 1) {
 634                                 $text .= ", one Syzygy hit";
 635                         } else {
 636                                 $text .= sprintf ", %u Syzygy hits", $info->{'tbhits'};
 637                         }
 638                 }
 639                 $text .= "\n\n";
 640         }
 641
 642         #$text .= book_info($pos_calculating->fen(), $pos_calculating->{'board'}, $pos_calculating->{'toplay'});
 643
 644         my @refutation_lines = ();
 645         if (defined($engine2)) {
 646                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
 647                         my $info = $engine2->{'info'};
 648                         last if (!exists($info->{'pv' . $mpv}));
 649                         eval {
 650                                 my $pv = $info->{'pv' . $mpv};
 651
 652                                 my $pretty_move = join('', prettyprint_pv($pos_calculating_second_engine, $pv->[0]));
 653                                 my @pretty_pv = prettyprint_pv($pos_calculating_second_engine, @$pv);
 654                                 if (scalar @pretty_pv > 5) {
 655                                         @pretty_pv = @pretty_pv[0..4];
 656                                         push @pretty_pv, "...";
 657                                 }
 658                                 my $key = $pretty_move;
 659                                 my $line = sprintf("  %-6s %6s %3s  %s",
 660                                         $pretty_move,
 661                                         short_score($info, $pos_calculating_second_engine, $mpv),
 662                                         "d" . $info->{'depth' . $mpv},
 663                                         join(', ', @pretty_pv));
 664                                 push @refutation_lines, [ $key, $line ];
 665                         };
 666                 }
 667         }
 668
 669         if ($#refutation_lines >= 0) {
 670                 $text .= "Shallow search of all legal moves:\n\n";
 671                 for my $line (sort { $a->[0] cmp $b->[0] } @refutation_lines) {
 672                         $text .= $line->[1] . "\n";
 673                 }
 674                 $text .= "\n\n";
 675         }
 676
 677         if ($last_text ne $text) {
 678                 print "\e[H\e[2J"; # clear the screen
 679                 print $text;
 680                 $last_text = $text;
 681         }
 682 }
 683
 684 sub output_json {
 685         my $info = $engine->{'info'};
 686
 687         my $json = {};
 688         $json->{'position'} = $pos_calculating->to_json_hash();
 689         $json->{'id'} = $engine->{'id'};
 690         $json->{'score'} = long_score($info, $pos_calculating, '');
 691         $json->{'short_score'} = short_score($info, $pos_calculating, '');
 692
 693         $json->{'nodes'} = $info->{'nodes'};
 694         $json->{'nps'} = $info->{'nps'};
 695         $json->{'depth'} = $info->{'depth'};
 696         $json->{'tbhits'} = $info->{'tbhits'};
 697         $json->{'seldepth'} = $info->{'seldepth'};
 698         $json->{'tablebase'} = $info->{'tablebase'};
 699
 700         # single-PV only for now
 701         $json->{'pv_uci'} = $info->{'pv'};
 702         $json->{'pv_pretty'} = [ prettyprint_pv($pos_calculating, @{$info->{'pv'}}) ];
 703
 704         my %refutation_lines = ();
 705         my @refutation_lines = ();
 706         if (defined($engine2)) {
 707                 for (my $mpv = 1; $mpv < 500; ++$mpv) {
 708                         my $info = $engine2->{'info'};
 709                         my $pretty_move = "";
 710                         my @pretty_pv = ();
 711                         last if (!exists($info->{'pv' . $mpv}));
 712
 713                         eval {
 714                                 my $pv = $info->{'pv' . $mpv};
 715                                 my $pretty_move = join('', prettyprint_pv($pos_calculating, $pv->[0]));
 716                                 my @pretty_pv = prettyprint_pv($pos_calculating, @$pv);
 717                                 $refutation_lines{$pv->[0]} = {
 718                                         sort_key => $pretty_move,
 719                                         depth => $info->{'depth' . $mpv},
 720                                         score_sort_key => score_sort_key($info, $pos_calculating, $mpv, 0),
 721                                         pretty_score => short_score($info, $pos_calculating, $mpv),
 722                                         pretty_move => $pretty_move,
 723                                         pv_pretty => \@pretty_pv,
 724                                 };
 725                                 $refutation_lines{$pv->[0]}->{'pv_uci'} = $pv;
 726                         };
 727                 }
 728         }
 729         $json->{'refutation_lines'} = \%refutation_lines;
 730
 731         open my $fh, ">", $remoteglotconf::json_output . ".tmp"
 732                 or return;
 733         print $fh JSON::XS::encode_json($json);
 734         close $fh;
 735         rename($remoteglotconf::json_output . ".tmp", $remoteglotconf::json_output);
 736 }
 737
 738 sub uciprint {
 739         my ($engine, $msg) = @_;
 740         $engine->print($msg);
 741         print UCILOG localtime() . " $engine->{'tag'} => $msg\n";
 742 }
 743
 744 sub short_score {
 745         my ($info, $pos, $mpv) = @_;
 746
 747         my $invert = ($pos->{'toplay'} eq 'B');
 748         if (defined($info->{'score_mate' . $mpv})) {
 749                 if ($invert) {
 750                         return sprintf "M%3d", -$info->{'score_mate' . $mpv};
 751                 } else {
 752                         return sprintf "M%3d", $info->{'score_mate' . $mpv};
 753                 }
 754         } else {
 755                 if (exists($info->{'score_cp' . $mpv})) {
 756                         my $score = $info->{'score_cp' . $mpv} * 0.01;
 757                         if ($score == 0) {
 758                                 if ($info->{'tablebase'}) {
 759                                         return "TB draw";
 760                                 } else {
 761                                         return " 0.00";
 762                                 }
 763                         }
 764                         if ($invert) {
 765                                 $score = -$score;
 766                         }
 767                         return sprintf "%+5.2f", $score;
 768                 }
 769         }
 770
 771         return undef;
 772 }
 773
 774 sub score_sort_key {
 775         my ($info, $pos, $mpv, $invert) = @_;
 776
 777         if (defined($info->{'score_mate' . $mpv})) {
 778                 my $mate = $info->{'score_mate' . $mpv};
 779                 my $score;
 780                 if ($mate > 0) {
 781                         # Side to move mates
 782                         $score = 99999 - $mate;
 783                 } else {
 784                         # Side to move is getting mated (note the double negative for $mate)
 785                         $score = -99999 - $mate;
 786                 }
 787                 if ($invert) {
 788                         $score = -$score;
 789                 }
 790                 return $score;
 791         } else {
 792                 if (exists($info->{'score_cp' . $mpv})) {
 793                         my $score = $info->{'score_cp' . $mpv};
 794                         if ($invert) {
 795                                 $score = -$score;
 796                         }
 797                         return $score;
 798                 }
 799         }
 800
 801         return undef;
 802 }
 803
 804 sub long_score {
 805         my ($info, $pos, $mpv) = @_;
 806
 807         if (defined($info->{'score_mate' . $mpv})) {
 808                 my $mate = $info->{'score_mate' . $mpv};
 809                 if ($pos->{'toplay'} eq 'B') {
 810                         $mate = -$mate;
 811                 }
 812                 if ($mate > 0) {
 813                         return sprintf "White mates in %u", $mate;
 814                 } else {
 815                         return sprintf "Black mates in %u", -$mate;
 816                 }
 817         } else {
 818                 if (exists($info->{'score_cp' . $mpv})) {
 819                         my $score = $info->{'score_cp' . $mpv} * 0.01;
 820                         if ($score == 0) {
 821                                 if ($info->{'tablebase'}) {
 822                                         return "Theoretical draw";
 823                                 } else {
 824                                         return "Score:  0.00";
 825                                 }
 826                         }
 827                         if ($pos->{'toplay'} eq 'B') {
 828                                 $score = -$score;
 829                         }
 830                         return sprintf "Score: %+5.2f", $score;
 831                 }
 832         }
 833
 834         return undef;
 835 }
 836
 837 my %book_cache = ();
 838 sub book_info {
 839         my ($fen, $board, $toplay) = @_;
 840
 841         if (exists($book_cache{$fen})) {
 842                 return $book_cache{$fen};
 843         }
 844
 845         my $ret = `./booklook $fen`;
 846         return "" if ($ret =~ /Not found/ || $ret eq '');
 847
 848         my @moves = ();
 849
 850         for my $m (split /\n/, $ret) {
 851                 my ($move, $annotation, $win, $draw, $lose, $rating, $rating_div) = split /,/, $m;
 852
 853                 my $pmove;
 854                 if ($move eq '')  {
 855                         $pmove = '(current)';
 856                 } else {
 857                         ($pmove) = prettyprint_pv_no_cache($board, $move);
 858                         $pmove .= $annotation;
 859                 }
 860
 861                 my $score;
 862                 if ($toplay eq 'W') {
 863                         $score = 1.0 * $win + 0.5 * $draw + 0.0 * $lose;
 864                 } else {
 865                         $score = 0.0 * $win + 0.5 * $draw + 1.0 * $lose;
 866                 }
 867                 my $n = $win + $draw + $lose;
 868
 869                 my $percent;
 870                 if ($n == 0) {
 871                         $percent = "     ";
 872                 } else {
 873                         $percent = sprintf "%4u%%", int(100.0 * $score / $n + 0.5);
 874                 }
 875
 876                 push @moves, [ $pmove, $n, $percent, $rating ];
 877         }
 878
 879         @moves[1..$#moves] = sort { $b->[2] cmp $a->[2] } @moves[1..$#moves];
 880
 881         my $text = "Book moves:\n\n              Perf.     N     Rating\n\n";
 882         for my $m (@moves) {
 883                 $text .= sprintf "  %-10s %s   %6u    %4s\n", $m->[0], $m->[2], $m->[1], $m->[3]
 884         }
 885
 886         return $text;
 887 }
 888
 889 sub schedule_tb_lookup {
 890         return if (!defined($remoteglotconf::tb_serial_key));
 891         my $pos = $pos_waiting // $pos_calculating;
 892         return if (exists($tb_cache{$pos->fen()}));
 893
 894         # If there's more than seven pieces, there's not going to be an answer,
 895         # so don't bother.
 896         return if ($pos->num_pieces() > 7);
 897
 898         # Max one at a time. If it's still relevant when it returns,
 899         # schedule_tb_lookup() will be called again.
 900         return if ($tb_lookup_running);
 901
 902         $tb_lookup_running = 1;
 903         my $url = 'http://158.250.18.203:6904/tasks/addtask?auth.login=' .
 904                 $remoteglotconf::tb_serial_key .
 905                 '&auth.password=aquarium&type=0&fen=' .
 906                 URI::Escape::uri_escape($pos->fen());
 907         print TBLOG "Downloading $url...\n";
 908         AnyEvent::HTTP::http_get($url, sub {
 909                 handle_tb_lookup_return(@_, $pos, $pos->fen());
 910         });
 911 }
 912
 913 sub handle_tb_lookup_return {
 914         my ($body, $header, $pos, $fen) = @_;
 915         print TBLOG "Response for [$fen]:\n";
 916         print TBLOG $header . "\n\n";
 917         print TBLOG $body . "\n\n";
 918         eval {
 919                 my $response = JSON::XS::decode_json($body);
 920                 if ($response->{'ErrorCode'} != 0) {
 921                         die "Unknown tablebase server error: " . $response->{'ErrorDesc'};
 922                 }
 923                 my $state = $response->{'Response'}{'StateString'};
 924                 if ($state eq 'COMPLETE') {
 925                         my $pgn = Chess::PGN::Parse->new(undef, $response->{'Response'}{'Moves'});
 926                         if (!defined($pgn) || !$pgn->read_game()) {
 927                                 warn "Error in parsing PGN\n";
 928                         } else {
 929                                 $pgn->quick_parse_game;
 930                                 my $pvpos = $pos;
 931                                 my $moves = $pgn->moves;
 932                                 my @uci_moves = ();
 933                                 for my $move (@$moves) {
 934                                         my $uci_move;
 935                                         ($pvpos, $uci_move) = $pvpos->make_pretty_move($move);
 936                                         push @uci_moves, $uci_move;
 937                                 }
 938                                 $tb_cache{$fen} = {
 939                                         result => $pgn->result,
 940                                         pv => \@uci_moves
 941                                 };
 942                                 output();
 943                         }
 944                 } elsif ($state =~ /QUEUED/ || $state =~ /PROCESSING/) {
 945                         # Try again in a second. Note that if we have changed
 946                         # position in the meantime, we might query a completely
 947                         # different position! But that's fine.
 948                 } else {
 949                         die "Unknown response state " . $state;
 950                 }
 951
 952                 # Wait a second before we schedule another one.
 953                 $tb_retry_timer = AnyEvent->timer(after => 1.0, cb => sub {
 954                         $tb_lookup_running = 0;
 955                         schedule_tb_lookup();
 956                 });
 957         };
 958         if ($@) {
 959                 warn "Error in tablebase lookup: $@";
 960
 961                 # Don't try this one again, but don't block new lookups either.
 962                 $tb_lookup_running = 0;
 963         }
 964 }
 965
 966 sub open_engine {
 967         my ($cmdline, $tag, $cb) = @_;
 968         return undef if (!defined($cmdline));
 969         return Engine->open($cmdline, $tag, $cb);
 970 }
 971
 972 sub col_letter_to_num {
 973         return ord(shift) - ord('a');
 974 }
 975
 976 sub row_letter_to_num {
 977         return 7 - (ord(shift) - ord('1'));
 978 }
 979
 980 sub parse_uci_move {
 981         my $move = shift;
 982         my $from_col = col_letter_to_num(substr($move, 0, 1));
 983         my $from_row = row_letter_to_num(substr($move, 1, 1));
 984         my $to_col   = col_letter_to_num(substr($move, 2, 1));
 985         my $to_row   = row_letter_to_num(substr($move, 3, 1));
 986         my $promo    = substr($move, 4, 1);
 987         return ($from_col, $from_row, $to_col, $to_row, $promo);
 988 }