git.sesse.net Git - casparcg/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2 project ("CasparCG Server")
   3
   4 find_package(Git)
   5
   6 set(GIT_REV "N/A")
   7
   8 if (GIT_FOUND)
   9         exec_program("${GIT_EXECUTABLE}" "${PROJECT_SOURCE_DIR}"
  10                         ARGS rev-parse --verify --short HEAD
  11                         OUTPUT_VARIABLE GIT_REV)
  12 endif ()
  13
  14 configure_file("${PROJECT_SOURCE_DIR}/version.tmpl" "${PROJECT_SOURCE_DIR}/version.h")
  15
  16 set(DEPENDENCIES_FOLDER                 "${PROJECT_SOURCE_DIR}/dependencies64")
  17
  18 set(BOOST_INCLUDE_PATH                  "${DEPENDENCIES_FOLDER}/boost")
  19 set(RXCPP_INCLUDE_PATH                  "${DEPENDENCIES_FOLDER}/RxCpp/include")
  20 set(TBB_INCLUDE_PATH                    "${DEPENDENCIES_FOLDER}/tbb/include")
  21 set(GLEW_INCLUDE_PATH                   "${DEPENDENCIES_FOLDER}/glew/include")
  22 set(SFML_INCLUDE_PATH                   "${DEPENDENCIES_FOLDER}/sfml/include")
  23 set(FREETYPE_INCLUDE_PATH               "${DEPENDENCIES_FOLDER}/freetype/include")
  24
  25 if (MSVC)
  26         set(FFMPEG_INCLUDE_PATH         "${DEPENDENCIES_FOLDER}/ffmpeg/include" "${DEPENDENCIES_FOLDER}/ffmpeg/include-win32")
  27 else ()
  28         set(FFMPEG_INCLUDE_PATH         "${DEPENDENCIES_FOLDER}/ffmpeg/include")
  29 endif ()
  30
  31 set(ASMLIB_INCLUDE_PATH                 "${DEPENDENCIES_FOLDER}/asmlib")
  32 set(FREEIMAGE_INCLUDE_PATH              "${DEPENDENCIES_FOLDER}/freeimage/include")
  33 set(OPENAL_INCLUDE_PATH                 "${DEPENDENCIES_FOLDER}/openal/include")
  34 set(BLUEFISH_INCLUDE_PATH               "${DEPENDENCIES_FOLDER}/bluefish/include")
  35
  36 if (MSVC)
  37         set(PLATFORM_FOLDER_NAME        "win32")
  38 elseif (CMAKE_COMPILER_IS_GNUCXX)
  39         set(PLATFORM_FOLDER_NAME        "linux")
  40 endif ()
  41
  42 set(FFMPEG_BIN_PATH                             "${DEPENDENCIES_FOLDER}/ffmpeg/bin/${PLATFORM_FOLDER_NAME}")
  43 set(FREEIMAGE_BIN_PATH                  "${DEPENDENCIES_FOLDER}/freeimage/bin/${PLATFORM_FOLDER_NAME}")
  44 set(GLEW_BIN_PATH                               "${DEPENDENCIES_FOLDER}/glew/bin")
  45 set(OPENAL_BIN_PATH                             "${DEPENDENCIES_FOLDER}/openal/bin")
  46 set(TBB_BIN_PATH                                "${DEPENDENCIES_FOLDER}/tbb/bin/${PLATFORM_FOLDER_NAME}")
  47 set(LIBERATION_FONTS_BIN_PATH   "${DEPENDENCIES_FOLDER}/liberation-fonts")
  48
  49 link_directories("${DEPENDENCIES_FOLDER}/boost/stage/lib/${PLATFORM_FOLDER_NAME}")
  50 link_directories("${DEPENDENCIES_FOLDER}/tbb/lib/${PLATFORM_FOLDER_NAME}")
  51 link_directories("${DEPENDENCIES_FOLDER}/glew/lib")
  52 link_directories("${DEPENDENCIES_FOLDER}/sfml/lib/${PLATFORM_FOLDER_NAME}")
  53 link_directories("${DEPENDENCIES_FOLDER}/sfml/extlibs/lib")
  54 link_directories("${DEPENDENCIES_FOLDER}/freetype/objs/win32/vc2010")
  55 link_directories("${DEPENDENCIES_FOLDER}/ffmpeg/lib/${PLATFORM_FOLDER_NAME}")
  56 link_directories("${DEPENDENCIES_FOLDER}/asmlib")
  57 link_directories("${DEPENDENCIES_FOLDER}/freeimage/lib/${PLATFORM_FOLDER_NAME}")
  58 link_directories("${DEPENDENCIES_FOLDER}/openal/lib")
  59 link_directories("${DEPENDENCIES_FOLDER}/bluefish/lib")
  60 link_directories("${DEPENDENCIES_FOLDER}/zlib/lib")
  61
  62 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  63
  64 add_definitions( -DSFML_STATIC )
  65 add_definitions( -DBOOST_THREAD_VERSION=4 )
  66 add_definitions( -DTBB_USE_CAPTURED_EXCEPTION=0 )
  67 add_definitions( -DUNICODE )
  68 add_definitions( -D_UNICODE )
  69
  70 if (MSVC)
  71         set(CMAKE_CXX_FLAGS                     "${CMAKE_CXX_FLAGS}                     /EHa /Zi /W4 /WX /MP /fp:fast /FIcommon/compiler/vs/disable_silly_warnings.h")
  72         set(CMAKE_CXX_FLAGS_DEBUG       "${CMAKE_CXX_FLAGS_DEBUG}       /D TBB_USE_ASSERT=1 /D TBB_USE_DEBUG /bigobj")
  73         set(CMAKE_CXX_FLAGS_RELEASE     "${CMAKE_CXX_FLAGS_RELEASE}     /Oi /Ot /Gy")
  74 elseif (CMAKE_COMPILER_IS_GNUCXX)
  75         set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O3 -g")
  76         add_compile_options( -std=c++11 )
  77         add_compile_options( -msse3 )
  78         add_compile_options( -mssse3 )
  79         add_compile_options( -msse4.1 )
  80         add_compile_options( -pthread )
  81         add_compile_options( -fnon-call-exceptions ) # Allow signal handler to throw exception
  82 endif ()
  83
  84 if (POLICY CMP0045)
  85         cmake_policy(SET CMP0045 OLD)
  86 endif ()
  87
  88 include(CMake/PrecompiledHeader.cmake)
  89
  90 set(CASPARCG_MODULE_INCLUDE_STATEMENTS  "" CACHE INTERNAL "")
  91 set(CASPARCG_MODULE_INIT_STATEMENTS             "" CACHE INTERNAL "")
  92 set(CASPARCG_MODULE_UNINIT_STATEMENTS   "" CACHE INTERNAL "")
  93 set(CASPARCG_MODULE_PROJECTS                    "" CACHE INTERNAL "")
  94 set(CASPARCG_RUNTIME_DEPENDENCIES               "" CACHE INTERNAL "")
  95
  96 function(casparcg_add_include_statement HEADER_FILE_TO_INCLUDE)
  97         set(CASPARCG_MODULE_INCLUDE_STATEMENTS "${CASPARCG_MODULE_INCLUDE_STATEMENTS}"
  98                         "#include <${HEADER_FILE_TO_INCLUDE}>"
  99                         CACHE INTERNAL "")
 100 endfunction()
 101
 102 function(casparcg_add_init_statement INIT_FUNCTION_NAME NAME_TO_LOG)
 103         set(CASPARCG_MODULE_INIT_STATEMENTS "${CASPARCG_MODULE_INIT_STATEMENTS}"
 104                         "       ${INIT_FUNCTION_NAME}(dependencies)\;"
 105                         "       CASPAR_LOG(info) << L\"Initialized ${NAME_TO_LOG} module.\"\;"
 106                         ""
 107                         CACHE INTERNAL "")
 108 endfunction()
 109
 110 function(casparcg_add_uninit_statement UNINIT_FUNCTION_NAME)
 111         set(CASPARCG_MODULE_UNINIT_STATEMENTS "${CASPARCG_MODULE_UNINIT_STATEMENTS}"
 112                         "       ${UNINIT_FUNCTION_NAME}()\;"
 113                         CACHE INTERNAL "")
 114 endfunction()
 115
 116 function(casparcg_add_module_project PROJECT)
 117         set(CASPARCG_MODULE_PROJECTS "${CASPARCG_MODULE_PROJECTS}" "${PROJECT}" CACHE INTERNAL "")
 118 endfunction()
 119
 120 # http://stackoverflow.com/questions/7172670/best-shortest-way-to-join-a-list-in-cmake
 121 function(join_list VALUES GLUE OUTPUT)
 122         string (REGEX REPLACE "([^\\]|^);" "\\1${GLUE}" _TMP_STR "${VALUES}")
 123         string (REGEX REPLACE "[\\](.)" "\\1" _TMP_STR "${_TMP_STR}") #fixes escaping
 124         set (${OUTPUT} "${_TMP_STR}" PARENT_SCOPE)
 125 endfunction()
 126
 127 function(casparcg_add_runtime_dependency FILE_TO_COPY)
 128         set(CASPARCG_RUNTIME_DEPENDENCIES "${CASPARCG_RUNTIME_DEPENDENCIES}" "${FILE_TO_COPY}" CACHE INTERNAL "")
 129 endfunction()
 130
 131 add_subdirectory(accelerator)
 132 add_subdirectory(common)
 133 add_subdirectory(core)
 134 add_subdirectory(modules)
 135
 136 add_subdirectory(protocol)
 137 add_subdirectory(shell)