git.sesse.net Git - skvidarsync/blob - bin/sync.pl

   1 #! /usr/bin/perl
   2 use strict;
   3 use warnings;
   4 no warnings qw(once);
   5 use Crypt::JWT;
   6 use JSON::XS;
   7 use LWP::UserAgent;
   8 use DBI;
   9 use POSIX;
  10 binmode STDOUT, ':utf8';
  11 binmode STDERR, ':utf8';
  12 use utf8;
  13
  14 # TODO:
  15 # - support non-fixed sheets
  16 # - detect moves between groups
  17
  18 require '../include/config.pm';
  19
  20 my @log = ();
  21
  22 sub get_oauth_bearer_token {
  23         my $ua = shift;
  24         my $now = time();
  25         my $jwt = JSON::XS::encode_json({
  26                 "iss" => $config::jwt_key->{'client_email'},
  27                 "scope" => "https://www.googleapis.com/auth/spreadsheets",
  28                 "aud" => "https://www.googleapis.com/oauth2/v4/token",
  29                 "exp" => $now + 1800,
  30                 "iat" => $now,
  31         });
  32         my $jws_token = Crypt::JWT::encode_jwt(payload=>$jwt, alg=>'RS256', key=>\$config::jwt_key->{'private_key'});
  33         my $response = $ua->post('https://www.googleapis.com/oauth2/v4/token', [
  34                 'grant_type' => 'urn:ietf:params:oauth:grant-type:jwt-bearer',
  35                 'assertion' => $jws_token ]);
  36         return JSON::XS::decode_json($response->decoded_content)->{'access_token'};
  37 }
  38
  39 sub get_slack_name {
  40         my ($ua, $userid) = @_;
  41         my $req = HTTP::Request->new('GET', 'https://slack.com/api/users.info?user=' . $userid, [
  42                'Authorization' => 'Bearer ' . $config::oauth_token
  43         ]);
  44         my $response = $ua->request($req);
  45         die $response->status_line if !$response->is_success;
  46
  47         my $user_json = JSON::XS::decode_json($response->decoded_content);
  48         die "Something went wrong: " . $response->decoded_content if (!defined($user_json) || !$user_json->{'ok'});
  49
  50         return $user_json->{'user'}{'real_name'};
  51 }
  52
  53 sub get_spreadsheet_name {
  54         my $cell = shift;
  55         my $name = $cell->{'userEnteredValue'}{'stringValue'};
  56         return undef if (!defined($name));
  57         return undef if ($name =~ /^G[1-4]\.[1-4]/);
  58         $name =~ s/🆕//;
  59         $name =~ s/\(.*\)//g;
  60         $name =~ s/\[.*\]//g;
  61         $name =~ s/ - .*//;
  62         $name =~ s/G\d\.\d?\??//;
  63         $name =~ s/\?//g;
  64         $name =~ s/\s*$//;
  65         $name =~ s/^\s*//;
  66         return $name;
  67 }
  68
  69 sub matches_name {
  70         my ($slack_name, $spreadsheet_name) = @_;
  71         if (lc($slack_name) eq lc($spreadsheet_name)) {
  72                 return 1;
  73         }
  74
  75         my @ap = split /\s+/, $slack_name;
  76         my @bp = split /\s+/, $spreadsheet_name;
  77         if (scalar @ap >= 2 && scalar @bp >= 2 && lc($ap[0]) eq lc($bp[0])) {
  78                 # First name matches, try to match some surname
  79                 my $found = 0;
  80                 for my $ai (1..$#ap) {
  81                         for my $bi (1..$#bp) {
  82                                 $found = 1 if (lc($ap[$ai]) eq lc($bp[$bi]));
  83                         }
  84                 }
  85                 if ($found) {
  86                         skv_log("Fuzzy-matchet $slack_name -> $spreadsheet_name.");
  87                         return 1;
  88                 }
  89         }
  90
  91         return 0;
  92 }
  93
  94 sub format_cell_names_for_seen {
  95         my $seen = shift;
  96         my @cells = map { chr(ord('A') + $_->[2]) . $_->[1] } @$seen;
  97         return join(', ', @cells);
  98 }
  99
 100 sub skv_log {
 101         my $msg = shift;
 102         print STDERR "$msg\n";
 103         push @log, $msg;
 104 }
 105
 106 sub serialize_skv_log_to_sheet {
 107         return {
 108                 updateCells => {
 109                         rows => [{
 110                                 values => [{
 111                                         userEnteredValue => { stringValue => join("\n", @log) }
 112                                 }]
 113                         }],
 114                         fields => 'userEnteredValue.stringValue',
 115                         range => {
 116                                 sheetId => $config::log_tab_id,
 117                                 startRowIndex => 0,
 118                                 endRowIndex => 1,
 119                                 startColumnIndex => 0,
 120                                 endColumnIndex => 1
 121                         }
 122                 }
 123         };
 124 }
 125
 126 sub sheet_batch_update {
 127         my ($ua, $token, @requests) = @_;
 128         my $update = {
 129                 requests => \@requests
 130         };
 131         my $response = $ua->post(
 132                 'https://sheets.googleapis.com/v4/spreadsheets/' . $config::sheet_id . ':batchUpdate?key=' . $config::gsheets_api_key,
 133                 Content => JSON::XS::encode_json($update),
 134                 Content_type => 'application/json;charset=UTF-8',
 135                 Authorization => 'Bearer ' . $token
 136         );
 137         die $response->decoded_content if !$response->is_success;
 138 }
 139
 140 skv_log("Siste sync startet: " . POSIX::ctime(time));
 141
 142 # Initialize the handles we need for communication.
 143 my $dbh = DBI->connect("dbi:Pg:dbname=$config::dbname;host=127.0.0.1", $config::dbuser, $config::dbpass, {RaiseError => 1})
 144         or die "Could not connect to Postgres: " . DBI->errstr;
 145 my $ua = LWP::UserAgent->new('SKVidarLang/1.0');
 146 my $token = get_oauth_bearer_token($ua);
 147
 148 # Find the newest message, and what it is linked to.
 149 # TODO: Support more than one, and test better for errors here.
 150 my $q = $dbh->prepare('select * from message_sheet_link where channel=? order by ts desc limit 1');
 151 $q->execute($config::invitation_channel);
 152 my $linkref = $q->fetchrow_hashref;
 153 my $invitation_ts = $linkref->{'ts'};
 154 my $wanted_sheet_title = $linkref->{'sheet_title'};
 155 die "Could not get newest sheet title" if (!defined($wanted_sheet_title));
 156
 157 # See if we have any spreadsheets that match this title.
 158 my $response = $ua->get('https://sheets.googleapis.com/v4/spreadsheets/' . $config::sheet_id . '?key=' . $config::gsheets_api_key . '&fields=sheets/properties',
 159         Authorization => 'Bearer ' . $token
 160 );
 161 my $sheets_json = JSON::XS::decode_json($response->decoded_content);
 162 my ($tab_name, $tab_id);
 163 for my $sheet (@{$sheets_json->{'sheets'}}) {
 164         my $title = $sheet->{'properties'}{'title'};
 165         my $sheet_id = $sheet->{'properties'}{'sheetId'};
 166         if ($title =~ /\Q$wanted_sheet_title\E/) {
 167                 skv_log("Synkroniserer ($config::invitation_channel, $invitation_ts) mot arket “$title” (fane-ID $sheet_id).");
 168                 $tab_name = $title;
 169                 $tab_id = $sheet_id;
 170                 last;
 171         }
 172 }
 173 if (!defined($tab_name)) {
 174         skv_log("Fant ikke noen fane med “$wanted_sheet_title” i navnet; kan ikke synkronisere.\n");
 175         sheet_batch_update($ua, $token, [ serialize_skv_log_to_sheet() ]);
 176         die;
 177 }
 178
 179 # Find everyone who are marked as attending on Slack (via reactions).
 180 $q = $dbh->prepare('SELECT DISTINCT userid FROM current_reactions WHERE channel=? AND ts=? AND reaction IN (\'heart\', \'open_mouth\')');
 181 $q->execute($config::invitation_channel, $invitation_ts);
 182 my @attending_userids = ();
 183 while (my $ref = $q->fetchrow_hashref) {
 184         push @attending_userids, $ref->{'userid'};
 185 }
 186
 187 # Get the list of all people in the sheet (we're going to need them soon anyway).
 188 $response = $ua->get('https://sheets.googleapis.com/v4/spreadsheets/' . $config::sheet_id . '?key=' . $config::gsheets_api_key . '&ranges=' . $tab_name . '!A9:Z5000&fields=sheets/data/rowData/values/userEnteredValue',
 189         Authorization => 'Bearer ' . $token
 190 );
 191 my $main_sheet_json = JSON::XS::decode_json($response->decoded_content);
 192
 193 # Duplicate detection
 194 my %seen_names = ();
 195 {
 196         my $main_sheet_rows = $main_sheet_json->{'sheets'}[0]{'data'}[0]{'rowData'};
 197         my $rowno = 9;
 198         for my $row (@$main_sheet_rows) {
 199                 my $colno = 0;
 200                 for my $val (@{$row->{'values'}}) {
 201                         my $name = get_spreadsheet_name($val);
 202                         if (defined($name)) {
 203                                 push @{$seen_names{lc $name}}, [$name, $rowno, $colno];
 204                         }
 205                         ++$colno;
 206                 }
 207                 ++$rowno;
 208         }
 209         for my $name (sort keys %seen_names) {
 210                 my $seen = $seen_names{$name};
 211                 if (scalar @$seen >= 2) {
 212                         my $exemplar = $seen->[0][0];
 213                         skv_log("Duplikat: $exemplar (" . format_cell_names_for_seen($seen) . ")");
 214                 }
 215         }
 216 }
 217
 218 # Get our existing Slack->name mapping, from the sheets.
 219 my %slack_userid_to_real_name = ();
 220 my %slack_userid_to_slack_name = ();
 221 my %slack_userid_to_row = ();
 222 my %real_name_to_slack_userid = ();
 223 $response = $ua->get('https://sheets.googleapis.com/v4/spreadsheets/' . $config::sheet_id . '?key=' . $config::gsheets_api_key . '&ranges=Slack-mapping!A5:C5000&fields=sheets/data/rowData/values/userEnteredValue',
 224         Authorization => 'Bearer ' . $token
 225 );
 226 my $mapping_sheet_json = JSON::XS::decode_json($response->decoded_content);
 227 my $mapping_sheet_rows = $mapping_sheet_json->{'sheets'}[0]{'data'}[0]{'rowData'};
 228 my $cur_row = 5;
 229 for my $row (@$mapping_sheet_rows) {
 230         my $slack_id = $row->{'values'}[0]{'userEnteredValue'}{'stringValue'};
 231         my $slack_name = $row->{'values'}[1]{'userEnteredValue'}{'stringValue'};
 232         my $real_name = get_spreadsheet_name($row->{'values'}[2]);  # TODO support more
 233         $slack_userid_to_row{$slack_id} = $cur_row++;
 234         next if (!defined($slack_name));
 235         $slack_userid_to_slack_name{$slack_id} = $slack_name;
 236         next if (!defined($real_name));
 237         $slack_userid_to_real_name{$slack_id} = $real_name;
 238         $real_name_to_slack_userid{$real_name} = $slack_id;
 239 }
 240
 241 # See which ones we don't have a mapping for, and look them up in Slack.
 242 # TODO: Use an append call instead of $cur_row?
 243 my @slack_mapping_updates = ();
 244 for my $userid (@attending_userids) {
 245         next if (exists($slack_userid_to_real_name{$userid}));
 246
 247         # Make sure they have a row in the spreadsheet.
 248         my $write_row;
 249         if (exists($slack_userid_to_row{$userid})) {
 250                 $write_row = $slack_userid_to_row{$userid};
 251         } else {
 252                 $write_row = $cur_row++;
 253                 $slack_userid_to_row{$userid} = $write_row;
 254                 push @slack_mapping_updates, {
 255                         range => "Slack-mapping!A$write_row:A$write_row",
 256                         values => [ [ $userid ]]
 257                 };
 258         }
 259
 260         # Fetch their Slack name if we don't already have it.
 261         my $slack_name;
 262         if (exists($slack_userid_to_slack_name{$userid})) {
 263                 $slack_name = $slack_userid_to_slack_name{$userid};
 264         } else {
 265                 $slack_userid_to_slack_name{$userid} = $slack_name;
 266                 $slack_name = get_slack_name($ua, $userid);
 267                 push @slack_mapping_updates, {
 268                         range => "Slack-mapping!B$write_row:B$write_row",
 269                         values => [ [ $slack_name ]]
 270                 };
 271                 $slack_userid_to_slack_name{$userid} = $slack_name;
 272         }
 273
 274         if (exists($seen_names{lc $slack_name})) {
 275                 # The name exists exactly, once or more, so it's a direct match and we ignore any fuzz.
 276                 $slack_userid_to_real_name{$userid} = $slack_name;
 277                 push @slack_mapping_updates, {
 278                         range => "Slack-mapping!C$write_row:C$write_row",
 279                         values => [ [ $slack_name ]]
 280                 };
 281         } else {
 282                 # Do a search through all the available names in the sheet to find an obvious(ish) match.
 283                 my @candidates = ();
 284                 my $main_sheet_rows = $main_sheet_json->{'sheets'}[0]{'data'}[0]{'rowData'};
 285                 for my $row (@$main_sheet_rows) {
 286                         for my $val (@{$row->{'values'}}) {
 287                                 my $name = get_spreadsheet_name($val);
 288                                 if (defined($name) && matches_name($slack_name, $name)) {
 289                                         push @candidates, $name;
 290                                 }
 291                         }
 292                 }
 293                 if ($#candidates == -1) {
 294                         skv_log("$slack_name ($userid) er påmeldt på Slack, men fant ikke et regneark-navn for dem.");
 295                 } elsif ($#candidates == 0) {
 296                         my $name = $candidates[0];
 297                         $slack_userid_to_real_name{$userid} = $name;
 298                         push @slack_mapping_updates, {
 299                                 range => "Slack-mapping!C$write_row:C$write_row",
 300                                 values => [ [ $name ]]
 301                         };
 302                 } else {
 303                         skv_log("$slack_name ($userid) er påmeldt på Slack, men hadde flere fuzzy-matcher; vet ikke hvilket regneark-navn som skal brukes.");
 304                 }
 305         }
 306 }
 307 my $update = {
 308         valueInputOption => 'USER_ENTERED',
 309         data => \@slack_mapping_updates
 310 };
 311 $response = $ua->post(
 312         'https://sheets.googleapis.com/v4/spreadsheets/' . $config::sheet_id . '/values:batchUpdate?key=' . $config::gsheets_api_key,
 313         Content => JSON::XS::encode_json($update),
 314         Content_type => 'application/json;charset=UTF-8',
 315         Authorization => 'Bearer ' . $token
 316 );
 317 die $response->decoded_content if (!$response->is_success);
 318
 319 # Find the list of names to mark yellow.
 320 my %want_names = ();
 321 my $main_sheet_rows = $main_sheet_json->{'sheets'}[0]{'data'}[0]{'rowData'};
 322 for my $userid (@attending_userids) {
 323         next if (!exists($slack_userid_to_real_name{$userid}));
 324         my $slack_name = $slack_userid_to_slack_name{$userid};
 325         my $real_name = $slack_userid_to_real_name{$userid};
 326
 327         # See if we can find them in the spreadsheet.
 328         if (!exists($seen_names{lc $real_name})) {
 329                 skv_log("$slack_name ($userid) er påmeldt på Slack, og er mappet til $real_name, men var ikke i noen gruppe.");
 330         } else {
 331                 my $seen = $seen_names{lc $real_name};
 332                 if (scalar @$seen >= 2) {
 333                         skv_log("$slack_name ($userid) er påmeldt på Slack, men står flere steder (se over); vet ikke hvilken celle som skal brukes.");
 334                 } else {
 335                         $want_names{$seen->[0][0]} = 1;
 336                 }
 337         }
 338 }
 339
 340 # Find the list of names we already marked yellow.
 341 my %have_names = ();
 342 $dbh->{AutoCommit} = 0;
 343 $dbh->do('SET TRANSACTION ISOLATION LEVEL SERIALIZABLE');
 344 $q = $dbh->prepare('SELECT name FROM applied WHERE channel=? AND ts=?');
 345 $q->execute($config::invitation_channel, $invitation_ts);
 346 while (my $ref = $q->fetchrow_hashref) {
 347         $have_names{$ref->{'name'}} = 1;
 348 }
 349
 350 # Find the diff between the two.
 351 my @diffs = ();
 352 for my $real_name (keys %want_names) {
 353         next if (exists($have_names{$real_name}));
 354         skv_log("Markerer at $real_name skal på trening.");
 355         push @diffs, [
 356                 $real_name,
 357                 {
 358                         backgroundColor => {
 359                                 red => 1,
 360                                 green => 1,
 361                                 blue => 0,
 362                                 alpha => 1
 363                         }
 364                 }
 365         ];
 366         $dbh->do('INSERT INTO applied (channel, ts, name) VALUES (?, ?, ?)', undef,
 367                 $config::invitation_channel, $invitation_ts, $real_name);
 368 }
 369 for my $real_name (keys %have_names) {
 370         next if (exists($want_names{$real_name}));
 371         skv_log("Fjerner at $real_name skal på trening.");
 372         push @diffs, [
 373                 $real_name,
 374                 {
 375                         backgroundColor => {
 376                                 red => 1,
 377                                 green => 1,
 378                                 blue => 1,
 379                                 alpha => 0
 380                         }
 381                 }
 382         ];
 383         $dbh->do('DELETE FROM applied WHERE channel=? AND ts=? AND name=?', undef,
 384                 $config::invitation_channel, $invitation_ts, $real_name);
 385 }
 386
 387 my @yellow_updates = ();
 388 if (scalar @diffs > 0) {
 389         # Now fill in the actual stuff.
 390         for my $diff (@diffs) {
 391                 my $real_name = $diff->[0];
 392
 393                 # See if we can find them in the spreadsheet.
 394                 # FIXME use seen_names
 395                 my $rowno = 8;  # zero-indexed
 396                 my $found = 0;
 397                 for my $row (@$main_sheet_rows) {
 398                         my $colno = 0;
 399                         for my $val (@{$row->{'values'}}) {
 400                                 my $name = get_spreadsheet_name($val);
 401                                 if (defined($name) && $real_name eq $name) {
 402                                         push @yellow_updates, {
 403                                                 updateCells => {
 404                                                         rows => [{
 405                                                                 values => [{
 406                                                                         userEnteredFormat => $diff->[1]
 407                                                                 }]
 408                                                         }],
 409                                                         fields => 'userEnteredFormat.backgroundColor',
 410                                                         range => {
 411                                                                 sheetId => $tab_id,
 412                                                                 startRowIndex => $rowno,
 413                                                                 endRowIndex => $rowno + 1,
 414                                                                 startColumnIndex => $colno,
 415                                                                 endColumnIndex => $colno + 1
 416                                                         }
 417                                                 }
 418                                         };
 419                                         $found = 1;
 420                                 }
 421                                 ++$colno;
 422                         }
 423                         ++$rowno;
 424                 }
 425
 426                 if ($found) {
 427                 } else {
 428                         skv_log("Ønsket å fjerne at $real_name skulle på trening, men de var ikke i regnearket lenger.");
 429                 }
 430         }
 431 }
 432
 433 # Add the reaction log. (This only takes into account the last change
 434 # for each user; earlier ones are irrelevant and don't count. But it
 435 # doesn't deduplicate across reactions. Meh.)
 436 $q = $dbh->prepare('select userid,event_type,reaction,to_char(event_ts,\'YYYY-mm-dd HH24:MI\') as event_ts from ( select distinct on (channel,ts,userid,reaction) userid,event_type,reaction,timestamptz \'1970-01-01 utc\' + event_ts::float * interval \'1 second\' as event_ts from reaction_log where channel=? and ts=? and reaction in (\'heart\',\'open_mouth\') order by channel,ts,userid,reaction,event_ts desc ) t1 where event_ts > current_timestamp - interval \'8 hours\' order by event_ts desc limit 50');
 437 $q->execute($config::invitation_channel, $invitation_ts);
 438 my @recent_changes = ();
 439 while (my $ref = $q->fetchrow_hashref) {
 440         my $msg = $ref->{'event_ts'};
 441         if ($ref->{'event_type'} eq 'reaction_added') {
 442                 $msg .= ' +';
 443         } else {
 444                 $msg .= ' –';
 445         }
 446         if ($ref->{'reaction'} eq 'open_mouth') {
 447                 $msg .= '😮';
 448         } else {
 449                 $msg .= '❤️';
 450         }
 451         $msg .= ' ';
 452         if (exists($slack_userid_to_real_name{$ref->{'userid'}})) {
 453                 $msg .= $slack_userid_to_real_name{$ref->{'userid'}};
 454         } elsif (exists($slack_userid_to_slack_name{$ref->{'userid'}})) {
 455                 $msg .= $slack_userid_to_slack_name{$ref->{'userid'}} . ' (fant ikke regneark-navn)';
 456         } else {
 457                 # Should only happen if we didn't see the initial reaction_add, only reaction_remove.
 458                 $msg .= $ref->{'userid'} . ' (fant ikke Slack-navn)';
 459         }
 460         push @recent_changes, { values => [{ userEnteredValue => { stringValue => $msg } }] };
 461 }
 462 while (scalar @recent_changes < 50) {
 463         push @recent_changes, { values => [{ userEnteredValue => { stringValue => '' } }] };
 464 }
 465 push @yellow_updates, {
 466         updateCells => {
 467                 rows => \@recent_changes,
 468                 fields => 'userEnteredValue.stringValue',
 469                 range => {
 470                         sheetId => $config::log_tab_id,
 471                         startRowIndex => 4,
 472                         endRowIndex => 4 + scalar @recent_changes,
 473                         startColumnIndex => 0,
 474                         endColumnIndex => 1
 475                 }
 476         }
 477 };
 478
 479 # Push the final set of updates (including the log).
 480 skv_log("Ferdig.");
 481 push @yellow_updates, serialize_skv_log_to_sheet();
 482 sheet_batch_update($ua, $token, \@yellow_updates);
 483 $dbh->commit;