git.sesse.net Git - x264/blob - common/x86/x86inc.asm

   1 ;*****************************************************************************
   2 ;* x86inc.asm: x264asm abstraction layer
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2005-2015 x264 project
   5 ;*
   6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
   7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
   8 ;*          Fiona Glaser <fiona@x264.com>
   9 ;*          Henrik Gramner <henrik@gramner.com>
  10 ;*
  11 ;* Permission to use, copy, modify, and/or distribute this software for any
  12 ;* purpose with or without fee is hereby granted, provided that the above
  13 ;* copyright notice and this permission notice appear in all copies.
  14 ;*
  15 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  16 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  17 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  18 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  19 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  20 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  21 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  22 ;*****************************************************************************
  23
  24 ; This is a header file for the x264ASM assembly language, which uses
  25 ; NASM/YASM syntax combined with a large number of macros to provide easy
  26 ; abstraction between different calling conventions (x86_32, win64, linux64).
  27 ; It also has various other useful features to simplify writing the kind of
  28 ; DSP functions that are most often used in x264.
  29
  30 ; Unlike the rest of x264, this file is available under an ISC license, as it
  31 ; has significant usefulness outside of x264 and we want it to be available
  32 ; to the largest audience possible.  Of course, if you modify it for your own
  33 ; purposes to add a new feature, we strongly encourage contributing a patch
  34 ; as this feature might be useful for others as well.  Send patches or ideas
  35 ; to x264-devel@videolan.org .
  36
  37 %ifndef private_prefix
  38     %define private_prefix x264
  39 %endif
  40
  41 %ifndef public_prefix
  42     %define public_prefix private_prefix
  43 %endif
  44
  45 %ifndef STACK_ALIGNMENT
  46     %if ARCH_X86_64
  47         %define STACK_ALIGNMENT 16
  48     %else
  49         %define STACK_ALIGNMENT 4
  50     %endif
  51 %endif
  52
  53 %define WIN64  0
  54 %define UNIX64 0
  55 %if ARCH_X86_64
  56     %ifidn __OUTPUT_FORMAT__,win32
  57         %define WIN64  1
  58     %elifidn __OUTPUT_FORMAT__,win64
  59         %define WIN64  1
  60     %elifidn __OUTPUT_FORMAT__,x64
  61         %define WIN64  1
  62     %else
  63         %define UNIX64 1
  64     %endif
  65 %endif
  66
  67 %define FORMAT_ELF 0
  68 %ifidn __OUTPUT_FORMAT__,elf
  69     %define FORMAT_ELF 1
  70 %elifidn __OUTPUT_FORMAT__,elf32
  71     %define FORMAT_ELF 1
  72 %elifidn __OUTPUT_FORMAT__,elf64
  73     %define FORMAT_ELF 1
  74 %endif
  75
  76 %ifdef PREFIX
  77     %define mangle(x) _ %+ x
  78 %else
  79     %define mangle(x) x
  80 %endif
  81
  82 %macro SECTION_RODATA 0-1 16
  83     SECTION .rodata align=%1
  84 %endmacro
  85
  86 %if WIN64
  87     %define PIC
  88 %elif ARCH_X86_64 == 0
  89 ; x86_32 doesn't require PIC.
  90 ; Some distros prefer shared objects to be PIC, but nothing breaks if
  91 ; the code contains a few textrels, so we'll skip that complexity.
  92     %undef PIC
  93 %endif
  94 %ifdef PIC
  95     default rel
  96 %endif
  97
  98 %ifdef __NASM_VER__
  99     %use smartalign
 100 %endif
 101
 102 ; Macros to eliminate most code duplication between x86_32 and x86_64:
 103 ; Currently this works only for leaf functions which load all their arguments
 104 ; into registers at the start, and make no other use of the stack. Luckily that
 105 ; covers most of x264's asm.
 106
 107 ; PROLOGUE:
 108 ; %1 = number of arguments. loads them from stack if needed.
 109 ; %2 = number of registers used. pushes callee-saved regs if needed.
 110 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
 111 ; %4 = (optional) stack size to be allocated. The stack will be aligned before
 112 ;      allocating the specified stack size. If the required stack alignment is
 113 ;      larger than the known stack alignment the stack will be manually aligned
 114 ;      and an extra register will be allocated to hold the original stack
 115 ;      pointer (to not invalidate r0m etc.). To prevent the use of an extra
 116 ;      register as stack pointer, request a negative stack size.
 117 ; %4+/%5+ = list of names to define to registers
 118 ; PROLOGUE can also be invoked by adding the same options to cglobal
 119
 120 ; e.g.
 121 ; cglobal foo, 2,3,7,0x40, dst, src, tmp
 122 ; declares a function (foo) that automatically loads two arguments (dst and
 123 ; src) into registers, uses one additional register (tmp) plus 7 vector
 124 ; registers (m0-m6) and allocates 0x40 bytes of stack space.
 125
 126 ; TODO Some functions can use some args directly from the stack. If they're the
 127 ; last args then you can just not declare them, but if they're in the middle
 128 ; we need more flexible macro.
 129
 130 ; RET:
 131 ; Pops anything that was pushed by PROLOGUE, and returns.
 132
 133 ; REP_RET:
 134 ; Use this instead of RET if it's a branch target.
 135
 136 ; registers:
 137 ; rN and rNq are the native-size register holding function argument N
 138 ; rNd, rNw, rNb are dword, word, and byte size
 139 ; rNh is the high 8 bits of the word size
 140 ; rNm is the original location of arg N (a register or on the stack), dword
 141 ; rNmp is native size
 142
 143 %macro DECLARE_REG 2-3
 144     %define r%1q %2
 145     %define r%1d %2d
 146     %define r%1w %2w
 147     %define r%1b %2b
 148     %define r%1h %2h
 149     %if %0 == 2
 150         %define r%1m  %2d
 151         %define r%1mp %2
 152     %elif ARCH_X86_64 ; memory
 153         %define r%1m [rstk + stack_offset + %3]
 154         %define r%1mp qword r %+ %1 %+ m
 155     %else
 156         %define r%1m [rstk + stack_offset + %3]
 157         %define r%1mp dword r %+ %1 %+ m
 158     %endif
 159     %define r%1  %2
 160 %endmacro
 161
 162 %macro DECLARE_REG_SIZE 3
 163     %define r%1q r%1
 164     %define e%1q r%1
 165     %define r%1d e%1
 166     %define e%1d e%1
 167     %define r%1w %1
 168     %define e%1w %1
 169     %define r%1h %3
 170     %define e%1h %3
 171     %define r%1b %2
 172     %define e%1b %2
 173 %if ARCH_X86_64 == 0
 174     %define r%1  e%1
 175 %endif
 176 %endmacro
 177
 178 DECLARE_REG_SIZE ax, al, ah
 179 DECLARE_REG_SIZE bx, bl, bh
 180 DECLARE_REG_SIZE cx, cl, ch
 181 DECLARE_REG_SIZE dx, dl, dh
 182 DECLARE_REG_SIZE si, sil, null
 183 DECLARE_REG_SIZE di, dil, null
 184 DECLARE_REG_SIZE bp, bpl, null
 185
 186 ; t# defines for when per-arch register allocation is more complex than just function arguments
 187
 188 %macro DECLARE_REG_TMP 1-*
 189     %assign %%i 0
 190     %rep %0
 191         CAT_XDEFINE t, %%i, r%1
 192         %assign %%i %%i+1
 193         %rotate 1
 194     %endrep
 195 %endmacro
 196
 197 %macro DECLARE_REG_TMP_SIZE 0-*
 198     %rep %0
 199         %define t%1q t%1 %+ q
 200         %define t%1d t%1 %+ d
 201         %define t%1w t%1 %+ w
 202         %define t%1h t%1 %+ h
 203         %define t%1b t%1 %+ b
 204         %rotate 1
 205     %endrep
 206 %endmacro
 207
 208 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14
 209
 210 %if ARCH_X86_64
 211     %define gprsize 8
 212 %else
 213     %define gprsize 4
 214 %endif
 215
 216 %macro PUSH 1
 217     push %1
 218     %ifidn rstk, rsp
 219         %assign stack_offset stack_offset+gprsize
 220     %endif
 221 %endmacro
 222
 223 %macro POP 1
 224     pop %1
 225     %ifidn rstk, rsp
 226         %assign stack_offset stack_offset-gprsize
 227     %endif
 228 %endmacro
 229
 230 %macro PUSH_IF_USED 1-*
 231     %rep %0
 232         %if %1 < regs_used
 233             PUSH r%1
 234         %endif
 235         %rotate 1
 236     %endrep
 237 %endmacro
 238
 239 %macro POP_IF_USED 1-*
 240     %rep %0
 241         %if %1 < regs_used
 242             pop r%1
 243         %endif
 244         %rotate 1
 245     %endrep
 246 %endmacro
 247
 248 %macro LOAD_IF_USED 1-*
 249     %rep %0
 250         %if %1 < num_args
 251             mov r%1, r %+ %1 %+ mp
 252         %endif
 253         %rotate 1
 254     %endrep
 255 %endmacro
 256
 257 %macro SUB 2
 258     sub %1, %2
 259     %ifidn %1, rstk
 260         %assign stack_offset stack_offset+(%2)
 261     %endif
 262 %endmacro
 263
 264 %macro ADD 2
 265     add %1, %2
 266     %ifidn %1, rstk
 267         %assign stack_offset stack_offset-(%2)
 268     %endif
 269 %endmacro
 270
 271 %macro movifnidn 2
 272     %ifnidn %1, %2
 273         mov %1, %2
 274     %endif
 275 %endmacro
 276
 277 %macro movsxdifnidn 2
 278     %ifnidn %1, %2
 279         movsxd %1, %2
 280     %endif
 281 %endmacro
 282
 283 %macro ASSERT 1
 284     %if (%1) == 0
 285         %error assert failed
 286     %endif
 287 %endmacro
 288
 289 %macro DEFINE_ARGS 0-*
 290     %ifdef n_arg_names
 291         %assign %%i 0
 292         %rep n_arg_names
 293             CAT_UNDEF arg_name %+ %%i, q
 294             CAT_UNDEF arg_name %+ %%i, d
 295             CAT_UNDEF arg_name %+ %%i, w
 296             CAT_UNDEF arg_name %+ %%i, h
 297             CAT_UNDEF arg_name %+ %%i, b
 298             CAT_UNDEF arg_name %+ %%i, m
 299             CAT_UNDEF arg_name %+ %%i, mp
 300             CAT_UNDEF arg_name, %%i
 301             %assign %%i %%i+1
 302         %endrep
 303     %endif
 304
 305     %xdefine %%stack_offset stack_offset
 306     %undef stack_offset ; so that the current value of stack_offset doesn't get baked in by xdefine
 307     %assign %%i 0
 308     %rep %0
 309         %xdefine %1q r %+ %%i %+ q
 310         %xdefine %1d r %+ %%i %+ d
 311         %xdefine %1w r %+ %%i %+ w
 312         %xdefine %1h r %+ %%i %+ h
 313         %xdefine %1b r %+ %%i %+ b
 314         %xdefine %1m r %+ %%i %+ m
 315         %xdefine %1mp r %+ %%i %+ mp
 316         CAT_XDEFINE arg_name, %%i, %1
 317         %assign %%i %%i+1
 318         %rotate 1
 319     %endrep
 320     %xdefine stack_offset %%stack_offset
 321     %assign n_arg_names %0
 322 %endmacro
 323
 324 %define required_stack_alignment ((mmsize + 15) & ~15)
 325
 326 %macro ALLOC_STACK 1-2 0 ; stack_size, n_xmm_regs (for win64 only)
 327     %ifnum %1
 328         %if %1 != 0
 329             %assign %%pad 0
 330             %assign stack_size %1
 331             %if stack_size < 0
 332                 %assign stack_size -stack_size
 333             %endif
 334             %if WIN64
 335                 %assign %%pad %%pad + 32 ; shadow space
 336                 %if mmsize != 8
 337                     %assign xmm_regs_used %2
 338                     %if xmm_regs_used > 8
 339                         %assign %%pad %%pad + (xmm_regs_used-8)*16 ; callee-saved xmm registers
 340                     %endif
 341                 %endif
 342             %endif
 343             %if required_stack_alignment <= STACK_ALIGNMENT
 344                 ; maintain the current stack alignment
 345                 %assign stack_size_padded stack_size + %%pad + ((-%%pad-stack_offset-gprsize) & (STACK_ALIGNMENT-1))
 346                 SUB rsp, stack_size_padded
 347             %else
 348                 %assign %%reg_num (regs_used - 1)
 349                 %xdefine rstk r %+ %%reg_num
 350                 ; align stack, and save original stack location directly above
 351                 ; it, i.e. in [rsp+stack_size_padded], so we can restore the
 352                 ; stack in a single instruction (i.e. mov rsp, rstk or mov
 353                 ; rsp, [rsp+stack_size_padded])
 354                 %if %1 < 0 ; need to store rsp on stack
 355                     %xdefine rstkm [rsp + stack_size + %%pad]
 356                     %assign %%pad %%pad + gprsize
 357                 %else ; can keep rsp in rstk during whole function
 358                     %xdefine rstkm rstk
 359                 %endif
 360                 %assign stack_size_padded stack_size + ((%%pad + required_stack_alignment-1) & ~(required_stack_alignment-1))
 361                 mov rstk, rsp
 362                 and rsp, ~(required_stack_alignment-1)
 363                 sub rsp, stack_size_padded
 364                 movifnidn rstkm, rstk
 365             %endif
 366             WIN64_PUSH_XMM
 367         %endif
 368     %endif
 369 %endmacro
 370
 371 %macro SETUP_STACK_POINTER 1
 372     %ifnum %1
 373         %if %1 != 0 && required_stack_alignment > STACK_ALIGNMENT
 374             %if %1 > 0
 375                 %assign regs_used (regs_used + 1)
 376             %elif ARCH_X86_64 && regs_used == num_args && num_args <= 4 + UNIX64 * 2
 377                 %warning "Stack pointer will overwrite register argument"
 378             %endif
 379         %endif
 380     %endif
 381 %endmacro
 382
 383 %macro DEFINE_ARGS_INTERNAL 3+
 384     %ifnum %2
 385         DEFINE_ARGS %3
 386     %elif %1 == 4
 387         DEFINE_ARGS %2
 388     %elif %1 > 4
 389         DEFINE_ARGS %2, %3
 390     %endif
 391 %endmacro
 392
 393 %if WIN64 ; Windows x64 ;=================================================
 394
 395 DECLARE_REG 0,  rcx
 396 DECLARE_REG 1,  rdx
 397 DECLARE_REG 2,  R8
 398 DECLARE_REG 3,  R9
 399 DECLARE_REG 4,  R10, 40
 400 DECLARE_REG 5,  R11, 48
 401 DECLARE_REG 6,  rax, 56
 402 DECLARE_REG 7,  rdi, 64
 403 DECLARE_REG 8,  rsi, 72
 404 DECLARE_REG 9,  rbx, 80
 405 DECLARE_REG 10, rbp, 88
 406 DECLARE_REG 11, R12, 96
 407 DECLARE_REG 12, R13, 104
 408 DECLARE_REG 13, R14, 112
 409 DECLARE_REG 14, R15, 120
 410
 411 %macro PROLOGUE 2-5+ 0 ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
 412     %assign num_args %1
 413     %assign regs_used %2
 414     ASSERT regs_used >= num_args
 415     SETUP_STACK_POINTER %4
 416     ASSERT regs_used <= 15
 417     PUSH_IF_USED 7, 8, 9, 10, 11, 12, 13, 14
 418     ALLOC_STACK %4, %3
 419     %if mmsize != 8 && stack_size == 0
 420         WIN64_SPILL_XMM %3
 421     %endif
 422     LOAD_IF_USED 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14
 423     DEFINE_ARGS_INTERNAL %0, %4, %5
 424 %endmacro
 425
 426 %macro WIN64_PUSH_XMM 0
 427     ; Use the shadow space to store XMM6 and XMM7, the rest needs stack space allocated.
 428     %if xmm_regs_used > 6
 429         movaps [rstk + stack_offset +  8], xmm6
 430     %endif
 431     %if xmm_regs_used > 7
 432         movaps [rstk + stack_offset + 24], xmm7
 433     %endif
 434     %if xmm_regs_used > 8
 435         %assign %%i 8
 436         %rep xmm_regs_used-8
 437             movaps [rsp + (%%i-8)*16 + stack_size + 32], xmm %+ %%i
 438             %assign %%i %%i+1
 439         %endrep
 440     %endif
 441 %endmacro
 442
 443 %macro WIN64_SPILL_XMM 1
 444     %assign xmm_regs_used %1
 445     ASSERT xmm_regs_used <= 16
 446     %if xmm_regs_used > 8
 447         ; Allocate stack space for callee-saved xmm registers plus shadow space and align the stack.
 448         %assign %%pad (xmm_regs_used-8)*16 + 32
 449         %assign stack_size_padded %%pad + ((-%%pad-stack_offset-gprsize) & (STACK_ALIGNMENT-1))
 450         SUB rsp, stack_size_padded
 451     %endif
 452     WIN64_PUSH_XMM
 453 %endmacro
 454
 455 %macro WIN64_RESTORE_XMM_INTERNAL 1
 456     %assign %%pad_size 0
 457     %if xmm_regs_used > 8
 458         %assign %%i xmm_regs_used
 459         %rep xmm_regs_used-8
 460             %assign %%i %%i-1
 461             movaps xmm %+ %%i, [%1 + (%%i-8)*16 + stack_size + 32]
 462         %endrep
 463     %endif
 464     %if stack_size_padded > 0
 465         %if stack_size > 0 && required_stack_alignment > STACK_ALIGNMENT
 466             mov rsp, rstkm
 467         %else
 468             add %1, stack_size_padded
 469             %assign %%pad_size stack_size_padded
 470         %endif
 471     %endif
 472     %if xmm_regs_used > 7
 473         movaps xmm7, [%1 + stack_offset - %%pad_size + 24]
 474     %endif
 475     %if xmm_regs_used > 6
 476         movaps xmm6, [%1 + stack_offset - %%pad_size +  8]
 477     %endif
 478 %endmacro
 479
 480 %macro WIN64_RESTORE_XMM 1
 481     WIN64_RESTORE_XMM_INTERNAL %1
 482     %assign stack_offset (stack_offset-stack_size_padded)
 483     %assign xmm_regs_used 0
 484 %endmacro
 485
 486 %define has_epilogue regs_used > 7 || xmm_regs_used > 6 || mmsize == 32 || stack_size > 0
 487
 488 %macro RET 0
 489     WIN64_RESTORE_XMM_INTERNAL rsp
 490     POP_IF_USED 14, 13, 12, 11, 10, 9, 8, 7
 491 %if mmsize == 32
 492     vzeroupper
 493 %endif
 494     AUTO_REP_RET
 495 %endmacro
 496
 497 %elif ARCH_X86_64 ; *nix x64 ;=============================================
 498
 499 DECLARE_REG 0,  rdi
 500 DECLARE_REG 1,  rsi
 501 DECLARE_REG 2,  rdx
 502 DECLARE_REG 3,  rcx
 503 DECLARE_REG 4,  R8
 504 DECLARE_REG 5,  R9
 505 DECLARE_REG 6,  rax, 8
 506 DECLARE_REG 7,  R10, 16
 507 DECLARE_REG 8,  R11, 24
 508 DECLARE_REG 9,  rbx, 32
 509 DECLARE_REG 10, rbp, 40
 510 DECLARE_REG 11, R12, 48
 511 DECLARE_REG 12, R13, 56
 512 DECLARE_REG 13, R14, 64
 513 DECLARE_REG 14, R15, 72
 514
 515 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
 516     %assign num_args %1
 517     %assign regs_used %2
 518     ASSERT regs_used >= num_args
 519     SETUP_STACK_POINTER %4
 520     ASSERT regs_used <= 15
 521     PUSH_IF_USED 9, 10, 11, 12, 13, 14
 522     ALLOC_STACK %4
 523     LOAD_IF_USED 6, 7, 8, 9, 10, 11, 12, 13, 14
 524     DEFINE_ARGS_INTERNAL %0, %4, %5
 525 %endmacro
 526
 527 %define has_epilogue regs_used > 9 || mmsize == 32 || stack_size > 0
 528
 529 %macro RET 0
 530 %if stack_size_padded > 0
 531 %if required_stack_alignment > STACK_ALIGNMENT
 532     mov rsp, rstkm
 533 %else
 534     add rsp, stack_size_padded
 535 %endif
 536 %endif
 537     POP_IF_USED 14, 13, 12, 11, 10, 9
 538 %if mmsize == 32
 539     vzeroupper
 540 %endif
 541     AUTO_REP_RET
 542 %endmacro
 543
 544 %else ; X86_32 ;==============================================================
 545
 546 DECLARE_REG 0, eax, 4
 547 DECLARE_REG 1, ecx, 8
 548 DECLARE_REG 2, edx, 12
 549 DECLARE_REG 3, ebx, 16
 550 DECLARE_REG 4, esi, 20
 551 DECLARE_REG 5, edi, 24
 552 DECLARE_REG 6, ebp, 28
 553 %define rsp esp
 554
 555 %macro DECLARE_ARG 1-*
 556     %rep %0
 557         %define r%1m [rstk + stack_offset + 4*%1 + 4]
 558         %define r%1mp dword r%1m
 559         %rotate 1
 560     %endrep
 561 %endmacro
 562
 563 DECLARE_ARG 7, 8, 9, 10, 11, 12, 13, 14
 564
 565 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
 566     %assign num_args %1
 567     %assign regs_used %2
 568     ASSERT regs_used >= num_args
 569     %if num_args > 7
 570         %assign num_args 7
 571     %endif
 572     %if regs_used > 7
 573         %assign regs_used 7
 574     %endif
 575     SETUP_STACK_POINTER %4
 576     ASSERT regs_used <= 7
 577     PUSH_IF_USED 3, 4, 5, 6
 578     ALLOC_STACK %4
 579     LOAD_IF_USED 0, 1, 2, 3, 4, 5, 6
 580     DEFINE_ARGS_INTERNAL %0, %4, %5
 581 %endmacro
 582
 583 %define has_epilogue regs_used > 3 || mmsize == 32 || stack_size > 0
 584
 585 %macro RET 0
 586 %if stack_size_padded > 0
 587 %if required_stack_alignment > STACK_ALIGNMENT
 588     mov rsp, rstkm
 589 %else
 590     add rsp, stack_size_padded
 591 %endif
 592 %endif
 593     POP_IF_USED 6, 5, 4, 3
 594 %if mmsize == 32
 595     vzeroupper
 596 %endif
 597     AUTO_REP_RET
 598 %endmacro
 599
 600 %endif ;======================================================================
 601
 602 %if WIN64 == 0
 603 %macro WIN64_SPILL_XMM 1
 604 %endmacro
 605 %macro WIN64_RESTORE_XMM 1
 606 %endmacro
 607 %macro WIN64_PUSH_XMM 0
 608 %endmacro
 609 %endif
 610
 611 ; On AMD cpus <=K10, an ordinary ret is slow if it immediately follows either
 612 ; a branch or a branch target. So switch to a 2-byte form of ret in that case.
 613 ; We can automatically detect "follows a branch", but not a branch target.
 614 ; (SSSE3 is a sufficient condition to know that your cpu doesn't have this problem.)
 615 %macro REP_RET 0
 616     %if has_epilogue
 617         RET
 618     %else
 619         rep ret
 620     %endif
 621 %endmacro
 622
 623 %define last_branch_adr $$
 624 %macro AUTO_REP_RET 0
 625     %ifndef cpuflags
 626         times ((last_branch_adr-$)>>31)+1 rep ; times 1 iff $ != last_branch_adr.
 627     %elif notcpuflag(ssse3)
 628         times ((last_branch_adr-$)>>31)+1 rep
 629     %endif
 630     ret
 631 %endmacro
 632
 633 %macro BRANCH_INSTR 0-*
 634     %rep %0
 635         %macro %1 1-2 %1
 636             %2 %1
 637             %%branch_instr:
 638             %xdefine last_branch_adr %%branch_instr
 639         %endmacro
 640         %rotate 1
 641     %endrep
 642 %endmacro
 643
 644 BRANCH_INSTR jz, je, jnz, jne, jl, jle, jnl, jnle, jg, jge, jng, jnge, ja, jae, jna, jnae, jb, jbe, jnb, jnbe, jc, jnc, js, jns, jo, jno, jp, jnp
 645
 646 %macro TAIL_CALL 2 ; callee, is_nonadjacent
 647     %if has_epilogue
 648         call %1
 649         RET
 650     %elif %2
 651         jmp %1
 652     %endif
 653 %endmacro
 654
 655 ;=============================================================================
 656 ; arch-independent part
 657 ;=============================================================================
 658
 659 %assign function_align 16
 660
 661 ; Begin a function.
 662 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
 663 ; subsequent uses of the function name automatically refer to the mangled version.
 664 ; Appends cpuflags to the function name if cpuflags has been specified.
 665 ; The "" empty default parameter is a workaround for nasm, which fails if SUFFIX
 666 ; is empty and we call cglobal_internal with just %1 %+ SUFFIX (without %2).
 667 %macro cglobal 1-2+ "" ; name, [PROLOGUE args]
 668     cglobal_internal 1, %1 %+ SUFFIX, %2
 669 %endmacro
 670 %macro cvisible 1-2+ "" ; name, [PROLOGUE args]
 671     cglobal_internal 0, %1 %+ SUFFIX, %2
 672 %endmacro
 673 %macro cglobal_internal 2-3+
 674     %if %1
 675         %xdefine %%FUNCTION_PREFIX private_prefix
 676         %xdefine %%VISIBILITY hidden
 677     %else
 678         %xdefine %%FUNCTION_PREFIX public_prefix
 679         %xdefine %%VISIBILITY
 680     %endif
 681     %ifndef cglobaled_%2
 682         %xdefine %2 mangle(%%FUNCTION_PREFIX %+ _ %+ %2)
 683         %xdefine %2.skip_prologue %2 %+ .skip_prologue
 684         CAT_XDEFINE cglobaled_, %2, 1
 685     %endif
 686     %xdefine current_function %2
 687     %if FORMAT_ELF
 688         global %2:function %%VISIBILITY
 689     %else
 690         global %2
 691     %endif
 692     align function_align
 693     %2:
 694     RESET_MM_PERMUTATION        ; needed for x86-64, also makes disassembly somewhat nicer
 695     %xdefine rstk rsp           ; copy of the original stack pointer, used when greater alignment than the known stack alignment is required
 696     %assign stack_offset 0      ; stack pointer offset relative to the return address
 697     %assign stack_size 0        ; amount of stack space that can be freely used inside a function
 698     %assign stack_size_padded 0 ; total amount of allocated stack space, including space for callee-saved xmm registers on WIN64 and alignment padding
 699     %assign xmm_regs_used 0     ; number of XMM registers requested, used for dealing with callee-saved registers on WIN64
 700     %ifnidn %3, ""
 701         PROLOGUE %3
 702     %endif
 703 %endmacro
 704
 705 %macro cextern 1
 706     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
 707     CAT_XDEFINE cglobaled_, %1, 1
 708     extern %1
 709 %endmacro
 710
 711 ; like cextern, but without the prefix
 712 %macro cextern_naked 1
 713     %ifdef PREFIX
 714         %xdefine %1 mangle(%1)
 715     %endif
 716     CAT_XDEFINE cglobaled_, %1, 1
 717     extern %1
 718 %endmacro
 719
 720 %macro const 1-2+
 721     %xdefine %1 mangle(private_prefix %+ _ %+ %1)
 722     %if FORMAT_ELF
 723         global %1:data hidden
 724     %else
 725         global %1
 726     %endif
 727     %1: %2
 728 %endmacro
 729
 730 ; This is needed for ELF, otherwise the GNU linker assumes the stack is executable by default.
 731 %if FORMAT_ELF
 732     [SECTION .note.GNU-stack noalloc noexec nowrite progbits]
 733 %endif
 734
 735 ; cpuflags
 736
 737 %assign cpuflags_mmx      (1<<0)
 738 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
 739 %assign cpuflags_3dnow    (1<<2) | cpuflags_mmx
 740 %assign cpuflags_3dnowext (1<<3) | cpuflags_3dnow
 741 %assign cpuflags_sse      (1<<4) | cpuflags_mmx2
 742 %assign cpuflags_sse2     (1<<5) | cpuflags_sse
 743 %assign cpuflags_sse2slow (1<<6) | cpuflags_sse2
 744 %assign cpuflags_sse3     (1<<7) | cpuflags_sse2
 745 %assign cpuflags_ssse3    (1<<8) | cpuflags_sse3
 746 %assign cpuflags_sse4     (1<<9) | cpuflags_ssse3
 747 %assign cpuflags_sse42    (1<<10)| cpuflags_sse4
 748 %assign cpuflags_avx      (1<<11)| cpuflags_sse42
 749 %assign cpuflags_xop      (1<<12)| cpuflags_avx
 750 %assign cpuflags_fma4     (1<<13)| cpuflags_avx
 751 %assign cpuflags_fma3     (1<<14)| cpuflags_avx
 752 %assign cpuflags_avx2     (1<<15)| cpuflags_fma3
 753
 754 %assign cpuflags_cache32  (1<<16)
 755 %assign cpuflags_cache64  (1<<17)
 756 %assign cpuflags_slowctz  (1<<18)
 757 %assign cpuflags_lzcnt    (1<<19)
 758 %assign cpuflags_aligned  (1<<20) ; not a cpu feature, but a function variant
 759 %assign cpuflags_atom     (1<<21)
 760 %assign cpuflags_bmi1     (1<<22)|cpuflags_lzcnt
 761 %assign cpuflags_bmi2     (1<<23)|cpuflags_bmi1
 762
 763 %define    cpuflag(x) ((cpuflags & (cpuflags_ %+ x)) == (cpuflags_ %+ x))
 764 %define notcpuflag(x) ((cpuflags & (cpuflags_ %+ x)) != (cpuflags_ %+ x))
 765
 766 ; Takes an arbitrary number of cpuflags from the above list.
 767 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
 768 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
 769 %macro INIT_CPUFLAGS 0-*
 770     %xdefine SUFFIX
 771     %undef cpuname
 772     %assign cpuflags 0
 773
 774     %if %0 >= 1
 775         %rep %0
 776             %ifdef cpuname
 777                 %xdefine cpuname cpuname %+ _%1
 778             %else
 779                 %xdefine cpuname %1
 780             %endif
 781             %assign cpuflags cpuflags | cpuflags_%1
 782             %rotate 1
 783         %endrep
 784         %xdefine SUFFIX _ %+ cpuname
 785
 786         %if cpuflag(avx)
 787             %assign avx_enabled 1
 788         %endif
 789         %if (mmsize == 16 && notcpuflag(sse2)) || (mmsize == 32 && notcpuflag(avx2))
 790             %define mova movaps
 791             %define movu movups
 792             %define movnta movntps
 793         %endif
 794         %if cpuflag(aligned)
 795             %define movu mova
 796         %elif cpuflag(sse3) && notcpuflag(ssse3)
 797             %define movu lddqu
 798         %endif
 799     %endif
 800
 801     %if ARCH_X86_64 || cpuflag(sse2)
 802         %ifdef __NASM_VER__
 803             ALIGNMODE k8
 804         %else
 805             CPU amdnop
 806         %endif
 807     %else
 808         %ifdef __NASM_VER__
 809             ALIGNMODE nop
 810         %else
 811             CPU basicnop
 812         %endif
 813     %endif
 814 %endmacro
 815
 816 ; Merge mmx and sse*
 817 ; m# is a simd register of the currently selected size
 818 ; xm# is the corresponding xmm register if mmsize >= 16, otherwise the same as m#
 819 ; ym# is the corresponding ymm register if mmsize >= 32, otherwise the same as m#
 820 ; (All 3 remain in sync through SWAP.)
 821
 822 %macro CAT_XDEFINE 3
 823     %xdefine %1%2 %3
 824 %endmacro
 825
 826 %macro CAT_UNDEF 2
 827     %undef %1%2
 828 %endmacro
 829
 830 %macro INIT_MMX 0-1+
 831     %assign avx_enabled 0
 832     %define RESET_MM_PERMUTATION INIT_MMX %1
 833     %define mmsize 8
 834     %define num_mmregs 8
 835     %define mova movq
 836     %define movu movq
 837     %define movh movd
 838     %define movnta movntq
 839     %assign %%i 0
 840     %rep 8
 841     CAT_XDEFINE m, %%i, mm %+ %%i
 842     CAT_XDEFINE nnmm, %%i, %%i
 843     %assign %%i %%i+1
 844     %endrep
 845     %rep 8
 846     CAT_UNDEF m, %%i
 847     CAT_UNDEF nnmm, %%i
 848     %assign %%i %%i+1
 849     %endrep
 850     INIT_CPUFLAGS %1
 851 %endmacro
 852
 853 %macro INIT_XMM 0-1+
 854     %assign avx_enabled 0
 855     %define RESET_MM_PERMUTATION INIT_XMM %1
 856     %define mmsize 16
 857     %define num_mmregs 8
 858     %if ARCH_X86_64
 859     %define num_mmregs 16
 860     %endif
 861     %define mova movdqa
 862     %define movu movdqu
 863     %define movh movq
 864     %define movnta movntdq
 865     %assign %%i 0
 866     %rep num_mmregs
 867     CAT_XDEFINE m, %%i, xmm %+ %%i
 868     CAT_XDEFINE nnxmm, %%i, %%i
 869     %assign %%i %%i+1
 870     %endrep
 871     INIT_CPUFLAGS %1
 872 %endmacro
 873
 874 %macro INIT_YMM 0-1+
 875     %assign avx_enabled 1
 876     %define RESET_MM_PERMUTATION INIT_YMM %1
 877     %define mmsize 32
 878     %define num_mmregs 8
 879     %if ARCH_X86_64
 880     %define num_mmregs 16
 881     %endif
 882     %define mova movdqa
 883     %define movu movdqu
 884     %undef movh
 885     %define movnta movntdq
 886     %assign %%i 0
 887     %rep num_mmregs
 888     CAT_XDEFINE m, %%i, ymm %+ %%i
 889     CAT_XDEFINE nnymm, %%i, %%i
 890     %assign %%i %%i+1
 891     %endrep
 892     INIT_CPUFLAGS %1
 893 %endmacro
 894
 895 INIT_XMM
 896
 897 %macro DECLARE_MMCAST 1
 898     %define  mmmm%1   mm%1
 899     %define  mmxmm%1  mm%1
 900     %define  mmymm%1  mm%1
 901     %define xmmmm%1   mm%1
 902     %define xmmxmm%1 xmm%1
 903     %define xmmymm%1 xmm%1
 904     %define ymmmm%1   mm%1
 905     %define ymmxmm%1 xmm%1
 906     %define ymmymm%1 ymm%1
 907     %define xm%1 xmm %+ m%1
 908     %define ym%1 ymm %+ m%1
 909 %endmacro
 910
 911 %assign i 0
 912 %rep 16
 913     DECLARE_MMCAST i
 914 %assign i i+1
 915 %endrep
 916
 917 ; I often want to use macros that permute their arguments. e.g. there's no
 918 ; efficient way to implement butterfly or transpose or dct without swapping some
 919 ; arguments.
 920 ;
 921 ; I would like to not have to manually keep track of the permutations:
 922 ; If I insert a permutation in the middle of a function, it should automatically
 923 ; change everything that follows. For more complex macros I may also have multiple
 924 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
 925 ;
 926 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
 927 ; permutes its arguments. It's equivalent to exchanging the contents of the
 928 ; registers, except that this way you exchange the register names instead, so it
 929 ; doesn't cost any cycles.
 930
 931 %macro PERMUTE 2-* ; takes a list of pairs to swap
 932 %rep %0/2
 933     %xdefine %%tmp%2 m%2
 934     %rotate 2
 935 %endrep
 936 %rep %0/2
 937     %xdefine m%1 %%tmp%2
 938     CAT_XDEFINE nn, m%1, %1
 939     %rotate 2
 940 %endrep
 941 %endmacro
 942
 943 %macro SWAP 2+ ; swaps a single chain (sometimes more concise than pairs)
 944 %ifnum %1 ; SWAP 0, 1, ...
 945     SWAP_INTERNAL_NUM %1, %2
 946 %else ; SWAP m0, m1, ...
 947     SWAP_INTERNAL_NAME %1, %2
 948 %endif
 949 %endmacro
 950
 951 %macro SWAP_INTERNAL_NUM 2-*
 952     %rep %0-1
 953         %xdefine %%tmp m%1
 954         %xdefine m%1 m%2
 955         %xdefine m%2 %%tmp
 956         CAT_XDEFINE nn, m%1, %1
 957         CAT_XDEFINE nn, m%2, %2
 958     %rotate 1
 959     %endrep
 960 %endmacro
 961
 962 %macro SWAP_INTERNAL_NAME 2-*
 963     %xdefine %%args nn %+ %1
 964     %rep %0-1
 965         %xdefine %%args %%args, nn %+ %2
 966     %rotate 1
 967     %endrep
 968     SWAP_INTERNAL_NUM %%args
 969 %endmacro
 970
 971 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
 972 ; calls to that function will automatically load the permutation, so values can
 973 ; be returned in mmregs.
 974 %macro SAVE_MM_PERMUTATION 0-1
 975     %if %0
 976         %xdefine %%f %1_m
 977     %else
 978         %xdefine %%f current_function %+ _m
 979     %endif
 980     %assign %%i 0
 981     %rep num_mmregs
 982         CAT_XDEFINE %%f, %%i, m %+ %%i
 983     %assign %%i %%i+1
 984     %endrep
 985 %endmacro
 986
 987 %macro LOAD_MM_PERMUTATION 1 ; name to load from
 988     %ifdef %1_m0
 989         %assign %%i 0
 990         %rep num_mmregs
 991             CAT_XDEFINE m, %%i, %1_m %+ %%i
 992             CAT_XDEFINE nn, m %+ %%i, %%i
 993         %assign %%i %%i+1
 994         %endrep
 995     %endif
 996 %endmacro
 997
 998 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
 999 %macro call 1
1000     call_internal %1, %1 %+ SUFFIX
1001 %endmacro
1002 %macro call_internal 2
1003     %xdefine %%i %1
1004     %ifndef cglobaled_%1
1005         %ifdef cglobaled_%2
1006             %xdefine %%i %2
1007         %endif
1008     %endif
1009     call %%i
1010     LOAD_MM_PERMUTATION %%i
1011 %endmacro
1012
1013 ; Substitutions that reduce instruction size but are functionally equivalent
1014 %macro add 2
1015     %ifnum %2
1016         %if %2==128
1017             sub %1, -128
1018         %else
1019             add %1, %2
1020         %endif
1021     %else
1022         add %1, %2
1023     %endif
1024 %endmacro
1025
1026 %macro sub 2
1027     %ifnum %2
1028         %if %2==128
1029             add %1, -128
1030         %else
1031             sub %1, %2
1032         %endif
1033     %else
1034         sub %1, %2
1035     %endif
1036 %endmacro
1037
1038 ;=============================================================================
1039 ; AVX abstraction layer
1040 ;=============================================================================
1041
1042 %assign i 0
1043 %rep 16
1044     %if i < 8
1045         CAT_XDEFINE sizeofmm, i, 8
1046     %endif
1047     CAT_XDEFINE sizeofxmm, i, 16
1048     CAT_XDEFINE sizeofymm, i, 32
1049 %assign i i+1
1050 %endrep
1051 %undef i
1052
1053 %macro CHECK_AVX_INSTR_EMU 3-*
1054     %xdefine %%opcode %1
1055     %xdefine %%dst %2
1056     %rep %0-2
1057         %ifidn %%dst, %3
1058             %error non-avx emulation of ``%%opcode'' is not supported
1059         %endif
1060         %rotate 1
1061     %endrep
1062 %endmacro
1063
1064 ;%1 == instruction
1065 ;%2 == minimal instruction set
1066 ;%3 == 1 if float, 0 if int
1067 ;%4 == 1 if non-destructive or 4-operand (xmm, xmm, xmm, imm), 0 otherwise
1068 ;%5 == 1 if commutative (i.e. doesn't matter which src arg is which), 0 if not
1069 ;%6+: operands
1070 %macro RUN_AVX_INSTR 6-9+
1071     %ifnum sizeof%7
1072         %assign __sizeofreg sizeof%7
1073     %elifnum sizeof%6
1074         %assign __sizeofreg sizeof%6
1075     %else
1076         %assign __sizeofreg mmsize
1077     %endif
1078     %assign __emulate_avx 0
1079     %if avx_enabled && __sizeofreg >= 16
1080         %xdefine __instr v%1
1081     %else
1082         %xdefine __instr %1
1083         %if %0 >= 8+%4
1084             %assign __emulate_avx 1
1085         %endif
1086     %endif
1087     %ifnidn %2, fnord
1088         %ifdef cpuname
1089             %if notcpuflag(%2)
1090                 %error use of ``%1'' %2 instruction in cpuname function: current_function
1091             %elif cpuflags_%2 < cpuflags_sse && notcpuflag(sse2) && __sizeofreg > 8
1092                 %error use of ``%1'' sse2 instruction in cpuname function: current_function
1093             %endif
1094         %endif
1095     %endif
1096
1097     %if __emulate_avx
1098         %xdefine __src1 %7
1099         %xdefine __src2 %8
1100         %ifnidn %6, %7
1101             %if %0 >= 9
1102                 CHECK_AVX_INSTR_EMU {%1 %6, %7, %8, %9}, %6, %8, %9
1103             %else
1104                 CHECK_AVX_INSTR_EMU {%1 %6, %7, %8}, %6, %8
1105             %endif
1106             %if %5 && %4 == 0
1107                 %ifnid %8
1108                     ; 3-operand AVX instructions with a memory arg can only have it in src2,
1109                     ; whereas SSE emulation prefers to have it in src1 (i.e. the mov).
1110                     ; So, if the instruction is commutative with a memory arg, swap them.
1111                     %xdefine __src1 %8
1112                     %xdefine __src2 %7
1113                 %endif
1114             %endif
1115             %if __sizeofreg == 8
1116                 MOVQ %6, __src1
1117             %elif %3
1118                 MOVAPS %6, __src1
1119             %else
1120                 MOVDQA %6, __src1
1121             %endif
1122         %endif
1123         %if %0 >= 9
1124             %1 %6, __src2, %9
1125         %else
1126             %1 %6, __src2
1127         %endif
1128     %elif %0 >= 9
1129         __instr %6, %7, %8, %9
1130     %elif %0 == 8
1131         __instr %6, %7, %8
1132     %elif %0 == 7
1133         __instr %6, %7
1134     %else
1135         __instr %6
1136     %endif
1137 %endmacro
1138
1139 ;%1 == instruction
1140 ;%2 == minimal instruction set
1141 ;%3 == 1 if float, 0 if int
1142 ;%4 == 1 if non-destructive or 4-operand (xmm, xmm, xmm, imm), 0 otherwise
1143 ;%5 == 1 if commutative (i.e. doesn't matter which src arg is which), 0 if not
1144 %macro AVX_INSTR 1-5 fnord, 0, 1, 0
1145     %macro %1 1-10 fnord, fnord, fnord, fnord, %1, %2, %3, %4, %5
1146         %ifidn %2, fnord
1147             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1
1148         %elifidn %3, fnord
1149             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2
1150         %elifidn %4, fnord
1151             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3
1152         %elifidn %5, fnord
1153             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3, %4
1154         %else
1155             RUN_AVX_INSTR %6, %7, %8, %9, %10, %1, %2, %3, %4, %5
1156         %endif
1157     %endmacro
1158 %endmacro
1159
1160 ; Instructions with both VEX and non-VEX encodings
1161 ; Non-destructive instructions are written without parameters
1162 AVX_INSTR addpd, sse2, 1, 0, 1
1163 AVX_INSTR addps, sse, 1, 0, 1
1164 AVX_INSTR addsd, sse2, 1, 0, 1
1165 AVX_INSTR addss, sse, 1, 0, 1
1166 AVX_INSTR addsubpd, sse3, 1, 0, 0
1167 AVX_INSTR addsubps, sse3, 1, 0, 0
1168 AVX_INSTR aesdec, fnord, 0, 0, 0
1169 AVX_INSTR aesdeclast, fnord, 0, 0, 0
1170 AVX_INSTR aesenc, fnord, 0, 0, 0
1171 AVX_INSTR aesenclast, fnord, 0, 0, 0
1172 AVX_INSTR aesimc
1173 AVX_INSTR aeskeygenassist
1174 AVX_INSTR andnpd, sse2, 1, 0, 0
1175 AVX_INSTR andnps, sse, 1, 0, 0
1176 AVX_INSTR andpd, sse2, 1, 0, 1
1177 AVX_INSTR andps, sse, 1, 0, 1
1178 AVX_INSTR blendpd, sse4, 1, 0, 0
1179 AVX_INSTR blendps, sse4, 1, 0, 0
1180 AVX_INSTR blendvpd, sse4, 1, 0, 0
1181 AVX_INSTR blendvps, sse4, 1, 0, 0
1182 AVX_INSTR cmppd, sse2, 1, 1, 0
1183 AVX_INSTR cmpps, sse, 1, 1, 0
1184 AVX_INSTR cmpsd, sse2, 1, 1, 0
1185 AVX_INSTR cmpss, sse, 1, 1, 0
1186 AVX_INSTR comisd, sse2
1187 AVX_INSTR comiss, sse
1188 AVX_INSTR cvtdq2pd, sse2
1189 AVX_INSTR cvtdq2ps, sse2
1190 AVX_INSTR cvtpd2dq, sse2
1191 AVX_INSTR cvtpd2ps, sse2
1192 AVX_INSTR cvtps2dq, sse2
1193 AVX_INSTR cvtps2pd, sse2
1194 AVX_INSTR cvtsd2si, sse2
1195 AVX_INSTR cvtsd2ss, sse2
1196 AVX_INSTR cvtsi2sd, sse2
1197 AVX_INSTR cvtsi2ss, sse
1198 AVX_INSTR cvtss2sd, sse2
1199 AVX_INSTR cvtss2si, sse
1200 AVX_INSTR cvttpd2dq, sse2
1201 AVX_INSTR cvttps2dq, sse2
1202 AVX_INSTR cvttsd2si, sse2
1203 AVX_INSTR cvttss2si, sse
1204 AVX_INSTR divpd, sse2, 1, 0, 0
1205 AVX_INSTR divps, sse, 1, 0, 0
1206 AVX_INSTR divsd, sse2, 1, 0, 0
1207 AVX_INSTR divss, sse, 1, 0, 0
1208 AVX_INSTR dppd, sse4, 1, 1, 0
1209 AVX_INSTR dpps, sse4, 1, 1, 0
1210 AVX_INSTR extractps, sse4
1211 AVX_INSTR haddpd, sse3, 1, 0, 0
1212 AVX_INSTR haddps, sse3, 1, 0, 0
1213 AVX_INSTR hsubpd, sse3, 1, 0, 0
1214 AVX_INSTR hsubps, sse3, 1, 0, 0
1215 AVX_INSTR insertps, sse4, 1, 1, 0
1216 AVX_INSTR lddqu, sse3
1217 AVX_INSTR ldmxcsr, sse
1218 AVX_INSTR maskmovdqu, sse2
1219 AVX_INSTR maxpd, sse2, 1, 0, 1
1220 AVX_INSTR maxps, sse, 1, 0, 1
1221 AVX_INSTR maxsd, sse2, 1, 0, 1
1222 AVX_INSTR maxss, sse, 1, 0, 1
1223 AVX_INSTR minpd, sse2, 1, 0, 1
1224 AVX_INSTR minps, sse, 1, 0, 1
1225 AVX_INSTR minsd, sse2, 1, 0, 1
1226 AVX_INSTR minss, sse, 1, 0, 1
1227 AVX_INSTR movapd, sse2
1228 AVX_INSTR movaps, sse
1229 AVX_INSTR movd, mmx
1230 AVX_INSTR movddup, sse3
1231 AVX_INSTR movdqa, sse2
1232 AVX_INSTR movdqu, sse2
1233 AVX_INSTR movhlps, sse, 1, 0, 0
1234 AVX_INSTR movhpd, sse2, 1, 0, 0
1235 AVX_INSTR movhps, sse, 1, 0, 0
1236 AVX_INSTR movlhps, sse, 1, 0, 0
1237 AVX_INSTR movlpd, sse2, 1, 0, 0
1238 AVX_INSTR movlps, sse, 1, 0, 0
1239 AVX_INSTR movmskpd, sse2
1240 AVX_INSTR movmskps, sse
1241 AVX_INSTR movntdq, sse2
1242 AVX_INSTR movntdqa, sse4
1243 AVX_INSTR movntpd, sse2
1244 AVX_INSTR movntps, sse
1245 AVX_INSTR movq, mmx
1246 AVX_INSTR movsd, sse2, 1, 0, 0
1247 AVX_INSTR movshdup, sse3
1248 AVX_INSTR movsldup, sse3
1249 AVX_INSTR movss, sse, 1, 0, 0
1250 AVX_INSTR movupd, sse2
1251 AVX_INSTR movups, sse
1252 AVX_INSTR mpsadbw, sse4
1253 AVX_INSTR mulpd, sse2, 1, 0, 1
1254 AVX_INSTR mulps, sse, 1, 0, 1
1255 AVX_INSTR mulsd, sse2, 1, 0, 1
1256 AVX_INSTR mulss, sse, 1, 0, 1
1257 AVX_INSTR orpd, sse2, 1, 0, 1
1258 AVX_INSTR orps, sse, 1, 0, 1
1259 AVX_INSTR pabsb, ssse3
1260 AVX_INSTR pabsd, ssse3
1261 AVX_INSTR pabsw, ssse3
1262 AVX_INSTR packsswb, mmx, 0, 0, 0
1263 AVX_INSTR packssdw, mmx, 0, 0, 0
1264 AVX_INSTR packuswb, mmx, 0, 0, 0
1265 AVX_INSTR packusdw, sse4, 0, 0, 0
1266 AVX_INSTR paddb, mmx, 0, 0, 1
1267 AVX_INSTR paddw, mmx, 0, 0, 1
1268 AVX_INSTR paddd, mmx, 0, 0, 1
1269 AVX_INSTR paddq, sse2, 0, 0, 1
1270 AVX_INSTR paddsb, mmx, 0, 0, 1
1271 AVX_INSTR paddsw, mmx, 0, 0, 1
1272 AVX_INSTR paddusb, mmx, 0, 0, 1
1273 AVX_INSTR paddusw, mmx, 0, 0, 1
1274 AVX_INSTR palignr, ssse3
1275 AVX_INSTR pand, mmx, 0, 0, 1
1276 AVX_INSTR pandn, mmx, 0, 0, 0
1277 AVX_INSTR pavgb, mmx2, 0, 0, 1
1278 AVX_INSTR pavgw, mmx2, 0, 0, 1
1279 AVX_INSTR pblendvb, sse4, 0, 0, 0
1280 AVX_INSTR pblendw, sse4
1281 AVX_INSTR pclmulqdq
1282 AVX_INSTR pcmpestri, sse42
1283 AVX_INSTR pcmpestrm, sse42
1284 AVX_INSTR pcmpistri, sse42
1285 AVX_INSTR pcmpistrm, sse42
1286 AVX_INSTR pcmpeqb, mmx, 0, 0, 1
1287 AVX_INSTR pcmpeqw, mmx, 0, 0, 1
1288 AVX_INSTR pcmpeqd, mmx, 0, 0, 1
1289 AVX_INSTR pcmpeqq, sse4, 0, 0, 1
1290 AVX_INSTR pcmpgtb, mmx, 0, 0, 0
1291 AVX_INSTR pcmpgtw, mmx, 0, 0, 0
1292 AVX_INSTR pcmpgtd, mmx, 0, 0, 0
1293 AVX_INSTR pcmpgtq, sse42, 0, 0, 0
1294 AVX_INSTR pextrb, sse4
1295 AVX_INSTR pextrd, sse4
1296 AVX_INSTR pextrq, sse4
1297 AVX_INSTR pextrw, mmx2
1298 AVX_INSTR phaddw, ssse3, 0, 0, 0
1299 AVX_INSTR phaddd, ssse3, 0, 0, 0
1300 AVX_INSTR phaddsw, ssse3, 0, 0, 0
1301 AVX_INSTR phminposuw, sse4
1302 AVX_INSTR phsubw, ssse3, 0, 0, 0
1303 AVX_INSTR phsubd, ssse3, 0, 0, 0
1304 AVX_INSTR phsubsw, ssse3, 0, 0, 0
1305 AVX_INSTR pinsrb, sse4
1306 AVX_INSTR pinsrd, sse4
1307 AVX_INSTR pinsrq, sse4
1308 AVX_INSTR pinsrw, mmx2
1309 AVX_INSTR pmaddwd, mmx, 0, 0, 1
1310 AVX_INSTR pmaddubsw, ssse3, 0, 0, 0
1311 AVX_INSTR pmaxsb, sse4, 0, 0, 1
1312 AVX_INSTR pmaxsw, mmx2, 0, 0, 1
1313 AVX_INSTR pmaxsd, sse4, 0, 0, 1
1314 AVX_INSTR pmaxub, mmx2, 0, 0, 1
1315 AVX_INSTR pmaxuw, sse4, 0, 0, 1
1316 AVX_INSTR pmaxud, sse4, 0, 0, 1
1317 AVX_INSTR pminsb, sse4, 0, 0, 1
1318 AVX_INSTR pminsw, mmx2, 0, 0, 1
1319 AVX_INSTR pminsd, sse4, 0, 0, 1
1320 AVX_INSTR pminub, mmx2, 0, 0, 1
1321 AVX_INSTR pminuw, sse4, 0, 0, 1
1322 AVX_INSTR pminud, sse4, 0, 0, 1
1323 AVX_INSTR pmovmskb, mmx2
1324 AVX_INSTR pmovsxbw, sse4
1325 AVX_INSTR pmovsxbd, sse4
1326 AVX_INSTR pmovsxbq, sse4
1327 AVX_INSTR pmovsxwd, sse4
1328 AVX_INSTR pmovsxwq, sse4
1329 AVX_INSTR pmovsxdq, sse4
1330 AVX_INSTR pmovzxbw, sse4
1331 AVX_INSTR pmovzxbd, sse4
1332 AVX_INSTR pmovzxbq, sse4
1333 AVX_INSTR pmovzxwd, sse4
1334 AVX_INSTR pmovzxwq, sse4
1335 AVX_INSTR pmovzxdq, sse4
1336 AVX_INSTR pmuldq, sse4, 0, 0, 1
1337 AVX_INSTR pmulhrsw, ssse3, 0, 0, 1
1338 AVX_INSTR pmulhuw, mmx2, 0, 0, 1
1339 AVX_INSTR pmulhw, mmx, 0, 0, 1
1340 AVX_INSTR pmullw, mmx, 0, 0, 1
1341 AVX_INSTR pmulld, sse4, 0, 0, 1
1342 AVX_INSTR pmuludq, sse2, 0, 0, 1
1343 AVX_INSTR por, mmx, 0, 0, 1
1344 AVX_INSTR psadbw, mmx2, 0, 0, 1
1345 AVX_INSTR pshufb, ssse3, 0, 0, 0
1346 AVX_INSTR pshufd, sse2
1347 AVX_INSTR pshufhw, sse2
1348 AVX_INSTR pshuflw, sse2
1349 AVX_INSTR psignb, ssse3, 0, 0, 0
1350 AVX_INSTR psignw, ssse3, 0, 0, 0
1351 AVX_INSTR psignd, ssse3, 0, 0, 0
1352 AVX_INSTR psllw, mmx, 0, 0, 0
1353 AVX_INSTR pslld, mmx, 0, 0, 0
1354 AVX_INSTR psllq, mmx, 0, 0, 0
1355 AVX_INSTR pslldq, sse2, 0, 0, 0
1356 AVX_INSTR psraw, mmx, 0, 0, 0
1357 AVX_INSTR psrad, mmx, 0, 0, 0
1358 AVX_INSTR psrlw, mmx, 0, 0, 0
1359 AVX_INSTR psrld, mmx, 0, 0, 0
1360 AVX_INSTR psrlq, mmx, 0, 0, 0
1361 AVX_INSTR psrldq, sse2, 0, 0, 0
1362 AVX_INSTR psubb, mmx, 0, 0, 0
1363 AVX_INSTR psubw, mmx, 0, 0, 0
1364 AVX_INSTR psubd, mmx, 0, 0, 0
1365 AVX_INSTR psubq, sse2, 0, 0, 0
1366 AVX_INSTR psubsb, mmx, 0, 0, 0
1367 AVX_INSTR psubsw, mmx, 0, 0, 0
1368 AVX_INSTR psubusb, mmx, 0, 0, 0
1369 AVX_INSTR psubusw, mmx, 0, 0, 0
1370 AVX_INSTR ptest, sse4
1371 AVX_INSTR punpckhbw, mmx, 0, 0, 0
1372 AVX_INSTR punpckhwd, mmx, 0, 0, 0
1373 AVX_INSTR punpckhdq, mmx, 0, 0, 0
1374 AVX_INSTR punpckhqdq, sse2, 0, 0, 0
1375 AVX_INSTR punpcklbw, mmx, 0, 0, 0
1376 AVX_INSTR punpcklwd, mmx, 0, 0, 0
1377 AVX_INSTR punpckldq, mmx, 0, 0, 0
1378 AVX_INSTR punpcklqdq, sse2, 0, 0, 0
1379 AVX_INSTR pxor, mmx, 0, 0, 1
1380 AVX_INSTR rcpps, sse, 1, 0, 0
1381 AVX_INSTR rcpss, sse, 1, 0, 0
1382 AVX_INSTR roundpd, sse4
1383 AVX_INSTR roundps, sse4
1384 AVX_INSTR roundsd, sse4
1385 AVX_INSTR roundss, sse4
1386 AVX_INSTR rsqrtps, sse, 1, 0, 0
1387 AVX_INSTR rsqrtss, sse, 1, 0, 0
1388 AVX_INSTR shufpd, sse2, 1, 1, 0
1389 AVX_INSTR shufps, sse, 1, 1, 0
1390 AVX_INSTR sqrtpd, sse2, 1, 0, 0
1391 AVX_INSTR sqrtps, sse, 1, 0, 0
1392 AVX_INSTR sqrtsd, sse2, 1, 0, 0
1393 AVX_INSTR sqrtss, sse, 1, 0, 0
1394 AVX_INSTR stmxcsr, sse
1395 AVX_INSTR subpd, sse2, 1, 0, 0
1396 AVX_INSTR subps, sse, 1, 0, 0
1397 AVX_INSTR subsd, sse2, 1, 0, 0
1398 AVX_INSTR subss, sse, 1, 0, 0
1399 AVX_INSTR ucomisd, sse2
1400 AVX_INSTR ucomiss, sse
1401 AVX_INSTR unpckhpd, sse2, 1, 0, 0
1402 AVX_INSTR unpckhps, sse, 1, 0, 0
1403 AVX_INSTR unpcklpd, sse2, 1, 0, 0
1404 AVX_INSTR unpcklps, sse, 1, 0, 0
1405 AVX_INSTR xorpd, sse2, 1, 0, 1
1406 AVX_INSTR xorps, sse, 1, 0, 1
1407
1408 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
1409 AVX_INSTR pfadd, 3dnow, 1, 0, 1
1410 AVX_INSTR pfsub, 3dnow, 1, 0, 0
1411 AVX_INSTR pfmul, 3dnow, 1, 0, 1
1412
1413 ; base-4 constants for shuffles
1414 %assign i 0
1415 %rep 256
1416     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
1417     %if j < 10
1418         CAT_XDEFINE q000, j, i
1419     %elif j < 100
1420         CAT_XDEFINE q00, j, i
1421     %elif j < 1000
1422         CAT_XDEFINE q0, j, i
1423     %else
1424         CAT_XDEFINE q, j, i
1425     %endif
1426 %assign i i+1
1427 %endrep
1428 %undef i
1429 %undef j
1430
1431 %macro FMA_INSTR 3
1432     %macro %1 4-7 %1, %2, %3
1433         %if cpuflag(xop)
1434             v%5 %1, %2, %3, %4
1435         %elifnidn %1, %4
1436             %6 %1, %2, %3
1437             %7 %1, %4
1438         %else
1439             %error non-xop emulation of ``%5 %1, %2, %3, %4'' is not supported
1440         %endif
1441     %endmacro
1442 %endmacro
1443
1444 FMA_INSTR  pmacsww,  pmullw, paddw
1445 FMA_INSTR  pmacsdd,  pmulld, paddd ; sse4 emulation
1446 FMA_INSTR pmacsdql,  pmuldq, paddq ; sse4 emulation
1447 FMA_INSTR pmadcswd, pmaddwd, paddd
1448
1449 ; convert FMA4 to FMA3 if possible
1450 %macro FMA4_INSTR 4
1451     %macro %1 4-8 %1, %2, %3, %4
1452         %if cpuflag(fma4)
1453             v%5 %1, %2, %3, %4
1454         %elifidn %1, %2
1455             v%6 %1, %4, %3 ; %1 = %1 * %3 + %4
1456         %elifidn %1, %3
1457             v%7 %1, %2, %4 ; %1 = %2 * %1 + %4
1458         %elifidn %1, %4
1459             v%8 %1, %2, %3 ; %1 = %2 * %3 + %1
1460         %else
1461             %error fma3 emulation of ``%5 %1, %2, %3, %4'' is not supported
1462         %endif
1463     %endmacro
1464 %endmacro
1465
1466 FMA4_INSTR fmaddpd, fmadd132pd, fmadd213pd, fmadd231pd
1467 FMA4_INSTR fmaddps, fmadd132ps, fmadd213ps, fmadd231ps
1468 FMA4_INSTR fmaddsd, fmadd132sd, fmadd213sd, fmadd231sd
1469 FMA4_INSTR fmaddss, fmadd132ss, fmadd213ss, fmadd231ss
1470
1471 FMA4_INSTR fmaddsubpd, fmaddsub132pd, fmaddsub213pd, fmaddsub231pd
1472 FMA4_INSTR fmaddsubps, fmaddsub132ps, fmaddsub213ps, fmaddsub231ps
1473 FMA4_INSTR fmsubaddpd, fmsubadd132pd, fmsubadd213pd, fmsubadd231pd
1474 FMA4_INSTR fmsubaddps, fmsubadd132ps, fmsubadd213ps, fmsubadd231ps
1475
1476 FMA4_INSTR fmsubpd, fmsub132pd, fmsub213pd, fmsub231pd
1477 FMA4_INSTR fmsubps, fmsub132ps, fmsub213ps, fmsub231ps
1478 FMA4_INSTR fmsubsd, fmsub132sd, fmsub213sd, fmsub231sd
1479 FMA4_INSTR fmsubss, fmsub132ss, fmsub213ss, fmsub231ss
1480
1481 FMA4_INSTR fnmaddpd, fnmadd132pd, fnmadd213pd, fnmadd231pd
1482 FMA4_INSTR fnmaddps, fnmadd132ps, fnmadd213ps, fnmadd231ps
1483 FMA4_INSTR fnmaddsd, fnmadd132sd, fnmadd213sd, fnmadd231sd
1484 FMA4_INSTR fnmaddss, fnmadd132ss, fnmadd213ss, fnmadd231ss
1485
1486 FMA4_INSTR fnmsubpd, fnmsub132pd, fnmsub213pd, fnmsub231pd
1487 FMA4_INSTR fnmsubps, fnmsub132ps, fnmsub213ps, fnmsub231ps
1488 FMA4_INSTR fnmsubsd, fnmsub132sd, fnmsub213sd, fnmsub231sd
1489 FMA4_INSTR fnmsubss, fnmsub132ss, fnmsub213ss, fnmsub231ss
1490
1491 ; workaround: vpbroadcastq is broken in x86_32 due to a yasm bug (fixed in 1.3.0)
1492 %ifdef __YASM_VER__
1493     %if __YASM_VERSION_ID__ < 0x01030000 && ARCH_X86_64 == 0
1494         %macro vpbroadcastq 2
1495             %if sizeof%1 == 16
1496                 movddup %1, %2
1497             %else
1498                 vbroadcastsd %1, %2
1499             %endif
1500         %endmacro
1501     %endif
1502 %endif