git.sesse.net Git - x264/blob - common/x86/dct-32.asm

   1 ;*****************************************************************************
   2 ;* dct-32.asm: x86_32 transform and zigzag
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2003-2011 x264 project
   5 ;*
   6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
   7 ;*          Holger Lubitz <holger@lubitz.org>
   8 ;*          Laurent Aimar <fenrir@via.ecp.fr>
   9 ;*          Min Chen <chenm001.163.com>
  10 ;*          Christian Heine <sennindemokrit@gmx.net>
  11 ;*
  12 ;* This program is free software; you can redistribute it and/or modify
  13 ;* it under the terms of the GNU General Public License as published by
  14 ;* the Free Software Foundation; either version 2 of the License, or
  15 ;* (at your option) any later version.
  16 ;*
  17 ;* This program is distributed in the hope that it will be useful,
  18 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;* GNU General Public License for more details.
  21 ;*
  22 ;* You should have received a copy of the GNU General Public License
  23 ;* along with this program; if not, write to the Free Software
  24 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02111, USA.
  25 ;*
  26 ;* This program is also available under a commercial proprietary license.
  27 ;* For more information, contact us at licensing@x264.com.
  28 ;*****************************************************************************
  29
  30 %include "x86inc.asm"
  31 %include "x86util.asm"
  32
  33 SECTION .text
  34
  35 %ifndef HIGH_BIT_DEPTH
  36 cextern pw_32
  37 cextern hsub_mul
  38
  39 ; in: m0..m7
  40 ; out: 0,4,6 in mem, rest in regs
  41 %macro DCT8_1D 9
  42     SUMSUB_BA w, %8, %1      ; %8 = s07,  %1 = d07
  43     SUMSUB_BA w, %7, %2      ; %7 = s16,  %2 = d16
  44     SUMSUB_BA w, %6, %3      ; %6 = s25,  %3 = d25
  45     SUMSUB_BA w, %5, %4      ; %5 = s34,  %4 = d34
  46     SUMSUB_BA w, %5, %8      ; %5 = a0,   %8 = a2
  47     SUMSUB_BA w, %6, %7      ; %6 = a1,   %7 = a3
  48     SUMSUB_BA w, %6, %5      ; %6 = dst0, %5 = dst4
  49     mova    [%9+0x00], m%6
  50     mova    [%9+0x40], m%5
  51     psraw   m%6, m%7, 1      ; a3>>1
  52     paddw   m%6, m%8         ; a2 + (a3>>1)
  53     psraw   m%8, 1           ; a2>>1
  54     psubw   m%8, m%7         ; (a2>>1) - a3
  55     mova    [%9+0x60], m%8
  56     psraw   m%5, m%3, 1
  57     paddw   m%5, m%3         ; d25+(d25>>1)
  58     psubw   m%7, m%1, m%4    ; a5 = d07-d34-(d25+(d25>>1))
  59     psubw   m%7, m%5
  60     psraw   m%5, m%2, 1
  61     paddw   m%5, m%2         ; d16+(d16>>1)
  62     paddw   m%8, m%1, m%4
  63     psubw   m%8, m%5         ; a6 = d07+d34-(d16+(d16>>1))
  64     psraw   m%5, m%1, 1
  65     paddw   m%5, m%1         ; d07+(d07>>1)
  66     paddw   m%5, m%2
  67     paddw   m%5, m%3         ; a4 = d16+d25+(d07+(d07>>1))
  68     psraw   m%1, m%4, 1
  69     paddw   m%1, m%4         ; d34+(d34>>1)
  70     paddw   m%1, m%2
  71     psubw   m%1, m%3         ; a7 = d16-d25+(d34+(d34>>1))
  72     psraw   m%4, m%1, 2
  73     paddw   m%4, m%5         ; a4 + (a7>>2)
  74     psraw   m%3, m%8, 2
  75     paddw   m%3, m%7         ; a5 + (a6>>2)
  76     psraw   m%5, 2
  77     psraw   m%7, 2
  78     psubw   m%5, m%1         ; (a4>>2) - a7
  79     psubw   m%8, m%7         ; a6 - (a5>>2)
  80     SWAP %2, %4, %3, %6, %8, %5
  81 %endmacro
  82
  83 ; in: 0,4 in mem, rest in regs
  84 ; out: m0..m7
  85 %macro IDCT8_1D 9
  86     psraw     m%1, m%3, 1
  87     psraw     m%5, m%7, 1
  88     psubw     m%1, m%7
  89     paddw     m%5, m%3
  90     psraw     m%7, m%2, 1
  91     paddw     m%7, m%2
  92     paddw     m%7, m%4
  93     paddw     m%7, m%6
  94     psraw     m%3, m%6, 1
  95     paddw     m%3, m%6
  96     paddw     m%3, m%8
  97     psubw     m%3, m%2
  98     psubw     m%2, m%4
  99     psubw     m%6, m%4
 100     paddw     m%2, m%8
 101     psubw     m%6, m%8
 102     psraw     m%4, 1
 103     psraw     m%8, 1
 104     psubw     m%2, m%4
 105     psubw     m%6, m%8
 106     psraw     m%4, m%7, 2
 107     psraw     m%8, m%3, 2
 108     paddw     m%4, m%6
 109     paddw     m%8, m%2
 110     psraw     m%6, 2
 111     psraw     m%2, 2
 112     psubw     m%7, m%6
 113     psubw     m%2, m%3
 114     mova      m%3, [%9+0x00]
 115     mova      m%6, [%9+0x40]
 116     SUMSUB_BA w, %6, %3
 117     SUMSUB_BA w, %5, %6
 118     SUMSUB_BA w, %1, %3
 119     SUMSUB_BA w, %7, %5
 120     SUMSUB_BA w, %2, %1
 121     SUMSUB_BA w, %8, %3
 122     SUMSUB_BA w, %4, %6
 123     SWAP %1, %3
 124     SWAP %5, %7
 125     SWAP %1, %5, %6
 126     SWAP %3, %8, %7
 127 %endmacro
 128
 129 INIT_MMX
 130 ALIGN 16
 131 load_diff_4x8_mmx:
 132     LOAD_DIFF m0, m7, none, [r1+0*FENC_STRIDE], [r2+0*FDEC_STRIDE]
 133     LOAD_DIFF m1, m7, none, [r1+1*FENC_STRIDE], [r2+1*FDEC_STRIDE]
 134     LOAD_DIFF m2, m7, none, [r1+2*FENC_STRIDE], [r2+2*FDEC_STRIDE]
 135     LOAD_DIFF m3, m7, none, [r1+3*FENC_STRIDE], [r2+3*FDEC_STRIDE]
 136     LOAD_DIFF m4, m7, none, [r1+4*FENC_STRIDE], [r2+4*FDEC_STRIDE]
 137     LOAD_DIFF m5, m7, none, [r1+5*FENC_STRIDE], [r2+5*FDEC_STRIDE]
 138     movq  [r0], m0
 139     LOAD_DIFF m6, m7, none, [r1+6*FENC_STRIDE], [r2+6*FDEC_STRIDE]
 140     LOAD_DIFF m7, m0, none, [r1+7*FENC_STRIDE], [r2+7*FDEC_STRIDE]
 141     movq  m0, [r0]
 142     ret
 143
 144 cglobal dct8_mmx
 145     DCT8_1D 0,1,2,3,4,5,6,7,r0
 146     SAVE_MM_PERMUTATION
 147     ret
 148
 149 %macro SPILL_SHUFFLE 3-* ; ptr, list of regs, list of memory offsets
 150     %xdefine %%base %1
 151     %rep %0/2
 152     %xdefine %%tmp m%2
 153     %rotate %0/2
 154     mova [%%base + %2*16], %%tmp
 155     %rotate 1-%0/2
 156     %endrep
 157 %endmacro
 158
 159 %macro UNSPILL_SHUFFLE 3-*
 160     %xdefine %%base %1
 161     %rep %0/2
 162     %xdefine %%tmp m%2
 163     %rotate %0/2
 164     mova %%tmp, [%%base + %2*16]
 165     %rotate 1-%0/2
 166     %endrep
 167 %endmacro
 168
 169 %macro SPILL 2+ ; assume offsets are the same as reg numbers
 170     SPILL_SHUFFLE %1, %2, %2
 171 %endmacro
 172
 173 %macro UNSPILL 2+
 174     UNSPILL_SHUFFLE %1, %2, %2
 175 %endmacro
 176
 177 ;-----------------------------------------------------------------------------
 178 ; void sub8x8_dct8( int16_t dct[8][8], uint8_t *pix1, uint8_t *pix2 )
 179 ;-----------------------------------------------------------------------------
 180 cglobal sub8x8_dct8_mmx, 3,3
 181 global sub8x8_dct8_mmx.skip_prologue
 182 .skip_prologue:
 183     RESET_MM_PERMUTATION
 184     call load_diff_4x8_mmx
 185     call dct8_mmx
 186     UNSPILL r0, 0
 187     TRANSPOSE4x4W 0,1,2,3,4
 188     SPILL r0, 0,1,2,3
 189     UNSPILL r0, 4,6
 190     TRANSPOSE4x4W 4,5,6,7,0
 191     SPILL r0, 4,5,6,7
 192     RESET_MM_PERMUTATION
 193     add   r1, 4
 194     add   r2, 4
 195     add   r0, 8
 196     call load_diff_4x8_mmx
 197     sub   r1, 4
 198     sub   r2, 4
 199     call dct8_mmx
 200     sub   r0, 8
 201     UNSPILL r0+8, 4,6
 202     TRANSPOSE4x4W 4,5,6,7,0
 203     SPILL r0+8, 4,5,6,7
 204     UNSPILL r0+8, 0
 205     TRANSPOSE4x4W 0,1,2,3,5
 206     UNSPILL r0, 4,5,6,7
 207     SPILL_SHUFFLE r0, 0,1,2,3, 4,5,6,7
 208     movq  mm4, m6 ; depends on the permutation to not produce conflicts
 209     movq  mm0, m4
 210     movq  mm1, m5
 211     movq  mm2, mm4
 212     movq  mm3, m7
 213     RESET_MM_PERMUTATION
 214     UNSPILL r0+8, 4,5,6,7
 215     add   r0, 8
 216     call dct8_mmx
 217     sub   r0, 8
 218     SPILL r0+8, 1,2,3,5,7
 219     RESET_MM_PERMUTATION
 220     UNSPILL r0, 0,1,2,3,4,5,6,7
 221     call dct8_mmx
 222     SPILL r0, 1,2,3,5,7
 223     ret
 224
 225 cglobal idct8_mmx
 226     IDCT8_1D 0,1,2,3,4,5,6,7,r1
 227     SAVE_MM_PERMUTATION
 228     ret
 229
 230 %macro ADD_STORE_ROW 3
 231     movq  m1, [r0+%1*FDEC_STRIDE]
 232     punpckhbw m2, m1, m0
 233     punpcklbw m1, m0
 234     paddw m1, %2
 235     paddw m2, %3
 236     packuswb m1, m2
 237     movq  [r0+%1*FDEC_STRIDE], m1
 238 %endmacro
 239
 240 ;-----------------------------------------------------------------------------
 241 ; void add8x8_idct8( uint8_t *dst, int16_t dct[8][8] )
 242 ;-----------------------------------------------------------------------------
 243 cglobal add8x8_idct8_mmx, 2,2
 244 global add8x8_idct8_mmx.skip_prologue
 245 .skip_prologue:
 246     INIT_MMX
 247     add word [r1], 32
 248     UNSPILL r1, 1,2,3,5,6,7
 249     call idct8_mmx
 250     SPILL r1, 7
 251     TRANSPOSE4x4W 0,1,2,3,7
 252     SPILL r1, 0,1,2,3
 253     UNSPILL r1, 7
 254     TRANSPOSE4x4W 4,5,6,7,0
 255     SPILL r1, 4,5,6,7
 256     INIT_MMX
 257     UNSPILL r1+8, 1,2,3,5,6,7
 258     add r1, 8
 259     call idct8_mmx
 260     sub r1, 8
 261     SPILL r1+8, 7
 262     TRANSPOSE4x4W 0,1,2,3,7
 263     SPILL r1+8, 0,1,2,3
 264     UNSPILL r1+8, 7
 265     TRANSPOSE4x4W 4,5,6,7,0
 266     SPILL r1+8, 4,5,6,7
 267     INIT_MMX
 268     movq  m3, [r1+0x08]
 269     movq  m0, [r1+0x40]
 270     movq  [r1+0x40], m3
 271     movq  [r1+0x08], m0
 272     ; memory layout at this time:
 273     ; A0------ A1------
 274     ; B0------ F0------
 275     ; C0------ G0------
 276     ; D0------ H0------
 277     ; E0------ E1------
 278     ; B1------ F1------
 279     ; C1------ G1------
 280     ; D1------ H1------
 281     UNSPILL_SHUFFLE r1, 1,2,3, 5,6,7
 282     UNSPILL r1+8, 5,6,7
 283     add r1, 8
 284     call idct8_mmx
 285     sub r1, 8
 286     psraw m0, 6
 287     psraw m1, 6
 288     psraw m2, 6
 289     psraw m3, 6
 290     psraw m4, 6
 291     psraw m5, 6
 292     psraw m6, 6
 293     psraw m7, 6
 294     movq  [r1+0x08], m0 ; mm4
 295     movq  [r1+0x48], m4 ; mm5
 296     movq  [r1+0x58], m5 ; mm0
 297     movq  [r1+0x68], m6 ; mm2
 298     movq  [r1+0x78], m7 ; mm6
 299     movq  mm5, [r1+0x18]
 300     movq  mm6, [r1+0x28]
 301     movq  [r1+0x18], m1 ; mm1
 302     movq  [r1+0x28], m2 ; mm7
 303     movq  mm7, [r1+0x38]
 304     movq  [r1+0x38], m3 ; mm3
 305     movq  mm1, [r1+0x10]
 306     movq  mm2, [r1+0x20]
 307     movq  mm3, [r1+0x30]
 308     call idct8_mmx
 309     psraw m0, 6
 310     psraw m1, 6
 311     psraw m2, 6
 312     psraw m3, 6
 313     psraw m4, 6
 314     psraw m5, 6
 315     psraw m6, 6
 316     psraw m7, 6
 317     SPILL r1, 0,1,2
 318     pxor  m0, m0
 319     ADD_STORE_ROW 0, [r1+0x00], [r1+0x08]
 320     ADD_STORE_ROW 1, [r1+0x10], [r1+0x18]
 321     ADD_STORE_ROW 2, [r1+0x20], [r1+0x28]
 322     ADD_STORE_ROW 3, m3, [r1+0x38]
 323     ADD_STORE_ROW 4, m4, [r1+0x48]
 324     ADD_STORE_ROW 5, m5, [r1+0x58]
 325     ADD_STORE_ROW 6, m6, [r1+0x68]
 326     ADD_STORE_ROW 7, m7, [r1+0x78]
 327     ret
 328
 329 %macro DCT_SUB8 0
 330 cglobal sub8x8_dct, 3,3
 331     add r2, 4*FDEC_STRIDE
 332 global current_function %+ .skip_prologue
 333 .skip_prologue:
 334 %if cpuflag(ssse3)
 335     mova m7, [hsub_mul]
 336 %endif
 337     LOAD_DIFF8x4 0, 1, 2, 3, 6, 7, r1, r2-4*FDEC_STRIDE
 338     SPILL r0, 1,2
 339     SWAP 2, 7
 340     LOAD_DIFF8x4 4, 5, 6, 7, 1, 2, r1, r2-4*FDEC_STRIDE
 341     UNSPILL r0, 1
 342     SPILL r0, 7
 343     SWAP 2, 7
 344     UNSPILL r0, 2
 345     DCT4_1D 0, 1, 2, 3, 7
 346     TRANSPOSE2x4x4W 0, 1, 2, 3, 7
 347     UNSPILL r0, 7
 348     SPILL r0, 2
 349     DCT4_1D 4, 5, 6, 7, 2
 350     TRANSPOSE2x4x4W 4, 5, 6, 7, 2
 351     UNSPILL r0, 2
 352     SPILL r0, 6
 353     DCT4_1D 0, 1, 2, 3, 6
 354     UNSPILL r0, 6
 355     STORE_DCT 0, 1, 2, 3, r0, 0
 356     DCT4_1D 4, 5, 6, 7, 3
 357     STORE_DCT 4, 5, 6, 7, r0, 64
 358     ret
 359
 360 ;-----------------------------------------------------------------------------
 361 ; void sub8x8_dct8( int16_t dct[8][8], uint8_t *pix1, uint8_t *pix2 )
 362 ;-----------------------------------------------------------------------------
 363 cglobal sub8x8_dct8, 3,3
 364     add r2, 4*FDEC_STRIDE
 365 global current_function %+ .skip_prologue
 366 .skip_prologue:
 367 %if cpuflag(ssse3)
 368     mova m7, [hsub_mul]
 369     LOAD_DIFF8x4 0, 1, 2, 3, 4, 7, r1, r2-4*FDEC_STRIDE
 370     SPILL r0, 0,1
 371     SWAP 1, 7
 372     LOAD_DIFF8x4 4, 5, 6, 7, 0, 1, r1, r2-4*FDEC_STRIDE
 373     UNSPILL r0, 0,1
 374 %else
 375     LOAD_DIFF m0, m7, none, [r1+0*FENC_STRIDE], [r2-4*FDEC_STRIDE]
 376     LOAD_DIFF m1, m7, none, [r1+1*FENC_STRIDE], [r2-3*FDEC_STRIDE]
 377     LOAD_DIFF m2, m7, none, [r1+2*FENC_STRIDE], [r2-2*FDEC_STRIDE]
 378     LOAD_DIFF m3, m7, none, [r1+3*FENC_STRIDE], [r2-1*FDEC_STRIDE]
 379     LOAD_DIFF m4, m7, none, [r1+4*FENC_STRIDE], [r2+0*FDEC_STRIDE]
 380     LOAD_DIFF m5, m7, none, [r1+5*FENC_STRIDE], [r2+1*FDEC_STRIDE]
 381     SPILL r0, 0
 382     LOAD_DIFF m6, m7, none, [r1+6*FENC_STRIDE], [r2+2*FDEC_STRIDE]
 383     LOAD_DIFF m7, m0, none, [r1+7*FENC_STRIDE], [r2+3*FDEC_STRIDE]
 384     UNSPILL r0, 0
 385 %endif
 386     DCT8_1D 0,1,2,3,4,5,6,7,r0
 387     UNSPILL r0, 0,4
 388     TRANSPOSE8x8W 0,1,2,3,4,5,6,7,[r0+0x60],[r0+0x40],1
 389     UNSPILL r0, 4
 390     DCT8_1D 0,1,2,3,4,5,6,7,r0
 391     SPILL r0, 1,2,3,5,7
 392     ret
 393 %endmacro
 394
 395 INIT_XMM sse2
 396 %define movdqa movaps
 397 %define punpcklqdq movlhps
 398 DCT_SUB8
 399 %undef movdqa
 400 %undef punpcklqdq
 401 INIT_XMM ssse3
 402 DCT_SUB8
 403 INIT_XMM avx
 404 DCT_SUB8
 405
 406 ;-----------------------------------------------------------------------------
 407 ; void add8x8_idct( uint8_t *pix, int16_t dct[4][4][4] )
 408 ;-----------------------------------------------------------------------------
 409 %macro ADD8x8 0
 410 cglobal add8x8_idct, 2,2
 411     add r0, 4*FDEC_STRIDE
 412 global current_function %+ .skip_prologue
 413 .skip_prologue:
 414     UNSPILL_SHUFFLE r1, 0,2,1,3, 0,1,2,3
 415     SBUTTERFLY qdq, 0, 1, 4
 416     SBUTTERFLY qdq, 2, 3, 4
 417     UNSPILL_SHUFFLE r1, 4,6,5,7, 4,5,6,7
 418     SPILL r1, 0
 419     SBUTTERFLY qdq, 4, 5, 0
 420     SBUTTERFLY qdq, 6, 7, 0
 421     UNSPILL r1,0
 422     IDCT4_1D w,0,1,2,3,r1
 423     SPILL r1, 4
 424     TRANSPOSE2x4x4W 0,1,2,3,4
 425     UNSPILL r1, 4
 426     IDCT4_1D w,4,5,6,7,r1
 427     SPILL r1, 0
 428     TRANSPOSE2x4x4W 4,5,6,7,0
 429     UNSPILL r1, 0
 430     paddw m0, [pw_32]
 431     IDCT4_1D w,0,1,2,3,r1
 432     paddw m4, [pw_32]
 433     IDCT4_1D w,4,5,6,7,r1
 434     SPILL r1, 6,7
 435     pxor m7, m7
 436     DIFFx2 m0, m1, m6, m7, [r0-4*FDEC_STRIDE], [r0-3*FDEC_STRIDE]; m5
 437     DIFFx2 m2, m3, m6, m7, [r0-2*FDEC_STRIDE], [r0-1*FDEC_STRIDE]; m5
 438     UNSPILL_SHUFFLE r1, 0,2, 6,7
 439     DIFFx2 m4, m5, m6, m7, [r0+0*FDEC_STRIDE], [r0+1*FDEC_STRIDE]; m5
 440     DIFFx2 m0, m2, m6, m7, [r0+2*FDEC_STRIDE], [r0+3*FDEC_STRIDE]; m5
 441     STORE_IDCT m1, m3, m5, m2
 442     ret
 443 %endmacro ; ADD8x8
 444
 445 INIT_XMM sse2
 446 ADD8x8
 447 INIT_XMM avx
 448 ADD8x8
 449
 450 ;-----------------------------------------------------------------------------
 451 ; void add8x8_idct8( uint8_t *p_dst, int16_t dct[8][8] )
 452 ;-----------------------------------------------------------------------------
 453 %macro ADD8x8_IDCT8 0
 454 cglobal add8x8_idct8, 2,2
 455     add r0, 4*FDEC_STRIDE
 456 global current_function %+ .skip_prologue
 457 .skip_prologue:
 458     UNSPILL r1, 1,2,3,5,6,7
 459     IDCT8_1D   0,1,2,3,4,5,6,7,r1
 460     SPILL r1, 6
 461     TRANSPOSE8x8W 0,1,2,3,4,5,6,7,[r1+0x60],[r1+0x40],1
 462     paddw      m0, [pw_32]
 463     SPILL r1, 0
 464     IDCT8_1D   0,1,2,3,4,5,6,7,r1
 465     SPILL r1, 6,7
 466     pxor       m7, m7
 467     DIFFx2 m0, m1, m6, m7, [r0-4*FDEC_STRIDE], [r0-3*FDEC_STRIDE]; m5
 468     DIFFx2 m2, m3, m6, m7, [r0-2*FDEC_STRIDE], [r0-1*FDEC_STRIDE]; m5
 469     UNSPILL_SHUFFLE r1, 0,2, 6,7
 470     DIFFx2 m4, m5, m6, m7, [r0+0*FDEC_STRIDE], [r0+1*FDEC_STRIDE]; m5
 471     DIFFx2 m0, m2, m6, m7, [r0+2*FDEC_STRIDE], [r0+3*FDEC_STRIDE]; m5
 472     STORE_IDCT m1, m3, m5, m2
 473     ret
 474 %endmacro ; ADD8x8_IDCT8
 475
 476 INIT_XMM sse2
 477 ADD8x8_IDCT8
 478 INIT_XMM avx
 479 ADD8x8_IDCT8
 480 %endif ; !HIGH_BIT_DEPTH