git.sesse.net Git - vlc/blob - extras/buildsystem/cmake/include/config.cmake

   1 ###########################################################
   2 # System Includes
   3 ###########################################################
   4 include( CheckIncludeFile )
   5 include (CheckTypeSize)
   6 include (CheckCSourceCompiles)
   7 include (CheckSymbolExists)
   8 include (CheckLibraryExists)
   9
  10 ###########################################################
  11 # Options
  12 ###########################################################
  13 # Options moved before the custom macro includes because those macros need path values, if the ENABLE_CONTRIB
  14 # has been set.
  15
  16 OPTION( ENABLE_HTTPD           "Enable httpd server" ON )
  17 OPTION( ENABLE_STREAM_OUT      "Enable stream output plugins" ON )
  18 OPTION( ENABLE_VLM             "Enable vlm" ON )
  19 OPTION( ENABLE_DYNAMIC_PLUGINS "Enable dynamic plugin" ON )
  20 OPTION( UPDATE_CHECK           "Enable automatic new version checking" OFF )
  21 OPTION( ENABLE_NO_SYMBOL_CHECK "Don't check symbols of modules against libvlc. (Enabling this option speeds up compilation)" OFF )
  22 OPTION( ENABLE_CONTRIB         "Attempt to use VLC contrib system to get the third-party libraries" ON )
  23 OPTION( ENABLE_LOADER          "Enable the win32 codec loader" OFF )
  24 OPTION( ENABLE_NLS             "Enable translation of the program's messages" ON)
  25
  26 if(ENABLE_CONTRIB)
  27
  28   set( CONTRIB_INCLUDE ${CMAKE_SOURCE_DIR}/extras/contrib/include)
  29   set( CONTRIB_LIB ${CMAKE_SOURCE_DIR}/extras/contrib/lib)
  30   set( CONTRIB_PROGRAM ${CMAKE_SOURCE_DIR}/extras/contrib/bin)
  31   set( CMAKE_LIBRARY_PATH ${CONTRIB_LIB} ${CMAKE_LIBRARY_PATH} )
  32   set( CMAKE_PROGRAM_PATH ${CONTRIB_PROGRAM} ${CMAKE_PROGRAM_PATH} )
  33   set( CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${CONTRIB_LIB}" )
  34   set( CMAKE_CXX_LINK_FLAGS "${CMAKE_CXX_LINK_FLAGS} -L${CONTRIB_LIB}" )
  35   set( CMAKE_SHARED_MODULE_CREATE_C_FLAGS "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
  36   set( CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
  37   set( CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
  38   set( CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
  39
  40   # include extras/contrib/include in the header search pathes
  41   include_directories(${CONTRIB_INCLUDE})
  42   set( CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${CONTRIB_INCLUDE} )
  43
  44   # include the extras/contrib/bin to the search path, otherwise, when finding programs it will automatically
  45   # default to system applications (e.g. we should favor the extras/contrib/bin/pkg-config over the system defined
  46   # one).
  47   if(WIN32)
  48     set( ENV{PATH} "${CONTRIB_PROGRAM};$ENV{PATH}" )
  49   else(WIN32)
  50     set( ENV{PATH} "${CONTRIB_PROGRAM}:$ENV{PATH}" )
  51   endif(WIN32)
  52 endif(ENABLE_CONTRIB)
  53
  54 ###########################################################
  55 # Custom Macro Includes
  56 ###########################################################
  57
  58 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_include_files.cmake )
  59 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_functions_exist.cmake )
  60 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_add_compile_flag.cmake )
  61 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_type.cmake )
  62 include( ${CMAKE_SOURCE_DIR}/cmake/pkg_check_modules.cmake )
  63
  64 ###########################################################
  65 # Versioning
  66 ###########################################################
  67
  68 set(VLC_VERSION_MAJOR "0")
  69 set(VLC_VERSION_MINOR "9")
  70 set(VLC_VERSION_PATCH "0")
  71 set(VLC_VERSION_EXTRA "-svn")
  72 set(VLC_VERSION ${VLC_VERSION_MAJOR}.${VLC_VERSION_MINOR}.${VLC_VERSION_PATCH}${VLC_VERSION_EXTRA})
  73
  74 set(PACKAGE "vlc")
  75 set(PACKAGE_NAME "vlc") #for gettext
  76 set(PACKAGE_VERSION "${VLC_VERSION}")
  77 set(PACKAGE_STRING "vlc")
  78 set(VERSION_MESSAGE "vlc-${VLC_VERSION}")
  79 set(COPYRIGHT_MESSAGE "Copyright © the VideoLAN team")
  80 set(COPYRIGHT_YEARS "2001-2008")
  81 set(PACKAGE_VERSION_EXTRA "${VLC_VERSION_EXTRA}")
  82 set(PACKAGE_VERSION_MAJOR "${VLC_VERSION_MAJOR}")
  83 set(PACKAGE_VERSION_MINOR "${VLC_VERSION_MINOR}")
  84 set(PACKAGE_VERSION_REVISION "${VLC_VERSION_PATCH}")
  85
  86 ###########################################################
  87 # Preflight Checks
  88 ###########################################################
  89
  90 IF (NOT CMAKE_BUILD_TYPE)
  91     set(CMAKE_BUILD_TYPE "Debug" CACHE STRING  "build type determining compiler flags" FORCE )
  92 endif(NOT CMAKE_BUILD_TYPE )
  93
  94 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  95     set(DEBUG ON)
  96     add_definitions(-DDEBUG=1)
  97     set(NDEBUG OFF)
  98 endif(CMAKE_BUILD_TYPE STREQUAL "Debug")
  99
 100 set( HAVE_DYNAMIC_PLUGINS ${ENABLE_DYNAMIC_PLUGINS})
 101 set( LIBEXT ${CMAKE_SHARED_MODULE_SUFFIX})
 102
 103 check_c_source_compiles(
 104     "struct __attribute__((__packed__)) foo { int a; } b; int main(){return 0;}"
 105     HAVE_ATTRIBUTE_PACKED)
 106
 107 ###########################################################
 108 # Headers checks
 109 ###########################################################
 110
 111 vlc_check_include_files (malloc.h stdbool.h locale.h)
 112 vlc_check_include_files (stddef.h stdlib.h sys/stat.h)
 113 vlc_check_include_files (stdio.h stdint.h inttypes.h)
 114 vlc_check_include_files (signal.h unistd.h dirent.h)
 115 vlc_check_include_files (netinet/in.h netinet/udplite.h)
 116 vlc_check_include_files (arpa/inet.h net/if.h)
 117 vlc_check_include_files (netdb.h fcntl.h sys/time.h poll.h)
 118 vlc_check_include_files (errno.h time.h alloca.h)
 119 vlc_check_include_files (limits.h)
 120
 121 vlc_check_include_files (string.h strings.h getopt.h)
 122
 123 vlc_check_include_files (dlfcn.h dl.h)
 124
 125 vlc_check_include_files (kernel/OS.h)
 126 vlc_check_include_files (memory.h)
 127 vlc_check_include_files (mach-o/dyld.h)
 128
 129 vlc_check_include_files (pthread.h)
 130
 131 find_package (Threads)
 132
 133 ###########################################################
 134 # Functions/structures checks
 135 ###########################################################
 136
 137 set(CMAKE_REQUIRED_LIBRARIES c)
 138 set(CMAKE_EXTRA_INCLUDE_FILES string.h)
 139 vlc_check_functions_exist(strcpy strcasecmp strncasecmp)
 140 vlc_check_functions_exist(strcasestr stristr strdup)
 141 vlc_check_functions_exist(strndup stricmp strnicmp)
 142 vlc_check_functions_exist(atof strtoll atoll lldiv)
 143 vlc_check_functions_exist(strlcpy stristr strnlen strsep)
 144 vlc_check_functions_exist(strtod strtof strtol stroul)
 145 vlc_check_functions_exist(stroull)
 146 set(CMAKE_EXTRA_INCLUDE_FILES)
 147
 148 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 149 vlc_check_functions_exist(vasprintf)
 150 set(CMAKE_EXTRA_INCLUDE_FILES)
 151
 152 set(CMAKE_EXTRA_INCLUDE_FILES libc.h)
 153 vlc_check_functions_exist(fork)
 154 set(CMAKE_EXTRA_INCLUDE_FILES)
 155
 156 set(CMAKE_EXTRA_INCLUDE_FILES stdlib.h)
 157 vlc_check_functions_exist(putenv getenv setenv)
 158 vlc_check_functions_exist(putenv getenv setenv)
 159 set(CMAKE_EXTRA_INCLUDE_FILES)
 160
 161 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 162 vlc_check_functions_exist(snprintf asprintf)
 163 vlc_check_functions_exist(putenv getenv setenv)
 164 set(CMAKE_EXTRA_INCLUDE_FILES)
 165
 166 set(CMAKE_EXTRA_INCLUDE_FILES unistd.h)
 167 vlc_check_functions_exist(isatty getcwd getuid swab)
 168 set(CMAKE_EXTRA_INCLUDE_FILES)
 169
 170 set(CMAKE_EXTRA_INCLUDE_FILES sys/stat.h)
 171 vlc_check_functions_exist(lstat fstat stat)
 172 set(CMAKE_EXTRA_INCLUDE_FILES)
 173
 174 set(CMAKE_EXTRA_INCLUDE_FILES arpa/inet.h)
 175 vlc_check_functions_exist(inet_aton inet_ntop inet_pton)
 176 set(CMAKE_EXTRA_INCLUDE_FILES)
 177
 178 set(CMAKE_EXTRA_INCLUDE_FILES sys/mman.h)
 179 vlc_check_functions_exist(mmap)
 180 set(CMAKE_EXTRA_INCLUDE_FILES)
 181
 182 set(CMAKE_EXTRA_INCLUDE_FILES locale.h)
 183 vlc_check_functions_exist(uselocale)
 184 set(CMAKE_EXTRA_INCLUDE_FILES)
 185
 186 set(CMAKE_REQUIRED_LIBRARIES)
 187
 188 check_library_exists(poll poll "" HAVE_POLL)
 189
 190 check_c_source_compiles(
 191 "#include <langinfo.h>
 192 int main() { char* cs = nl_langinfo(CODESET); }"
 193 HAVE_LANGINFO_CODESET)
 194
 195 vlc_check_type("struct addrinfo" "sys/socket.h;netdb.h")
 196 if(HAVE_STRUCT_ADDRINFO)
 197   set(HAVE_ADDRINFO ON)
 198 endif(HAVE_STRUCT_ADDRINFO)
 199 vlc_check_type("struct timespec" "time.h")
 200
 201 check_c_source_compiles (
 202 "#include <stdint.h> \n #ifdef UINTMAX \n #error no uintmax
 203  #endif
 204  int main() { return 0;}" HAVE_STDINT_H_WITH_UINTMAX)
 205
 206 check_symbol_exists(ntohl "sys/param.h"  NTOHL_IN_SYS_PARAM_H)
 207 check_symbol_exists(scandir "dirent.h"   HAVE_SCANDIR)
 208 check_symbol_exists(localtime_r "time.h" HAVE_LOCALTIME_R)
 209 check_symbol_exists(alloca "alloca.h"    HAVE_ALLOCA)
 210
 211 check_symbol_exists(va_copy "stdarg.h"   HAVE_VACOPY)
 212 check_symbol_exists(__va_copy "stdarg.h" HAVE___VA_COPY)
 213
 214
 215 check_symbol_exists(getnameinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETNAMEINFO)
 216 check_symbol_exists(getaddrinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETADDRINFO)
 217 if(NOT HAVE_GETADDRINFO)
 218     check_library_exists(getaddrinfo nsl "" HAVE_GETADDRINFO)
 219 endif(NOT HAVE_GETADDRINFO)
 220
 221 vlc_check_functions_exist(iconv)
 222 if(NOT HAVE_ICONV)
 223     set(LIBICONV "iconv")
 224     check_library_exists(iconv iconv "" HAVE_ICONV)
 225 endif(NOT HAVE_ICONV)
 226 set(CMAKE_REQUIRED_LIBRARIES ${LIBICONV})
 227 CHECK_C_SOURCE_COMPILES(" #include <iconv.h>
 228  int main() { return iconv(0, (char **)0, 0, (char**)0, 0); }" ICONV_NO_CONST)
 229 if( ICONV_NO_CONST )
 230   set( ICONV_CONST "const" )
 231 else( ICONV_NO_CONST )
 232   set( ICONV_CONST " ")
 233 endif( ICONV_NO_CONST )
 234 set(CMAKE_REQUIRED_LIBRARIES)
 235
 236 check_library_exists(rt clock_nanosleep "" HAVE_CLOCK_NANOSLEEP)
 237 if (HAVE_CLOCK_NANOSLEEP)
 238     set(LIBRT "rt")
 239 endif (HAVE_CLOCK_NANOSLEEP)
 240
 241 check_library_exists(m pow "" HAVE_LIBM)
 242 if (HAVE_LIBM)
 243     set (LIBM "m")
 244 endif (HAVE_LIBM)
 245
 246 check_symbol_exists(connect "sys/types.h;sys/socket.h" HAVE_CONNECT)
 247 if(NOT HAVE_CONNECT)
 248     check_library_exists(connect socket "" HAVE_CONNECT)
 249     if(NOT HAVE_CONNECT)
 250         vlc_module_add_link_libraries(libvlc connect)
 251         vlc_module_add_link_libraries(cdda   connect)
 252         vlc_module_add_link_libraries(cddax  connect)
 253     endif(NOT HAVE_CONNECT)
 254 endif(NOT HAVE_CONNECT)
 255
 256 ###########################################################
 257 # Other check
 258 ###########################################################
 259
 260 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_test_inline.cmake )
 261
 262 ###########################################################
 263 # Platform check
 264 ###########################################################
 265
 266 if(APPLE)
 267     include( ${CMAKE_SOURCE_DIR}/cmake/vlc_find_frameworks.cmake )
 268
 269     # Mac OS X (10.4 and 10.5)  can't poll a tty properly
 270     # So we deactivate its uses
 271     set(HAVE_POLL OFF)
 272
 273     if(ENABLE_NO_SYMBOL_CHECK)
 274         set(DYNAMIC_LOOKUP "-undefined dynamic_lookup")
 275     else(ENABLE_NO_SYMBOL_CHECK)
 276         set(DYNAMIC_LOOKUP)
 277     endif(ENABLE_NO_SYMBOL_CHECK)
 278     set(CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS
 279      "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} ${DYNAMIC_LOOKUP}")
 280     set(CMAKE_SHARED_MODULE_CREATE_C_FLAGS
 281      "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} ${DYNAMIC_LOOKUP}")
 282
 283     # For pre-10.5
 284     set( CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_C_FLAGS} -fno-common")
 285
 286     set(SYS_DARWIN 1)
 287     add_definitions(-std=gnu99) # Hack for obj-c files to be compiled with gnu99
 288     vlc_enable_modules(macosx minimal_macosx opengllayer
 289                        access_eyetv quartztext auhal)
 290
 291     # On Pre-10.5
 292     vlc_module_add_link_flags (ffmpeg "-read_only_relocs warning")
 293
 294    # vlc_check_include_files (ApplicationServices/ApplicationServices.h)
 295    # vlc_check_include_files (Carbon/Carbon.h)
 296    # vlc_check_include_files (CoreAudio/CoreAudio.h)
 297
 298    # check_symbol_exists (CFLocaleCopyCurrent "CoreFoundation/CoreFoundation.h" "" HAVE_CFLOCALECOPYCURRENT)
 299    # check_symbol_exists (CFPreferencesCopyAppValue "CoreFoundation/CoreFoundation.h" "" HAVE_CFPREFERENCESCOPYAPPVALUE)
 300
 301     vlc_find_frameworks(Cocoa Carbon OpenGL AGL IOKit Quicktime
 302                         WebKit QuartzCore Foundation ApplicationServices
 303                         CoreAudio AudioUnit AudioToolbox)
 304     vlc_module_add_link_libraries(macosx
 305         ${Cocoa_FRAMEWORKS}
 306         ${IOKit_FRAMEWORKS}
 307         ${OpenGL_FRAMEWORKS}
 308         ${AGL_FRAMEWORKS}
 309         ${Quicktime_FRAMEWORKS}
 310         ${WebKit_FRAMEWORKS})
 311     vlc_module_add_link_libraries(minimal_macosx
 312         ${Cocoa_FRAMEWORKS}
 313         ${Carbon_FRAMEWORKS}
 314         ${OpenGL_FRAMEWORKS}
 315         ${AGL_FRAMEWORKS})
 316     vlc_module_add_link_libraries(access_eyetv
 317         ${Foundation_FRAMEWORKS})
 318     vlc_module_add_link_libraries(opengllayer
 319          ${Cocoa_FRAMEWORKS}
 320          ${QuartzCore_FRAMEWORKS}
 321          ${OpenGL_FRAMEWORKS} )
 322     vlc_module_add_link_libraries(quartztext
 323          ${Carbon_FRAMEWORKS}
 324          ${ApplicationServices_FRAMEWORKS} )
 325     vlc_module_add_link_libraries(auhal
 326          ${Carbon_FRAMEWORKS}
 327          ${CoreAudio_FRAMEWORKS}
 328          ${AudioUnit_FRAMEWORKS}
 329          ${AudioToolbox_FRAMEWORKS} )
 330     vlc_module_add_link_libraries(mp4 ${IOKit_FRAMEWORKS} )
 331     vlc_module_add_link_libraries(mkv ${IOKit_FRAMEWORKS} )
 332
 333     add_executable(VLC MACOSX_BUNDLE src/vlc.c)
 334     target_link_libraries(VLC libvlc)
 335     set( MacOS ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/MacOS )
 336     add_custom_command(
 337         TARGET VLC
 338         POST_BUILD
 339         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 340         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx
 341         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx
 342         COMMAND for i in vlc.xcodeproj Resources README.MacOSX.rtf\; do cp -R ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx\; done
 343         COMMAND for i in AUTHORS COPYING THANKS\;do cp ${CMAKE_CURRENT_SOURCE_DIR}/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp\; done
 344         COMMAND for i in AppleRemote.h AppleRemote.m about.h about.m applescript.h applescript.m controls.h controls.m equalizer.h equalizer.m intf.h intf.m macosx.m misc.h misc.m open.h open.m output.h output.m playlist.h playlist.m playlistinfo.h playlistinfo.m prefs_widgets.h prefs_widgets.m prefs.h prefs.m vout.h voutqt.m voutgl.m wizard.h wizard.m extended.h extended.m bookmarks.h bookmarks.m sfilters.h sfilters.m update.h update.m interaction.h interaction.m embeddedwindow.h embeddedwindow.m fspanel.h fspanel.m vout.m\; do cp ${CMAKE_CURRENT_SOURCE_DIR}/modules/gui/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx\; done
 345         COMMAND cd ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx && xcodebuild -target vlc | grep -vE '^\([ \\t]|$$\)' && cd ../../../../ && cp ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Info.plist ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents && cp -R ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Resources/English.lproj ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources
 346         COMMAND cp -r ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/Resources ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents
 347         COMMAND find -d ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources -type d -name \\.svn -exec rm -rf {} "\;"
 348         COMMAND rm -rf ${MacOS}/modules ${MacOS}/locale ${MacOS}/share
 349         COMMAND ln -s ${CMAKE_CURRENT_SOURCE_DIR}/share ${MacOS}/share
 350         COMMAND ln -s ${CMAKE_CURRENT_BINARY_DIR}/modules ${MacOS}/modules
 351         COMMAND find ${CMAKE_BINARY_DIR}/po -name *.gmo -exec sh -c \"mkdir -p ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES\; ln -s {} ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES/vlc.mo\" "\;"
 352         COMMAND ln -sf VLC ${MacOS}/clivlc #useless?
 353         COMMAND printf "APPLVLC#" > ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/PkgInfo
 354         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 355     )
 356     set( MacOS )
 357
 358 endif(APPLE)
 359
 360 ###########################################################
 361 # info
 362 ###########################################################
 363
 364 macro(command_to_configvar command var)
 365  execute_process(
 366   COMMAND sh -c "${command}"
 367   OUTPUT_VARIABLE ${var}
 368   OUTPUT_STRIP_TRAILING_WHITESPACE)
 369  string( REPLACE "\n" "\\n" ${var} "${${var}}")
 370 endmacro(command_to_configvar)
 371
 372 command_to_configvar( "whoami" VLC_COMPILE_BY )
 373 command_to_configvar( "hostname" VLC_COMPILE_HOST )
 374 command_to_configvar( "hostname" VLC_COMPILE_DOMAIN )
 375 command_to_configvar( "${CMAKE_C_COMPILER} --version" VLC_COMPILER )
 376 # FIXME: WTF? this is not the configure line!
 377 command_to_configvar( "${CMAKE_C_COMPILER} --version" CONFIGURE_LINE )
 378 set( VLC_COMPILER "${CMAKE_C_COMPILER}" )
 379
 380 ###########################################################
 381 # Modules: Following are all listed in options
 382 ###########################################################
 383
 384 # This module will be enabled but user could disabled it
 385 vlc_enable_modules(dummy logger memcpy)
 386 vlc_enable_modules(mpgv mpga m4v m4a h264 vc1 demux_cdg cdg ps pva avi mp4 rawdv rawvid nsv real aiff mjpeg demuxdump flacsys tta)
 387 vlc_enable_modules(cvdsub svcdsub spudec subsdec subsusf t140 dvbsub cc mpeg_audio lpcm a52 dts cinepak flac)
 388 vlc_enable_modules(deinterlace invert adjust transform wave ripple psychedelic gradient motionblur rv32 rotate noise grain extract sharpen seamcarving)
 389 vlc_enable_modules(converter_fixed mono)
 390 vlc_enable_modules(trivial_resampler ugly_resampler)
 391 vlc_enable_modules(trivial_channel_mixer trivial_mixer)
 392 vlc_enable_modules(playlist export nsc xtag)
 393 vlc_enable_modules(i420_rgb grey_yuv rawvideo blend scale image logo magnify puzzle colorthres)
 394 vlc_enable_modules(wav araw subtitle vobsub adpcm a52sys dtssys au ty voc xa nuv smf)
 395 vlc_enable_modules(access_directory access_file access_udp access_tcp)
 396 vlc_enable_modules(access_http access_mms access_ftp)
 397 vlc_enable_modules(access_filter_bandwidth)
 398 vlc_enable_modules(packetizer_mpegvideo packetizer_h264)
 399 vlc_enable_modules(packetizer_mpeg4video packetizer_mpeg4audio)
 400 vlc_enable_modules(packetizer_vc1)
 401 vlc_enable_modules(spatializer)
 402 vlc_enable_modules(asf)
 403
 404 set(enabled ${ENABLE_STREAM_OUT})
 405 vlc_register_modules(${enabled} access_output_dummy access_output_udp access_output_file access_output_http)
 406 vlc_register_modules(${enabled} mux_ps mux_avi mux_mp4 mux_asf mux_dummy mux_wav mux_mpjpeg)
 407 vlc_register_modules(${enabled} packetizer_copy)
 408
 409 vlc_register_modules(${enabled} stream_out_dummy stream_out_standard stream_out_es stream_out_rtp stream_out_description vod_rtsp)
 410 vlc_register_modules(${enabled} stream_out_duplicate stream_out_display stream_out_transcode stream_out_bridge stream_out_mosaic_bridge stream_out_autodel)
 411 vlc_register_modules(${enabled} stream_out_gather)
 412 # vlc_register_modules(${enabled} stream_out_transrate)
 413 # vlc_register_modules(${enabled} rtcp)
 414 vlc_register_modules(${enabled} profile_parser)
 415
 416 if(NOT mingwce)
 417    set(enabled ON)
 418 endif(NOT mingwce)
 419 vlc_register_modules(${enabled} access_fake access_filter_timeshift access_filter_record access_filter_dump)
 420 vlc_register_modules(${enabled} gestures rc telnet hotkeys showintf marq podcast shout sap fake folder)
 421 vlc_register_modules(${enabled} rss mosaic wall motiondetect clone crop erase bluescreen alphamask gaussianblur)
 422 vlc_register_modules(${enabled} i420_yuy2 i422_yuy2 i420_ymga i422_i420 yuy2_i422 yuy2_i420 chroma_chain)
 423 vlc_register_modules(${enabled} aout_file linear_resampler bandlimited_resampler)
 424 vlc_register_modules(${enabled} float32_mixer spdif_mixer simple_channel_mixer)
 425 vlc_register_modules(${enabled} dolby_surround_decoder headphone_channel_mixer normvol equalizer param_eq)
 426 vlc_register_modules(${enabled} converter_float a52tospdif dtstospdif audio_format)
 427 set(enabled)
 428
 429 if(NOT WIN32)
 430    vlc_enable_modules(screensaver)
 431 endif(NOT WIN32)
 432
 433 # This module is disabled because the CMakeList.txt which
 434 # is generated isn't correct. We'll put that back
 435 # when cmake will be accepted as default build system
 436 vlc_disable_modules(motion)
 437
 438 ###########################################################
 439 # libraries
 440 ###########################################################
 441
 442 include_directories(${CONTRIB_INCLUDE})
 443
 444 #fixme: use find_package(cddb 0.9.5)
 445 pkg_check_modules(LIBCDDB libcddb>=0.9.5)
 446 if(${LIBCDDB_FOUND})
 447   vlc_module_add_link_libraries(cdda ${LIBCDDB_LIBRARIES})
 448   vlc_add_module_compile_flag(cdda ${LIBCDDB_CFLAGS} )
 449 endif(${LIBCDDB_FOUND})
 450
 451 find_package(Dlopen)
 452 set(HAVE_DL_DLOPEN ${Dlopen_FOUND})
 453
 454 # Advanced Linux Sound Architecture (ALSA)
 455 pkg_check_modules(ALSA alsa>=1.0.0-rc4)
 456 if (${ALSA_FOUND})
 457   set (HAVE_ALSA_NEW_API "1")
 458 else (${ALSA_FOUND})
 459   pkg_check_modules(ALSA alsa)
 460 endif (${ALSA_FOUND})
 461
 462 if (${ALSA_FOUND})
 463   set (HAVE_ALSA "1")
 464   vlc_enable_modules(alsa)
 465   vlc_add_module_compile_flag(alsa ${ALSA_CFLAGS})
 466   vlc_module_add_link_libraries(alsa ${ALSA_LIBRARIES})
 467 endif (${ALSA_FOUND})
 468
 469 # Open Sound System (OSS)
 470 # TODO
 471
 472 find_package(FFmpeg)
 473 if(FFmpeg_FOUND)
 474   string(REPLACE ";" " " FFmpeg_CFLAGS "${FFmpeg_CFLAGS}")
 475   set( CMAKE_REQUIRED_FLAGS_saved ${CMAKE_REQUIRED_FLAGS} )
 476   set( CMAKE_REQUIRED_FLAGS ${FFmpeg_CFLAGS} )
 477
 478   vlc_check_include_files (ffmpeg/avcodec.h libavcodec/avcodec.h)
 479   vlc_check_include_files (ffmpeg/avutil.h libavutil/avutil.h)
 480   vlc_check_include_files (ffmpeg/swscale.h libswscale/swscale.h)
 481   check_c_source_compiles( "#include <stdint.h>\n#include <postproc/postprocess.h>\nint main(){return 0;}" HAVE_POSTPROC_POSTPROCESS_H )
 482   vlc_check_include_files (libpostproc/postprocess.h)
 483
 484   message( STATUS "avcodec found ${HAVE_FFMPEG_AVCODEC_H} || ${HAVE_LIBAVCODEC_AVCODEC_H}")
 485   message( STATUS "avutil found ${HAVE_FFMPEG_AVUTIL_H} || ${HAVE_LIBAVUTIL_AVUTIL_H}")
 486   message( STATUS "swscale found ${HAVE_FFMPEG_SWSCALE_H} || ${HAVE_LIBSWSCALE_SWSCALE_H}")
 487   message( STATUS "postprocess found ${HAVE_POSTPROC_POSTPROCESS_H} || ${HAVE_LIBPOSTPROC_POSTPROCESS_H}")
 488
 489   vlc_enable_modules(ffmpeg)
 490   vlc_add_module_compile_flag(ffmpeg ${FFmpeg_CFLAGS})
 491   vlc_module_add_link_libraries(ffmpeg ${FFmpeg_LIBRARIES})
 492
 493   set( CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS_saved} )
 494   set( CMAKE_REQUIRED_FLAGS_saved )
 495 endif(FFmpeg_FOUND)
 496
 497 find_package(Lua)
 498 if(Lua_FOUND)
 499   set(HAVE_LUA TRUE)
 500   vlc_enable_modules(lua)
 501   vlc_check_include_files (lua.h lualib.h)
 502   vlc_add_module_compile_flag(lua ${Lua_CFLAGS} )
 503   vlc_module_add_link_libraries(lua ${Lua_LIBRARIES})
 504 endif(Lua_FOUND)
 505
 506 find_package(Qt4)
 507 if(QT4_FOUND)
 508   set(HAVE_QT4 TRUE)
 509   include_directories(${QT_INCLUDES})
 510   vlc_check_include_files (qt.h)
 511   vlc_enable_modules(qt4)
 512   #execute_process leaves the trailing newline appended to the variable, unlike exec_program
 513   #execute_process( COMMAND ${PKG_CONFIG_EXECUTABLE} --variable=prefix QtCore OUTPUT_VARIABLE QT4LOCALEDIR)
 514   exec_program( ${PKG_CONFIG_EXECUTABLE} ARGS --variable=prefix QtCore OUTPUT_VARIABLE QT4LOCALEDIR)
 515   set(QT4LOCALEDIR ${QT4LOCALEDIR}/share/qt4/translations )
 516   vlc_add_module_compile_flag(qt4 ${QT_CFLAGS})
 517   vlc_add_module_compile_flag(qt4 -DQT4LOCALEDIR=\\\\"${QT4LOCALEDIR}\\\\" )
 518   vlc_module_add_link_libraries(qt4 ${QT_QTCORE_LIBRARY} ${QT_QTGUI_LIBRARY})
 519
 520   # Define our own qt4_wrap_ui macro to match wanted behaviour
 521   MACRO (VLC_QT4_WRAP_UI outfiles )
 522     FOREACH (it ${ARGN})
 523      string(REPLACE ".ui" ".h" outfile "${it}")
 524       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 525       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 526       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 527         COMMAND mkdir -p `dirname ${outfile}`
 528         COMMAND ${QT_UIC_EXECUTABLE}
 529         ARGS -o ${outfile} ${infile}
 530         MAIN_DEPENDENCY ${infile})
 531       SET(${outfiles} ${${outfiles}} ${outfile})
 532     ENDFOREACH (it)
 533   ENDMACRO (VLC_QT4_WRAP_UI)
 534
 535   MACRO (VLC_QT4_GENERATE_MOC outfiles flags )
 536     string(REGEX MATCHALL "[^\\ ]+" flags_list ${flags})
 537     FOREACH (it ${ARGN})
 538       string(REPLACE ".hpp" ".moc.cpp" outfile "${it}")
 539       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 540       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 541       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 542         COMMAND mkdir -p `dirname ${outfile}`
 543         COMMAND ${QT_MOC_EXECUTABLE}
 544         ARGS ${flags_list}
 545         ARGS -I ${CMAKE_BINARY_DIR}/include
 546         ARGS -o ${outfile} ${infile}
 547         MAIN_DEPENDENCY ${it}
 548         )
 549       SET(${outfiles} ${${outfiles}} ${outfile})
 550     ENDFOREACH (it)
 551   ENDMACRO (VLC_QT4_GENERATE_MOC)
 552
 553
 554 endif(QT4_FOUND)
 555
 556 find_package(OpenGL)
 557 if(OPENGL_FOUND)
 558   vlc_enable_modules(opengl)
 559   vlc_check_include_files (gl/gl.h)
 560   vlc_check_include_files (gl/glu.h)
 561   vlc_check_include_files (gl/glx.h)
 562   vlc_add_module_compile_flag(opengl ${OPENGL_CFLAGS})
 563   vlc_module_add_link_libraries(opengl ${OPENGL_LIBRARIES})
 564 endif(OPENGL_FOUND)
 565
 566 find_package(Matroska 0.7.7)
 567 if(Matroska_FOUND)
 568   vlc_enable_modules(mkv)
 569   vlc_check_include_files (matroska/KaxAttachments.h)
 570   vlc_check_include_files (matroska/KaxVersion.h)
 571   vlc_module_add_link_libraries(mkv ${Matroska_LIBRARIES})
 572 endif(Matroska_FOUND)
 573
 574 find_package(Live555)
 575 if(Live555_FOUND)
 576   vlc_enable_modules(live555)
 577   vlc_add_module_compile_flag(live555 ${Live555_CFLAGS})
 578   vlc_module_add_link_libraries(live555 ${Live555_LIBRARIES})
 579 endif(Live555_FOUND)
 580
 581 set(CURSES_NEED_NCURSES TRUE)
 582 find_package(Curses)
 583 if(CURSES_LIBRARIES)
 584   vlc_enable_modules(ncurses)
 585   vlc_module_add_link_libraries(ncurses ${CURSES_LIBRARIES})
 586 endif(CURSES_LIBRARIES)
 587
 588 find_package(X11)
 589 if(X11_FOUND)
 590   vlc_enable_modules(x11 panoramix)
 591   vlc_check_include_files (X11/Xlib.h)
 592   vlc_module_add_link_libraries(x11       ${X11_LIBRARIES})
 593   vlc_module_add_link_libraries(panoramix ${X11_LIBRARIES})
 594 endif(X11_FOUND)
 595
 596 find_package(Mpeg2)
 597 if(Mpeg2_FOUND)
 598   vlc_enable_modules(libmpeg2)
 599   check_include_files ("stdint.h;mpeg2dec/mpeg2.h" HAVE_MPEG2DEC_MPEG2_H)
 600   vlc_module_add_link_libraries(libmpeg2 ${Mpeg2_LIBRARIES})
 601 endif(Mpeg2_FOUND)
 602
 603 find_package(Dvbpsi)
 604 if(Dvbpsi_FOUND)
 605   vlc_register_modules(${ENABLE_STREAM_OUT} mux_ts)
 606   vlc_enable_modules(ts)
 607   check_include_files ("stdint.h;dvbpsi/dvbpsi.h;dvbpsi/demux.h;dvbpsi/descriptor.h;dvbpsi/pat.h;dvbpsi/pmt.h;dvbpsi/sdt.h;dvbpsi/dr.h" HAVE_DVBPSI_DR_H)
 608   vlc_module_add_link_libraries(ts      ${Dvbpsi_LIBRARIES})
 609   vlc_module_add_link_libraries(mux_ts  ${Dvbpsi_LIBRARIES})
 610   vlc_module_add_link_libraries(dvb     ${Dvbpsi_LIBRARIES})
 611 endif(Dvbpsi_FOUND)
 612
 613 vlc_check_include_files (id3tag.h zlib.h)
 614 if(HAVE_ID3TAG_H AND HAVE_ZLIB_H)
 615   vlc_enable_modules(id3tag)
 616   vlc_module_add_link_libraries(id3tag  "id3tag;z")
 617 endif(HAVE_ID3TAG_H AND HAVE_ZLIB_H)
 618
 619 find_package(Taglib)
 620 if(Taglib_FOUND)
 621   set(HAVE_TAGLIB 1)
 622   vlc_enable_modules(taglib)
 623   vlc_module_add_link_libraries(taglib "${Taglib_LIBRARIES};z")
 624   vlc_add_module_compile_flag(taglib "${Taglib_CFLAGS}")
 625 endif(Taglib_FOUND)
 626
 627 vlc_check_include_files (zlib.h)
 628 if(HAVE_ZLIB_H)
 629   vlc_module_add_link_libraries(access_http z)
 630   vlc_module_add_link_libraries(mkv z)
 631   vlc_module_add_link_libraries(mp4 z)
 632   vlc_module_add_link_libraries(stream_out_bridge z)
 633   vlc_module_add_link_libraries(sap z)
 634 endif(HAVE_ZLIB_H)
 635
 636 set(CMAKE_REQUIRED_INCLUDES)
 637
 638 ###########################################################
 639 # Final configuration
 640 ###########################################################
 641
 642 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/include/config.h)