git.sesse.net Git - nageru/blob - smoothness.frag

   1 #version 450 core
   2
   3 in vec2 tc;
   4 out float smoothness_x, smoothness_y;
   5 const float eps_sq = 0.001 * 0.001;
   6
   7 uniform sampler2D flow_tex, diff_flow_tex;
   8
   9 // This must be a macro, since the offset needs to be a constant expression.
  10 #define get_flow(x_offs, y_offs) \
  11         (textureOffset(flow_tex, tc, ivec2((x_offs), (y_offs))).xy + \
  12         textureOffset(diff_flow_tex, tc, ivec2((x_offs), (y_offs))).xy)
  13
  14 float diffusivity(float u_x, float u_y, float v_x, float v_y)
  15 {
  16         return inversesqrt(u_x * u_x + u_y * u_y + v_x * v_x + v_y * v_y + eps_sq);
  17 }
  18
  19 void main()
  20 {
  21         float g, g_right, g_up;
  22
  23         // These are shared between some of the diffusivities.
  24         vec2 flow_0_0 = get_flow(0, 0);
  25         vec2 flow_1_1 = get_flow(1, 1);
  26
  27         // Find diffusivity (g) for this pixel, using central differences.
  28         {
  29                 vec2 uv_x = get_flow(1, 0) - get_flow(-1,  0);
  30                 vec2 uv_y = get_flow(0, 1) - get_flow( 0, -1);
  31                 g = diffusivity(uv_x.x, uv_y.x, uv_x.y, uv_y.y);
  32         }
  33
  34         // Now find diffusivity for the pixel to the right.
  35         {
  36                 vec2 uv_x = get_flow(2, 0) - flow_0_0;
  37                 vec2 uv_y = flow_1_1 - get_flow( 1, -1);
  38                 g_right = diffusivity(uv_x.x, uv_y.x, uv_x.y, uv_y.y);
  39         }
  40
  41         // And up.
  42         {
  43                 vec2 uv_x = flow_1_1 - get_flow(-1,  1);
  44                 vec2 uv_y = get_flow(0, 2) - flow_0_0;
  45                 g_up = diffusivity(uv_x.x, uv_y.x, uv_x.y, uv_y.y);
  46         }
  47
  48         smoothness_x = 0.5 * (g + g_right);
  49         smoothness_y = 0.5 * (g + g_up);
  50 }