#! /usr/bin/perl
use strict;
use warnings;
use Date::Manip;

# Parses tournament results from the DDR Europe result list

my $season = shift;
my ($name, $round, @rsongs);
die "Missing season (give on command line)." if (!defined($season));

print "begin;\n";

while (<>) {
	if (/<h2> \s* (.*?) \s* <\/h2>/x) {
		$name = $1;
		next;
	}
	if (/<br>Country: \s* (.*?) \s*
             <br>Location: \s* (.*?) \s*
             <br>Date: \s* (.*?) \s*
             <br>Mix: \s* (.*?) \s*
             <br>ScoringSystem: \s* (.*?) \s* <br>
            /x) {
		my ($country, $location, $date, $mix, $system) = ($1, $2, $3, $4, $5);
		$mix =~ s/Euromix/EuroMix/;

		print "INSERT INTO tournaments \n";
		print "  (season, name, country, location, \"date\", machine, scoringsystem) VALUES (\n";
		print "    (SELECT season FROM seasons WHERE name='$season'),\n";
		print "    '$name',\n";
		print "    (SELECT country FROM countries WHERE name='$country'),\n";
		print "    '$location',\n";
		printf "    '%s',\n", Date::Manip::UnixDate($date, '%Y-%m-%d');
		print "    (SELECT machine FROM machines WHERE name='$mix'),\n";
		print "    (SELECT scoringsystem FROM scoringsystems WHERE name='$system')\n";
		print ");\n";
	}

	# New round
	if (/<h3 \s* class=dthr> Round \s* (\d+) \s* <\/h3>/x) {
		$round = $1;

		print "INSERT INTO rounds (tournament, round, randomsongs, chosensongs) \n";
		print "  VALUES (\n";
		print "   (SELECT tournament FROM tournaments WHERE name='$name'),\n";
		print "   $round,\n";
		print "   0, 0);\n";  # Don't worry, we'll fix it later :-P
	}
	
	# New group, and the random songs for it
	if (/<th \s* class=dthp> ( Players | Group (\d+) )<\/th>/x) {
		# bit of an evil hack here
		my $group = $2;
		$group = 0 if ($1 eq 'Players');

		print "INSERT INTO groups (tournament, round, parallel) VALUES (\n";
		print "   (SELECT tournament FROM tournaments WHERE name='$name'),\n";
		print "   $round, $group);\n";

		# Find the random songs, if any
		@rsongs = ();

		while (s/<th \s* class=dthpsong> .*? "color:white"> (.*?) <\/a><\/th>//x) {
			push @rsongs, $1;

			print "INSERT INTO roundrandomsongs (tournament, round, parallel, song) VALUES (\n";
			print "   (SELECT tournament FROM tournaments WHERE name='$name'),\n";
			print "   $round, $group,\n";
			print "   (SELECT song FROM songs WHERE title='$1')\n";
			print ");\n";
		}

		# Correct the random songs in the table
		printf "UPDATE rounds SET randomsongs=%u WHERE \n", scalar @rsongs;
		print "  tournament=(SELECT tournament FROM tournaments WHERE name='$name') AND \n";
		print "  round=$round;\n";
	}

	# Header for chosen song
	if (/<th \s* class=dthp \s* colspan=2>&nbsp<\/th>/x) {
		printf "UPDATE rounds SET chosensongs=chosensongs+1 WHERE \n";
		print "  tournament=(SELECT tournament FROM tournaments WHERE name='$name') AND \n";
		print "  round=$round;\n";
	}
}

printf "commit;\n";
