git.sesse.net Git - x264/blob - common/x86/x86inc.asm

   1 ;*****************************************************************************
   2 ;* x86inc.asm: x264asm abstraction layer
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2005-2010 x264 project
   5 ;*
   6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
   7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
   8 ;*          Fiona Glaser <fiona@x264.com>
   9 ;*
  10 ;* Permission to use, copy, modify, and/or distribute this software for any
  11 ;* purpose with or without fee is hereby granted, provided that the above
  12 ;* copyright notice and this permission notice appear in all copies.
  13 ;*
  14 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  15 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  16 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  17 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  18 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  19 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  20 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  21 ;*****************************************************************************
  22
  23 ; This is a header file for the x264ASM assembly language, which uses
  24 ; NASM/YASM syntax combined with a large number of macros to provide easy
  25 ; abstraction between different calling conventions (x86_32, win64, linux64).
  26 ; It also has various other useful features to simplify writing the kind of
  27 ; DSP functions that are most often used in x264.
  28
  29 ; Unlike the rest of x264, this file is available under an ISC license, as it
  30 ; has significant usefulness outside of x264 and we want it to be available
  31 ; to the largest audience possible.  Of course, if you modify it for your own
  32 ; purposes to add a new feature, we strongly encourage contributing a patch
  33 ; as this feature might be useful for others as well.  Send patches or ideas
  34 ; to x264-devel@videolan.org .
  35
  36 %define program_name x264
  37
  38 %ifdef ARCH_X86_64
  39     %ifidn __OUTPUT_FORMAT__,win32
  40         %define WIN64
  41     %else
  42         %define UNIX64
  43     %endif
  44 %endif
  45
  46 %ifdef PREFIX
  47     %define mangle(x) _ %+ x
  48 %else
  49     %define mangle(x) x
  50 %endif
  51
  52 ; FIXME: All of the 64bit asm functions that take a stride as an argument
  53 ; via register, assume that the high dword of that register is filled with 0.
  54 ; This is true in practice (since we never do any 64bit arithmetic on strides,
  55 ; and x264's strides are all positive), but is not guaranteed by the ABI.
  56
  57 ; Name of the .rodata section.
  58 ; Kludge: Something on OS X fails to align .rodata even given an align attribute,
  59 ; so use a different read-only section.
  60 %macro SECTION_RODATA 0-1 16
  61     %ifidn __OUTPUT_FORMAT__,macho64
  62         SECTION .text align=%1
  63     %elifidn __OUTPUT_FORMAT__,macho
  64         SECTION .text align=%1
  65         fakegot:
  66     %else
  67         SECTION .rodata align=%1
  68     %endif
  69 %endmacro
  70
  71 %ifdef WIN64
  72     %define PIC
  73 %elifndef ARCH_X86_64
  74 ; x86_32 doesn't require PIC.
  75 ; Some distros prefer shared objects to be PIC, but nothing breaks if
  76 ; the code contains a few textrels, so we'll skip that complexity.
  77     %undef PIC
  78 %endif
  79 %ifdef PIC
  80     default rel
  81 %endif
  82
  83 ; Macros to eliminate most code duplication between x86_32 and x86_64:
  84 ; Currently this works only for leaf functions which load all their arguments
  85 ; into registers at the start, and make no other use of the stack. Luckily that
  86 ; covers most of x264's asm.
  87
  88 ; PROLOGUE:
  89 ; %1 = number of arguments. loads them from stack if needed.
  90 ; %2 = number of registers used. pushes callee-saved regs if needed.
  91 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
  92 ; %4 = list of names to define to registers
  93 ; PROLOGUE can also be invoked by adding the same options to cglobal
  94
  95 ; e.g.
  96 ; cglobal foo, 2,3,0, dst, src, tmp
  97 ; declares a function (foo), taking two args (dst and src) and one local variable (tmp)
  98
  99 ; TODO Some functions can use some args directly from the stack. If they're the
 100 ; last args then you can just not declare them, but if they're in the middle
 101 ; we need more flexible macro.
 102
 103 ; RET:
 104 ; Pops anything that was pushed by PROLOGUE
 105
 106 ; REP_RET:
 107 ; Same, but if it doesn't pop anything it becomes a 2-byte ret, for athlons
 108 ; which are slow when a normal ret follows a branch.
 109
 110 ; registers:
 111 ; rN and rNq are the native-size register holding function argument N
 112 ; rNd, rNw, rNb are dword, word, and byte size
 113 ; rNm is the original location of arg N (a register or on the stack), dword
 114 ; rNmp is native size
 115
 116 %macro DECLARE_REG 6
 117     %define r%1q %2
 118     %define r%1d %3
 119     %define r%1w %4
 120     %define r%1b %5
 121     %define r%1m %6
 122     %ifid %6 ; i.e. it's a register
 123         %define r%1mp %2
 124     %elifdef ARCH_X86_64 ; memory
 125         %define r%1mp qword %6
 126     %else
 127         %define r%1mp dword %6
 128     %endif
 129     %define r%1  %2
 130 %endmacro
 131
 132 %macro DECLARE_REG_SIZE 2
 133     %define r%1q r%1
 134     %define e%1q r%1
 135     %define r%1d e%1
 136     %define e%1d e%1
 137     %define r%1w %1
 138     %define e%1w %1
 139     %define r%1b %2
 140     %define e%1b %2
 141 %ifndef ARCH_X86_64
 142     %define r%1  e%1
 143 %endif
 144 %endmacro
 145
 146 DECLARE_REG_SIZE ax, al
 147 DECLARE_REG_SIZE bx, bl
 148 DECLARE_REG_SIZE cx, cl
 149 DECLARE_REG_SIZE dx, dl
 150 DECLARE_REG_SIZE si, sil
 151 DECLARE_REG_SIZE di, dil
 152 DECLARE_REG_SIZE bp, bpl
 153
 154 ; t# defines for when per-arch register allocation is more complex than just function arguments
 155
 156 %macro DECLARE_REG_TMP 1-*
 157     %assign %%i 0
 158     %rep %0
 159         CAT_XDEFINE t, %%i, r%1
 160         %assign %%i %%i+1
 161         %rotate 1
 162     %endrep
 163 %endmacro
 164
 165 %macro DECLARE_REG_TMP_SIZE 0-*
 166     %rep %0
 167         %define t%1q t%1 %+ q
 168         %define t%1d t%1 %+ d
 169         %define t%1w t%1 %+ w
 170         %define t%1b t%1 %+ b
 171         %rotate 1
 172     %endrep
 173 %endmacro
 174
 175 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9
 176
 177 %ifdef ARCH_X86_64
 178     %define gprsize 8
 179 %else
 180     %define gprsize 4
 181 %endif
 182
 183 %macro PUSH 1
 184     push %1
 185     %assign stack_offset stack_offset+gprsize
 186 %endmacro
 187
 188 %macro POP 1
 189     pop %1
 190     %assign stack_offset stack_offset-gprsize
 191 %endmacro
 192
 193 %macro SUB 2
 194     sub %1, %2
 195     %ifidn %1, rsp
 196         %assign stack_offset stack_offset+(%2)
 197     %endif
 198 %endmacro
 199
 200 %macro ADD 2
 201     add %1, %2
 202     %ifidn %1, rsp
 203         %assign stack_offset stack_offset-(%2)
 204     %endif
 205 %endmacro
 206
 207 %macro movifnidn 2
 208     %ifnidn %1, %2
 209         mov %1, %2
 210     %endif
 211 %endmacro
 212
 213 %macro movsxdifnidn 2
 214     %ifnidn %1, %2
 215         movsxd %1, %2
 216     %endif
 217 %endmacro
 218
 219 %macro ASSERT 1
 220     %if (%1) == 0
 221         %error assert failed
 222     %endif
 223 %endmacro
 224
 225 %macro DEFINE_ARGS 0-*
 226     %ifdef n_arg_names
 227         %assign %%i 0
 228         %rep n_arg_names
 229             CAT_UNDEF arg_name %+ %%i, q
 230             CAT_UNDEF arg_name %+ %%i, d
 231             CAT_UNDEF arg_name %+ %%i, w
 232             CAT_UNDEF arg_name %+ %%i, b
 233             CAT_UNDEF arg_name %+ %%i, m
 234             CAT_UNDEF arg_name, %%i
 235             %assign %%i %%i+1
 236         %endrep
 237     %endif
 238
 239     %assign %%i 0
 240     %rep %0
 241         %xdefine %1q r %+ %%i %+ q
 242         %xdefine %1d r %+ %%i %+ d
 243         %xdefine %1w r %+ %%i %+ w
 244         %xdefine %1b r %+ %%i %+ b
 245         %xdefine %1m r %+ %%i %+ m
 246         CAT_XDEFINE arg_name, %%i, %1
 247         %assign %%i %%i+1
 248         %rotate 1
 249     %endrep
 250     %assign n_arg_names %%i
 251 %endmacro
 252
 253 %ifdef WIN64 ; Windows x64 ;=================================================
 254
 255 DECLARE_REG 0, rcx, ecx, cx,  cl,  ecx
 256 DECLARE_REG 1, rdx, edx, dx,  dl,  edx
 257 DECLARE_REG 2, r8,  r8d, r8w, r8b, r8d
 258 DECLARE_REG 3, r9,  r9d, r9w, r9b, r9d
 259 DECLARE_REG 4, rdi, edi, di,  dil, [rsp + stack_offset + 40]
 260 DECLARE_REG 5, rsi, esi, si,  sil, [rsp + stack_offset + 48]
 261 DECLARE_REG 6, rax, eax, ax,  al,  [rsp + stack_offset + 56]
 262 %define r7m [rsp + stack_offset + 64]
 263 %define r8m [rsp + stack_offset + 72]
 264
 265 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
 266     %if %1 < %2
 267         mov r%1, [rsp + stack_offset + 8 + %1*8]
 268     %endif
 269 %endmacro
 270
 271 %macro PROLOGUE 2-4+ 0 ; #args, #regs, #xmm_regs, arg_names...
 272     ASSERT %2 >= %1
 273     %assign regs_used %2
 274     ASSERT regs_used <= 7
 275     %if regs_used > 4
 276         push r4
 277         push r5
 278         %assign stack_offset stack_offset+16
 279     %endif
 280     WIN64_SPILL_XMM %3
 281     LOAD_IF_USED 4, %1
 282     LOAD_IF_USED 5, %1
 283     LOAD_IF_USED 6, %1
 284     DEFINE_ARGS %4
 285 %endmacro
 286
 287 %macro WIN64_SPILL_XMM 1
 288     %assign xmm_regs_used %1
 289     ASSERT xmm_regs_used <= 16
 290     %if xmm_regs_used > 6
 291         sub rsp, (xmm_regs_used-6)*16+16
 292         %assign stack_offset stack_offset+(xmm_regs_used-6)*16+16
 293         %assign %%i xmm_regs_used
 294         %rep (xmm_regs_used-6)
 295             %assign %%i %%i-1
 296             movdqa [rsp + (%%i-6)*16+8], xmm %+ %%i
 297         %endrep
 298     %endif
 299 %endmacro
 300
 301 %macro WIN64_RESTORE_XMM_INTERNAL 1
 302     %if xmm_regs_used > 6
 303         %assign %%i xmm_regs_used
 304         %rep (xmm_regs_used-6)
 305             %assign %%i %%i-1
 306             movdqa xmm %+ %%i, [%1 + (%%i-6)*16+8]
 307         %endrep
 308         add %1, (xmm_regs_used-6)*16+16
 309     %endif
 310 %endmacro
 311
 312 %macro WIN64_RESTORE_XMM 1
 313     WIN64_RESTORE_XMM_INTERNAL %1
 314     %assign stack_offset stack_offset-(xmm_regs_used-6)*16+16
 315     %assign xmm_regs_used 0
 316 %endmacro
 317
 318 %macro RET 0
 319     WIN64_RESTORE_XMM_INTERNAL rsp
 320     %if regs_used > 4
 321         pop r5
 322         pop r4
 323     %endif
 324     ret
 325 %endmacro
 326
 327 %macro REP_RET 0
 328     %if regs_used > 4 || xmm_regs_used > 6
 329         RET
 330     %else
 331         rep ret
 332     %endif
 333 %endmacro
 334
 335 %elifdef ARCH_X86_64 ; *nix x64 ;=============================================
 336
 337 DECLARE_REG 0, rdi, edi, di,  dil, edi
 338 DECLARE_REG 1, rsi, esi, si,  sil, esi
 339 DECLARE_REG 2, rdx, edx, dx,  dl,  edx
 340 DECLARE_REG 3, rcx, ecx, cx,  cl,  ecx
 341 DECLARE_REG 4, r8,  r8d, r8w, r8b, r8d
 342 DECLARE_REG 5, r9,  r9d, r9w, r9b, r9d
 343 DECLARE_REG 6, rax, eax, ax,  al,  [rsp + stack_offset + 8]
 344 %define r7m [rsp + stack_offset + 16]
 345 %define r8m [rsp + stack_offset + 24]
 346
 347 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
 348     %if %1 < %2
 349         mov r%1, [rsp - 40 + %1*8]
 350     %endif
 351 %endmacro
 352
 353 %macro PROLOGUE 2-4+ ; #args, #regs, #xmm_regs, arg_names...
 354     ASSERT %2 >= %1
 355     ASSERT %2 <= 7
 356     LOAD_IF_USED 6, %1
 357     DEFINE_ARGS %4
 358 %endmacro
 359
 360 %macro RET 0
 361     ret
 362 %endmacro
 363
 364 %macro REP_RET 0
 365     rep ret
 366 %endmacro
 367
 368 %else ; X86_32 ;==============================================================
 369
 370 DECLARE_REG 0, eax, eax, ax, al,   [esp + stack_offset + 4]
 371 DECLARE_REG 1, ecx, ecx, cx, cl,   [esp + stack_offset + 8]
 372 DECLARE_REG 2, edx, edx, dx, dl,   [esp + stack_offset + 12]
 373 DECLARE_REG 3, ebx, ebx, bx, bl,   [esp + stack_offset + 16]
 374 DECLARE_REG 4, esi, esi, si, null, [esp + stack_offset + 20]
 375 DECLARE_REG 5, edi, edi, di, null, [esp + stack_offset + 24]
 376 DECLARE_REG 6, ebp, ebp, bp, null, [esp + stack_offset + 28]
 377 %define r7m [esp + stack_offset + 32]
 378 %define r8m [esp + stack_offset + 36]
 379 %define rsp esp
 380
 381 %macro PUSH_IF_USED 1 ; reg_id
 382     %if %1 < regs_used
 383         push r%1
 384         %assign stack_offset stack_offset+4
 385     %endif
 386 %endmacro
 387
 388 %macro POP_IF_USED 1 ; reg_id
 389     %if %1 < regs_used
 390         pop r%1
 391     %endif
 392 %endmacro
 393
 394 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
 395     %if %1 < %2
 396         mov r%1, [esp + stack_offset + 4 + %1*4]
 397     %endif
 398 %endmacro
 399
 400 %macro PROLOGUE 2-4+ ; #args, #regs, #xmm_regs, arg_names...
 401     ASSERT %2 >= %1
 402     %assign regs_used %2
 403     ASSERT regs_used <= 7
 404     PUSH_IF_USED 3
 405     PUSH_IF_USED 4
 406     PUSH_IF_USED 5
 407     PUSH_IF_USED 6
 408     LOAD_IF_USED 0, %1
 409     LOAD_IF_USED 1, %1
 410     LOAD_IF_USED 2, %1
 411     LOAD_IF_USED 3, %1
 412     LOAD_IF_USED 4, %1
 413     LOAD_IF_USED 5, %1
 414     LOAD_IF_USED 6, %1
 415     DEFINE_ARGS %4
 416 %endmacro
 417
 418 %macro RET 0
 419     POP_IF_USED 6
 420     POP_IF_USED 5
 421     POP_IF_USED 4
 422     POP_IF_USED 3
 423     ret
 424 %endmacro
 425
 426 %macro REP_RET 0
 427     %if regs_used > 3
 428         RET
 429     %else
 430         rep ret
 431     %endif
 432 %endmacro
 433
 434 %endif ;======================================================================
 435
 436 %ifndef WIN64
 437 %macro WIN64_SPILL_XMM 1
 438 %endmacro
 439 %macro WIN64_RESTORE_XMM 1
 440 %endmacro
 441 %endif
 442
 443
 444
 445 ;=============================================================================
 446 ; arch-independent part
 447 ;=============================================================================
 448
 449 %assign function_align 16
 450
 451 ; Symbol prefix for C linkage
 452 %macro cglobal 1-2+
 453     %xdefine %1 mangle(program_name %+ _ %+ %1)
 454     %xdefine %1.skip_prologue %1 %+ .skip_prologue
 455     %ifidn __OUTPUT_FORMAT__,elf
 456         global %1:function hidden
 457     %else
 458         global %1
 459     %endif
 460     align function_align
 461     %1:
 462     RESET_MM_PERMUTATION ; not really needed, but makes disassembly somewhat nicer
 463     %assign stack_offset 0
 464     %if %0 > 1
 465         PROLOGUE %2
 466     %endif
 467 %endmacro
 468
 469 %macro cextern 1
 470     %xdefine %1 mangle(program_name %+ _ %+ %1)
 471     extern %1
 472 %endmacro
 473
 474 ;like cextern, but without the prefix
 475 %macro cextern_naked 1
 476     %xdefine %1 mangle(%1)
 477     extern %1
 478 %endmacro
 479
 480 %macro const 2+
 481     %xdefine %1 mangle(program_name %+ _ %+ %1)
 482     global %1
 483     %1: %2
 484 %endmacro
 485
 486 ; This is needed for ELF, otherwise the GNU linker assumes the stack is
 487 ; executable by default.
 488 %ifidn __OUTPUT_FORMAT__,elf
 489 SECTION .note.GNU-stack noalloc noexec nowrite progbits
 490 %endif
 491
 492 ; merge mmx and sse*
 493
 494 %macro CAT_XDEFINE 3
 495     %xdefine %1%2 %3
 496 %endmacro
 497
 498 %macro CAT_UNDEF 2
 499     %undef %1%2
 500 %endmacro
 501
 502 %macro INIT_MMX 0
 503     %define RESET_MM_PERMUTATION INIT_MMX
 504     %define mmsize 8
 505     %define num_mmregs 8
 506     %define mova movq
 507     %define movu movq
 508     %define movh movd
 509     %define movnta movntq
 510     %assign %%i 0
 511     %rep 8
 512     CAT_XDEFINE m, %%i, mm %+ %%i
 513     CAT_XDEFINE nmm, %%i, %%i
 514     %assign %%i %%i+1
 515     %endrep
 516     %rep 8
 517     CAT_UNDEF m, %%i
 518     CAT_UNDEF nmm, %%i
 519     %assign %%i %%i+1
 520     %endrep
 521 %endmacro
 522
 523 %macro INIT_XMM 0
 524     %define RESET_MM_PERMUTATION INIT_XMM
 525     %define mmsize 16
 526     %define num_mmregs 8
 527     %ifdef ARCH_X86_64
 528     %define num_mmregs 16
 529     %endif
 530     %define mova movdqa
 531     %define movu movdqu
 532     %define movh movq
 533     %define movnta movntdq
 534     %assign %%i 0
 535     %rep num_mmregs
 536     CAT_XDEFINE m, %%i, xmm %+ %%i
 537     CAT_XDEFINE nxmm, %%i, %%i
 538     %assign %%i %%i+1
 539     %endrep
 540 %endmacro
 541
 542 INIT_MMX
 543
 544 ; I often want to use macros that permute their arguments. e.g. there's no
 545 ; efficient way to implement butterfly or transpose or dct without swapping some
 546 ; arguments.
 547 ;
 548 ; I would like to not have to manually keep track of the permutations:
 549 ; If I insert a permutation in the middle of a function, it should automatically
 550 ; change everything that follows. For more complex macros I may also have multiple
 551 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
 552 ;
 553 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
 554 ; permutes its arguments. It's equivalent to exchanging the contents of the
 555 ; registers, except that this way you exchange the register names instead, so it
 556 ; doesn't cost any cycles.
 557
 558 %macro PERMUTE 2-* ; takes a list of pairs to swap
 559 %rep %0/2
 560     %xdefine tmp%2 m%2
 561     %xdefine ntmp%2 nm%2
 562     %rotate 2
 563 %endrep
 564 %rep %0/2
 565     %xdefine m%1 tmp%2
 566     %xdefine nm%1 ntmp%2
 567     %undef tmp%2
 568     %undef ntmp%2
 569     %rotate 2
 570 %endrep
 571 %endmacro
 572
 573 %macro SWAP 2-* ; swaps a single chain (sometimes more concise than pairs)
 574 %rep %0-1
 575 %ifdef m%1
 576     %xdefine tmp m%1
 577     %xdefine m%1 m%2
 578     %xdefine m%2 tmp
 579     CAT_XDEFINE n, m%1, %1
 580     CAT_XDEFINE n, m%2, %2
 581 %else
 582     ; If we were called as "SWAP m0,m1" rather than "SWAP 0,1" infer the original numbers here.
 583     ; Be careful using this mode in nested macros though, as in some cases there may be
 584     ; other copies of m# that have already been dereferenced and don't get updated correctly.
 585     %xdefine %%n1 n %+ %1
 586     %xdefine %%n2 n %+ %2
 587     %xdefine tmp m %+ %%n1
 588     CAT_XDEFINE m, %%n1, m %+ %%n2
 589     CAT_XDEFINE m, %%n2, tmp
 590     CAT_XDEFINE n, m %+ %%n1, %%n1
 591     CAT_XDEFINE n, m %+ %%n2, %%n2
 592 %endif
 593     %undef tmp
 594     %rotate 1
 595 %endrep
 596 %endmacro
 597
 598 ; If SAVE_MM_PERMUTATION is placed at the end of a function and given the
 599 ; function name, then any later calls to that function will automatically
 600 ; load the permutation, so values can be returned in mmregs.
 601 %macro SAVE_MM_PERMUTATION 1 ; name to save as
 602     %assign %%i 0
 603     %rep num_mmregs
 604     CAT_XDEFINE %1_m, %%i, m %+ %%i
 605     %assign %%i %%i+1
 606     %endrep
 607 %endmacro
 608
 609 %macro LOAD_MM_PERMUTATION 1 ; name to load from
 610     %assign %%i 0
 611     %rep num_mmregs
 612     CAT_XDEFINE m, %%i, %1_m %+ %%i
 613     CAT_XDEFINE n, m %+ %%i, %%i
 614     %assign %%i %%i+1
 615     %endrep
 616 %endmacro
 617
 618 %macro call 1
 619     call %1
 620     %ifdef %1_m0
 621         LOAD_MM_PERMUTATION %1
 622     %endif
 623 %endmacro
 624
 625 ; Substitutions that reduce instruction size but are functionally equivalent
 626 %macro add 2
 627     %ifnum %2
 628         %if %2==128
 629             sub %1, -128
 630         %else
 631             add %1, %2
 632         %endif
 633     %else
 634         add %1, %2
 635     %endif
 636 %endmacro
 637
 638 %macro sub 2
 639     %ifnum %2
 640         %if %2==128
 641             add %1, -128
 642         %else
 643             sub %1, %2
 644         %endif
 645     %else
 646         sub %1, %2
 647     %endif
 648 %endmacro