#! /usr/bin/perl

use ccbs;
use strict;
use warnings;

my $cgi = new CGI;
my $id = $cgi->param('id');

my $dbh = ccbs::db_connect();

my $tournament = $dbh->selectrow_hashref('SELECT * FROM tournaments NATURAL JOIN seasons NATURAL JOIN countries NATURAL JOIN machines NATURAL JOIN scoringsystems WHERE tournament=?', undef, $id);
my $rankings = ccbs::db_fetch_all($dbh, 'SELECT ranking,nick,COALESCE(points,-1) AS points FROM tournamentrankings NATURAL JOIN players WHERE tournament=? ORDER BY ranking', $id);

# Swoop all the data in in a big join, then order it over to quasi-sane Perl objects.
# (round -> parallel -> player -> songs -> title,chosen,score)
my $scores = ccbs::db_fetch_all($dbh,
	'SELECT round,parallel,position,nick,title,chosen,score FROM scores NATURAL JOIN players NATURAL JOIN songs NATURAL JOIN roundparticipation WHERE tournament=? ORDER BY round,parallel,position,songnumber',
	$id);

my @rounds = ();

my ($round, $parallel, $player) = (-1,-1,'');
for my $score (@$scores) {
	if ($score->{'round'} != $round) {
		$round = $score->{'round'};
		push @rounds, { round => $round, parallels => [] };
		$parallel = -1;
	}
	my $p = $rounds[$#rounds]->{'parallels'};
	if ($score->{'parallel'} != $parallel) {
		$parallel = $score->{'parallel'};
		push @$p, { parallel => $parallel, players => [], songs => [], num_songs => 0 };
		$player = '';

		# Information on songs is not selected from roundrandomsongs etc.,
		# but is filled in the first time the song is seen for this round
		# (ie. below)
	}
	if ($score->{'position'} == 1) {
		if ($score->{'chosen'}) {
			push @{$p->[$#$p]->{'songs'}}, '';
		} else {
			push @{$p->[$#$p]->{'songs'}}, $score->{'title'};
		}
		$p->[$#$p]->{'num_songs'}++;
	}
	
	my $pl = $p->[$#$p]->{'players'};
	if ($score->{'nick'} ne $player) {
		$player = $score->{'nick'};
		push @$pl, { nick => $player, songs => [], total => 0 };

	}
	
	push @{$pl->[$#$pl]->{'songs'}}, {
		title => $score->{'title'},
		chosen => $score->{'chosen'},
		score => $score->{'score'}
	};
	$pl->[$#$pl]->{'total'} += $score->{'score'};
}

ccbs::print_header();
ccbs::process_template('show-tournament.tmpl', $tournament->{'tournamentname'}, {
	tournament => $tournament,
	rankings => $rankings,
	rounds => \@rounds
});
$dbh->disconnect;
