use strict;
use warnings;
use DBI;

package foosball;

sub db_connect {
	my $dbh = DBI->connect("dbi:Pg:dbname=foosball;host=127.0.0.1", "foosball", "cleanrun", {AutoCommit => 0});
	$dbh->{RaiseError} = 1;
	return $dbh;
}

sub find_single_rating {
	my ($dbh, $username, $limit) = @_;
	my ($age, $rating, $rd) = $dbh->selectrow_array('SELECT EXTRACT(EPOCH FROM (CURRENT_TIMESTAMP-ratetime)), rating, rd FROM single_rating WHERE username=? '.$limit.' ORDER BY ratetime DESC LIMIT 1',
		undef, $username);
	$rd = apply_aging($rd, $age / 86400.0);
	return ($rating, $rd);
}

sub find_double_rating {
	my ($dbh, $username, $limit) = @_;
	my ($age, $rating, $rd) = $dbh->selectrow_array('SELECT EXTRACT(EPOCH FROM (CURRENT_TIMESTAMP-ratetime)), rating, rd FROM double_rating WHERE username=? '.$limit.'ORDER BY ratetime DESC LIMIT 1',
		undef, $username);
	$rd = apply_aging($rd, $age / 86400.0);
	return ($rating, $rd);
}

sub create_user_if_not_exists {
	my ($dbh, $username) = @_;
	my $count = $dbh->selectrow_array('SELECT count(*) FROM users WHERE username=?',
		undef, $username);
	return if ($count > 0);
	$dbh->do('INSERT INTO users (username) VALUES (?)',
		undef, $username);
	$dbh->do('INSERT INTO single_rating (username,ratetime,rating,rd) VALUES (?,CURRENT_TIMESTAMP,1500.0,350.0)',
		undef, $username);
	$dbh->do('INSERT INTO double_rating (username,ratetime,rating,rd) VALUES (?,CURRENT_TIMESTAMP,1500.0,350.0)',
		undef, $username);
	return $dbh;
}

# 10-9 is 0.60
# 10-0 is 1.00
sub find_score {
	my ($score1, $score2) = @_;
	if ($score1 == 10) {
		# yay, a win
		return 0.60 + 0.40 * (9.0-$score2)/9.0;
	}
	if ($score2 == 10) {
		# a loss
		return 0.40 - 0.40 * (9.0-$score1)/9.0;
	}
	die "Nobody won?";
}

# c=8 => RD=50 moves to RD=350 over approx. five years
our $c = 8;

sub apply_aging {
	my ($rd, $age) = @_;
	$rd = sqrt($rd*$rd + $c * $c * ($age / 86400.0));
	$rd = 350.0 if ($rd > 350.0);
	return $rd;
}

our $q = log(10)/400.0;
our $pi = 3.1415926535897932384626433832795;

# computes a^b
sub pow {
	my ($a, $b) = @_;

	# a^b = exp(log(a^b)) = exp(b log a)
	return exp($b * log($a));
}

sub g {
	my $rd = shift;
	return 1.0 / sqrt(1.0 + 3.0 * $q * $q * $rd * $rd / ($pi*$pi));
}

sub E {
	my ($r, $rating, $rd) = @_;
	return 1.0 / (1.0 + pow(10.0, - g($rd) * ($r - $rating) / 400.0));
}

sub dsq {
	my ($r, $rating, $rd) = @_;
	return 1.0 / ($q*$q * g($rd) * g($rd) * E($r, $rating, $rd) * (1 - E($r, $rating, $rd)));
}

sub calc_rating {
	my ($rating1, $rd1, $rating2, $rd2, $score1, $score2) = @_;
	my $s1 = find_score($score1, $score2);
	my $d1sq = dsq($rating1, $rating2, $rd2);
	my $newr1 = $rating1 + ($q / (1.0/($rd1*$rd1) + 1.0 / $d1sq)) * g($rd2) * ($s1 - E($rating1, $rating2, $rd2));
	my $newrd1 = sqrt(1.0 / (1.0 / ($rd1*$rd1) + 1.0 / $d1sq));

	$newrd1 = 30.0 if ($newrd1 < 30.0);

	return ($newr1, $newrd1);
}

1;
