git.sesse.net Git - vlc/blob - extras/buildsystem/cmake/include/config.cmake

   1 include( CheckIncludeFile )
   2 include (CheckTypeSize)
   3 include (CheckCSourceCompiles)
   4 include (CheckSymbolExists)
   5 include (CheckLibraryExists)
   6
   7 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_include_files.cmake )
   8 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_functions_exist.cmake )
   9 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_add_compile_flag.cmake )
  10 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_type.cmake )
  11 include( ${CMAKE_SOURCE_DIR}/cmake/pkg_check_modules.cmake )
  12
  13 ###########################################################
  14 # VERSION
  15 ###########################################################
  16
  17 set(VLC_VERSION_MAJOR 0)
  18 set(VLC_VERSION_MINOR 9)
  19 set(VLC_VERSION_PATCH 0)
  20 set(VLC_VERSION_EXTRA "-svn")
  21
  22 set(PACKAGE "vlc")
  23 set(PACKAGE_STRING "vlc")
  24 set(VERSION_MESSAGE "vlc-${VLC_VERSION_MAJOR}.${VLC_VERSION_MINOR}.${VLC_VERSION_PATCH}${VLC_VERSION_EXTRA}")
  25 set(COPYRIGHT_MESSAGE "Copyright © the VideoLAN team")
  26 set(COPYRIGHT_YEARS "2001-2008")
  27
  28 ###########################################################
  29 # Options
  30 ###########################################################
  31
  32 OPTION( ENABLE_HTTPD           "Enable httpd server" ON )
  33 OPTION( ENABLE_VLM             "Enable vlm" ON )
  34 OPTION( ENABLE_DYNAMIC_PLUGINS "Enable dynamic plugin" ON )
  35 OPTION( UPDATE_CHECK           "Enable automatic new version checking" OFF )
  36 OPTION( ENABLE_NO_SYMBOL_CHECK "Don't check symbols of modules against libvlc. (Enabling this option speeds up compilation)" ON )
  37
  38 IF (NOT CMAKE_BUILD_TYPE)
  39     set(CMAKE_BUILD_TYPE "Debug" CACHE STRING  "build type determining compiler flags" FORCE )
  40 endif(NOT CMAKE_BUILD_TYPE )
  41
  42 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  43     set(DEBUG ON)
  44     set(NDEBUG ON)
  45 endif(CMAKE_BUILD_TYPE STREQUAL "Debug")
  46
  47 set( HAVE_DYNAMIC_PLUGINS ${ENABLE_DYNAMIC_PLUGINS})
  48 set( LIBEXT ${CMAKE_SHARED_MODULE_SUFFIX})
  49
  50 ###########################################################
  51 # Headers checks
  52 ###########################################################
  53
  54 vlc_check_include_files (malloc.h stdbool.h locale.h)
  55 vlc_check_include_files (stddef.h stdlib.h sys/stat.h)
  56 vlc_check_include_files (stdio.h stdint.h inttypes.h)
  57 vlc_check_include_files (signal.h unistd.h dirent.h)
  58 vlc_check_include_files (netinet/in.h netinet/udplite.h)
  59 vlc_check_include_files (arpa/inet.h net/if.h)
  60 vlc_check_include_files (netdb.h fcntl.h sys/time.h poll.h)
  61 vlc_check_include_files (errno.h time.h alloca.h)
  62 vlc_check_include_files (limits.h)
  63
  64 vlc_check_include_files (string.h strings.h getopt.h)
  65
  66 vlc_check_include_files (dlfcn.h dl.h)
  67
  68 vlc_check_include_files (kernel/OS.h)
  69 vlc_check_include_files (memory.h)
  70 vlc_check_include_files (mach-o/dyld.h)
  71
  72 vlc_check_include_files (pthread.h)
  73
  74 find_package (Threads)
  75
  76 ###########################################################
  77 # Functions/structures checks
  78 ###########################################################
  79 set(CMAKE_REQUIRED_LIBRARIES c)
  80 set(CMAKE_EXTRA_INCLUDE_FILES string.h)
  81 vlc_check_functions_exist(strcpy strcasecmp)
  82 vlc_check_functions_exist(strcasestr strdup)
  83 vlc_check_functions_exist(strndup stricmp strnicmp)
  84 vlc_check_functions_exist(atof strtoll atoll lldiv)
  85 vlc_check_functions_exist(strlcpy stristr strnlen strsep)
  86 vlc_check_functions_exist(strtod strtof strtol stroul)
  87 vlc_check_functions_exist(stroull)
  88 set(CMAKE_EXTRA_INCLUDE_FILES)
  89
  90 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
  91 vlc_check_functions_exist(vasprintf)
  92 set(CMAKE_EXTRA_INCLUDE_FILES)
  93
  94 set(CMAKE_EXTRA_INCLUDE_FILES libc.h)
  95 vlc_check_functions_exist(fork)
  96 set(CMAKE_EXTRA_INCLUDE_FILES)
  97
  98 set(CMAKE_EXTRA_INCLUDE_FILES stdlib.h)
  99 vlc_check_functions_exist(putenv getenv setenv)
 100 vlc_check_functions_exist(putenv getenv setenv)
 101 set(CMAKE_EXTRA_INCLUDE_FILES)
 102
 103 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 104 vlc_check_functions_exist(snprintf asprintf)
 105 vlc_check_functions_exist(putenv getenv setenv)
 106 set(CMAKE_EXTRA_INCLUDE_FILES)
 107
 108 set(CMAKE_EXTRA_INCLUDE_FILES unistd.h)
 109 vlc_check_functions_exist(isatty getcwd getuid)
 110 set(CMAKE_EXTRA_INCLUDE_FILES)
 111
 112 set(CMAKE_EXTRA_INCLUDE_FILES sys/stat.h)
 113 vlc_check_functions_exist(lstat fstat stat)
 114 set(CMAKE_EXTRA_INCLUDE_FILES)
 115
 116 set(CMAKE_EXTRA_INCLUDE_FILES arpa/inet.h)
 117 vlc_check_functions_exist(inet_pton inet_aton inet_ntop inet_pton)
 118 set(CMAKE_EXTRA_INCLUDE_FILES)
 119
 120 set(CMAKE_REQUIRED_LIBRARIES)
 121
 122 check_library_exists(poll poll "" HAVE_POLL)
 123
 124 check_c_source_compiles(
 125 "#include <langinfo.h>
 126 int main() { char* cs = nl_langinfo(CODESET); }"
 127 HAVE_LANGINFO_CODESET)
 128
 129 vlc_check_type("struct addrinfo" "sys/socket.h;netdb.h")
 130 if(HAVE_STRUCT_ADDRINFO)
 131   set(HAVE_ADDRINFO ON)
 132 endif(HAVE_STRUCT_ADDRINFO)
 133 vlc_check_type("struct timespec" "time.h")
 134
 135 check_c_source_compiles (
 136 "#include <stdint.h> \n #ifdef UINTMAX \n #error no uintmax
 137  #endif
 138  int main() { return 0;}" HAVE_STDINT_H_WITH_UINTMAX)
 139
 140 check_symbol_exists(ntohl "sys/param.h"  NTOHL_IN_SYS_PARAM_H)
 141 check_symbol_exists(scandir "dirent.h"   HAVE_SCANDIR)
 142 check_symbol_exists(scandir "dirent.h"   HAVE_SCANDIR)
 143 check_symbol_exists(localtime_r "time.h" HAVE_LOCALTIME_R)
 144 check_symbol_exists(alloca "alloca.h"    HAVE_ALLOCA)
 145
 146 check_symbol_exists(va_copy "stdarg.h"   HAVE_VACOPY)
 147 check_symbol_exists(__va_copy "stdarg.h" HAVE___VA_COPY)
 148
 149
 150 check_symbol_exists(getnameinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETNAMEINFO)
 151 check_symbol_exists(getaddrinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETADDRINFO)
 152 if(NOT HAVE_GETADDRINFO)
 153     check_library_exists(getaddrinfo nsl "" HAVE_GETADDRINFO)
 154 endif(NOT HAVE_GETADDRINFO)
 155
 156 vlc_check_functions_exist(iconv)
 157 if(NOT HAVE_ICONV)
 158     set(LIBICONV "iconv")
 159     check_library_exists(iconv iconv "" HAVE_ICONV)
 160 endif(NOT HAVE_ICONV)
 161 set(CMAKE_REQUIRED_LIBRARIES ${LIBICONV})
 162 CHECK_C_SOURCE_COMPILES(" #include <iconv.h>
 163  int main() { return iconv(0, (char **)0, 0, (char**)0, 0); }" ICONV_NO_CONST)
 164 if( ICONV_NO_CONST )
 165   set( ICONV_CONST "const" )
 166 else( ICONV_NO_CONST )
 167   set( ICONV_CONST " ")
 168 endif( ICONV_NO_CONST )
 169 set(CMAKE_REQUIRED_LIBRARIES)
 170
 171 check_library_exists(rt clock_nanosleep "" HAVE_CLOCK_NANOSLEEP)
 172 if (HAVE_CLOCK_NANOSLEEP)
 173     set(LIBRT "rt")
 174 endif (HAVE_CLOCK_NANOSLEEP)
 175
 176 check_library_exists(m pow "" HAVE_LIBM)
 177 if (HAVE_LIBM)
 178     set (LIBM "m")
 179 endif (HAVE_LIBM)
 180
 181 check_symbol_exists(connect "sys/types.h;sys/socket.h" HAVE_CONNECT)
 182 if(NOT HAVE_CONNECT)
 183     check_library_exists(connect socket HAVE_CONNECT)
 184     if(NOT HAVE_CONNECT)
 185         vlc_module_add_link_libraries(libvlc connect)
 186         vlc_module_add_link_libraries(cdda   connect)
 187         vlc_module_add_link_libraries(cddax  connect)
 188     endif(NOT HAVE_CONNECT)
 189 endif(NOT HAVE_CONNECT)
 190
 191 ###########################################################
 192 # Other check
 193 ###########################################################
 194 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_test_inline.cmake )
 195
 196 ###########################################################
 197 # Platform check
 198 ###########################################################
 199 if(APPLE)
 200     include( ${CMAKE_SOURCE_DIR}/cmake/vlc_find_frameworks.cmake )
 201
 202     if(ENABLE_NO_SYMBOL_CHECK)
 203         set(DYNAMIC_LOOKUP "-undefined dynamic_lookup")
 204     else(ENABLE_NO_SYMBOL_CHECK)
 205         set(DYNAMIC_LOOKUP)
 206     endif(ENABLE_NO_SYMBOL_CHECK)
 207     set(CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS
 208      "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} ${DYNAMIC_LOOKUP}")
 209     set(CMAKE_SHARED_MODULE_CREATE_C_FLAGS
 210      "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} ${DYNAMIC_LOOKUP}")
 211
 212     # For pre-10.5
 213     set( CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_C_FLAGS} -fno-common")
 214
 215     set(SYS_DARWIN 1)
 216     add_definitions(-std=gnu99) # Hack for obj-c files to be compiled with gnu99
 217     vlc_enable_modules(macosx minimal_macosx access_eyetv quartztext)
 218
 219     vlc_check_include_files (ApplicationServices/ApplicationServices.h)
 220     vlc_check_include_files (Carbon/Carbon.h)
 221     vlc_check_include_files (CoreAudio/CoreAudio.h)
 222
 223    # check_symbol_exists (CFLocaleCopyCurrent "CoreFoundation/CoreFoundation.h" "" HAVE_CFLOCALECOPYCURRENT)
 224    # check_symbol_exists (CFPreferencesCopyAppValue "CoreFoundation/CoreFoundation.h" "" HAVE_CFPREFERENCESCOPYAPPVALUE)
 225
 226     vlc_find_frameworks(Cocoa Carbon OpenGL AGL IOKit Quicktime
 227                         WebKit QuartzCore Foundation ApplicationServices)
 228     vlc_module_add_link_libraries(macosx
 229         ${Cocoa_FRAMEWORKS}
 230         ${IOKit_FRAMEWORKS}
 231         ${OpenGL_FRAMEWORKS}
 232         ${AGL_FRAMEWORKS}
 233         ${Quicktime_FRAMEWORKS}
 234         ${WebKit_FRAMEWORKS})
 235     vlc_module_add_link_libraries(minimal_macosx
 236         ${Cocoa_FRAMEWORKS}
 237         ${Carbon_FRAMEWORKS}
 238         ${OpenGL_FRAMEWORKS}
 239         ${AGL_FRAMEWORKS})
 240     vlc_module_add_link_libraries(access_eyetv
 241         ${Foundation_FRAMEWORKS})
 242     vlc_module_add_link_libraries(opengllayer
 243          ${Cocoa_FRAMEWORKS}
 244          ${QuartzCore_FRAMEWORKS}
 245          ${OpenGL_FRAMEWORKS} )
 246     vlc_module_add_link_libraries(quartztext
 247          ${Carbon_FRAMEWORKS}
 248          ${ApplicationServices_FRAMEWORKS} )
 249     vlc_module_add_link_libraries(mp4
 250          ${IOKit_FRAMEWORKS} )
 251
 252     add_executable(VLC MACOSX_BUNDLE src/vlc.c)
 253     target_link_libraries(VLC libvlc)
 254     set( MacOS ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/MacOS )
 255     add_custom_command(
 256         TARGET VLC
 257         POST_BUILD
 258         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 259         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx
 260         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx
 261         COMMAND for i in vlc.xcodeproj Resources README.MacOSX.rtf\; do cp -R ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx\; done
 262         COMMAND for i in AUTHORS COPYING THANKS\;do cp ${CMAKE_CURRENT_SOURCE_DIR}/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp\; done
 263         COMMAND for i in AppleRemote.h AppleRemote.m about.h about.m applescript.h applescript.m controls.h controls.m equalizer.h equalizer.m intf.h intf.m macosx.m misc.h misc.m open.h open.m output.h output.m playlist.h playlist.m playlistinfo.h playlistinfo.m prefs_widgets.h prefs_widgets.m prefs.h prefs.m vout.h voutqt.m voutgl.m wizard.h wizard.m extended.h extended.m bookmarks.h bookmarks.m sfilters.h sfilters.m update.h update.m interaction.h interaction.m embeddedwindow.h embeddedwindow.m fspanel.h fspanel.m vout.m\; do cp ${CMAKE_CURRENT_SOURCE_DIR}/modules/gui/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx\; done
 264         COMMAND cd ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx && xcodebuild -target vlc | grep -vE '^\([ \\t]|$$\)' && cd ../../../../ && cp ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Info.plist ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents && cp -R ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Resources/English.lproj ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources
 265         COMMAND cp -r ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/Resources ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents
 266         COMMAND find -d ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources -type d -name \\.svn -exec rm -rf {} "\;"
 267         COMMAND rm -rf ${MacOS}/modules ${MacOS}/locale ${MacOS}/share
 268         COMMAND ln -s ${CMAKE_CURRENT_SOURCE_DIR}/share ${MacOS}/share
 269         COMMAND ln -s ${CMAKE_CURRENT_BINARY_DIR}/modules ${MacOS}/modules
 270         COMMAND find ${CMAKE_BINARY_DIR}/po -name *.gmo -exec sh -c \"mkdir -p ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES\; ln -s {} ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES/vlc.mo\" "\;"
 271         COMMAND ln -sf VLC ${MacOS}/clivlc #useless?
 272         COMMAND printf "APPLVLC#" > ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/PkgInfo
 273     )
 274     set( MacOS )
 275
 276 endif(APPLE)
 277
 278 ###########################################################
 279 # info
 280 ###########################################################
 281
 282 macro(command_to_configvar command var)
 283  execute_process(
 284   COMMAND sh -c "${command}"
 285   OUTPUT_VARIABLE ${var}
 286   OUTPUT_STRIP_TRAILING_WHITESPACE)
 287  string( REPLACE "\n" "\\n" ${var} ${${var}})
 288 endmacro(command_to_configvar)
 289
 290 command_to_configvar( "whoami" VLC_COMPILE_BY )
 291 command_to_configvar( "hostname" VLC_COMPILE_HOST )
 292 command_to_configvar( "hostname" VLC_COMPILE_DOMAIN )
 293 command_to_configvar( "${CMAKE_C_COMPILER} --version" VLC_COMPILER )
 294 # FIXME: WTF? this is not the configure line!
 295 command_to_configvar( "${CMAKE_C_COMPILER} --version" CONFIGURE_LINE )
 296 set( VLC_COMPILER "${CMAKE_C_COMPILER}" )
 297
 298
 299 ###########################################################
 300 # Modules: Following are all listed in options
 301 ###########################################################
 302
 303 # This module will be enabled but user could disabled it
 304 vlc_enable_modules(dummy logger memcpy)
 305 vlc_enable_modules(mpgv mpga m4v m4a h264 vc1 demux_cdg cdg ps pva avi mp4 rawdv rawvid nsv real aiff mjpeg demuxdump flacsys tta)
 306 vlc_enable_modules(cvdsub svcdsub spudec subsdec subsusf t140 dvbsub cc mpeg_audio lpcm a52 dts cinepak flac)
 307 vlc_enable_modules(deinterlace invert adjust transform wave ripple psychedelic gradient motionblur rv32 rotate noise grain extract sharpen seamcarving)
 308 vlc_enable_modules(converter_fixed mono)
 309 vlc_enable_modules(trivial_resampler ugly_resampler)
 310 vlc_enable_modules(trivial_channel_mixer trivial_mixer)
 311 vlc_enable_modules(playlist export nsc xtag)
 312 vlc_enable_modules(i420_rgb grey_yuv rawvideo blend scale image logo magnify puzzle colorthres)
 313 vlc_enable_modules(wav araw subtitle vobsub adpcm a52sys dtssys au ty voc xa nuv smf)
 314 vlc_enable_modules(access_directory access_file access_udp access_tcp)
 315 vlc_enable_modules(access_http access_mms access_ftp)
 316 vlc_enable_modules(access_filter_bandwidth)
 317 vlc_enable_modules(packetizer_mpegvideo packetizer_h264)
 318 vlc_enable_modules(packetizer_mpeg4video packetizer_mpeg4audio)
 319 vlc_enable_modules(packetizer_vc1)
 320 vlc_enable_modules(spatializer)
 321
 322 if(NOT mingwce)
 323    set(enabled ON)
 324 endif(NOT mingwce)
 325 vlc_register_modules(${enabled} access_fake access_filter_timeshift access_filter_record access_filter_dump)
 326 vlc_register_modules(${enabled} gestures rc telnet hotkeys showintf marq podcast shout sap fake folder)
 327 vlc_register_modules(${enabled} rss mosaic wall motiondetect clone crop erase bluescreen alphamask gaussianblur)
 328 vlc_register_modules(${enabled} i420_yuy2 i422_yuy2 i420_ymga i422_i420 yuy2_i422 yuy2_i420 chroma_chain)
 329 vlc_register_modules(${enabled} aout_file linear_resampler bandlimited_resampler)
 330 vlc_register_modules(${enabled} float32_mixer spdif_mixer simple_channel_mixer)
 331 vlc_register_modules(${enabled} dolby_surround_decoder headphone_channel_mixer normvol equalizer param_eq)
 332 vlc_register_modules(${enabled} converter_float a52tospdif dtstospdif audio_format)
 333 set(enabled)
 334
 335 if(NOT WIN32)
 336    vlc_enable_modules(screensaver)
 337 endif(NOT WIN32)
 338
 339 # Following modules will be disabled but listed in options
 340
 341 vlc_disable_modules(asf)
 342
 343 # This module is disabled because the CMakeList.txt which
 344 # is generated isn't correct. We'll put that back
 345 # when cmake will be accepted as default build system
 346 vlc_disable_modules(motion)
 347
 348 ###########################################################
 349 # libraries
 350 ###########################################################
 351 OPTION( ENABLE_CONTRIB "Attempt to use VLC contrib system to get the third-party libraries" ON )
 352 if(ENABLE_CONTRIB)
 353   set( CONTRIB_INCLUDE ${CMAKE_SOURCE_DIR}/extras/contrib/include)
 354   set( CONTRIB_LIB ${CMAKE_SOURCE_DIR}/extras/contrib/lib)
 355   set( CONTRIB_PROGRAM ${CMAKE_SOURCE_DIR}/extras/contrib/bin)
 356   set( CMAKE_LIBRARY_PATH ${CONTRIB_LIB} ${CMAKE_LIBRARY_PATH} )
 357   set( CMAKE_PROGRAM_PATH ${CONTRIB_PROGRAM} ${CMAKE_PROGRAM_PATH} )
 358   set( CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${CONTRIB_LIB}" )
 359   set( CMAKE_CXX_LINK_FLAGS "${CMAKE_CXX_LINK_FLAGS} -L${CONTRIB_LIB}" )
 360   set( CMAKE_SHARED_MODULE_CREATE_C_FLAGS "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
 361   set( CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
 362   set( CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
 363   set( CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
 364   add_definitions(-I${CONTRIB_INCLUDE})
 365 endif(ENABLE_CONTRIB)
 366
 367 set(CMAKE_REQUIRED_INCLUDES ${CONTRIB_INCLUDE})
 368
 369 #fixme: use find_package(cddb 0.9.5)
 370 pkg_check_modules(LIBCDDB libcddb>=0.9.5)
 371 if(${LIBCDDB_FOUND})
 372   vlc_module_add_link_libraries(cdda ${LIBCDDB_LIBRARIES})
 373   vlc_add_module_compile_flag(cdda ${LIBCDDB_CFLAGS} )
 374 endif(${LIBCDDB_FOUND})
 375
 376 find_package(Dlopen)
 377 set(HAVE_DL_DLOPEN ${Dlopen_FOUND})
 378
 379 # Advanced Linux Sound Architecture (ALSA)
 380 pkg_check_modules(ALSA alsa>=1.0.0-rc4)
 381 if (${ALSA_FOUND})
 382   set (HAVE_ALSA_NEW_API "1")
 383 else (${ALSA_FOUND})
 384   pkg_check_modules(ALSA alsa)
 385 endif (${ALSA_FOUND})
 386
 387 if (${ALSA_FOUND})
 388   set (HAVE_ALSA "1")
 389   vlc_enable_modules(alsa)
 390   vlc_add_module_compile_flag(alsa ${ALSA_CFLAGS})
 391   vlc_module_add_link_libraries(alsa ${ALSA_LIBRARIES})
 392 endif (${ALSA_FOUND})
 393
 394 # Open Sound System (OSS)
 395 # TODO
 396
 397 find_package(FFmpeg)
 398 if(FFmpeg_FOUND)
 399   vlc_check_include_files (ffmpeg/avcodec.h)
 400   vlc_check_include_files (ffmpeg/avutil.h)
 401   vlc_check_include_files (ffmpeg/swscale.h)
 402   check_include_files ("stdint.h;postproc/postprocess.h" HAVE_POSTPROC_POSTPROCESS_H)
 403   vlc_enable_modules(ffmpeg)
 404   vlc_add_module_compile_flag(ffmpeg ${FFmpeg_CFLAGS} )
 405   vlc_module_add_link_libraries(ffmpeg ${FFmpeg_LIBRARIES})
 406 endif(FFmpeg_FOUND)
 407
 408 find_package(Lua)
 409 if(Lua_FOUND)
 410   set(HAVE_LUA TRUE)
 411   vlc_enable_modules(lua)
 412   vlc_check_include_files (lua.h lualib.h)
 413   vlc_add_module_compile_flag(lua ${Lua_CFLAGS} )
 414   vlc_module_add_link_libraries(lua ${Lua_LIBRARIES})
 415 endif(Lua_FOUND)
 416
 417 find_package(Qt4)
 418 if(QT4_FOUND)
 419   set(HAVE_QT4 TRUE)
 420   include_directories(${QT_INCLUDES})
 421   vlc_check_include_files (qt.h)
 422   vlc_enable_modules(qt4)
 423   vlc_add_module_compile_flag(qt4 ${QT_CFLAGS} )
 424   vlc_module_add_link_libraries(qt4 ${QT_LIBRARIES})
 425   # Define our own qt4_wrap_ui macro to match wanted behaviour
 426   MACRO (VLC_QT4_WRAP_UI outfiles )
 427     FOREACH (it ${ARGN})
 428      string(REPLACE ".ui" ".h" outfile "${it}")
 429       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 430       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 431       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 432         COMMAND mkdir -p `dirname ${outfile}`
 433         COMMAND ${QT_UIC_EXECUTABLE}
 434         ARGS -o ${outfile} ${infile}
 435         MAIN_DEPENDENCY ${infile})
 436       SET(${outfiles} ${${outfiles}} ${outfile})
 437     ENDFOREACH (it)
 438
 439   ENDMACRO (VLC_QT4_WRAP_UI)
 440
 441 endif(QT4_FOUND)
 442
 443 find_package(OpenGL)
 444 if(OPENGL_FOUND)
 445   vlc_enable_modules(opengl)
 446   vlc_check_include_files (gl/gl.h)
 447   vlc_check_include_files (gl/glu.h)
 448   vlc_check_include_files (gl/glx.h)
 449   vlc_add_module_compile_flag(opengl ${OPENGL_CFLAGS})
 450   vlc_module_add_link_libraries(opengl ${OPENGL_LIBRARIES})
 451 endif(OPENGL_FOUND)
 452
 453 set(CMAKE_REQUIRED_INCLUDES)
 454
 455 ###########################################################
 456 # Final configuration
 457 ###########################################################
 458 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/include/config.h)
 459