git.sesse.net Git - vlc/blob - extras/buildsystem/cmake/include/config.cmake

   1 ###########################################################
   2 # System Includes
   3 ###########################################################
   4 include( CheckIncludeFile )
   5 include (CheckTypeSize)
   6 include (CheckCSourceCompiles)
   7 include (CheckSymbolExists)
   8 include (CheckLibraryExists)
   9
  10 ###########################################################
  11 # Options
  12 ###########################################################
  13 # Options moved before the custom macro includes because those macros need path values, if the ENABLE_CONTRIB
  14 # has been set.
  15
  16 OPTION( ENABLE_HTTPD           "Enable httpd server" ON )
  17 OPTION( ENABLE_STREAM_OUT      "Enable stream output plugins" ON )
  18 OPTION( ENABLE_VLM             "Enable vlm" ON )
  19 OPTION( ENABLE_DYNAMIC_PLUGINS "Enable dynamic plugin" ON )
  20 OPTION( UPDATE_CHECK           "Enable automatic new version checking" OFF )
  21 OPTION( ENABLE_NO_SYMBOL_CHECK "Don't check symbols of modules against libvlc. (Enabling this option speeds up compilation)" OFF )
  22 OPTION( ENABLE_CONTRIB         "Attempt to use VLC contrib system to get the third-party libraries" ON )
  23 OPTION( ENABLE_LOADER          "Enable the win32 codec loader" ON )
  24
  25 if(ENABLE_CONTRIB)
  26
  27   set( CONTRIB_INCLUDE ${CMAKE_SOURCE_DIR}/extras/contrib/include)
  28   set( CONTRIB_LIB ${CMAKE_SOURCE_DIR}/extras/contrib/lib)
  29   set( CONTRIB_PROGRAM ${CMAKE_SOURCE_DIR}/extras/contrib/bin)
  30   set( CMAKE_LIBRARY_PATH ${CONTRIB_LIB} ${CMAKE_LIBRARY_PATH} )
  31   set( CMAKE_PROGRAM_PATH ${CONTRIB_PROGRAM} ${CMAKE_PROGRAM_PATH} )
  32   set( CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${CONTRIB_LIB}" )
  33   set( CMAKE_CXX_LINK_FLAGS "${CMAKE_CXX_LINK_FLAGS} -L${CONTRIB_LIB}" )
  34   set( CMAKE_SHARED_MODULE_CREATE_C_FLAGS "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
  35   set( CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
  36   set( CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
  37   set( CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
  38
  39   # include extras/contrib/include in the header search pathes
  40   include_directories(${CONTRIB_INCLUDE})
  41   set( CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${CONTRIB_INCLUDE} )
  42
  43   # include the extras/contrib/bin to the search path, otherwise, when finding programs it will automatically
  44   # default to system applications (e.g. we should favor the extras/contrib/bin/pkg-config over the system defined
  45   # one).
  46   if(WIN32)
  47     set( ENV{PATH} "${CONTRIB_PROGRAM};$ENV{PATH}" )
  48   else(WIN32)
  49     set( ENV{PATH} "${CONTRIB_PROGRAM}:$ENV{PATH}" )
  50   endif(WIN32)
  51 endif(ENABLE_CONTRIB)
  52
  53 ###########################################################
  54 # Custom Macro Includes
  55 ###########################################################
  56
  57 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_include_files.cmake )
  58 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_functions_exist.cmake )
  59 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_add_compile_flag.cmake )
  60 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_type.cmake )
  61 include( ${CMAKE_SOURCE_DIR}/cmake/pkg_check_modules.cmake )
  62
  63 ###########################################################
  64 # Versioning
  65 ###########################################################
  66
  67 set(VLC_VERSION_MAJOR "0")
  68 set(VLC_VERSION_MINOR "9")
  69 set(VLC_VERSION_PATCH "0")
  70 set(VLC_VERSION_EXTRA "-svn")
  71 set(VLC_VERSION ${VLC_VERSION_MAJOR}.${VLC_VERSION_MINOR}.${VLC_VERSION_PATCH}${VLC_VERSION_EXTRA})
  72
  73 set(PACKAGE "vlc")
  74 set(PACKAGE_VERSION "${VLC_VERSION}")
  75 set(PACKAGE_STRING "vlc")
  76 set(VERSION_MESSAGE "vlc-${VLC_VERSION}")
  77 set(COPYRIGHT_MESSAGE "Copyright © the VideoLAN team")
  78 set(COPYRIGHT_YEARS "2001-2008")
  79 set(PACKAGE_VERSION_EXTRA "${VLC_VERSION_EXTRA}")
  80 set(PACKAGE_VERSION_MAJOR "${VLC_VERSION_MAJOR}")
  81 set(PACKAGE_VERSION_MINOR "${VLC_VERSION_MINOR}")
  82 set(PACKAGE_VERSION_REVISION "${VLC_VERSION_PATCH}")
  83
  84 ###########################################################
  85 # Preflight Checks
  86 ###########################################################
  87
  88 IF (NOT CMAKE_BUILD_TYPE)
  89     set(CMAKE_BUILD_TYPE "Debug" CACHE STRING  "build type determining compiler flags" FORCE )
  90 endif(NOT CMAKE_BUILD_TYPE )
  91
  92 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  93     set(DEBUG ON)
  94     add_definitions(-DDEBUG=1)
  95     set(NDEBUG OFF)
  96 endif(CMAKE_BUILD_TYPE STREQUAL "Debug")
  97
  98 set( HAVE_DYNAMIC_PLUGINS ${ENABLE_DYNAMIC_PLUGINS})
  99 set( LIBEXT ${CMAKE_SHARED_MODULE_SUFFIX})
 100
 101 check_c_source_compiles(
 102     "struct __attribute__((__packed__)) foo { int a; } b; int main(){return 0;}"
 103     HAVE_ATTRIBUTE_PACKED)
 104
 105 ###########################################################
 106 # Headers checks
 107 ###########################################################
 108
 109 vlc_check_include_files (malloc.h stdbool.h locale.h)
 110 vlc_check_include_files (stddef.h stdlib.h sys/stat.h)
 111 vlc_check_include_files (stdio.h stdint.h inttypes.h)
 112 vlc_check_include_files (signal.h unistd.h dirent.h)
 113 vlc_check_include_files (netinet/in.h netinet/udplite.h)
 114 vlc_check_include_files (arpa/inet.h net/if.h)
 115 vlc_check_include_files (netdb.h fcntl.h sys/time.h poll.h)
 116 vlc_check_include_files (errno.h time.h alloca.h)
 117 vlc_check_include_files (limits.h)
 118
 119 vlc_check_include_files (string.h strings.h getopt.h)
 120
 121 vlc_check_include_files (dlfcn.h dl.h)
 122
 123 vlc_check_include_files (kernel/OS.h)
 124 vlc_check_include_files (memory.h)
 125 vlc_check_include_files (mach-o/dyld.h)
 126
 127 vlc_check_include_files (pthread.h)
 128
 129 find_package (Threads)
 130
 131 ###########################################################
 132 # Functions/structures checks
 133 ###########################################################
 134
 135 set(CMAKE_REQUIRED_LIBRARIES c)
 136 set(CMAKE_EXTRA_INCLUDE_FILES string.h)
 137 vlc_check_functions_exist(strcpy strcasecmp)
 138 vlc_check_functions_exist(strcasestr strdup)
 139 vlc_check_functions_exist(strndup stricmp strnicmp)
 140 vlc_check_functions_exist(atof strtoll atoll lldiv)
 141 vlc_check_functions_exist(strlcpy stristr strnlen strsep)
 142 vlc_check_functions_exist(strtod strtof strtol stroul)
 143 vlc_check_functions_exist(stroull)
 144 set(CMAKE_EXTRA_INCLUDE_FILES)
 145
 146 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 147 vlc_check_functions_exist(vasprintf)
 148 set(CMAKE_EXTRA_INCLUDE_FILES)
 149
 150 set(CMAKE_EXTRA_INCLUDE_FILES libc.h)
 151 vlc_check_functions_exist(fork)
 152 set(CMAKE_EXTRA_INCLUDE_FILES)
 153
 154 set(CMAKE_EXTRA_INCLUDE_FILES stdlib.h)
 155 vlc_check_functions_exist(putenv getenv setenv)
 156 vlc_check_functions_exist(putenv getenv setenv)
 157 set(CMAKE_EXTRA_INCLUDE_FILES)
 158
 159 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 160 vlc_check_functions_exist(snprintf asprintf)
 161 vlc_check_functions_exist(putenv getenv setenv)
 162 set(CMAKE_EXTRA_INCLUDE_FILES)
 163
 164 set(CMAKE_EXTRA_INCLUDE_FILES unistd.h)
 165 vlc_check_functions_exist(isatty getcwd getuid swab)
 166 set(CMAKE_EXTRA_INCLUDE_FILES)
 167
 168 set(CMAKE_EXTRA_INCLUDE_FILES sys/stat.h)
 169 vlc_check_functions_exist(lstat fstat stat)
 170 set(CMAKE_EXTRA_INCLUDE_FILES)
 171
 172 set(CMAKE_EXTRA_INCLUDE_FILES arpa/inet.h)
 173 vlc_check_functions_exist(inet_aton inet_ntop inet_pton)
 174 set(CMAKE_EXTRA_INCLUDE_FILES)
 175
 176 set(CMAKE_EXTRA_INCLUDE_FILES sys/mman.h)
 177 vlc_check_functions_exist(mmap)
 178 set(CMAKE_EXTRA_INCLUDE_FILES)
 179
 180 set(CMAKE_REQUIRED_LIBRARIES)
 181
 182 check_library_exists(poll poll "" HAVE_POLL)
 183
 184 check_c_source_compiles(
 185 "#include <langinfo.h>
 186 int main() { char* cs = nl_langinfo(CODESET); }"
 187 HAVE_LANGINFO_CODESET)
 188
 189 vlc_check_type("struct addrinfo" "sys/socket.h;netdb.h")
 190 if(HAVE_STRUCT_ADDRINFO)
 191   set(HAVE_ADDRINFO ON)
 192 endif(HAVE_STRUCT_ADDRINFO)
 193 vlc_check_type("struct timespec" "time.h")
 194
 195 check_c_source_compiles (
 196 "#include <stdint.h> \n #ifdef UINTMAX \n #error no uintmax
 197  #endif
 198  int main() { return 0;}" HAVE_STDINT_H_WITH_UINTMAX)
 199
 200 check_symbol_exists(ntohl "sys/param.h"  NTOHL_IN_SYS_PARAM_H)
 201 check_symbol_exists(scandir "dirent.h"   HAVE_SCANDIR)
 202 check_symbol_exists(localtime_r "time.h" HAVE_LOCALTIME_R)
 203 check_symbol_exists(alloca "alloca.h"    HAVE_ALLOCA)
 204
 205 check_symbol_exists(va_copy "stdarg.h"   HAVE_VACOPY)
 206 check_symbol_exists(__va_copy "stdarg.h" HAVE___VA_COPY)
 207
 208
 209 check_symbol_exists(getnameinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETNAMEINFO)
 210 check_symbol_exists(getaddrinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETADDRINFO)
 211 if(NOT HAVE_GETADDRINFO)
 212     check_library_exists(getaddrinfo nsl "" HAVE_GETADDRINFO)
 213 endif(NOT HAVE_GETADDRINFO)
 214
 215 vlc_check_functions_exist(iconv)
 216 if(NOT HAVE_ICONV)
 217     set(LIBICONV "iconv")
 218     check_library_exists(iconv iconv "" HAVE_ICONV)
 219 endif(NOT HAVE_ICONV)
 220 set(CMAKE_REQUIRED_LIBRARIES ${LIBICONV})
 221 CHECK_C_SOURCE_COMPILES(" #include <iconv.h>
 222  int main() { return iconv(0, (char **)0, 0, (char**)0, 0); }" ICONV_NO_CONST)
 223 if( ICONV_NO_CONST )
 224   set( ICONV_CONST "const" )
 225 else( ICONV_NO_CONST )
 226   set( ICONV_CONST " ")
 227 endif( ICONV_NO_CONST )
 228 set(CMAKE_REQUIRED_LIBRARIES)
 229
 230 check_library_exists(rt clock_nanosleep "" HAVE_CLOCK_NANOSLEEP)
 231 if (HAVE_CLOCK_NANOSLEEP)
 232     set(LIBRT "rt")
 233 endif (HAVE_CLOCK_NANOSLEEP)
 234
 235 check_library_exists(m pow "" HAVE_LIBM)
 236 if (HAVE_LIBM)
 237     set (LIBM "m")
 238 endif (HAVE_LIBM)
 239
 240 check_symbol_exists(connect "sys/types.h;sys/socket.h" HAVE_CONNECT)
 241 if(NOT HAVE_CONNECT)
 242     check_library_exists(connect socket "" HAVE_CONNECT)
 243     if(NOT HAVE_CONNECT)
 244         vlc_module_add_link_libraries(libvlc connect)
 245         vlc_module_add_link_libraries(cdda   connect)
 246         vlc_module_add_link_libraries(cddax  connect)
 247     endif(NOT HAVE_CONNECT)
 248 endif(NOT HAVE_CONNECT)
 249
 250 ###########################################################
 251 # Other check
 252 ###########################################################
 253
 254 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_test_inline.cmake )
 255
 256 ###########################################################
 257 # Platform check
 258 ###########################################################
 259
 260 if(APPLE)
 261     include( ${CMAKE_SOURCE_DIR}/cmake/vlc_find_frameworks.cmake )
 262
 263     # Mac OS X (10.4 and 10.5)  can't poll a tty properly
 264     # So we deactivate its uses
 265     set(HAVE_POLL OFF)
 266
 267     if(ENABLE_NO_SYMBOL_CHECK)
 268         set(DYNAMIC_LOOKUP "-undefined dynamic_lookup")
 269     else(ENABLE_NO_SYMBOL_CHECK)
 270         set(DYNAMIC_LOOKUP)
 271     endif(ENABLE_NO_SYMBOL_CHECK)
 272     set(CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS
 273      "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} ${DYNAMIC_LOOKUP}")
 274     set(CMAKE_SHARED_MODULE_CREATE_C_FLAGS
 275      "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} ${DYNAMIC_LOOKUP}")
 276
 277     # For pre-10.5
 278     set( CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_C_FLAGS} -fno-common")
 279
 280     set(SYS_DARWIN 1)
 281     add_definitions(-std=gnu99) # Hack for obj-c files to be compiled with gnu99
 282     vlc_enable_modules(macosx minimal_macosx opengllayer
 283                        access_eyetv quartztext auhal)
 284
 285     # On Pre-10.5
 286     vlc_module_add_link_flags (ffmpeg "-read_only_relocs warning")
 287
 288    # vlc_check_include_files (ApplicationServices/ApplicationServices.h)
 289    # vlc_check_include_files (Carbon/Carbon.h)
 290    # vlc_check_include_files (CoreAudio/CoreAudio.h)
 291
 292    # check_symbol_exists (CFLocaleCopyCurrent "CoreFoundation/CoreFoundation.h" "" HAVE_CFLOCALECOPYCURRENT)
 293    # check_symbol_exists (CFPreferencesCopyAppValue "CoreFoundation/CoreFoundation.h" "" HAVE_CFPREFERENCESCOPYAPPVALUE)
 294
 295     vlc_find_frameworks(Cocoa Carbon OpenGL AGL IOKit Quicktime
 296                         WebKit QuartzCore Foundation ApplicationServices
 297                         CoreAudio AudioUnit AudioToolbox)
 298     vlc_module_add_link_libraries(macosx
 299         ${Cocoa_FRAMEWORKS}
 300         ${IOKit_FRAMEWORKS}
 301         ${OpenGL_FRAMEWORKS}
 302         ${AGL_FRAMEWORKS}
 303         ${Quicktime_FRAMEWORKS}
 304         ${WebKit_FRAMEWORKS})
 305     vlc_module_add_link_libraries(minimal_macosx
 306         ${Cocoa_FRAMEWORKS}
 307         ${Carbon_FRAMEWORKS}
 308         ${OpenGL_FRAMEWORKS}
 309         ${AGL_FRAMEWORKS})
 310     vlc_module_add_link_libraries(access_eyetv
 311         ${Foundation_FRAMEWORKS})
 312     vlc_module_add_link_libraries(opengllayer
 313          ${Cocoa_FRAMEWORKS}
 314          ${QuartzCore_FRAMEWORKS}
 315          ${OpenGL_FRAMEWORKS} )
 316     vlc_module_add_link_libraries(quartztext
 317          ${Carbon_FRAMEWORKS}
 318          ${ApplicationServices_FRAMEWORKS} )
 319     vlc_module_add_link_libraries(auhal
 320          ${Carbon_FRAMEWORKS}
 321          ${CoreAudio_FRAMEWORKS}
 322          ${AudioUnit_FRAMEWORKS}
 323          ${AudioToolbox_FRAMEWORKS} )
 324     vlc_module_add_link_libraries(mp4 ${IOKit_FRAMEWORKS} )
 325     vlc_module_add_link_libraries(mkv ${IOKit_FRAMEWORKS} )
 326
 327     add_executable(VLC MACOSX_BUNDLE src/vlc.c)
 328     target_link_libraries(VLC libvlc)
 329     set( MacOS ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/MacOS )
 330     add_custom_command(
 331         TARGET VLC
 332         POST_BUILD
 333         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 334         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx
 335         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx
 336         COMMAND for i in vlc.xcodeproj Resources README.MacOSX.rtf\; do cp -R ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx\; done
 337         COMMAND for i in AUTHORS COPYING THANKS\;do cp ${CMAKE_CURRENT_SOURCE_DIR}/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp\; done
 338         COMMAND for i in AppleRemote.h AppleRemote.m about.h about.m applescript.h applescript.m controls.h controls.m equalizer.h equalizer.m intf.h intf.m macosx.m misc.h misc.m open.h open.m output.h output.m playlist.h playlist.m playlistinfo.h playlistinfo.m prefs_widgets.h prefs_widgets.m prefs.h prefs.m vout.h voutqt.m voutgl.m wizard.h wizard.m extended.h extended.m bookmarks.h bookmarks.m sfilters.h sfilters.m update.h update.m interaction.h interaction.m embeddedwindow.h embeddedwindow.m fspanel.h fspanel.m vout.m\; do cp ${CMAKE_CURRENT_SOURCE_DIR}/modules/gui/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx\; done
 339         COMMAND cd ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx && xcodebuild -target vlc | grep -vE '^\([ \\t]|$$\)' && cd ../../../../ && cp ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Info.plist ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents && cp -R ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Resources/English.lproj ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources
 340         COMMAND cp -r ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/Resources ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents
 341         COMMAND find -d ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources -type d -name \\.svn -exec rm -rf {} "\;"
 342         COMMAND rm -rf ${MacOS}/modules ${MacOS}/locale ${MacOS}/share
 343         COMMAND ln -s ${CMAKE_CURRENT_SOURCE_DIR}/share ${MacOS}/share
 344         COMMAND ln -s ${CMAKE_CURRENT_BINARY_DIR}/modules ${MacOS}/modules
 345         COMMAND find ${CMAKE_BINARY_DIR}/po -name *.gmo -exec sh -c \"mkdir -p ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES\; ln -s {} ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES/vlc.mo\" "\;"
 346         COMMAND ln -sf VLC ${MacOS}/clivlc #useless?
 347         COMMAND printf "APPLVLC#" > ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/PkgInfo
 348         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 349     )
 350     set( MacOS )
 351
 352 endif(APPLE)
 353
 354 ###########################################################
 355 # info
 356 ###########################################################
 357
 358 macro(command_to_configvar command var)
 359  execute_process(
 360   COMMAND sh -c "${command}"
 361   OUTPUT_VARIABLE ${var}
 362   OUTPUT_STRIP_TRAILING_WHITESPACE)
 363  string( REPLACE "\n" "\\n" ${var} "${${var}}")
 364 endmacro(command_to_configvar)
 365
 366 command_to_configvar( "whoami" VLC_COMPILE_BY )
 367 command_to_configvar( "hostname" VLC_COMPILE_HOST )
 368 command_to_configvar( "hostname" VLC_COMPILE_DOMAIN )
 369 command_to_configvar( "${CMAKE_C_COMPILER} --version" VLC_COMPILER )
 370 # FIXME: WTF? this is not the configure line!
 371 command_to_configvar( "${CMAKE_C_COMPILER} --version" CONFIGURE_LINE )
 372 set( VLC_COMPILER "${CMAKE_C_COMPILER}" )
 373
 374 ###########################################################
 375 # Modules: Following are all listed in options
 376 ###########################################################
 377
 378 # This module will be enabled but user could disabled it
 379 vlc_enable_modules(dummy logger memcpy)
 380 vlc_enable_modules(mpgv mpga m4v m4a h264 vc1 demux_cdg cdg ps pva avi mp4 rawdv rawvid nsv real aiff mjpeg demuxdump flacsys tta)
 381 vlc_enable_modules(cvdsub svcdsub spudec subsdec subsusf t140 dvbsub cc mpeg_audio lpcm a52 dts cinepak flac)
 382 vlc_enable_modules(deinterlace invert adjust transform wave ripple psychedelic gradient motionblur rv32 rotate noise grain extract sharpen seamcarving)
 383 vlc_enable_modules(converter_fixed mono)
 384 vlc_enable_modules(trivial_resampler ugly_resampler)
 385 vlc_enable_modules(trivial_channel_mixer trivial_mixer)
 386 vlc_enable_modules(playlist export nsc xtag)
 387 vlc_enable_modules(i420_rgb grey_yuv rawvideo blend scale image logo magnify puzzle colorthres)
 388 vlc_enable_modules(wav araw subtitle vobsub adpcm a52sys dtssys au ty voc xa nuv smf)
 389 vlc_enable_modules(access_directory access_file access_udp access_tcp)
 390 vlc_enable_modules(access_http access_mms access_ftp)
 391 vlc_enable_modules(access_filter_bandwidth)
 392 vlc_enable_modules(packetizer_mpegvideo packetizer_h264)
 393 vlc_enable_modules(packetizer_mpeg4video packetizer_mpeg4audio)
 394 vlc_enable_modules(packetizer_vc1)
 395 vlc_enable_modules(spatializer)
 396 vlc_enable_modules(asf)
 397
 398 set(enabled ${ENABLE_STREAM_OUT})
 399 vlc_register_modules(${enabled} access_output_dummy access_output_udp access_output_file access_output_http)
 400 vlc_register_modules(${enabled} mux_ps mux_avi mux_mp4 mux_asf mux_dummy mux_wav mux_mpjpeg)
 401 vlc_register_modules(${enabled} packetizer_copy)
 402
 403 vlc_register_modules(${enabled} stream_out_dummy stream_out_standard stream_out_es stream_out_rtp stream_out_description vod_rtsp)
 404 vlc_register_modules(${enabled} stream_out_duplicate stream_out_display stream_out_transcode stream_out_bridge stream_out_mosaic_bridge stream_out_autodel)
 405 vlc_register_modules(${enabled} stream_out_gather)
 406 # vlc_register_modules(${enabled} stream_out_transrate)
 407 # vlc_register_modules(${enabled} rtcp)
 408 vlc_register_modules(${enabled} profile_parser)
 409
 410 if(NOT mingwce)
 411    set(enabled ON)
 412 endif(NOT mingwce)
 413 vlc_register_modules(${enabled} access_fake access_filter_timeshift access_filter_record access_filter_dump)
 414 vlc_register_modules(${enabled} gestures rc telnet hotkeys showintf marq podcast shout sap fake folder)
 415 vlc_register_modules(${enabled} rss mosaic wall motiondetect clone crop erase bluescreen alphamask gaussianblur)
 416 vlc_register_modules(${enabled} i420_yuy2 i422_yuy2 i420_ymga i422_i420 yuy2_i422 yuy2_i420 chroma_chain)
 417 vlc_register_modules(${enabled} aout_file linear_resampler bandlimited_resampler)
 418 vlc_register_modules(${enabled} float32_mixer spdif_mixer simple_channel_mixer)
 419 vlc_register_modules(${enabled} dolby_surround_decoder headphone_channel_mixer normvol equalizer param_eq)
 420 vlc_register_modules(${enabled} converter_float a52tospdif dtstospdif audio_format)
 421 set(enabled)
 422
 423 if(NOT WIN32)
 424    vlc_enable_modules(screensaver)
 425 endif(NOT WIN32)
 426
 427 # This module is disabled because the CMakeList.txt which
 428 # is generated isn't correct. We'll put that back
 429 # when cmake will be accepted as default build system
 430 vlc_disable_modules(motion)
 431
 432 ###########################################################
 433 # libraries
 434 ###########################################################
 435
 436 include_directories(${CONTRIB_INCLUDE})
 437
 438 #fixme: use find_package(cddb 0.9.5)
 439 pkg_check_modules(LIBCDDB libcddb>=0.9.5)
 440 if(${LIBCDDB_FOUND})
 441   vlc_module_add_link_libraries(cdda ${LIBCDDB_LIBRARIES})
 442   vlc_add_module_compile_flag(cdda ${LIBCDDB_CFLAGS} )
 443 endif(${LIBCDDB_FOUND})
 444
 445 find_package(Dlopen)
 446 set(HAVE_DL_DLOPEN ${Dlopen_FOUND})
 447
 448 # Advanced Linux Sound Architecture (ALSA)
 449 pkg_check_modules(ALSA alsa>=1.0.0-rc4)
 450 if (${ALSA_FOUND})
 451   set (HAVE_ALSA_NEW_API "1")
 452 else (${ALSA_FOUND})
 453   pkg_check_modules(ALSA alsa)
 454 endif (${ALSA_FOUND})
 455
 456 if (${ALSA_FOUND})
 457   set (HAVE_ALSA "1")
 458   vlc_enable_modules(alsa)
 459   vlc_add_module_compile_flag(alsa ${ALSA_CFLAGS})
 460   vlc_module_add_link_libraries(alsa ${ALSA_LIBRARIES})
 461 endif (${ALSA_FOUND})
 462
 463 # Open Sound System (OSS)
 464 # TODO
 465
 466 find_package(FFmpeg)
 467 if(FFmpeg_FOUND)
 468   string(REPLACE ";" " " FFmpeg_CFLAGS "${FFmpeg_CFLAGS}")
 469   set( CMAKE_REQUIRED_FLAGS_saved ${CMAKE_REQUIRED_FLAGS} )
 470   set( CMAKE_REQUIRED_FLAGS ${FFmpeg_CFLAGS} )
 471
 472   vlc_check_include_files (ffmpeg/avcodec.h libavcodec/avcodec.h)
 473   vlc_check_include_files (ffmpeg/avutil.h libavutil/avutil.h)
 474   vlc_check_include_files (ffmpeg/swscale.h libswscale/swscale.h)
 475   check_c_source_compiles( "#include <stdint.h>\n#include <postproc/postprocess.h>\nint main(){return 0;}" HAVE_POSTPROC_POSTPROCESS_H )
 476   vlc_check_include_files (libpostproc/postprocess.h)
 477
 478   message( STATUS "avcodec found ${HAVE_FFMPEG_AVCODEC_H} || ${HAVE_LIBAVCODEC_AVCODEC_H}")
 479   message( STATUS "avutil found ${HAVE_FFMPEG_AVUTIL_H} || ${HAVE_LIBAVUTIL_AVUTIL_H}")
 480   message( STATUS "swscale found ${HAVE_FFMPEG_SWSCALE_H} || ${HAVE_LIBSWSCALE_SWSCALE_H}")
 481   message( STATUS "postprocess found ${HAVE_POSTPROC_POSTPROCESS_H} || ${HAVE_LIBPOSTPROC_POSTPROCESS_H}")
 482
 483   vlc_enable_modules(ffmpeg)
 484   vlc_add_module_compile_flag(ffmpeg ${FFmpeg_CFLAGS})
 485   vlc_module_add_link_libraries(ffmpeg ${FFmpeg_LIBRARIES})
 486
 487   set( CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS_saved} )
 488   set( CMAKE_REQUIRED_FLAGS_saved )
 489 endif(FFmpeg_FOUND)
 490
 491 find_package(Lua)
 492 if(Lua_FOUND)
 493   set(HAVE_LUA TRUE)
 494   vlc_enable_modules(lua)
 495   vlc_check_include_files (lua.h lualib.h)
 496   vlc_add_module_compile_flag(lua ${Lua_CFLAGS} )
 497   vlc_module_add_link_libraries(lua ${Lua_LIBRARIES})
 498 endif(Lua_FOUND)
 499
 500 find_package(Qt4)
 501 if(QT4_FOUND)
 502   set(HAVE_QT4 TRUE)
 503   include_directories(${QT_INCLUDES})
 504   vlc_check_include_files (qt.h)
 505   vlc_enable_modules(qt4)
 506   vlc_add_module_compile_flag(qt4 ${QT_CFLAGS} )
 507   vlc_module_add_link_libraries(qt4 ${QT_QTCORE_LIBRARY} ${QT_QTGUI_LIBRARY})
 508
 509   # Define our own qt4_wrap_ui macro to match wanted behaviour
 510   MACRO (VLC_QT4_WRAP_UI outfiles )
 511     FOREACH (it ${ARGN})
 512      string(REPLACE ".ui" ".h" outfile "${it}")
 513       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 514       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 515       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 516         COMMAND mkdir -p `dirname ${outfile}`
 517         COMMAND ${QT_UIC_EXECUTABLE}
 518         ARGS -o ${outfile} ${infile}
 519         MAIN_DEPENDENCY ${infile})
 520       SET(${outfiles} ${${outfiles}} ${outfile})
 521     ENDFOREACH (it)
 522   ENDMACRO (VLC_QT4_WRAP_UI)
 523
 524   MACRO (VLC_QT4_GENERATE_MOC outfiles flags )
 525     string(REGEX MATCHALL "[^\\ ]+" flags_list ${flags})
 526     FOREACH (it ${ARGN})
 527       string(REPLACE ".hpp" ".moc.cpp" outfile "${it}")
 528       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 529       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 530       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 531         COMMAND mkdir -p `dirname ${outfile}`
 532         COMMAND ${QT_MOC_EXECUTABLE}
 533         ARGS ${flags_list}
 534         ARGS -I ${CMAKE_BINARY_DIR}/include
 535         ARGS -o ${outfile} ${infile}
 536         MAIN_DEPENDENCY ${it}
 537         )
 538       SET(${outfiles} ${${outfiles}} ${outfile})
 539     ENDFOREACH (it)
 540   ENDMACRO (VLC_QT4_GENERATE_MOC)
 541
 542
 543 endif(QT4_FOUND)
 544
 545 find_package(OpenGL)
 546 if(OPENGL_FOUND)
 547   vlc_enable_modules(opengl)
 548   vlc_check_include_files (gl/gl.h)
 549   vlc_check_include_files (gl/glu.h)
 550   vlc_check_include_files (gl/glx.h)
 551   vlc_add_module_compile_flag(opengl ${OPENGL_CFLAGS})
 552   vlc_module_add_link_libraries(opengl ${OPENGL_LIBRARIES})
 553 endif(OPENGL_FOUND)
 554
 555 find_package(Matroska 0.7.7)
 556 if(Matroska_FOUND)
 557   vlc_enable_modules(mkv)
 558   vlc_check_include_files (matroska/KaxAttachments.h)
 559   vlc_check_include_files (matroska/KaxVersion.h)
 560   vlc_module_add_link_libraries(mkv ${Matroska_LIBRARIES})
 561 endif(Matroska_FOUND)
 562
 563 find_package(Live555)
 564 if(Live555_FOUND)
 565   vlc_enable_modules(live555)
 566   vlc_add_module_compile_flag(live555 ${Live555_CFLAGS})
 567   vlc_module_add_link_libraries(live555 ${Live555_LIBRARIES})
 568 endif(Live555_FOUND)
 569
 570 find_package(Curses)
 571 if(CURSES_LIBRARIES)
 572   vlc_enable_modules(ncurses)
 573   vlc_module_add_link_libraries(ncurses ${CURSES_LIBRARIES})
 574 endif(CURSES_LIBRARIES)
 575
 576 find_package(X11)
 577 if(X11_FOUND)
 578   vlc_enable_modules(x11 panoramix)
 579   vlc_check_include_files (X11/Xlib.h)
 580   vlc_module_add_link_libraries(x11       ${X11_LIBRARIES})
 581   vlc_module_add_link_libraries(panoramix ${X11_LIBRARIES})
 582 endif(X11_FOUND)
 583
 584 find_package(Mpeg2)
 585 if(Mpeg2_FOUND)
 586   vlc_enable_modules(libmpeg2)
 587   check_include_files ("stdint.h;mpeg2dec/mpeg2.h" HAVE_MPEG2DEC_MPEG2_H)
 588   vlc_module_add_link_libraries(libmpeg2 ${Mpeg2_LIBRARIES})
 589 endif(Mpeg2_FOUND)
 590
 591 find_package(Dvbpsi)
 592 if(Dvbpsi_FOUND)
 593   vlc_register_modules(${ENABLE_STREAM_OUT} mux_ts)
 594   vlc_enable_modules(ts)
 595   check_include_files ("stdint.h;dvbpsi/dvbpsi.h;dvbpsi/demux.h;dvbpsi/descriptor.h;dvbpsi/pat.h;dvbpsi/pmt.h;dvbpsi/sdt.h;dvbpsi/dr.h" HAVE_DVBPSI_DR_H)
 596   vlc_module_add_link_libraries(ts      ${Dvbpsi_LIBRARIES})
 597   vlc_module_add_link_libraries(mux_ts  ${Dvbpsi_LIBRARIES})
 598   vlc_module_add_link_libraries(dvb     ${Dvbpsi_LIBRARIES})
 599 endif(Dvbpsi_FOUND)
 600
 601 vlc_check_include_files (id3tag.h zlib.h)
 602 if(HAVE_ID3TAG_H AND HAVE_ZLIB_H)
 603   vlc_enable_modules(id3tag)
 604   vlc_module_add_link_libraries(id3tag  "id3tag;z")
 605 endif(HAVE_ID3TAG_H AND HAVE_ZLIB_H)
 606
 607 find_package(Taglib)
 608 if(Taglib_FOUND)
 609   set(HAVE_TAGLIB 1)
 610   vlc_enable_modules(taglib)
 611   vlc_module_add_link_libraries(taglib "${Taglib_LIBRARIES};z")
 612   vlc_add_module_compile_flag(taglib "${Taglib_CFLAGS}")
 613 endif(Taglib_FOUND)
 614
 615 vlc_check_include_files (zlib.h)
 616 if(HAVE_ZLIB_H)
 617   vlc_module_add_link_libraries(access_http z)
 618   vlc_module_add_link_libraries(mkv z)
 619   vlc_module_add_link_libraries(mp4 z)
 620   vlc_module_add_link_libraries(stream_out_bridge z)
 621   vlc_module_add_link_libraries(sap z)
 622 endif(HAVE_ZLIB_H)
 623
 624 set(CMAKE_REQUIRED_INCLUDES)
 625
 626 ###########################################################
 627 # Final configuration
 628 ###########################################################
 629
 630 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/include/config.h)