#! /usr/bin/perl
use strict;
use warnings;
use CGI;
use JSON::XS;
use lib '..';
use Position;

our %openings = ();
read_openings();

my $cgi = CGI->new;
my $fen = $cgi->param('fen');
my $pos = Position->from_fen($fen);
my $hex = unpack('H*', $pos->bitpacked_fen);
open my $fh, "-|", "../binlookup", "../open.mtbl", $hex
	or die "../binlookup: $!";

my $opening;

my @moves = ();
while (<$fh>) {
	chomp;
	my ($move, $white, $draw, $black, $opening_num, $white_avg_elo, $black_avg_elo, $num_elo) = split;
	push @moves, {
		move => $move,
		white => $white * 1,
		draw => $draw * 1,
		black => $black * 1,
		white_avg_elo => $white_avg_elo * 1,
		black_avg_elo => $black_avg_elo * 1,
		num_elo => $num_elo * 1
	};
	$opening = $openings{$opening_num} // 'A00: Start position';
}
close $fh;

@moves = sort { num($b) <=> num($a) } @moves;

print $cgi->header(-type=>'application/json');
print JSON::XS::encode_json({ moves => \@moves, opening => $opening });

sub num {
	my $x = shift;
	return $x->{'white'} + $x->{'draw'} + $x->{'black'};
}

sub read_openings {
	open my $fh, "../openings.txt"
		or die "../openings.txt: $!";
	for my $line (<$fh>) {
		chomp $line;
		my ($hash, $eco, $opening, $variation, $subvariation) = split /\t/, $line;
		if ($variation eq '') {
			$openings{$hash} = $eco . ": " . $opening;
		} else {
			$openings{$hash} = $eco . ": " . $opening . ": " . $variation;
		}
	}
	close $fh;
}
