git.sesse.net Git - x264/blob - common/x86/x86inc.asm

   1 ;*****************************************************************************
   2 ;* x86inc.asm
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2005-2008 x264 project
   5 ;*
   6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
   7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
   8 ;*
   9 ;* Permission to use, copy, modify, and/or distribute this software for any
  10 ;* purpose with or without fee is hereby granted, provided that the above
  11 ;* copyright notice and this permission notice appear in all copies.
  12 ;*
  13 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  14 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  15 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  16 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  17 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  18 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  19 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  20 ;*****************************************************************************
  21
  22 ; This is a header file for the x264ASM assembly language, which uses
  23 ; NASM/YASM syntax combined with a large number of macros to provide easy
  24 ; abstraction between different calling conventions (x86_32, win64, linux64).
  25 ; It also has various other useful features to simplify writing the kind of
  26 ; DSP functions that are most often used in x264.
  27
  28 ; Unlike the rest of x264, this file is available under an ISC license, as it
  29 ; has significant usefulness outside of x264 and we want it to be available
  30 ; to the largest audience possible.  Of course, if you modify it for your own
  31 ; purposes to add a new feature, we strongly encourage contributing a patch
  32 ; as this feature might be useful for others as well.  Send patches or ideas
  33 ; to x264-devel@videolan.org .
  34
  35 %define program_name x264
  36
  37 %ifdef ARCH_X86_64
  38     %ifidn __OUTPUT_FORMAT__,win32
  39         %define WIN64
  40     %else
  41         %define UNIX64
  42     %endif
  43 %endif
  44
  45 %ifdef PREFIX
  46     %define mangle(x) _ %+ x
  47 %else
  48     %define mangle(x) x
  49 %endif
  50
  51 ; FIXME: All of the 64bit asm functions that take a stride as an argument
  52 ; via register, assume that the high dword of that register is filled with 0.
  53 ; This is true in practice (since we never do any 64bit arithmetic on strides,
  54 ; and x264's strides are all positive), but is not guaranteed by the ABI.
  55
  56 ; Name of the .rodata section.
  57 ; Kludge: Something on OS X fails to align .rodata even given an align attribute,
  58 ; so use a different read-only section.
  59 %macro SECTION_RODATA 0-1 16
  60     %ifidn __OUTPUT_FORMAT__,macho64
  61         SECTION .text align=%1
  62     %elifidn __OUTPUT_FORMAT__,macho
  63         SECTION .text align=%1
  64         fakegot:
  65     %else
  66         SECTION .rodata align=%1
  67     %endif
  68 %endmacro
  69
  70 %ifdef WIN64
  71     %define PIC
  72 %elifndef ARCH_X86_64
  73 ; x86_32 doesn't require PIC.
  74 ; Some distros prefer shared objects to be PIC, but nothing breaks if
  75 ; the code contains a few textrels, so we'll skip that complexity.
  76     %undef PIC
  77 %endif
  78 %ifdef PIC
  79     default rel
  80 %endif
  81
  82 ; Macros to eliminate most code duplication between x86_32 and x86_64:
  83 ; Currently this works only for leaf functions which load all their arguments
  84 ; into registers at the start, and make no other use of the stack. Luckily that
  85 ; covers most of x264's asm.
  86
  87 ; PROLOGUE:
  88 ; %1 = number of arguments. loads them from stack if needed.
  89 ; %2 = number of registers used. pushes callee-saved regs if needed.
  90 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
  91 ; %4 = list of names to define to registers
  92 ; PROLOGUE can also be invoked by adding the same options to cglobal
  93
  94 ; e.g.
  95 ; cglobal foo, 2,3,0, dst, src, tmp
  96 ; declares a function (foo), taking two args (dst and src) and one local variable (tmp)
  97
  98 ; TODO Some functions can use some args directly from the stack. If they're the
  99 ; last args then you can just not declare them, but if they're in the middle
 100 ; we need more flexible macro.
 101
 102 ; RET:
 103 ; Pops anything that was pushed by PROLOGUE
 104
 105 ; REP_RET:
 106 ; Same, but if it doesn't pop anything it becomes a 2-byte ret, for athlons
 107 ; which are slow when a normal ret follows a branch.
 108
 109 ; registers:
 110 ; rN and rNq are the native-size register holding function argument N
 111 ; rNd, rNw, rNb are dword, word, and byte size
 112 ; rNm is the original location of arg N (a register or on the stack), dword
 113 ; rNmp is native size
 114
 115 %macro DECLARE_REG 6
 116     %define r%1q %2
 117     %define r%1d %3
 118     %define r%1w %4
 119     %define r%1b %5
 120     %define r%1m %6
 121     %ifid %6 ; i.e. it's a register
 122         %define r%1mp %2
 123     %elifdef ARCH_X86_64 ; memory
 124         %define r%1mp qword %6
 125     %else
 126         %define r%1mp dword %6
 127     %endif
 128     %define r%1  %2
 129 %endmacro
 130
 131 %macro DECLARE_REG_SIZE 2
 132     %define r%1q r%1
 133     %define e%1q r%1
 134     %define r%1d e%1
 135     %define e%1d e%1
 136     %define r%1w %1
 137     %define e%1w %1
 138     %define r%1b %2
 139     %define e%1b %2
 140 %ifndef ARCH_X86_64
 141     %define r%1  e%1
 142 %endif
 143 %endmacro
 144
 145 DECLARE_REG_SIZE ax, al
 146 DECLARE_REG_SIZE bx, bl
 147 DECLARE_REG_SIZE cx, cl
 148 DECLARE_REG_SIZE dx, dl
 149 DECLARE_REG_SIZE si, sil
 150 DECLARE_REG_SIZE di, dil
 151 DECLARE_REG_SIZE bp, bpl
 152
 153 ; t# defines for when per-arch register allocation is more complex than just function arguments
 154
 155 %macro DECLARE_REG_TMP 1-*
 156     %assign %%i 0
 157     %rep %0
 158         CAT_XDEFINE t, %%i, r%1
 159         %assign %%i %%i+1
 160         %rotate 1
 161     %endrep
 162 %endmacro
 163
 164 %macro DECLARE_REG_TMP_SIZE 0-*
 165     %rep %0
 166         %define t%1q t%1 %+ q
 167         %define t%1d t%1 %+ d
 168         %define t%1w t%1 %+ w
 169         %define t%1b t%1 %+ b
 170         %rotate 1
 171     %endrep
 172 %endmacro
 173
 174 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9
 175
 176 %ifdef ARCH_X86_64
 177     %define gprsize 8
 178 %else
 179     %define gprsize 4
 180 %endif
 181
 182 %macro PUSH 1
 183     push %1
 184     %assign stack_offset stack_offset+gprsize
 185 %endmacro
 186
 187 %macro POP 1
 188     pop %1
 189     %assign stack_offset stack_offset-gprsize
 190 %endmacro
 191
 192 %macro SUB 2
 193     sub %1, %2
 194     %ifidn %1, rsp
 195         %assign stack_offset stack_offset+(%2)
 196     %endif
 197 %endmacro
 198
 199 %macro ADD 2
 200     add %1, %2
 201     %ifidn %1, rsp
 202         %assign stack_offset stack_offset-(%2)
 203     %endif
 204 %endmacro
 205
 206 %macro movifnidn 2
 207     %ifnidn %1, %2
 208         mov %1, %2
 209     %endif
 210 %endmacro
 211
 212 %macro movsxdifnidn 2
 213     %ifnidn %1, %2
 214         movsxd %1, %2
 215     %endif
 216 %endmacro
 217
 218 %macro ASSERT 1
 219     %if (%1) == 0
 220         %error assert failed
 221     %endif
 222 %endmacro
 223
 224 %macro DEFINE_ARGS 0-*
 225     %ifdef n_arg_names
 226         %assign %%i 0
 227         %rep n_arg_names
 228             CAT_UNDEF arg_name %+ %%i, q
 229             CAT_UNDEF arg_name %+ %%i, d
 230             CAT_UNDEF arg_name %+ %%i, w
 231             CAT_UNDEF arg_name %+ %%i, b
 232             CAT_UNDEF arg_name %+ %%i, m
 233             CAT_UNDEF arg_name, %%i
 234             %assign %%i %%i+1
 235         %endrep
 236     %endif
 237
 238     %assign %%i 0
 239     %rep %0
 240         %xdefine %1q r %+ %%i %+ q
 241         %xdefine %1d r %+ %%i %+ d
 242         %xdefine %1w r %+ %%i %+ w
 243         %xdefine %1b r %+ %%i %+ b
 244         %xdefine %1m r %+ %%i %+ m
 245         CAT_XDEFINE arg_name, %%i, %1
 246         %assign %%i %%i+1
 247         %rotate 1
 248     %endrep
 249     %assign n_arg_names %%i
 250 %endmacro
 251
 252 %ifdef WIN64 ; Windows x64 ;=================================================
 253
 254 DECLARE_REG 0, rcx, ecx, cx,  cl,  ecx
 255 DECLARE_REG 1, rdx, edx, dx,  dl,  edx
 256 DECLARE_REG 2, r8,  r8d, r8w, r8b, r8d
 257 DECLARE_REG 3, r9,  r9d, r9w, r9b, r9d
 258 DECLARE_REG 4, rdi, edi, di,  dil, [rsp + stack_offset + 40]
 259 DECLARE_REG 5, rsi, esi, si,  sil, [rsp + stack_offset + 48]
 260 DECLARE_REG 6, rax, eax, ax,  al,  [rsp + stack_offset + 56]
 261 %define r7m [rsp + stack_offset + 64]
 262 %define r8m [rsp + stack_offset + 72]
 263
 264 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
 265     %if %1 < %2
 266         mov r%1, [rsp + stack_offset + 8 + %1*8]
 267     %endif
 268 %endmacro
 269
 270 %macro PROLOGUE 2-4+ 0 ; #args, #regs, #xmm_regs, arg_names...
 271     ASSERT %2 >= %1
 272     %assign regs_used %2
 273     ASSERT regs_used <= 7
 274     %assign xmm_regs_used %3
 275     ASSERT xmm_regs_used <= 16
 276     %if regs_used > 4
 277         push r4
 278         push r5
 279         %assign stack_offset stack_offset+16
 280     %endif
 281     %if xmm_regs_used > 6
 282         sub rsp, (xmm_regs_used-6)*16+16
 283         %assign stack_offset stack_offset+(xmm_regs_used-6)*16+16
 284         %assign %%i xmm_regs_used
 285         %rep (xmm_regs_used-6)
 286             %assign %%i %%i-1
 287             movdqa [rsp + (%%i-6)*16+8], xmm %+ %%i
 288         %endrep
 289     %endif
 290     LOAD_IF_USED 4, %1
 291     LOAD_IF_USED 5, %1
 292     LOAD_IF_USED 6, %1
 293     DEFINE_ARGS %4
 294 %endmacro
 295
 296 %macro RESTORE_XMM_INTERNAL 1
 297     %if xmm_regs_used > 6
 298         %assign %%i xmm_regs_used
 299         %rep (xmm_regs_used-6)
 300             %assign %%i %%i-1
 301             movdqa xmm %+ %%i, [%1 + (%%i-6)*16+8]
 302         %endrep
 303         add %1, (xmm_regs_used-6)*16+16
 304     %endif
 305 %endmacro
 306
 307 %macro RESTORE_XMM 1
 308     RESTORE_XMM_INTERNAL %1
 309     %assign stack_offset stack_offset-(xmm_regs_used-6)*16+16
 310     %assign xmm_regs_used 0
 311 %endmacro
 312
 313 %macro RET 0
 314     RESTORE_XMM_INTERNAL rsp
 315     %if regs_used > 4
 316         pop r5
 317         pop r4
 318     %endif
 319     ret
 320 %endmacro
 321
 322 %macro REP_RET 0
 323     %if regs_used > 4 || xmm_regs_used > 6
 324         RET
 325     %else
 326         rep ret
 327     %endif
 328 %endmacro
 329
 330 %elifdef ARCH_X86_64 ; *nix x64 ;=============================================
 331
 332 DECLARE_REG 0, rdi, edi, di,  dil, edi
 333 DECLARE_REG 1, rsi, esi, si,  sil, esi
 334 DECLARE_REG 2, rdx, edx, dx,  dl,  edx
 335 DECLARE_REG 3, rcx, ecx, cx,  cl,  ecx
 336 DECLARE_REG 4, r8,  r8d, r8w, r8b, r8d
 337 DECLARE_REG 5, r9,  r9d, r9w, r9b, r9d
 338 DECLARE_REG 6, rax, eax, ax,  al,  [rsp + stack_offset + 8]
 339 %define r7m [rsp + stack_offset + 16]
 340 %define r8m [rsp + stack_offset + 24]
 341
 342 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
 343     %if %1 < %2
 344         mov r%1, [rsp - 40 + %1*8]
 345     %endif
 346 %endmacro
 347
 348 %macro PROLOGUE 2-4+ ; #args, #regs, #xmm_regs, arg_names...
 349     ASSERT %2 >= %1
 350     ASSERT %2 <= 7
 351     LOAD_IF_USED 6, %1
 352     DEFINE_ARGS %4
 353 %endmacro
 354
 355 %macro RET 0
 356     ret
 357 %endmacro
 358
 359 %macro REP_RET 0
 360     rep ret
 361 %endmacro
 362
 363 %else ; X86_32 ;==============================================================
 364
 365 DECLARE_REG 0, eax, eax, ax, al,   [esp + stack_offset + 4]
 366 DECLARE_REG 1, ecx, ecx, cx, cl,   [esp + stack_offset + 8]
 367 DECLARE_REG 2, edx, edx, dx, dl,   [esp + stack_offset + 12]
 368 DECLARE_REG 3, ebx, ebx, bx, bl,   [esp + stack_offset + 16]
 369 DECLARE_REG 4, esi, esi, si, null, [esp + stack_offset + 20]
 370 DECLARE_REG 5, edi, edi, di, null, [esp + stack_offset + 24]
 371 DECLARE_REG 6, ebp, ebp, bp, null, [esp + stack_offset + 28]
 372 %define r7m [esp + stack_offset + 32]
 373 %define r8m [esp + stack_offset + 36]
 374 %define rsp esp
 375
 376 %macro PUSH_IF_USED 1 ; reg_id
 377     %if %1 < regs_used
 378         push r%1
 379         %assign stack_offset stack_offset+4
 380     %endif
 381 %endmacro
 382
 383 %macro POP_IF_USED 1 ; reg_id
 384     %if %1 < regs_used
 385         pop r%1
 386     %endif
 387 %endmacro
 388
 389 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
 390     %if %1 < %2
 391         mov r%1, [esp + stack_offset + 4 + %1*4]
 392     %endif
 393 %endmacro
 394
 395 %macro PROLOGUE 2-4+ ; #args, #regs, #xmm_regs, arg_names...
 396     ASSERT %2 >= %1
 397     %assign regs_used %2
 398     ASSERT regs_used <= 7
 399     PUSH_IF_USED 3
 400     PUSH_IF_USED 4
 401     PUSH_IF_USED 5
 402     PUSH_IF_USED 6
 403     LOAD_IF_USED 0, %1
 404     LOAD_IF_USED 1, %1
 405     LOAD_IF_USED 2, %1
 406     LOAD_IF_USED 3, %1
 407     LOAD_IF_USED 4, %1
 408     LOAD_IF_USED 5, %1
 409     LOAD_IF_USED 6, %1
 410     DEFINE_ARGS %4
 411 %endmacro
 412
 413 %macro RET 0
 414     POP_IF_USED 6
 415     POP_IF_USED 5
 416     POP_IF_USED 4
 417     POP_IF_USED 3
 418     ret
 419 %endmacro
 420
 421 %macro REP_RET 0
 422     %if regs_used > 3
 423         RET
 424     %else
 425         rep ret
 426     %endif
 427 %endmacro
 428
 429 %endif ;======================================================================
 430
 431
 432
 433 ;=============================================================================
 434 ; arch-independent part
 435 ;=============================================================================
 436
 437 %assign function_align 16
 438
 439 ; Symbol prefix for C linkage
 440 %macro cglobal 1-2+
 441     %xdefine %1 mangle(program_name %+ _ %+ %1)
 442     %xdefine %1.skip_prologue %1 %+ .skip_prologue
 443     %ifidn __OUTPUT_FORMAT__,elf
 444         global %1:function hidden
 445     %else
 446         global %1
 447     %endif
 448     align function_align
 449     %1:
 450     RESET_MM_PERMUTATION ; not really needed, but makes disassembly somewhat nicer
 451     %assign stack_offset 0
 452     %if %0 > 1
 453         PROLOGUE %2
 454     %endif
 455 %endmacro
 456
 457 %macro cextern 1
 458     %xdefine %1 mangle(program_name %+ _ %+ %1)
 459     extern %1
 460 %endmacro
 461
 462 ;like cextern, but without the prefix
 463 %macro cextern_naked 1
 464     %xdefine %1 mangle(%1)
 465     extern %1
 466 %endmacro
 467
 468 %macro const 2+
 469     %xdefine %1 mangle(program_name %+ _ %+ %1)
 470     global %1
 471     %1: %2
 472 %endmacro
 473
 474 ; This is needed for ELF, otherwise the GNU linker assumes the stack is
 475 ; executable by default.
 476 %ifidn __OUTPUT_FORMAT__,elf
 477 SECTION .note.GNU-stack noalloc noexec nowrite progbits
 478 %endif
 479
 480 ; merge mmx and sse*
 481
 482 %macro CAT_XDEFINE 3
 483     %xdefine %1%2 %3
 484 %endmacro
 485
 486 %macro CAT_UNDEF 2
 487     %undef %1%2
 488 %endmacro
 489
 490 %macro INIT_MMX 0
 491     %define RESET_MM_PERMUTATION INIT_MMX
 492     %define mmsize 8
 493     %define num_mmregs 8
 494     %define mova movq
 495     %define movu movq
 496     %define movh movd
 497     %define movnt movntq
 498     %assign %%i 0
 499     %rep 8
 500     CAT_XDEFINE m, %%i, mm %+ %%i
 501     CAT_XDEFINE nmm, %%i, %%i
 502     %assign %%i %%i+1
 503     %endrep
 504     %rep 8
 505     CAT_UNDEF m, %%i
 506     CAT_UNDEF nmm, %%i
 507     %assign %%i %%i+1
 508     %endrep
 509 %endmacro
 510
 511 %macro INIT_XMM 0
 512     %define RESET_MM_PERMUTATION INIT_XMM
 513     %define mmsize 16
 514     %define num_mmregs 8
 515     %ifdef ARCH_X86_64
 516     %define num_mmregs 16
 517     %endif
 518     %define mova movdqa
 519     %define movu movdqu
 520     %define movh movq
 521     %define movnt movntdq
 522     %assign %%i 0
 523     %rep num_mmregs
 524     CAT_XDEFINE m, %%i, xmm %+ %%i
 525     CAT_XDEFINE nxmm, %%i, %%i
 526     %assign %%i %%i+1
 527     %endrep
 528 %endmacro
 529
 530 INIT_MMX
 531
 532 ; I often want to use macros that permute their arguments. e.g. there's no
 533 ; efficient way to implement butterfly or transpose or dct without swapping some
 534 ; arguments.
 535 ;
 536 ; I would like to not have to manually keep track of the permutations:
 537 ; If I insert a permutation in the middle of a function, it should automatically
 538 ; change everything that follows. For more complex macros I may also have multiple
 539 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
 540 ;
 541 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
 542 ; permutes its arguments. It's equivalent to exchanging the contents of the
 543 ; registers, except that this way you exchange the register names instead, so it
 544 ; doesn't cost any cycles.
 545
 546 %macro PERMUTE 2-* ; takes a list of pairs to swap
 547 %rep %0/2
 548     %xdefine tmp%2 m%2
 549     %xdefine ntmp%2 nm%2
 550     %rotate 2
 551 %endrep
 552 %rep %0/2
 553     %xdefine m%1 tmp%2
 554     %xdefine nm%1 ntmp%2
 555     %undef tmp%2
 556     %undef ntmp%2
 557     %rotate 2
 558 %endrep
 559 %endmacro
 560
 561 %macro SWAP 2-* ; swaps a single chain (sometimes more concise than pairs)
 562 %rep %0-1
 563 %ifdef m%1
 564     %xdefine tmp m%1
 565     %xdefine m%1 m%2
 566     %xdefine m%2 tmp
 567     CAT_XDEFINE n, m%1, %1
 568     CAT_XDEFINE n, m%2, %2
 569 %else
 570     ; If we were called as "SWAP m0,m1" rather than "SWAP 0,1" infer the original numbers here.
 571     ; Be careful using this mode in nested macros though, as in some cases there may be
 572     ; other copies of m# that have already been dereferenced and don't get updated correctly.
 573     %xdefine %%n1 n %+ %1
 574     %xdefine %%n2 n %+ %2
 575     %xdefine tmp m %+ %%n1
 576     CAT_XDEFINE m, %%n1, m %+ %%n2
 577     CAT_XDEFINE m, %%n2, tmp
 578     CAT_XDEFINE n, m %+ %%n1, %%n1
 579     CAT_XDEFINE n, m %+ %%n2, %%n2
 580 %endif
 581     %undef tmp
 582     %rotate 1
 583 %endrep
 584 %endmacro
 585
 586 ; If SAVE_MM_PERMUTATION is placed at the end of a function and given the
 587 ; function name, then any later calls to that function will automatically
 588 ; load the permutation, so values can be returned in mmregs.
 589 %macro SAVE_MM_PERMUTATION 1 ; name to save as
 590     %assign %%i 0
 591     %rep num_mmregs
 592     CAT_XDEFINE %1_m, %%i, m %+ %%i
 593     %assign %%i %%i+1
 594     %endrep
 595 %endmacro
 596
 597 %macro LOAD_MM_PERMUTATION 1 ; name to load from
 598     %assign %%i 0
 599     %rep num_mmregs
 600     CAT_XDEFINE m, %%i, %1_m %+ %%i
 601     CAT_XDEFINE n, m %+ %%i, %%i
 602     %assign %%i %%i+1
 603     %endrep
 604 %endmacro
 605
 606 %macro call 1
 607     call %1
 608     %ifdef %1_m0
 609         LOAD_MM_PERMUTATION %1
 610     %endif
 611 %endmacro
 612
 613 ; Substitutions that reduce instruction size but are functionally equivalent
 614 %macro add 2
 615     %ifnum %2
 616         %if %2==128
 617             sub %1, -128
 618         %else
 619             add %1, %2
 620         %endif
 621     %else
 622         add %1, %2
 623     %endif
 624 %endmacro
 625
 626 %macro sub 2
 627     %ifnum %2
 628         %if %2==128
 629             add %1, -128
 630         %else
 631             sub %1, %2
 632         %endif
 633     %else
 634         sub %1, %2
 635     %endif
 636 %endmacro