git.sesse.net Git - x264/blob - common/x86/x86util.asm

   1 ;*****************************************************************************
   2 ;* x86util.asm
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2008 x264 project
   5 ;*
   6 ;* Authors: Holger Lubitz <holger@lubitz.org>
   7 ;*          Loren Merritt <lorenm@u.washington.edu>
   8 ;*
   9 ;* This program is free software; you can redistribute it and/or modify
  10 ;* it under the terms of the GNU General Public License as published by
  11 ;* the Free Software Foundation; either version 2 of the License, or
  12 ;* (at your option) any later version.
  13 ;*
  14 ;* This program is distributed in the hope that it will be useful,
  15 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;* GNU General Public License for more details.
  18 ;*
  19 ;* You should have received a copy of the GNU General Public License
  20 ;* along with this program; if not, write to the Free Software
  21 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02111, USA.
  22 ;*****************************************************************************
  23
  24 %assign FENC_STRIDE 16
  25 %assign FDEC_STRIDE 32
  26
  27 %macro SBUTTERFLY 4
  28     mova      m%4, m%2
  29     punpckl%1 m%2, m%3
  30     punpckh%1 m%4, m%3
  31     SWAP %3, %4
  32 %endmacro
  33
  34 %macro SBUTTERFLY2 4
  35     mova      m%4, m%2
  36     punpckh%1 m%2, m%3
  37     punpckl%1 m%4, m%3
  38     SWAP %2, %4, %3
  39 %endmacro
  40
  41 %macro TRANSPOSE4x4W 5
  42     SBUTTERFLY wd, %1, %2, %5
  43     SBUTTERFLY wd, %3, %4, %5
  44     SBUTTERFLY dq, %1, %3, %5
  45     SBUTTERFLY dq, %2, %4, %5
  46     SWAP %2, %3
  47 %endmacro
  48
  49 %macro TRANSPOSE2x4x4W 5
  50     SBUTTERFLY wd,  %1, %2, %5
  51     SBUTTERFLY wd,  %3, %4, %5
  52     SBUTTERFLY dq,  %1, %3, %5
  53     SBUTTERFLY dq,  %2, %4, %5
  54     SBUTTERFLY qdq, %1, %2, %5
  55     SBUTTERFLY qdq, %3, %4, %5
  56 %endmacro
  57
  58 %macro TRANSPOSE4x4D 5
  59     SBUTTERFLY dq,  %1, %2, %5
  60     SBUTTERFLY dq,  %3, %4, %5
  61     SBUTTERFLY qdq, %1, %3, %5
  62     SBUTTERFLY qdq, %2, %4, %5
  63     SWAP %2, %3
  64 %endmacro
  65
  66 %macro TRANSPOSE8x8W 9-11
  67 %ifdef ARCH_X86_64
  68     SBUTTERFLY wd,  %1, %2, %9
  69     SBUTTERFLY wd,  %3, %4, %9
  70     SBUTTERFLY wd,  %5, %6, %9
  71     SBUTTERFLY wd,  %7, %8, %9
  72     SBUTTERFLY dq,  %1, %3, %9
  73     SBUTTERFLY dq,  %2, %4, %9
  74     SBUTTERFLY dq,  %5, %7, %9
  75     SBUTTERFLY dq,  %6, %8, %9
  76     SBUTTERFLY qdq, %1, %5, %9
  77     SBUTTERFLY qdq, %2, %6, %9
  78     SBUTTERFLY qdq, %3, %7, %9
  79     SBUTTERFLY qdq, %4, %8, %9
  80     SWAP %2, %5
  81     SWAP %4, %7
  82 %else
  83 ; in:  m0..m7, unless %11 in which case m6 is in %9
  84 ; out: m0..m7, unless %11 in which case m4 is in %10
  85 ; spills into %9 and %10
  86 %if %0<11
  87     movdqa %9, m%7
  88 %endif
  89     SBUTTERFLY wd,  %1, %2, %7
  90     movdqa %10, m%2
  91     movdqa m%7, %9
  92     SBUTTERFLY wd,  %3, %4, %2
  93     SBUTTERFLY wd,  %5, %6, %2
  94     SBUTTERFLY wd,  %7, %8, %2
  95     SBUTTERFLY dq,  %1, %3, %2
  96     movdqa %9, m%3
  97     movdqa m%2, %10
  98     SBUTTERFLY dq,  %2, %4, %3
  99     SBUTTERFLY dq,  %5, %7, %3
 100     SBUTTERFLY dq,  %6, %8, %3
 101     SBUTTERFLY qdq, %1, %5, %3
 102     SBUTTERFLY qdq, %2, %6, %3
 103     movdqa %10, m%2
 104     movdqa m%3, %9
 105     SBUTTERFLY qdq, %3, %7, %2
 106     SBUTTERFLY qdq, %4, %8, %2
 107     SWAP %2, %5
 108     SWAP %4, %7
 109 %if %0<11
 110     movdqa m%5, %10
 111 %endif
 112 %endif
 113 %endmacro
 114
 115 %macro ABS1_MMX 2    ; a, tmp
 116     pxor    %2, %2
 117     psubw   %2, %1
 118     pmaxsw  %1, %2
 119 %endmacro
 120
 121 %macro ABS2_MMX 4    ; a, b, tmp0, tmp1
 122     pxor    %3, %3
 123     pxor    %4, %4
 124     psubw   %3, %1
 125     psubw   %4, %2
 126     pmaxsw  %1, %3
 127     pmaxsw  %2, %4
 128 %endmacro
 129
 130 %macro ABS1_SSSE3 2
 131     pabsw   %1, %1
 132 %endmacro
 133
 134 %macro ABS2_SSSE3 4
 135     pabsw   %1, %1
 136     pabsw   %2, %2
 137 %endmacro
 138
 139 %define ABS1 ABS1_MMX
 140 %define ABS2 ABS2_MMX
 141
 142 %macro ABS4 6
 143     ABS2 %1, %2, %5, %6
 144     ABS2 %3, %4, %5, %6
 145 %endmacro
 146
 147 %macro SPLATB_MMX 3
 148     movd      %1, [%2-3] ;to avoid crossing a cacheline
 149     punpcklbw %1, %1
 150 %if mmsize==16
 151     pshuflw   %1, %1, 0xff
 152     punpcklqdq %1, %1
 153 %else
 154     pshufw    %1, %1, 0xff
 155 %endif
 156 %endmacro
 157
 158 %macro SPLATB_SSSE3 3
 159     movd      %1, [%2-3]
 160     pshufb    %1, %3
 161 %endmacro
 162
 163 %macro PALIGNR_MMX 4
 164     %ifnidn %4, %2
 165     mova    %4, %2
 166     %endif
 167     %if mmsize == 8
 168     psllq   %1, (8-%3)*8
 169     psrlq   %4, %3*8
 170     %else
 171     pslldq  %1, 16-%3
 172     psrldq  %4, %3
 173     %endif
 174     por     %1, %4
 175 %endmacro
 176
 177 %macro PALIGNR_SSSE3 4
 178     palignr %1, %2, %3
 179 %endmacro
 180
 181 %macro DEINTB 5 ; mask, reg1, mask, reg2, optional src to fill masks from
 182 %ifnum %5
 183     mova   m%1, m%5
 184     mova   m%3, m%5
 185 %else
 186     mova   m%1, %5
 187     mova   m%3, m%1
 188 %endif
 189     pand   m%1, m%2 ; dst .. y6 .. y4
 190     pand   m%3, m%4 ; src .. y6 .. y4
 191     psrlw  m%2, 8   ; dst .. y7 .. y5
 192     psrlw  m%4, 8   ; src .. y7 .. y5
 193 %endmacro
 194
 195 %macro SUMSUB_BA 2-3
 196 %if %0==2
 197     paddw   %1, %2
 198     paddw   %2, %2
 199     psubw   %2, %1
 200 %else
 201     mova    %3, %1
 202     paddw   %1, %2
 203     psubw   %2, %3
 204 %endif
 205 %endmacro
 206
 207 %macro SUMSUB_BADC 4-5
 208 %if %0==5
 209     SUMSUB_BA %1, %2, %5
 210     SUMSUB_BA %3, %4, %5
 211 %else
 212     paddw   %1, %2
 213     paddw   %3, %4
 214     paddw   %2, %2
 215     paddw   %4, %4
 216     psubw   %2, %1
 217     psubw   %4, %3
 218 %endif
 219 %endmacro
 220
 221 %macro HADAMARD4_V 4+
 222     SUMSUB_BADC %1, %2, %3, %4
 223     SUMSUB_BADC %1, %3, %2, %4
 224 %endmacro
 225
 226 %macro HADAMARD8_V 8+
 227     SUMSUB_BADC %1, %2, %3, %4
 228     SUMSUB_BADC %5, %6, %7, %8
 229     SUMSUB_BADC %1, %3, %2, %4
 230     SUMSUB_BADC %5, %7, %6, %8
 231     SUMSUB_BADC %1, %5, %2, %6
 232     SUMSUB_BADC %3, %7, %4, %8
 233 %endmacro
 234
 235 %macro TRANS_SSE2 5-6
 236 ; TRANSPOSE2x2
 237 ; %1: transpose width (d/q) - use SBUTTERFLY qdq for dq
 238 ; %2: ord/unord (for compat with sse4, unused)
 239 ; %3/%4: source regs
 240 ; %5/%6: tmp regs
 241 %ifidn %1, d
 242 %define mask [mask_10]
 243 %define shift 16
 244 %elifidn %1, q
 245 %define mask [mask_1100]
 246 %define shift 32
 247 %endif
 248 %if %0==6 ; less dependency if we have two tmp
 249     mova   m%5, mask   ; ff00
 250     mova   m%6, m%4    ; x5x4
 251     psll%1 m%4, shift  ; x4..
 252     pand   m%6, m%5    ; x5..
 253     pandn  m%5, m%3    ; ..x0
 254     psrl%1 m%3, shift  ; ..x1
 255     por    m%4, m%5    ; x4x0
 256     por    m%3, m%6    ; x5x1
 257 %else ; more dependency, one insn less. sometimes faster, sometimes not
 258     mova   m%5, m%4    ; x5x4
 259     psll%1 m%4, shift  ; x4..
 260     pxor   m%4, m%3    ; (x4^x1)x0
 261     pand   m%4, mask   ; (x4^x1)..
 262     pxor   m%3, m%4    ; x4x0
 263     psrl%1 m%4, shift  ; ..(x1^x4)
 264     pxor   m%5, m%4    ; x5x1
 265     SWAP   %4, %3, %5
 266 %endif
 267 %endmacro
 268
 269 %macro TRANS_SSE4 5-6 ; see above
 270 %ifidn %1, d
 271     mova   m%5, m%3
 272 %ifidn %2, ord
 273     psrl%1 m%3, 16
 274 %endif
 275     pblendw m%3, m%4, 10101010b
 276     psll%1 m%4, 16
 277 %ifidn %2, ord
 278     pblendw m%4, m%5, 01010101b
 279 %else
 280     psrl%1 m%5, 16
 281     por    m%4, m%5
 282 %endif
 283 %elifidn %1, q
 284     mova   m%5, m%3
 285     shufps m%3, m%4, 10001000b
 286     shufps m%5, m%4, 11011101b
 287     SWAP   %4, %5
 288 %endif
 289 %endmacro
 290
 291 %macro HADAMARD 5-6
 292 ; %1=distance in words (0 for vertical pass, 1/2/4 for horizontal passes)
 293 ; %2=sumsub/max/amax (sum and diff / maximum / maximum of absolutes)
 294 ; %3/%4: regs
 295 ; %5(%6): tmpregs
 296 %if %1!=0 ; have to reorder stuff for horizontal op
 297     %ifidn %2, sumsub
 298          %define ORDER ord
 299          ; sumsub needs order because a-b != b-a unless a=b
 300     %else
 301          %define ORDER unord
 302          ; if we just max, order doesn't matter (allows pblendw+or in sse4)
 303     %endif
 304     %if %1==1
 305          TRANS d, ORDER, %3, %4, %5, %6
 306     %elif %1==2
 307          %if mmsize==8
 308              SBUTTERFLY dq, %3, %4, %5
 309          %else
 310              TRANS q, ORDER, %3, %4, %5, %6
 311          %endif
 312     %elif %1==4
 313          SBUTTERFLY qdq, %3, %4, %5
 314     %endif
 315 %endif
 316 %ifidn %2, sumsub
 317     SUMSUB_BA m%3, m%4, m%5
 318 %else
 319     %ifidn %2, amax
 320         %if %0==6
 321             ABS2 m%3, m%4, m%5, m%6
 322         %else
 323             ABS1 m%3, m%5
 324             ABS1 m%4, m%5
 325         %endif
 326     %endif
 327     pmaxsw m%3, m%4
 328 %endif
 329 %endmacro
 330
 331
 332 %macro HADAMARD2_2D 6-7 sumsub
 333     HADAMARD 0, sumsub, %1, %2, %5
 334     HADAMARD 0, sumsub, %3, %4, %5
 335     SBUTTERFLY %6, %1, %2, %5
 336 %ifnum %7
 337     HADAMARD 0, amax, %1, %2, %5, %7
 338 %else
 339     HADAMARD 0, %7, %1, %2, %5
 340 %endif
 341     SBUTTERFLY %6, %3, %4, %5
 342 %ifnum %7
 343     HADAMARD 0, amax, %3, %4, %5, %7
 344 %else
 345     HADAMARD 0, %7, %3, %4, %5
 346 %endif
 347 %endmacro
 348
 349 %macro HADAMARD4_2D 5-6 sumsub
 350     HADAMARD2_2D %1, %2, %3, %4, %5, wd
 351     HADAMARD2_2D %1, %3, %2, %4, %5, dq, %6
 352     SWAP %2, %3
 353 %endmacro
 354
 355 %macro HADAMARD4_2D_SSE 5-6 sumsub
 356     HADAMARD  0, sumsub, %1, %2, %5 ; 1st V row 0 + 1
 357     HADAMARD  0, sumsub, %3, %4, %5 ; 1st V row 2 + 3
 358     SBUTTERFLY   wd, %1, %2, %5     ; %1: m0 1+0 %2: m1 1+0
 359     SBUTTERFLY   wd, %3, %4, %5     ; %3: m0 3+2 %4: m1 3+2
 360     HADAMARD2_2D %1, %3, %2, %4, %5, dq
 361     SBUTTERFLY  qdq, %1, %2, %5
 362     HADAMARD  0, %6, %1, %2, %5     ; 2nd H m1/m0 row 0+1
 363     SBUTTERFLY  qdq, %3, %4, %5
 364     HADAMARD  0, %6, %3, %4, %5     ; 2nd H m1/m0 row 2+3
 365 %endmacro
 366
 367 %macro HADAMARD8_2D 9-10 sumsub
 368     HADAMARD2_2D %1, %2, %3, %4, %9, wd
 369     HADAMARD2_2D %5, %6, %7, %8, %9, wd
 370     HADAMARD2_2D %1, %3, %2, %4, %9, dq
 371     HADAMARD2_2D %5, %7, %6, %8, %9, dq
 372     HADAMARD2_2D %1, %5, %3, %7, %9, qdq, %10
 373     HADAMARD2_2D %2, %6, %4, %8, %9, qdq, %10
 374 %ifnidn %10, amax
 375     SWAP %2, %5
 376     SWAP %4, %7
 377 %endif
 378 %endmacro
 379
 380 %macro SUMSUB2_AB 3
 381     mova    %3, %1
 382     paddw   %1, %1
 383     paddw   %1, %2
 384     psubw   %3, %2
 385     psubw   %3, %2
 386 %endmacro
 387
 388 %macro SUMSUB2_BA 3
 389     mova    m%3, m%1
 390     paddw   m%1, m%2
 391     paddw   m%1, m%2
 392     psubw   m%2, m%3
 393     psubw   m%2, m%3
 394 %endmacro
 395
 396 %macro SUMSUBD2_AB 4
 397     mova    %4, %1
 398     mova    %3, %2
 399     psraw   %2, 1  ; %2: %2>>1
 400     psraw   %1, 1  ; %1: %1>>1
 401     paddw   %2, %4 ; %2: %2>>1+%1
 402     psubw   %1, %3 ; %1: %1>>1-%2
 403 %endmacro
 404
 405 %macro DCT4_1D 5
 406 %ifnum %5
 407     SUMSUB_BADC m%4, m%1, m%3, m%2; m%5
 408     SUMSUB_BA   m%3, m%4, m%5
 409     SUMSUB2_AB  m%1, m%2, m%5
 410     SWAP %1, %3, %4, %5, %2
 411 %else
 412     SUMSUB_BADC m%4, m%1, m%3, m%2
 413     SUMSUB_BA   m%3, m%4
 414     mova       [%5], m%2
 415     SUMSUB2_AB m%1, [%5], m%2
 416     SWAP %1, %3, %4, %2
 417 %endif
 418 %endmacro
 419
 420 %macro IDCT4_1D 5-6
 421 %ifnum %5
 422     SUMSUBD2_AB m%2, m%4, m%6, m%5
 423     ; %2: %2>>1-%4 %4: %2+%4>>1
 424     SUMSUB_BA   m%3, m%1, m%6
 425     ; %3: %1+%3 %1: %1-%3
 426     SUMSUB_BADC m%4, m%3, m%2, m%1, m%6
 427     ; %4: %1+%3 + (%2+%4>>1)
 428     ; %3: %1+%3 - (%2+%4>>1)
 429     ; %2: %1-%3 + (%2>>1-%4)
 430     ; %1: %1-%3 - (%2>>1-%4)
 431 %else
 432     SUMSUBD2_AB m%2, m%4, [%5], [%5+16]
 433     SUMSUB_BA   m%3, m%1
 434     SUMSUB_BADC m%4, m%3, m%2, m%1
 435 %endif
 436     SWAP %1, %4, %3
 437     ; %1: %1+%3 + (%2+%4>>1) row0
 438     ; %2: %1-%3 + (%2>>1-%4) row1
 439     ; %3: %1-%3 - (%2>>1-%4) row2
 440     ; %4: %1+%3 - (%2+%4>>1) row3
 441 %endmacro
 442
 443
 444 %macro LOAD_DIFF 5
 445 %ifidn %3, none
 446     movh       %1, %4
 447     movh       %2, %5
 448     punpcklbw  %1, %2
 449     punpcklbw  %2, %2
 450     psubw      %1, %2
 451 %else
 452     movh       %1, %4
 453     punpcklbw  %1, %3
 454     movh       %2, %5
 455     punpcklbw  %2, %3
 456     psubw      %1, %2
 457 %endif
 458 %endmacro
 459
 460 %macro LOAD_DIFF8x4_SSE2 8
 461     LOAD_DIFF  m%1, m%5, m%6, [%7+%1*FENC_STRIDE], [%8+%1*FDEC_STRIDE]
 462     LOAD_DIFF  m%2, m%5, m%6, [%7+%2*FENC_STRIDE], [%8+%2*FDEC_STRIDE]
 463     LOAD_DIFF  m%3, m%5, m%6, [%7+%3*FENC_STRIDE], [%8+%3*FDEC_STRIDE]
 464     LOAD_DIFF  m%4, m%5, m%6, [%7+%4*FENC_STRIDE], [%8+%4*FDEC_STRIDE]
 465 %endmacro
 466
 467 %macro LOAD_DIFF8x4_SSSE3 8 ; 4x dst, 1x tmp, 1x mul, 2x ptr
 468     movh       m%2, [%8+%1*FDEC_STRIDE]
 469     movh       m%1, [%7+%1*FENC_STRIDE]
 470     punpcklbw  m%1, m%2
 471     movh       m%3, [%8+%2*FDEC_STRIDE]
 472     movh       m%2, [%7+%2*FENC_STRIDE]
 473     punpcklbw  m%2, m%3
 474     movh       m%4, [%8+%3*FDEC_STRIDE]
 475     movh       m%3, [%7+%3*FENC_STRIDE]
 476     punpcklbw  m%3, m%4
 477     movh       m%5, [%8+%4*FDEC_STRIDE]
 478     movh       m%4, [%7+%4*FENC_STRIDE]
 479     punpcklbw  m%4, m%5
 480     pmaddubsw  m%1, m%6
 481     pmaddubsw  m%2, m%6
 482     pmaddubsw  m%3, m%6
 483     pmaddubsw  m%4, m%6
 484 %endmacro
 485
 486 %macro STORE_DCT 6
 487     movq   [%5+%6+ 0], m%1
 488     movq   [%5+%6+ 8], m%2
 489     movq   [%5+%6+16], m%3
 490     movq   [%5+%6+24], m%4
 491     movhps [%5+%6+32], m%1
 492     movhps [%5+%6+40], m%2
 493     movhps [%5+%6+48], m%3
 494     movhps [%5+%6+56], m%4
 495 %endmacro
 496
 497 %macro STORE_IDCT 4
 498     movhps [r0-4*FDEC_STRIDE], %1
 499     movh   [r0-3*FDEC_STRIDE], %1
 500     movhps [r0-2*FDEC_STRIDE], %2
 501     movh   [r0-1*FDEC_STRIDE], %2
 502     movhps [r0+0*FDEC_STRIDE], %3
 503     movh   [r0+1*FDEC_STRIDE], %3
 504     movhps [r0+2*FDEC_STRIDE], %4
 505     movh   [r0+3*FDEC_STRIDE], %4
 506 %endmacro
 507
 508 %macro LOAD_DIFF_8x4P 7-10 r0,r2,0 ; 4x dest, 2x temp, 2x pointer, increment?
 509     LOAD_DIFF m%1, m%5, m%7, [%8],      [%9]
 510     LOAD_DIFF m%2, m%6, m%7, [%8+r1],   [%9+r3]
 511     LOAD_DIFF m%3, m%5, m%7, [%8+2*r1], [%9+2*r3]
 512     LOAD_DIFF m%4, m%6, m%7, [%8+r4],   [%9+r5]
 513 %if %10
 514     lea %8, [%8+4*r1]
 515     lea %9, [%9+4*r3]
 516 %endif
 517 %endmacro
 518
 519 %macro DIFFx2 6-7
 520     movh       %3, %5
 521     punpcklbw  %3, %4
 522     psraw      %1, 6
 523     paddsw     %1, %3
 524     movh       %3, %6
 525     punpcklbw  %3, %4
 526     psraw      %2, 6
 527     paddsw     %2, %3
 528     packuswb   %2, %1
 529 %endmacro
 530
 531 %macro STORE_DIFF 4
 532     movh       %2, %4
 533     punpcklbw  %2, %3
 534     psraw      %1, 6
 535     paddsw     %1, %2
 536     packuswb   %1, %1
 537     movh       %4, %1
 538 %endmacro