git.sesse.net Git - vlc/blob - extras/buildsystem/cmake/include/config.cmake

   1 include( CheckIncludeFile )
   2 include (CheckTypeSize)
   3 include (CheckCSourceCompiles)
   4 include (CheckSymbolExists)
   5 include (CheckLibraryExists)
   6
   7 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_include_files.cmake )
   8 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_functions_exist.cmake )
   9 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_add_compile_flag.cmake )
  10 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_type.cmake )
  11 include( ${CMAKE_SOURCE_DIR}/cmake/pkg_check_modules.cmake )
  12
  13 ###########################################################
  14 # VERSION
  15 ###########################################################
  16
  17 set(VLC_VERSION_MAJOR 0)
  18 set(VLC_VERSION_MINOR 9)
  19 set(VLC_VERSION_PATCH 0)
  20 set(VLC_VERSION_EXTRA "-svn")
  21
  22 set(PACKAGE "vlc")
  23 set(PACKAGE_STRING "vlc")
  24 set(VERSION_MESSAGE "vlc-${VLC_VERSION_MAJOR}.${VLC_VERSION_MINOR}.${VLC_VERSION_PATCH}${VLC_VERSION_EXTRA}")
  25 set(COPYRIGHT_MESSAGE "Copyright © the VideoLAN team")
  26 set(COPYRIGHT_YEARS "2001-2008")
  27
  28 ###########################################################
  29 # Options
  30 ###########################################################
  31
  32 OPTION( ENABLE_HTTPD           "Enable httpd server" ON )
  33 OPTION( ENABLE_VLM             "Enable vlm" ON )
  34 OPTION( ENABLE_DYNAMIC_PLUGINS "Enable dynamic plugin" ON )
  35 OPTION( UPDATE_CHECK           "Enable automatic new version checking" OFF )
  36 OPTION( ENABLE_NO_SYMBOL_CHECK "Don't check symbols of modules against libvlc. (Enabling this option speeds up compilation)" OFF )
  37
  38 IF (NOT CMAKE_BUILD_TYPE)
  39     set(CMAKE_BUILD_TYPE "Debug" CACHE STRING  "build type determining compiler flags" FORCE )
  40 endif(NOT CMAKE_BUILD_TYPE )
  41
  42 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  43     set(DEBUG ON)
  44     add_declarations(-DDEBUG=1)
  45     set(NDEBUG OFF)
  46 endif(CMAKE_BUILD_TYPE STREQUAL "Debug")
  47
  48 set( HAVE_DYNAMIC_PLUGINS ${ENABLE_DYNAMIC_PLUGINS})
  49 set( LIBEXT ${CMAKE_SHARED_MODULE_SUFFIX})
  50
  51 ###########################################################
  52 # Headers checks
  53 ###########################################################
  54
  55 vlc_check_include_files (malloc.h stdbool.h locale.h)
  56 vlc_check_include_files (stddef.h stdlib.h sys/stat.h)
  57 vlc_check_include_files (stdio.h stdint.h inttypes.h)
  58 vlc_check_include_files (signal.h unistd.h dirent.h)
  59 vlc_check_include_files (netinet/in.h netinet/udplite.h)
  60 vlc_check_include_files (arpa/inet.h net/if.h)
  61 vlc_check_include_files (netdb.h fcntl.h sys/time.h poll.h)
  62 vlc_check_include_files (errno.h time.h alloca.h)
  63 vlc_check_include_files (limits.h)
  64
  65 vlc_check_include_files (string.h strings.h getopt.h)
  66
  67 vlc_check_include_files (dlfcn.h dl.h)
  68
  69 vlc_check_include_files (kernel/OS.h)
  70 vlc_check_include_files (memory.h)
  71 vlc_check_include_files (mach-o/dyld.h)
  72
  73 vlc_check_include_files (pthread.h)
  74
  75 find_package (Threads)
  76
  77 ###########################################################
  78 # Functions/structures checks
  79 ###########################################################
  80 set(CMAKE_REQUIRED_LIBRARIES c)
  81 set(CMAKE_EXTRA_INCLUDE_FILES string.h)
  82 vlc_check_functions_exist(strcpy strcasecmp)
  83 vlc_check_functions_exist(strcasestr strdup)
  84 vlc_check_functions_exist(strndup stricmp strnicmp)
  85 vlc_check_functions_exist(atof strtoll atoll lldiv)
  86 vlc_check_functions_exist(strlcpy stristr strnlen strsep)
  87 vlc_check_functions_exist(strtod strtof strtol stroul)
  88 vlc_check_functions_exist(stroull)
  89 set(CMAKE_EXTRA_INCLUDE_FILES)
  90
  91 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
  92 vlc_check_functions_exist(vasprintf)
  93 set(CMAKE_EXTRA_INCLUDE_FILES)
  94
  95 set(CMAKE_EXTRA_INCLUDE_FILES libc.h)
  96 vlc_check_functions_exist(fork)
  97 set(CMAKE_EXTRA_INCLUDE_FILES)
  98
  99 set(CMAKE_EXTRA_INCLUDE_FILES stdlib.h)
 100 vlc_check_functions_exist(putenv getenv setenv)
 101 vlc_check_functions_exist(putenv getenv setenv)
 102 set(CMAKE_EXTRA_INCLUDE_FILES)
 103
 104 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 105 vlc_check_functions_exist(snprintf asprintf)
 106 vlc_check_functions_exist(putenv getenv setenv)
 107 set(CMAKE_EXTRA_INCLUDE_FILES)
 108
 109 set(CMAKE_EXTRA_INCLUDE_FILES unistd.h)
 110 vlc_check_functions_exist(isatty getcwd getuid)
 111 set(CMAKE_EXTRA_INCLUDE_FILES)
 112
 113 set(CMAKE_EXTRA_INCLUDE_FILES sys/stat.h)
 114 vlc_check_functions_exist(lstat fstat stat)
 115 set(CMAKE_EXTRA_INCLUDE_FILES)
 116
 117 set(CMAKE_EXTRA_INCLUDE_FILES arpa/inet.h)
 118 vlc_check_functions_exist(inet_aton inet_ntop inet_pton)
 119 set(CMAKE_EXTRA_INCLUDE_FILES)
 120
 121 set(CMAKE_REQUIRED_LIBRARIES)
 122
 123 check_library_exists(poll poll "" HAVE_POLL)
 124
 125 check_c_source_compiles(
 126 "#include <langinfo.h>
 127 int main() { char* cs = nl_langinfo(CODESET); }"
 128 HAVE_LANGINFO_CODESET)
 129
 130 vlc_check_type("struct addrinfo" "sys/socket.h;netdb.h")
 131 if(HAVE_STRUCT_ADDRINFO)
 132   set(HAVE_ADDRINFO ON)
 133 endif(HAVE_STRUCT_ADDRINFO)
 134 vlc_check_type("struct timespec" "time.h")
 135
 136 check_c_source_compiles (
 137 "#include <stdint.h> \n #ifdef UINTMAX \n #error no uintmax
 138  #endif
 139  int main() { return 0;}" HAVE_STDINT_H_WITH_UINTMAX)
 140
 141 check_symbol_exists(ntohl "sys/param.h"  NTOHL_IN_SYS_PARAM_H)
 142 check_symbol_exists(scandir "dirent.h"   HAVE_SCANDIR)
 143 check_symbol_exists(localtime_r "time.h" HAVE_LOCALTIME_R)
 144 check_symbol_exists(alloca "alloca.h"    HAVE_ALLOCA)
 145
 146 check_symbol_exists(va_copy "stdarg.h"   HAVE_VACOPY)
 147 check_symbol_exists(__va_copy "stdarg.h" HAVE___VA_COPY)
 148
 149
 150 check_symbol_exists(getnameinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETNAMEINFO)
 151 check_symbol_exists(getaddrinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETADDRINFO)
 152 if(NOT HAVE_GETADDRINFO)
 153     check_library_exists(getaddrinfo nsl "" HAVE_GETADDRINFO)
 154 endif(NOT HAVE_GETADDRINFO)
 155
 156 vlc_check_functions_exist(iconv)
 157 if(NOT HAVE_ICONV)
 158     set(LIBICONV "iconv")
 159     check_library_exists(iconv iconv "" HAVE_ICONV)
 160 endif(NOT HAVE_ICONV)
 161 set(CMAKE_REQUIRED_LIBRARIES ${LIBICONV})
 162 CHECK_C_SOURCE_COMPILES(" #include <iconv.h>
 163  int main() { return iconv(0, (char **)0, 0, (char**)0, 0); }" ICONV_NO_CONST)
 164 if( ICONV_NO_CONST )
 165   set( ICONV_CONST "const" )
 166 else( ICONV_NO_CONST )
 167   set( ICONV_CONST " ")
 168 endif( ICONV_NO_CONST )
 169 set(CMAKE_REQUIRED_LIBRARIES)
 170
 171 check_library_exists(rt clock_nanosleep "" HAVE_CLOCK_NANOSLEEP)
 172 if (HAVE_CLOCK_NANOSLEEP)
 173     set(LIBRT "rt")
 174 endif (HAVE_CLOCK_NANOSLEEP)
 175
 176 check_library_exists(m pow "" HAVE_LIBM)
 177 if (HAVE_LIBM)
 178     set (LIBM "m")
 179 endif (HAVE_LIBM)
 180
 181 check_symbol_exists(connect "sys/types.h;sys/socket.h" HAVE_CONNECT)
 182 if(NOT HAVE_CONNECT)
 183     check_library_exists(connect socket "" HAVE_CONNECT)
 184     if(NOT HAVE_CONNECT)
 185         vlc_module_add_link_libraries(libvlc connect)
 186         vlc_module_add_link_libraries(cdda   connect)
 187         vlc_module_add_link_libraries(cddax  connect)
 188     endif(NOT HAVE_CONNECT)
 189 endif(NOT HAVE_CONNECT)
 190
 191 ###########################################################
 192 # Other check
 193 ###########################################################
 194 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_test_inline.cmake )
 195
 196 ###########################################################
 197 # Platform check
 198 ###########################################################
 199 if(APPLE)
 200     include( ${CMAKE_SOURCE_DIR}/cmake/vlc_find_frameworks.cmake )
 201
 202     if(ENABLE_NO_SYMBOL_CHECK)
 203         set(DYNAMIC_LOOKUP "-undefined dynamic_lookup")
 204     else(ENABLE_NO_SYMBOL_CHECK)
 205         set(DYNAMIC_LOOKUP)
 206     endif(ENABLE_NO_SYMBOL_CHECK)
 207     set(CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS
 208      "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} ${DYNAMIC_LOOKUP}")
 209     set(CMAKE_SHARED_MODULE_CREATE_C_FLAGS
 210      "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} ${DYNAMIC_LOOKUP}")
 211
 212     # For pre-10.5
 213     set( CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_C_FLAGS} -fno-common")
 214
 215     set(SYS_DARWIN 1)
 216     add_definitions(-std=gnu99) # Hack for obj-c files to be compiled with gnu99
 217     vlc_enable_modules(macosx minimal_macosx access_eyetv quartztext auhal)
 218
 219     # On Pre-10.5
 220     vlc_module_add_link_flags (ffmpeg "-read_only_relocs warning")
 221
 222     vlc_check_include_files (ApplicationServices/ApplicationServices.h)
 223     vlc_check_include_files (Carbon/Carbon.h)
 224     vlc_check_include_files (CoreAudio/CoreAudio.h)
 225
 226    # check_symbol_exists (CFLocaleCopyCurrent "CoreFoundation/CoreFoundation.h" "" HAVE_CFLOCALECOPYCURRENT)
 227    # check_symbol_exists (CFPreferencesCopyAppValue "CoreFoundation/CoreFoundation.h" "" HAVE_CFPREFERENCESCOPYAPPVALUE)
 228
 229     vlc_find_frameworks(Cocoa Carbon OpenGL AGL IOKit Quicktime
 230                         WebKit QuartzCore Foundation ApplicationServices
 231                         CoreAudio AudioUnit AudioToolbox)
 232     vlc_module_add_link_libraries(macosx
 233         ${Cocoa_FRAMEWORKS}
 234         ${IOKit_FRAMEWORKS}
 235         ${OpenGL_FRAMEWORKS}
 236         ${AGL_FRAMEWORKS}
 237         ${Quicktime_FRAMEWORKS}
 238         ${WebKit_FRAMEWORKS})
 239     vlc_module_add_link_libraries(minimal_macosx
 240         ${Cocoa_FRAMEWORKS}
 241         ${Carbon_FRAMEWORKS}
 242         ${OpenGL_FRAMEWORKS}
 243         ${AGL_FRAMEWORKS})
 244     vlc_module_add_link_libraries(access_eyetv
 245         ${Foundation_FRAMEWORKS})
 246     vlc_module_add_link_libraries(opengllayer
 247          ${Cocoa_FRAMEWORKS}
 248          ${QuartzCore_FRAMEWORKS}
 249          ${OpenGL_FRAMEWORKS} )
 250     vlc_module_add_link_libraries(quartztext
 251          ${Carbon_FRAMEWORKS}
 252          ${ApplicationServices_FRAMEWORKS} )
 253     vlc_module_add_link_libraries(auhal
 254          ${Carbon_FRAMEWORKS}
 255          ${CoreAudio_FRAMEWORKS}
 256          ${AudioUnit_FRAMEWORKS}
 257          ${AudioToolbox_FRAMEWORKS} )
 258     vlc_module_add_link_libraries(mp4 ${IOKit_FRAMEWORKS} )
 259     vlc_module_add_link_libraries(mkv ${IOKit_FRAMEWORKS} )
 260
 261     add_executable(VLC MACOSX_BUNDLE src/vlc.c)
 262     target_link_libraries(VLC libvlc)
 263     set( MacOS ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/MacOS )
 264     add_custom_command(
 265         TARGET VLC
 266         POST_BUILD
 267         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 268         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx
 269         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx
 270         COMMAND for i in vlc.xcodeproj Resources README.MacOSX.rtf\; do cp -R ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx\; done
 271         COMMAND for i in AUTHORS COPYING THANKS\;do cp ${CMAKE_CURRENT_SOURCE_DIR}/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp\; done
 272         COMMAND for i in AppleRemote.h AppleRemote.m about.h about.m applescript.h applescript.m controls.h controls.m equalizer.h equalizer.m intf.h intf.m macosx.m misc.h misc.m open.h open.m output.h output.m playlist.h playlist.m playlistinfo.h playlistinfo.m prefs_widgets.h prefs_widgets.m prefs.h prefs.m vout.h voutqt.m voutgl.m wizard.h wizard.m extended.h extended.m bookmarks.h bookmarks.m sfilters.h sfilters.m update.h update.m interaction.h interaction.m embeddedwindow.h embeddedwindow.m fspanel.h fspanel.m vout.m\; do cp ${CMAKE_CURRENT_SOURCE_DIR}/modules/gui/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx\; done
 273         COMMAND cd ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx && xcodebuild -target vlc | grep -vE '^\([ \\t]|$$\)' && cd ../../../../ && cp ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Info.plist ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents && cp -R ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Resources/English.lproj ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources
 274         COMMAND cp -r ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/Resources ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents
 275         COMMAND find -d ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources -type d -name \\.svn -exec rm -rf {} "\;"
 276         COMMAND rm -rf ${MacOS}/modules ${MacOS}/locale ${MacOS}/share
 277         COMMAND ln -s ${CMAKE_CURRENT_SOURCE_DIR}/share ${MacOS}/share
 278         COMMAND ln -s ${CMAKE_CURRENT_BINARY_DIR}/modules ${MacOS}/modules
 279         COMMAND find ${CMAKE_BINARY_DIR}/po -name *.gmo -exec sh -c \"mkdir -p ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES\; ln -s {} ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES/vlc.mo\" "\;"
 280         COMMAND ln -sf VLC ${MacOS}/clivlc #useless?
 281         COMMAND printf "APPLVLC#" > ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/PkgInfo
 282     )
 283     set( MacOS )
 284
 285 endif(APPLE)
 286
 287 ###########################################################
 288 # info
 289 ###########################################################
 290
 291 macro(command_to_configvar command var)
 292  execute_process(
 293   COMMAND sh -c "${command}"
 294   OUTPUT_VARIABLE ${var}
 295   OUTPUT_STRIP_TRAILING_WHITESPACE)
 296  string( REPLACE "\n" "\\n" ${var} "${${var}}")
 297 endmacro(command_to_configvar)
 298
 299 command_to_configvar( "whoami" VLC_COMPILE_BY )
 300 command_to_configvar( "hostname" VLC_COMPILE_HOST )
 301 command_to_configvar( "hostname" VLC_COMPILE_DOMAIN )
 302 command_to_configvar( "${CMAKE_C_COMPILER} --version" VLC_COMPILER )
 303 # FIXME: WTF? this is not the configure line!
 304 command_to_configvar( "${CMAKE_C_COMPILER} --version" CONFIGURE_LINE )
 305 set( VLC_COMPILER "${CMAKE_C_COMPILER}" )
 306
 307
 308 ###########################################################
 309 # Modules: Following are all listed in options
 310 ###########################################################
 311
 312 # This module will be enabled but user could disabled it
 313 vlc_enable_modules(dummy logger memcpy)
 314 vlc_enable_modules(mpgv mpga m4v m4a h264 vc1 demux_cdg cdg ps pva avi mp4 rawdv rawvid nsv real aiff mjpeg demuxdump flacsys tta)
 315 vlc_enable_modules(cvdsub svcdsub spudec subsdec subsusf t140 dvbsub cc mpeg_audio lpcm a52 dts cinepak flac)
 316 vlc_enable_modules(deinterlace invert adjust transform wave ripple psychedelic gradient motionblur rv32 rotate noise grain extract sharpen seamcarving)
 317 vlc_enable_modules(converter_fixed mono)
 318 vlc_enable_modules(trivial_resampler ugly_resampler)
 319 vlc_enable_modules(trivial_channel_mixer trivial_mixer)
 320 vlc_enable_modules(playlist export nsc xtag)
 321 vlc_enable_modules(i420_rgb grey_yuv rawvideo blend scale image logo magnify puzzle colorthres)
 322 vlc_enable_modules(wav araw subtitle vobsub adpcm a52sys dtssys au ty voc xa nuv smf)
 323 vlc_enable_modules(access_directory access_file access_udp access_tcp)
 324 vlc_enable_modules(access_http access_mms access_ftp)
 325 vlc_enable_modules(access_filter_bandwidth)
 326 vlc_enable_modules(packetizer_mpegvideo packetizer_h264)
 327 vlc_enable_modules(packetizer_mpeg4video packetizer_mpeg4audio)
 328 vlc_enable_modules(packetizer_vc1)
 329 vlc_enable_modules(spatializer)
 330
 331 if(NOT mingwce)
 332    set(enabled ON)
 333 endif(NOT mingwce)
 334 vlc_register_modules(${enabled} access_fake access_filter_timeshift access_filter_record access_filter_dump)
 335 vlc_register_modules(${enabled} gestures rc telnet hotkeys showintf marq podcast shout sap fake folder)
 336 vlc_register_modules(${enabled} rss mosaic wall motiondetect clone crop erase bluescreen alphamask gaussianblur)
 337 vlc_register_modules(${enabled} i420_yuy2 i422_yuy2 i420_ymga i422_i420 yuy2_i422 yuy2_i420 chroma_chain)
 338 vlc_register_modules(${enabled} aout_file linear_resampler bandlimited_resampler)
 339 vlc_register_modules(${enabled} float32_mixer spdif_mixer simple_channel_mixer)
 340 vlc_register_modules(${enabled} dolby_surround_decoder headphone_channel_mixer normvol equalizer param_eq)
 341 vlc_register_modules(${enabled} converter_float a52tospdif dtstospdif audio_format)
 342 set(enabled)
 343
 344 if(NOT WIN32)
 345    vlc_enable_modules(screensaver)
 346 endif(NOT WIN32)
 347
 348 # Following modules will be disabled but listed in options
 349
 350 vlc_disable_modules(asf)
 351
 352 # This module is disabled because the CMakeList.txt which
 353 # is generated isn't correct. We'll put that back
 354 # when cmake will be accepted as default build system
 355 vlc_disable_modules(motion)
 356
 357 ###########################################################
 358 # libraries
 359 ###########################################################
 360 OPTION( ENABLE_CONTRIB "Attempt to use VLC contrib system to get the third-party libraries" ON )
 361 if(ENABLE_CONTRIB)
 362   set( CONTRIB_INCLUDE ${CMAKE_SOURCE_DIR}/extras/contrib/include)
 363   set( CONTRIB_LIB ${CMAKE_SOURCE_DIR}/extras/contrib/lib)
 364   set( CONTRIB_PROGRAM ${CMAKE_SOURCE_DIR}/extras/contrib/bin)
 365   set( CMAKE_LIBRARY_PATH ${CONTRIB_LIB} ${CMAKE_LIBRARY_PATH} )
 366   set( CMAKE_PROGRAM_PATH ${CONTRIB_PROGRAM} ${CMAKE_PROGRAM_PATH} )
 367   set( CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${CONTRIB_LIB}" )
 368   set( CMAKE_CXX_LINK_FLAGS "${CMAKE_CXX_LINK_FLAGS} -L${CONTRIB_LIB}" )
 369   set( CMAKE_SHARED_MODULE_CREATE_C_FLAGS "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
 370   set( CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
 371   set( CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
 372   set( CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
 373   add_definitions(-I${CONTRIB_INCLUDE})
 374 endif(ENABLE_CONTRIB)
 375
 376 set(CMAKE_REQUIRED_INCLUDES ${CONTRIB_INCLUDE})
 377
 378 #fixme: use find_package(cddb 0.9.5)
 379 pkg_check_modules(LIBCDDB libcddb>=0.9.5)
 380 if(${LIBCDDB_FOUND})
 381   vlc_module_add_link_libraries(cdda ${LIBCDDB_LIBRARIES})
 382   vlc_add_module_compile_flag(cdda ${LIBCDDB_CFLAGS} )
 383 endif(${LIBCDDB_FOUND})
 384
 385 find_package(Dlopen)
 386 set(HAVE_DL_DLOPEN ${Dlopen_FOUND})
 387
 388 # Advanced Linux Sound Architecture (ALSA)
 389 pkg_check_modules(ALSA alsa>=1.0.0-rc4)
 390 if (${ALSA_FOUND})
 391   set (HAVE_ALSA_NEW_API "1")
 392 else (${ALSA_FOUND})
 393   pkg_check_modules(ALSA alsa)
 394 endif (${ALSA_FOUND})
 395
 396 if (${ALSA_FOUND})
 397   set (HAVE_ALSA "1")
 398   vlc_enable_modules(alsa)
 399   vlc_add_module_compile_flag(alsa ${ALSA_CFLAGS})
 400   vlc_module_add_link_libraries(alsa ${ALSA_LIBRARIES})
 401 endif (${ALSA_FOUND})
 402
 403 # Open Sound System (OSS)
 404 # TODO
 405
 406 find_package(FFmpeg)
 407 if(FFmpeg_FOUND)
 408   vlc_check_include_files (ffmpeg/avcodec.h)
 409   vlc_check_include_files (ffmpeg/avutil.h)
 410   vlc_check_include_files (ffmpeg/swscale.h)
 411   check_include_files ("stdint.h;postproc/postprocess.h" HAVE_POSTPROC_POSTPROCESS_H)
 412   vlc_enable_modules(ffmpeg)
 413   vlc_add_module_compile_flag(ffmpeg ${FFmpeg_CFLAGS} )
 414   vlc_module_add_link_libraries(ffmpeg ${FFmpeg_LIBRARIES})
 415 endif(FFmpeg_FOUND)
 416
 417 find_package(Lua)
 418 if(Lua_FOUND)
 419   set(HAVE_LUA TRUE)
 420   vlc_enable_modules(lua)
 421   vlc_check_include_files (lua.h lualib.h)
 422   vlc_add_module_compile_flag(lua ${Lua_CFLAGS} )
 423   vlc_module_add_link_libraries(lua ${Lua_LIBRARIES})
 424 endif(Lua_FOUND)
 425
 426 find_package(Qt4)
 427 if(QT4_FOUND)
 428   set(HAVE_QT4 TRUE)
 429   include_directories(${QT_INCLUDES})
 430   vlc_check_include_files (qt.h)
 431   vlc_enable_modules(qt4)
 432   vlc_add_module_compile_flag(qt4 ${QT_CFLAGS} )
 433   vlc_module_add_link_libraries(qt4 ${QT_LIBRARIES})
 434
 435   # Define our own qt4_wrap_ui macro to match wanted behaviour
 436   MACRO (VLC_QT4_WRAP_UI outfiles )
 437     FOREACH (it ${ARGN})
 438      string(REPLACE ".ui" ".h" outfile "${it}")
 439       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 440       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 441       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 442         COMMAND mkdir -p `dirname ${outfile}`
 443         COMMAND ${QT_UIC_EXECUTABLE}
 444         ARGS -o ${outfile} ${infile}
 445         MAIN_DEPENDENCY ${infile})
 446       SET(${outfiles} ${${outfiles}} ${outfile})
 447     ENDFOREACH (it)
 448   ENDMACRO (VLC_QT4_WRAP_UI)
 449
 450 endif(QT4_FOUND)
 451
 452 find_package(OpenGL)
 453 if(OPENGL_FOUND)
 454   vlc_enable_modules(opengl)
 455   vlc_check_include_files (gl/gl.h)
 456   vlc_check_include_files (gl/glu.h)
 457   vlc_check_include_files (gl/glx.h)
 458   vlc_add_module_compile_flag(opengl ${OPENGL_CFLAGS})
 459   vlc_module_add_link_libraries(opengl ${OPENGL_LIBRARIES})
 460 endif(OPENGL_FOUND)
 461
 462 find_package(Matroska 0.7.7)
 463 if(Matroska_FOUND)
 464   vlc_enable_modules(mkv)
 465   vlc_check_include_files (matroska/KaxAttachments.h)
 466   vlc_check_include_files (matroska/KaxVersion.h)
 467   vlc_module_add_link_libraries(mkv ${Matroska_LIBRARIES})
 468 endif(Matroska_FOUND)
 469
 470 find_package(Live555 0.7.7)
 471 if(Live555_FOUND)
 472   vlc_enable_modules(live555)
 473   vlc_add_module_compile_flag(live555 ${Live555_CFLAGS})
 474   vlc_module_add_link_libraries(live555 ${Live555_LIBRARIES})
 475 endif(Live555_FOUND)
 476
 477 set(CMAKE_REQUIRED_INCLUDES)
 478
 479 ###########################################################
 480 # Final configuration
 481 ###########################################################
 482 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/include/config.h)