git.sesse.net Git - vlc/blob - extras/buildsystem/cmake/include/config.cmake

   1 ###########################################################
   2 # System Includes
   3 ###########################################################
   4 include( CheckIncludeFile )
   5 include (CheckTypeSize)
   6 include (CheckCSourceCompiles)
   7 include (CheckSymbolExists)
   8 include (CheckLibraryExists)
   9
  10 ###########################################################
  11 # Options
  12 ###########################################################
  13 # Options moved before the custom macro includes because those macros need path values, if the ENABLE_CONTRIB
  14 # has been set.
  15
  16 OPTION( ENABLE_HTTPD           "Enable httpd server" ON )
  17 OPTION( ENABLE_STREAM_OUT      "Enable stream output plugins" ON )
  18 OPTION( ENABLE_VLM             "Enable vlm" ON )
  19 OPTION( ENABLE_DYNAMIC_PLUGINS "Enable dynamic plugin" ON )
  20 OPTION( UPDATE_CHECK           "Enable automatic new version checking" OFF )
  21 OPTION( ENABLE_NO_SYMBOL_CHECK "Don't check symbols of modules against libvlc. (Enabling this option speeds up compilation)" OFF )
  22 OPTION( ENABLE_CONTRIB         "Attempt to use VLC contrib system to get the third-party libraries" ON )
  23 OPTION( ENABLE_LOADER          "Enable the win32 codec loader" ON )
  24
  25 if(ENABLE_CONTRIB)
  26
  27   set( CONTRIB_INCLUDE ${CMAKE_SOURCE_DIR}/extras/contrib/include)
  28   set( CONTRIB_LIB ${CMAKE_SOURCE_DIR}/extras/contrib/lib)
  29   set( CONTRIB_PROGRAM ${CMAKE_SOURCE_DIR}/extras/contrib/bin)
  30   set( CMAKE_LIBRARY_PATH ${CONTRIB_LIB} ${CMAKE_LIBRARY_PATH} )
  31   set( CMAKE_PROGRAM_PATH ${CONTRIB_PROGRAM} ${CMAKE_PROGRAM_PATH} )
  32   set( CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${CONTRIB_LIB}" )
  33   set( CMAKE_CXX_LINK_FLAGS "${CMAKE_CXX_LINK_FLAGS} -L${CONTRIB_LIB}" )
  34   set( CMAKE_SHARED_MODULE_CREATE_C_FLAGS "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
  35   set( CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
  36   set( CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
  37   set( CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
  38
  39   # include extras/contrib/include in the header search pathes
  40   include_directories(${CONTRIB_INCLUDE})
  41   set( CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${CONTRIB_INCLUDE} )
  42
  43   # include the extras/contrib/bin to the search path, otherwise, when finding programs it will automatically
  44   # default to system applications (e.g. we should favor the extras/contrib/bin/pkg-config over the system defined
  45   # one).
  46   if(WIN32)
  47     set( ENV{PATH} "${CONTRIB_PROGRAM};$ENV{PATH}" )
  48   else(WIN32)
  49     set( ENV{PATH} "${CONTRIB_PROGRAM}:$ENV{PATH}" )
  50   endif(WIN32)
  51 endif(ENABLE_CONTRIB)
  52
  53 ###########################################################
  54 # Custom Macro Includes
  55 ###########################################################
  56
  57 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_include_files.cmake )
  58 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_functions_exist.cmake )
  59 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_add_compile_flag.cmake )
  60 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_type.cmake )
  61 include( ${CMAKE_SOURCE_DIR}/cmake/pkg_check_modules.cmake )
  62
  63 ###########################################################
  64 # Versioning
  65 ###########################################################
  66
  67 set(VLC_VERSION_MAJOR "0")
  68 set(VLC_VERSION_MINOR "9")
  69 set(VLC_VERSION_PATCH "0")
  70 set(VLC_VERSION_EXTRA "-svn")
  71 set(VLC_VERSION ${VLC_VERSION_MAJOR}.${VLC_VERSION_MINOR}.${VLC_VERSION_PATCH}${VLC_VERSION_EXTRA})
  72
  73 set(PACKAGE "vlc")
  74 set(PACKAGE_VERSION "${VLC_VERSION}")
  75 set(PACKAGE_STRING "vlc")
  76 set(VERSION_MESSAGE "vlc-${VLC_VERSION}")
  77 set(COPYRIGHT_MESSAGE "Copyright © the VideoLAN team")
  78 set(COPYRIGHT_YEARS "2001-2008")
  79 set(PACKAGE_VERSION_EXTRA "${VLC_VERSION_EXTRA}")
  80 set(PACKAGE_VERSION_MAJOR "${VLC_VERSION_MAJOR}")
  81 set(PACKAGE_VERSION_MINOR "${VLC_VERSION_MINOR}")
  82 set(PACKAGE_VERSION_REVISION "${VLC_VERSION_PATCH}")
  83
  84 ###########################################################
  85 # Preflight Checks
  86 ###########################################################
  87
  88 IF (NOT CMAKE_BUILD_TYPE)
  89     set(CMAKE_BUILD_TYPE "Debug" CACHE STRING  "build type determining compiler flags" FORCE )
  90 endif(NOT CMAKE_BUILD_TYPE )
  91
  92 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  93     set(DEBUG ON)
  94     add_definitions(-DDEBUG=1)
  95     set(NDEBUG OFF)
  96 endif(CMAKE_BUILD_TYPE STREQUAL "Debug")
  97
  98 set( HAVE_DYNAMIC_PLUGINS ${ENABLE_DYNAMIC_PLUGINS})
  99 set( LIBEXT ${CMAKE_SHARED_MODULE_SUFFIX})
 100
 101 ###########################################################
 102 # Headers checks
 103 ###########################################################
 104
 105 vlc_check_include_files (malloc.h stdbool.h locale.h)
 106 vlc_check_include_files (stddef.h stdlib.h sys/stat.h)
 107 vlc_check_include_files (stdio.h stdint.h inttypes.h)
 108 vlc_check_include_files (signal.h unistd.h dirent.h)
 109 vlc_check_include_files (netinet/in.h netinet/udplite.h)
 110 vlc_check_include_files (arpa/inet.h net/if.h)
 111 vlc_check_include_files (netdb.h fcntl.h sys/time.h poll.h)
 112 vlc_check_include_files (errno.h time.h alloca.h)
 113 vlc_check_include_files (limits.h)
 114
 115 vlc_check_include_files (string.h strings.h getopt.h)
 116
 117 vlc_check_include_files (dlfcn.h dl.h)
 118
 119 vlc_check_include_files (kernel/OS.h)
 120 vlc_check_include_files (memory.h)
 121 vlc_check_include_files (mach-o/dyld.h)
 122
 123 vlc_check_include_files (pthread.h)
 124
 125 find_package (Threads)
 126
 127 ###########################################################
 128 # Functions/structures checks
 129 ###########################################################
 130
 131 set(CMAKE_REQUIRED_LIBRARIES c)
 132 set(CMAKE_EXTRA_INCLUDE_FILES string.h)
 133 vlc_check_functions_exist(strcpy strcasecmp)
 134 vlc_check_functions_exist(strcasestr strdup)
 135 vlc_check_functions_exist(strndup stricmp strnicmp)
 136 vlc_check_functions_exist(atof strtoll atoll lldiv)
 137 vlc_check_functions_exist(strlcpy stristr strnlen strsep)
 138 vlc_check_functions_exist(strtod strtof strtol stroul)
 139 vlc_check_functions_exist(stroull)
 140 set(CMAKE_EXTRA_INCLUDE_FILES)
 141
 142 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 143 vlc_check_functions_exist(vasprintf)
 144 set(CMAKE_EXTRA_INCLUDE_FILES)
 145
 146 set(CMAKE_EXTRA_INCLUDE_FILES libc.h)
 147 vlc_check_functions_exist(fork)
 148 set(CMAKE_EXTRA_INCLUDE_FILES)
 149
 150 set(CMAKE_EXTRA_INCLUDE_FILES stdlib.h)
 151 vlc_check_functions_exist(putenv getenv setenv)
 152 vlc_check_functions_exist(putenv getenv setenv)
 153 set(CMAKE_EXTRA_INCLUDE_FILES)
 154
 155 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 156 vlc_check_functions_exist(snprintf asprintf)
 157 vlc_check_functions_exist(putenv getenv setenv)
 158 set(CMAKE_EXTRA_INCLUDE_FILES)
 159
 160 set(CMAKE_EXTRA_INCLUDE_FILES unistd.h)
 161 vlc_check_functions_exist(isatty getcwd getuid swab)
 162 set(CMAKE_EXTRA_INCLUDE_FILES)
 163
 164 set(CMAKE_EXTRA_INCLUDE_FILES sys/stat.h)
 165 vlc_check_functions_exist(lstat fstat stat)
 166 set(CMAKE_EXTRA_INCLUDE_FILES)
 167
 168 set(CMAKE_EXTRA_INCLUDE_FILES arpa/inet.h)
 169 vlc_check_functions_exist(inet_aton inet_ntop inet_pton)
 170 set(CMAKE_EXTRA_INCLUDE_FILES)
 171
 172 set(CMAKE_EXTRA_INCLUDE_FILES sys/mman.h)
 173 vlc_check_functions_exist(mmap)
 174 set(CMAKE_EXTRA_INCLUDE_FILES)
 175
 176 set(CMAKE_REQUIRED_LIBRARIES)
 177
 178 check_library_exists(poll poll "" HAVE_POLL)
 179
 180 check_c_source_compiles(
 181 "#include <langinfo.h>
 182 int main() { char* cs = nl_langinfo(CODESET); }"
 183 HAVE_LANGINFO_CODESET)
 184
 185 vlc_check_type("struct addrinfo" "sys/socket.h;netdb.h")
 186 if(HAVE_STRUCT_ADDRINFO)
 187   set(HAVE_ADDRINFO ON)
 188 endif(HAVE_STRUCT_ADDRINFO)
 189 vlc_check_type("struct timespec" "time.h")
 190
 191 check_c_source_compiles (
 192 "#include <stdint.h> \n #ifdef UINTMAX \n #error no uintmax
 193  #endif
 194  int main() { return 0;}" HAVE_STDINT_H_WITH_UINTMAX)
 195
 196 check_symbol_exists(ntohl "sys/param.h"  NTOHL_IN_SYS_PARAM_H)
 197 check_symbol_exists(scandir "dirent.h"   HAVE_SCANDIR)
 198 check_symbol_exists(localtime_r "time.h" HAVE_LOCALTIME_R)
 199 check_symbol_exists(alloca "alloca.h"    HAVE_ALLOCA)
 200
 201 check_symbol_exists(va_copy "stdarg.h"   HAVE_VACOPY)
 202 check_symbol_exists(__va_copy "stdarg.h" HAVE___VA_COPY)
 203
 204
 205 check_symbol_exists(getnameinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETNAMEINFO)
 206 check_symbol_exists(getaddrinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETADDRINFO)
 207 if(NOT HAVE_GETADDRINFO)
 208     check_library_exists(getaddrinfo nsl "" HAVE_GETADDRINFO)
 209 endif(NOT HAVE_GETADDRINFO)
 210
 211 vlc_check_functions_exist(iconv)
 212 if(NOT HAVE_ICONV)
 213     set(LIBICONV "iconv")
 214     check_library_exists(iconv iconv "" HAVE_ICONV)
 215 endif(NOT HAVE_ICONV)
 216 set(CMAKE_REQUIRED_LIBRARIES ${LIBICONV})
 217 CHECK_C_SOURCE_COMPILES(" #include <iconv.h>
 218  int main() { return iconv(0, (char **)0, 0, (char**)0, 0); }" ICONV_NO_CONST)
 219 if( ICONV_NO_CONST )
 220   set( ICONV_CONST "const" )
 221 else( ICONV_NO_CONST )
 222   set( ICONV_CONST " ")
 223 endif( ICONV_NO_CONST )
 224 set(CMAKE_REQUIRED_LIBRARIES)
 225
 226 check_library_exists(rt clock_nanosleep "" HAVE_CLOCK_NANOSLEEP)
 227 if (HAVE_CLOCK_NANOSLEEP)
 228     set(LIBRT "rt")
 229 endif (HAVE_CLOCK_NANOSLEEP)
 230
 231 check_library_exists(m pow "" HAVE_LIBM)
 232 if (HAVE_LIBM)
 233     set (LIBM "m")
 234 endif (HAVE_LIBM)
 235
 236 check_symbol_exists(connect "sys/types.h;sys/socket.h" HAVE_CONNECT)
 237 if(NOT HAVE_CONNECT)
 238     check_library_exists(connect socket "" HAVE_CONNECT)
 239     if(NOT HAVE_CONNECT)
 240         vlc_module_add_link_libraries(libvlc connect)
 241         vlc_module_add_link_libraries(cdda   connect)
 242         vlc_module_add_link_libraries(cddax  connect)
 243     endif(NOT HAVE_CONNECT)
 244 endif(NOT HAVE_CONNECT)
 245
 246 ###########################################################
 247 # Other check
 248 ###########################################################
 249
 250 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_test_inline.cmake )
 251
 252 ###########################################################
 253 # Platform check
 254 ###########################################################
 255
 256 if(APPLE)
 257     include( ${CMAKE_SOURCE_DIR}/cmake/vlc_find_frameworks.cmake )
 258
 259     # Mac OS X (10.4 and 10.5)  can't poll a tty properly
 260     # So we deactivate its uses
 261     set(HAVE_POLL OFF)
 262
 263     if(ENABLE_NO_SYMBOL_CHECK)
 264         set(DYNAMIC_LOOKUP "-undefined dynamic_lookup")
 265     else(ENABLE_NO_SYMBOL_CHECK)
 266         set(DYNAMIC_LOOKUP)
 267     endif(ENABLE_NO_SYMBOL_CHECK)
 268     set(CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS
 269      "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} ${DYNAMIC_LOOKUP}")
 270     set(CMAKE_SHARED_MODULE_CREATE_C_FLAGS
 271      "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} ${DYNAMIC_LOOKUP}")
 272
 273     # For pre-10.5
 274     set( CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_C_FLAGS} -fno-common")
 275
 276     set(SYS_DARWIN 1)
 277     add_definitions(-std=gnu99) # Hack for obj-c files to be compiled with gnu99
 278     vlc_enable_modules(macosx minimal_macosx opengllayer
 279                        access_eyetv quartztext auhal)
 280
 281     # On Pre-10.5
 282     vlc_module_add_link_flags (ffmpeg "-read_only_relocs warning")
 283
 284    # vlc_check_include_files (ApplicationServices/ApplicationServices.h)
 285    # vlc_check_include_files (Carbon/Carbon.h)
 286    # vlc_check_include_files (CoreAudio/CoreAudio.h)
 287
 288    # check_symbol_exists (CFLocaleCopyCurrent "CoreFoundation/CoreFoundation.h" "" HAVE_CFLOCALECOPYCURRENT)
 289    # check_symbol_exists (CFPreferencesCopyAppValue "CoreFoundation/CoreFoundation.h" "" HAVE_CFPREFERENCESCOPYAPPVALUE)
 290
 291     vlc_find_frameworks(Cocoa Carbon OpenGL AGL IOKit Quicktime
 292                         WebKit QuartzCore Foundation ApplicationServices
 293                         CoreAudio AudioUnit AudioToolbox)
 294     vlc_module_add_link_libraries(macosx
 295         ${Cocoa_FRAMEWORKS}
 296         ${IOKit_FRAMEWORKS}
 297         ${OpenGL_FRAMEWORKS}
 298         ${AGL_FRAMEWORKS}
 299         ${Quicktime_FRAMEWORKS}
 300         ${WebKit_FRAMEWORKS})
 301     vlc_module_add_link_libraries(minimal_macosx
 302         ${Cocoa_FRAMEWORKS}
 303         ${Carbon_FRAMEWORKS}
 304         ${OpenGL_FRAMEWORKS}
 305         ${AGL_FRAMEWORKS})
 306     vlc_module_add_link_libraries(access_eyetv
 307         ${Foundation_FRAMEWORKS})
 308     vlc_module_add_link_libraries(opengllayer
 309          ${Cocoa_FRAMEWORKS}
 310          ${QuartzCore_FRAMEWORKS}
 311          ${OpenGL_FRAMEWORKS} )
 312     vlc_module_add_link_libraries(quartztext
 313          ${Carbon_FRAMEWORKS}
 314          ${ApplicationServices_FRAMEWORKS} )
 315     vlc_module_add_link_libraries(auhal
 316          ${Carbon_FRAMEWORKS}
 317          ${CoreAudio_FRAMEWORKS}
 318          ${AudioUnit_FRAMEWORKS}
 319          ${AudioToolbox_FRAMEWORKS} )
 320     vlc_module_add_link_libraries(mp4 ${IOKit_FRAMEWORKS} )
 321     vlc_module_add_link_libraries(mkv ${IOKit_FRAMEWORKS} )
 322
 323     add_executable(VLC MACOSX_BUNDLE src/vlc.c)
 324     target_link_libraries(VLC libvlc)
 325     set( MacOS ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/MacOS )
 326     add_custom_command(
 327         TARGET VLC
 328         POST_BUILD
 329         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 330         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx
 331         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx
 332         COMMAND for i in vlc.xcodeproj Resources README.MacOSX.rtf\; do cp -R ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx\; done
 333         COMMAND for i in AUTHORS COPYING THANKS\;do cp ${CMAKE_CURRENT_SOURCE_DIR}/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp\; done
 334         COMMAND for i in AppleRemote.h AppleRemote.m about.h about.m applescript.h applescript.m controls.h controls.m equalizer.h equalizer.m intf.h intf.m macosx.m misc.h misc.m open.h open.m output.h output.m playlist.h playlist.m playlistinfo.h playlistinfo.m prefs_widgets.h prefs_widgets.m prefs.h prefs.m vout.h voutqt.m voutgl.m wizard.h wizard.m extended.h extended.m bookmarks.h bookmarks.m sfilters.h sfilters.m update.h update.m interaction.h interaction.m embeddedwindow.h embeddedwindow.m fspanel.h fspanel.m vout.m\; do cp ${CMAKE_CURRENT_SOURCE_DIR}/modules/gui/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx\; done
 335         COMMAND cd ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx && xcodebuild -target vlc | grep -vE '^\([ \\t]|$$\)' && cd ../../../../ && cp ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Info.plist ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents && cp -R ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Resources/English.lproj ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources
 336         COMMAND cp -r ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/Resources ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents
 337         COMMAND find -d ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources -type d -name \\.svn -exec rm -rf {} "\;"
 338         COMMAND rm -rf ${MacOS}/modules ${MacOS}/locale ${MacOS}/share
 339         COMMAND ln -s ${CMAKE_CURRENT_SOURCE_DIR}/share ${MacOS}/share
 340         COMMAND ln -s ${CMAKE_CURRENT_BINARY_DIR}/modules ${MacOS}/modules
 341         COMMAND find ${CMAKE_BINARY_DIR}/po -name *.gmo -exec sh -c \"mkdir -p ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES\; ln -s {} ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES/vlc.mo\" "\;"
 342         COMMAND ln -sf VLC ${MacOS}/clivlc #useless?
 343         COMMAND printf "APPLVLC#" > ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/PkgInfo
 344         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 345     )
 346     set( MacOS )
 347
 348 endif(APPLE)
 349
 350 ###########################################################
 351 # info
 352 ###########################################################
 353
 354 macro(command_to_configvar command var)
 355  execute_process(
 356   COMMAND sh -c "${command}"
 357   OUTPUT_VARIABLE ${var}
 358   OUTPUT_STRIP_TRAILING_WHITESPACE)
 359  string( REPLACE "\n" "\\n" ${var} "${${var}}")
 360 endmacro(command_to_configvar)
 361
 362 command_to_configvar( "whoami" VLC_COMPILE_BY )
 363 command_to_configvar( "hostname" VLC_COMPILE_HOST )
 364 command_to_configvar( "hostname" VLC_COMPILE_DOMAIN )
 365 command_to_configvar( "${CMAKE_C_COMPILER} --version" VLC_COMPILER )
 366 # FIXME: WTF? this is not the configure line!
 367 command_to_configvar( "${CMAKE_C_COMPILER} --version" CONFIGURE_LINE )
 368 set( VLC_COMPILER "${CMAKE_C_COMPILER}" )
 369
 370 ###########################################################
 371 # Modules: Following are all listed in options
 372 ###########################################################
 373
 374 # This module will be enabled but user could disabled it
 375 vlc_enable_modules(dummy logger memcpy)
 376 vlc_enable_modules(mpgv mpga m4v m4a h264 vc1 demux_cdg cdg ps pva avi mp4 rawdv rawvid nsv real aiff mjpeg demuxdump flacsys tta)
 377 vlc_enable_modules(cvdsub svcdsub spudec subsdec subsusf t140 dvbsub cc mpeg_audio lpcm a52 dts cinepak flac)
 378 vlc_enable_modules(deinterlace invert adjust transform wave ripple psychedelic gradient motionblur rv32 rotate noise grain extract sharpen seamcarving)
 379 vlc_enable_modules(converter_fixed mono)
 380 vlc_enable_modules(trivial_resampler ugly_resampler)
 381 vlc_enable_modules(trivial_channel_mixer trivial_mixer)
 382 vlc_enable_modules(playlist export nsc xtag)
 383 vlc_enable_modules(i420_rgb grey_yuv rawvideo blend scale image logo magnify puzzle colorthres)
 384 vlc_enable_modules(wav araw subtitle vobsub adpcm a52sys dtssys au ty voc xa nuv smf)
 385 vlc_enable_modules(access_directory access_file access_udp access_tcp)
 386 vlc_enable_modules(access_http access_mms access_ftp)
 387 vlc_enable_modules(access_filter_bandwidth)
 388 vlc_enable_modules(packetizer_mpegvideo packetizer_h264)
 389 vlc_enable_modules(packetizer_mpeg4video packetizer_mpeg4audio)
 390 vlc_enable_modules(packetizer_vc1)
 391 vlc_enable_modules(spatializer)
 392 vlc_enable_modules(asf)
 393
 394 set(enabled ${ENABLE_STREAM_OUT})
 395 vlc_register_modules(${enabled} access_output_dummy access_output_udp access_output_file access_output_http)
 396 vlc_register_modules(${enabled} mux_ps mux_avi mux_mp4 mux_asf mux_dummy mux_wav mux_mpjpeg)
 397 vlc_register_modules(${enabled} packetizer_copy)
 398
 399 vlc_register_modules(${enabled} stream_out_dummy stream_out_standard stream_out_es stream_out_rtp stream_out_description vod_rtsp)
 400 vlc_register_modules(${enabled} stream_out_duplicate stream_out_display stream_out_transcode stream_out_bridge stream_out_mosaic_bridge stream_out_autodel)
 401 vlc_register_modules(${enabled} stream_out_gather)
 402 # vlc_register_modules(${enabled} stream_out_transrate)
 403 # vlc_register_modules(${enabled} rtcp)
 404 vlc_register_modules(${enabled} profile_parser)
 405
 406 if(NOT mingwce)
 407    set(enabled ON)
 408 endif(NOT mingwce)
 409 vlc_register_modules(${enabled} access_fake access_filter_timeshift access_filter_record access_filter_dump)
 410 vlc_register_modules(${enabled} gestures rc telnet hotkeys showintf marq podcast shout sap fake folder)
 411 vlc_register_modules(${enabled} rss mosaic wall motiondetect clone crop erase bluescreen alphamask gaussianblur)
 412 vlc_register_modules(${enabled} i420_yuy2 i422_yuy2 i420_ymga i422_i420 yuy2_i422 yuy2_i420 chroma_chain)
 413 vlc_register_modules(${enabled} aout_file linear_resampler bandlimited_resampler)
 414 vlc_register_modules(${enabled} float32_mixer spdif_mixer simple_channel_mixer)
 415 vlc_register_modules(${enabled} dolby_surround_decoder headphone_channel_mixer normvol equalizer param_eq)
 416 vlc_register_modules(${enabled} converter_float a52tospdif dtstospdif audio_format)
 417 set(enabled)
 418
 419 if(NOT WIN32)
 420    vlc_enable_modules(screensaver)
 421 endif(NOT WIN32)
 422
 423 # This module is disabled because the CMakeList.txt which
 424 # is generated isn't correct. We'll put that back
 425 # when cmake will be accepted as default build system
 426 vlc_disable_modules(motion)
 427
 428 ###########################################################
 429 # libraries
 430 ###########################################################
 431
 432 include_directories(${CONTRIB_INCLUDE})
 433
 434 #fixme: use find_package(cddb 0.9.5)
 435 pkg_check_modules(LIBCDDB libcddb>=0.9.5)
 436 if(${LIBCDDB_FOUND})
 437   vlc_module_add_link_libraries(cdda ${LIBCDDB_LIBRARIES})
 438   vlc_add_module_compile_flag(cdda ${LIBCDDB_CFLAGS} )
 439 endif(${LIBCDDB_FOUND})
 440
 441 find_package(Dlopen)
 442 set(HAVE_DL_DLOPEN ${Dlopen_FOUND})
 443
 444 # Advanced Linux Sound Architecture (ALSA)
 445 pkg_check_modules(ALSA alsa>=1.0.0-rc4)
 446 if (${ALSA_FOUND})
 447   set (HAVE_ALSA_NEW_API "1")
 448 else (${ALSA_FOUND})
 449   pkg_check_modules(ALSA alsa)
 450 endif (${ALSA_FOUND})
 451
 452 if (${ALSA_FOUND})
 453   set (HAVE_ALSA "1")
 454   vlc_enable_modules(alsa)
 455   vlc_add_module_compile_flag(alsa ${ALSA_CFLAGS})
 456   vlc_module_add_link_libraries(alsa ${ALSA_LIBRARIES})
 457 endif (${ALSA_FOUND})
 458
 459 # Open Sound System (OSS)
 460 # TODO
 461
 462 find_package(FFmpeg)
 463 if(FFmpeg_FOUND)
 464   string(REPLACE ";" " " FFmpeg_CFLAGS "${FFmpeg_CFLAGS}")
 465   set( CMAKE_REQUIRED_FLAGS_saved ${CMAKE_REQUIRED_FLAGS} )
 466   set( CMAKE_REQUIRED_FLAGS ${FFmpeg_CFLAGS} )
 467
 468   vlc_check_include_files (ffmpeg/avcodec.h libavcodec/avcodec.h)
 469   vlc_check_include_files (ffmpeg/avutil.h libavutil/avutil.h)
 470   vlc_check_include_files (ffmpeg/swscale.h libswscale/swscale.h)
 471   check_c_source_compiles( "#include <stdint.h>\n#include <postproc/postprocess.h>\nint main(){return 0;}" HAVE_POSTPROC_POSTPROCESS_H )
 472   vlc_check_include_files (libpostproc/postprocess.h)
 473
 474   message( STATUS "avcodec found ${HAVE_FFMPEG_AVCODEC_H} || ${HAVE_LIBAVCODEC_AVCODEC_H}")
 475   message( STATUS "avutil found ${HAVE_FFMPEG_AVUTIL_H} || ${HAVE_LIBAVUTIL_AVUTIL_H}")
 476   message( STATUS "swscale found ${HAVE_FFMPEG_SWSCALE_H} || ${HAVE_LIBSWSCALE_SWSCALE_H}")
 477   message( STATUS "postprocess found ${HAVE_POSTPROC_POSTPROCESS_H} || ${HAVE_LIBPOSTPROC_POSTPROCESS_H}")
 478
 479   vlc_enable_modules(ffmpeg)
 480   vlc_add_module_compile_flag(ffmpeg ${FFmpeg_CFLAGS})
 481   vlc_module_add_link_libraries(ffmpeg ${FFmpeg_LIBRARIES})
 482
 483   set( CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS_saved} )
 484   set( CMAKE_REQUIRED_FLAGS_saved )
 485 endif(FFmpeg_FOUND)
 486
 487 find_package(Lua)
 488 if(Lua_FOUND)
 489   set(HAVE_LUA TRUE)
 490   vlc_enable_modules(lua)
 491   vlc_check_include_files (lua.h lualib.h)
 492   vlc_add_module_compile_flag(lua ${Lua_CFLAGS} )
 493   vlc_module_add_link_libraries(lua ${Lua_LIBRARIES})
 494 endif(Lua_FOUND)
 495
 496 find_package(Qt4)
 497 if(QT4_FOUND)
 498   set(HAVE_QT4 TRUE)
 499   include_directories(${QT_INCLUDES})
 500   vlc_check_include_files (qt.h)
 501   vlc_enable_modules(qt4)
 502   vlc_add_module_compile_flag(qt4 ${QT_CFLAGS} )
 503   vlc_module_add_link_libraries(qt4 ${QT_QTCORE_LIBRARY} ${QT_QTGUI_LIBRARY})
 504
 505   # Define our own qt4_wrap_ui macro to match wanted behaviour
 506   MACRO (VLC_QT4_WRAP_UI outfiles )
 507     FOREACH (it ${ARGN})
 508      string(REPLACE ".ui" ".h" outfile "${it}")
 509       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 510       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 511       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 512         COMMAND mkdir -p `dirname ${outfile}`
 513         COMMAND ${QT_UIC_EXECUTABLE}
 514         ARGS -o ${outfile} ${infile}
 515         MAIN_DEPENDENCY ${infile})
 516       SET(${outfiles} ${${outfiles}} ${outfile})
 517     ENDFOREACH (it)
 518   ENDMACRO (VLC_QT4_WRAP_UI)
 519
 520   MACRO (VLC_QT4_GENERATE_MOC outfiles flags )
 521     string(REGEX MATCHALL "[^\\ ]+" flags_list ${flags})
 522     FOREACH (it ${ARGN})
 523       string(REPLACE ".hpp" ".moc.cpp" outfile "${it}")
 524       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 525       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 526       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 527         COMMAND mkdir -p `dirname ${outfile}`
 528         COMMAND ${QT_MOC_EXECUTABLE}
 529         ARGS ${flags_list}
 530         ARGS -I ${CMAKE_BINARY_DIR}/include
 531         ARGS -o ${outfile} ${infile}
 532         MAIN_DEPENDENCY ${it}
 533         )
 534       SET(${outfiles} ${${outfiles}} ${outfile})
 535     ENDFOREACH (it)
 536   ENDMACRO (VLC_QT4_GENERATE_MOC)
 537
 538
 539 endif(QT4_FOUND)
 540
 541 find_package(OpenGL)
 542 if(OPENGL_FOUND)
 543   vlc_enable_modules(opengl)
 544   vlc_check_include_files (gl/gl.h)
 545   vlc_check_include_files (gl/glu.h)
 546   vlc_check_include_files (gl/glx.h)
 547   vlc_add_module_compile_flag(opengl ${OPENGL_CFLAGS})
 548   vlc_module_add_link_libraries(opengl ${OPENGL_LIBRARIES})
 549 endif(OPENGL_FOUND)
 550
 551 find_package(Matroska 0.7.7)
 552 if(Matroska_FOUND)
 553   vlc_enable_modules(mkv)
 554   vlc_check_include_files (matroska/KaxAttachments.h)
 555   vlc_check_include_files (matroska/KaxVersion.h)
 556   vlc_module_add_link_libraries(mkv ${Matroska_LIBRARIES})
 557 endif(Matroska_FOUND)
 558
 559 find_package(Live555)
 560 if(Live555_FOUND)
 561   vlc_enable_modules(live555)
 562   vlc_add_module_compile_flag(live555 ${Live555_CFLAGS})
 563   vlc_module_add_link_libraries(live555 ${Live555_LIBRARIES})
 564 endif(Live555_FOUND)
 565
 566 find_package(Curses)
 567 if(CURSES_LIBRARIES)
 568   vlc_enable_modules(ncurses)
 569   vlc_module_add_link_libraries(ncurses ${CURSES_LIBRARIES})
 570 endif(CURSES_LIBRARIES)
 571
 572 find_package(X11)
 573 if(X11_FOUND)
 574   vlc_enable_modules(x11 panoramix)
 575   vlc_check_include_files (X11/Xlib.h)
 576   vlc_module_add_link_libraries(x11       ${X11_LIBRARIES})
 577   vlc_module_add_link_libraries(panoramix ${X11_LIBRARIES})
 578 endif(X11_FOUND)
 579
 580 find_package(Mpeg2)
 581 if(Mpeg2_FOUND)
 582   vlc_enable_modules(libmpeg2)
 583   check_include_files ("stdint.h;mpeg2dec/mpeg2.h" HAVE_MPEG2DEC_MPEG2_H)
 584   vlc_module_add_link_libraries(libmpeg2 ${Mpeg2_LIBRARIES})
 585 endif(Mpeg2_FOUND)
 586
 587 find_package(Dvbpsi)
 588 if(Dvbpsi_FOUND)
 589   vlc_register_modules(${ENABLE_STREAM_OUT} mux_ts)
 590   vlc_enable_modules(ts)
 591   check_include_files ("stdint.h;dvbpsi/dvbpsi.h;dvbpsi/demux.h;dvbpsi/descriptor.h;dvbpsi/pat.h;dvbpsi/pmt.h;dvbpsi/sdt.h;dvbpsi/dr.h" HAVE_DVBPSI_DR_H)
 592   vlc_module_add_link_libraries(ts      ${Dvbpsi_LIBRARIES})
 593   vlc_module_add_link_libraries(mux_ts  ${Dvbpsi_LIBRARIES})
 594   vlc_module_add_link_libraries(dvb     ${Dvbpsi_LIBRARIES})
 595 endif(Dvbpsi_FOUND)
 596
 597 vlc_check_include_files (id3tag.h zlib.h)
 598 if(HAVE_ID3TAG_H AND HAVE_ZLIB_H)
 599   vlc_enable_modules(id3tag)
 600   vlc_module_add_link_libraries(id3tag  "id3tag;z")
 601 endif(HAVE_ID3TAG_H AND HAVE_ZLIB_H)
 602
 603 set(CMAKE_REQUIRED_INCLUDES)
 604
 605 ###########################################################
 606 # Final configuration
 607 ###########################################################
 608
 609 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/include/config.h)