git.sesse.net Git - vlc/blob - extras/buildsystem/cmake/include/config.cmake

   1 include( CheckIncludeFile )
   2 include (CheckTypeSize)
   3 include (CheckCSourceCompiles)
   4 include (CheckSymbolExists)
   5 include (CheckLibraryExists)
   6
   7 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_include_files.cmake )
   8 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_functions_exist.cmake )
   9 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_add_compile_flag.cmake )
  10 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_check_type.cmake )
  11 include( ${CMAKE_SOURCE_DIR}/cmake/pkg_check_modules.cmake )
  12
  13 ###########################################################
  14 # VERSION
  15 ###########################################################
  16
  17 set(VLC_VERSION_MAJOR 0)
  18 set(VLC_VERSION_MINOR 9)
  19 set(VLC_VERSION_PATCH 0)
  20 set(VLC_VERSION_EXTRA "-svn")
  21 set(VLC_VERSION ${VLC_VERSION_MAJOR}.${VLC_VERSION_MINOR}.${VLC_VERSION_PATCH}${VLC_VERSION_EXTRA})
  22
  23 set(PACKAGE "vlc")
  24 set(PACKAGE_VERSION "${VLC_VERSION}")
  25 set(PACKAGE_STRING "vlc")
  26 set(VERSION_MESSAGE "vlc-${VLC_VERSION}")
  27 set(COPYRIGHT_MESSAGE "Copyright © the VideoLAN team")
  28 set(COPYRIGHT_YEARS "2001-2008")
  29
  30 ###########################################################
  31 # Options
  32 ###########################################################
  33
  34 OPTION( ENABLE_HTTPD           "Enable httpd server" ON )
  35 OPTION( ENABLE_VLM             "Enable vlm" ON )
  36 OPTION( ENABLE_DYNAMIC_PLUGINS "Enable dynamic plugin" ON )
  37 OPTION( UPDATE_CHECK           "Enable automatic new version checking" OFF )
  38 OPTION( ENABLE_NO_SYMBOL_CHECK "Don't check symbols of modules against libvlc. (Enabling this option speeds up compilation)" OFF )
  39
  40 IF (NOT CMAKE_BUILD_TYPE)
  41     set(CMAKE_BUILD_TYPE "Debug" CACHE STRING  "build type determining compiler flags" FORCE )
  42 endif(NOT CMAKE_BUILD_TYPE )
  43
  44 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  45     set(DEBUG ON)
  46     add_definitions(-DDEBUG=1)
  47     set(NDEBUG OFF)
  48 endif(CMAKE_BUILD_TYPE STREQUAL "Debug")
  49
  50 set( HAVE_DYNAMIC_PLUGINS ${ENABLE_DYNAMIC_PLUGINS})
  51 set( LIBEXT ${CMAKE_SHARED_MODULE_SUFFIX})
  52
  53 ###########################################################
  54 # Headers checks
  55 ###########################################################
  56
  57 vlc_check_include_files (malloc.h stdbool.h locale.h)
  58 vlc_check_include_files (stddef.h stdlib.h sys/stat.h)
  59 vlc_check_include_files (stdio.h stdint.h inttypes.h)
  60 vlc_check_include_files (signal.h unistd.h dirent.h)
  61 vlc_check_include_files (netinet/in.h netinet/udplite.h)
  62 vlc_check_include_files (arpa/inet.h net/if.h)
  63 vlc_check_include_files (netdb.h fcntl.h sys/time.h poll.h)
  64 vlc_check_include_files (errno.h time.h alloca.h)
  65 vlc_check_include_files (limits.h)
  66
  67 vlc_check_include_files (string.h strings.h getopt.h)
  68
  69 vlc_check_include_files (dlfcn.h dl.h)
  70
  71 vlc_check_include_files (kernel/OS.h)
  72 vlc_check_include_files (memory.h)
  73 vlc_check_include_files (mach-o/dyld.h)
  74
  75 vlc_check_include_files (pthread.h)
  76
  77 find_package (Threads)
  78
  79 ###########################################################
  80 # Functions/structures checks
  81 ###########################################################
  82 set(CMAKE_REQUIRED_LIBRARIES c)
  83 set(CMAKE_EXTRA_INCLUDE_FILES string.h)
  84 vlc_check_functions_exist(strcpy strcasecmp)
  85 vlc_check_functions_exist(strcasestr strdup)
  86 vlc_check_functions_exist(strndup stricmp strnicmp)
  87 vlc_check_functions_exist(atof strtoll atoll lldiv)
  88 vlc_check_functions_exist(strlcpy stristr strnlen strsep)
  89 vlc_check_functions_exist(strtod strtof strtol stroul)
  90 vlc_check_functions_exist(stroull)
  91 set(CMAKE_EXTRA_INCLUDE_FILES)
  92
  93 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
  94 vlc_check_functions_exist(vasprintf)
  95 set(CMAKE_EXTRA_INCLUDE_FILES)
  96
  97 set(CMAKE_EXTRA_INCLUDE_FILES libc.h)
  98 vlc_check_functions_exist(fork)
  99 set(CMAKE_EXTRA_INCLUDE_FILES)
 100
 101 set(CMAKE_EXTRA_INCLUDE_FILES stdlib.h)
 102 vlc_check_functions_exist(putenv getenv setenv)
 103 vlc_check_functions_exist(putenv getenv setenv)
 104 set(CMAKE_EXTRA_INCLUDE_FILES)
 105
 106 set(CMAKE_EXTRA_INCLUDE_FILES stdio.h)
 107 vlc_check_functions_exist(snprintf asprintf)
 108 vlc_check_functions_exist(putenv getenv setenv)
 109 set(CMAKE_EXTRA_INCLUDE_FILES)
 110
 111 set(CMAKE_EXTRA_INCLUDE_FILES unistd.h)
 112 vlc_check_functions_exist(isatty getcwd getuid)
 113 set(CMAKE_EXTRA_INCLUDE_FILES)
 114
 115 set(CMAKE_EXTRA_INCLUDE_FILES sys/stat.h)
 116 vlc_check_functions_exist(lstat fstat stat)
 117 set(CMAKE_EXTRA_INCLUDE_FILES)
 118
 119 set(CMAKE_EXTRA_INCLUDE_FILES arpa/inet.h)
 120 vlc_check_functions_exist(inet_aton inet_ntop inet_pton)
 121 set(CMAKE_EXTRA_INCLUDE_FILES)
 122
 123 set(CMAKE_REQUIRED_LIBRARIES)
 124
 125 check_library_exists(poll poll "" HAVE_POLL)
 126
 127 check_c_source_compiles(
 128 "#include <langinfo.h>
 129 int main() { char* cs = nl_langinfo(CODESET); }"
 130 HAVE_LANGINFO_CODESET)
 131
 132 vlc_check_type("struct addrinfo" "sys/socket.h;netdb.h")
 133 if(HAVE_STRUCT_ADDRINFO)
 134   set(HAVE_ADDRINFO ON)
 135 endif(HAVE_STRUCT_ADDRINFO)
 136 vlc_check_type("struct timespec" "time.h")
 137
 138 check_c_source_compiles (
 139 "#include <stdint.h> \n #ifdef UINTMAX \n #error no uintmax
 140  #endif
 141  int main() { return 0;}" HAVE_STDINT_H_WITH_UINTMAX)
 142
 143 check_symbol_exists(ntohl "sys/param.h"  NTOHL_IN_SYS_PARAM_H)
 144 check_symbol_exists(scandir "dirent.h"   HAVE_SCANDIR)
 145 check_symbol_exists(localtime_r "time.h" HAVE_LOCALTIME_R)
 146 check_symbol_exists(alloca "alloca.h"    HAVE_ALLOCA)
 147
 148 check_symbol_exists(va_copy "stdarg.h"   HAVE_VACOPY)
 149 check_symbol_exists(__va_copy "stdarg.h" HAVE___VA_COPY)
 150
 151
 152 check_symbol_exists(getnameinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETNAMEINFO)
 153 check_symbol_exists(getaddrinfo "sys/types.h;sys/socket.h;netdb.h" HAVE_GETADDRINFO)
 154 if(NOT HAVE_GETADDRINFO)
 155     check_library_exists(getaddrinfo nsl "" HAVE_GETADDRINFO)
 156 endif(NOT HAVE_GETADDRINFO)
 157
 158 vlc_check_functions_exist(iconv)
 159 if(NOT HAVE_ICONV)
 160     set(LIBICONV "iconv")
 161     check_library_exists(iconv iconv "" HAVE_ICONV)
 162 endif(NOT HAVE_ICONV)
 163 set(CMAKE_REQUIRED_LIBRARIES ${LIBICONV})
 164 CHECK_C_SOURCE_COMPILES(" #include <iconv.h>
 165  int main() { return iconv(0, (char **)0, 0, (char**)0, 0); }" ICONV_NO_CONST)
 166 if( ICONV_NO_CONST )
 167   set( ICONV_CONST "const" )
 168 else( ICONV_NO_CONST )
 169   set( ICONV_CONST " ")
 170 endif( ICONV_NO_CONST )
 171 set(CMAKE_REQUIRED_LIBRARIES)
 172
 173 check_library_exists(rt clock_nanosleep "" HAVE_CLOCK_NANOSLEEP)
 174 if (HAVE_CLOCK_NANOSLEEP)
 175     set(LIBRT "rt")
 176 endif (HAVE_CLOCK_NANOSLEEP)
 177
 178 check_library_exists(m pow "" HAVE_LIBM)
 179 if (HAVE_LIBM)
 180     set (LIBM "m")
 181 endif (HAVE_LIBM)
 182
 183 check_symbol_exists(connect "sys/types.h;sys/socket.h" HAVE_CONNECT)
 184 if(NOT HAVE_CONNECT)
 185     check_library_exists(connect socket "" HAVE_CONNECT)
 186     if(NOT HAVE_CONNECT)
 187         vlc_module_add_link_libraries(libvlc connect)
 188         vlc_module_add_link_libraries(cdda   connect)
 189         vlc_module_add_link_libraries(cddax  connect)
 190     endif(NOT HAVE_CONNECT)
 191 endif(NOT HAVE_CONNECT)
 192
 193 ###########################################################
 194 # Other check
 195 ###########################################################
 196 include( ${CMAKE_SOURCE_DIR}/cmake/vlc_test_inline.cmake )
 197
 198 ###########################################################
 199 # Platform check
 200 ###########################################################
 201 if(APPLE)
 202     include( ${CMAKE_SOURCE_DIR}/cmake/vlc_find_frameworks.cmake )
 203
 204     if(ENABLE_NO_SYMBOL_CHECK)
 205         set(DYNAMIC_LOOKUP "-undefined dynamic_lookup")
 206     else(ENABLE_NO_SYMBOL_CHECK)
 207         set(DYNAMIC_LOOKUP)
 208     endif(ENABLE_NO_SYMBOL_CHECK)
 209     set(CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS
 210      "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} ${DYNAMIC_LOOKUP}")
 211     set(CMAKE_SHARED_MODULE_CREATE_C_FLAGS
 212      "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} ${DYNAMIC_LOOKUP}")
 213
 214     # For pre-10.5
 215     set( CMAKE_SHARED_LIBRARY_C_FLAGS "${CMAKE_C_FLAGS} -fno-common")
 216
 217     set(SYS_DARWIN 1)
 218     add_definitions(-std=gnu99) # Hack for obj-c files to be compiled with gnu99
 219     vlc_enable_modules(macosx minimal_macosx opengllayer
 220                        access_eyetv quartztext auhal)
 221
 222     # On Pre-10.5
 223     vlc_module_add_link_flags (ffmpeg "-read_only_relocs warning")
 224
 225     vlc_check_include_files (ApplicationServices/ApplicationServices.h)
 226     vlc_check_include_files (Carbon/Carbon.h)
 227     vlc_check_include_files (CoreAudio/CoreAudio.h)
 228
 229    # check_symbol_exists (CFLocaleCopyCurrent "CoreFoundation/CoreFoundation.h" "" HAVE_CFLOCALECOPYCURRENT)
 230    # check_symbol_exists (CFPreferencesCopyAppValue "CoreFoundation/CoreFoundation.h" "" HAVE_CFPREFERENCESCOPYAPPVALUE)
 231
 232     vlc_find_frameworks(Cocoa Carbon OpenGL AGL IOKit Quicktime
 233                         WebKit QuartzCore Foundation ApplicationServices
 234                         CoreAudio AudioUnit AudioToolbox)
 235     vlc_module_add_link_libraries(macosx
 236         ${Cocoa_FRAMEWORKS}
 237         ${IOKit_FRAMEWORKS}
 238         ${OpenGL_FRAMEWORKS}
 239         ${AGL_FRAMEWORKS}
 240         ${Quicktime_FRAMEWORKS}
 241         ${WebKit_FRAMEWORKS})
 242     vlc_module_add_link_libraries(minimal_macosx
 243         ${Cocoa_FRAMEWORKS}
 244         ${Carbon_FRAMEWORKS}
 245         ${OpenGL_FRAMEWORKS}
 246         ${AGL_FRAMEWORKS})
 247     vlc_module_add_link_libraries(access_eyetv
 248         ${Foundation_FRAMEWORKS})
 249     vlc_module_add_link_libraries(opengllayer
 250          ${Cocoa_FRAMEWORKS}
 251          ${QuartzCore_FRAMEWORKS}
 252          ${OpenGL_FRAMEWORKS} )
 253     vlc_module_add_link_libraries(quartztext
 254          ${Carbon_FRAMEWORKS}
 255          ${ApplicationServices_FRAMEWORKS} )
 256     vlc_module_add_link_libraries(auhal
 257          ${Carbon_FRAMEWORKS}
 258          ${CoreAudio_FRAMEWORKS}
 259          ${AudioUnit_FRAMEWORKS}
 260          ${AudioToolbox_FRAMEWORKS} )
 261     vlc_module_add_link_libraries(mp4 ${IOKit_FRAMEWORKS} )
 262     vlc_module_add_link_libraries(mkv ${IOKit_FRAMEWORKS} )
 263
 264     add_executable(VLC MACOSX_BUNDLE src/vlc.c)
 265     target_link_libraries(VLC libvlc)
 266     set( MacOS ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/MacOS )
 267     add_custom_command(
 268         TARGET VLC
 269         POST_BUILD
 270         COMMAND rm -Rf ${CMAKE_CURRENT_BINARY_DIR}/tmp
 271         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx
 272         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx
 273         COMMAND for i in vlc.xcodeproj Resources README.MacOSX.rtf\; do cp -R ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx\; done
 274         COMMAND for i in AUTHORS COPYING THANKS\;do cp ${CMAKE_CURRENT_SOURCE_DIR}/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp\; done
 275         COMMAND for i in AppleRemote.h AppleRemote.m about.h about.m applescript.h applescript.m controls.h controls.m equalizer.h equalizer.m intf.h intf.m macosx.m misc.h misc.m open.h open.m output.h output.m playlist.h playlist.m playlistinfo.h playlistinfo.m prefs_widgets.h prefs_widgets.m prefs.h prefs.m vout.h voutqt.m voutgl.m wizard.h wizard.m extended.h extended.m bookmarks.h bookmarks.m sfilters.h sfilters.m update.h update.m interaction.h interaction.m embeddedwindow.h embeddedwindow.m fspanel.h fspanel.m vout.m\; do cp ${CMAKE_CURRENT_SOURCE_DIR}/modules/gui/macosx/$$i ${CMAKE_CURRENT_BINARY_DIR}/tmp/modules/gui/macosx\; done
 276         COMMAND cd ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx && xcodebuild -target vlc | grep -vE '^\([ \\t]|$$\)' && cd ../../../../ && cp ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Info.plist ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents && cp -R ${CMAKE_CURRENT_BINARY_DIR}/tmp/extras/package/macosx/build/Default/VLC.bundle/Contents/Resources/English.lproj ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources
 277         COMMAND cp -r ${CMAKE_CURRENT_SOURCE_DIR}/extras/package/macosx/Resources ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents
 278         COMMAND find -d ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/Resources -type d -name \\.svn -exec rm -rf {} "\;"
 279         COMMAND rm -rf ${MacOS}/modules ${MacOS}/locale ${MacOS}/share
 280         COMMAND ln -s ${CMAKE_CURRENT_SOURCE_DIR}/share ${MacOS}/share
 281         COMMAND ln -s ${CMAKE_CURRENT_BINARY_DIR}/modules ${MacOS}/modules
 282         COMMAND find ${CMAKE_BINARY_DIR}/po -name *.gmo -exec sh -c \"mkdir -p ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES\; ln -s {} ${MacOS}/locale/\\`basename {}|sed s/\\.gmo//\\`/LC_MESSAGES/vlc.mo\" "\;"
 283         COMMAND ln -sf VLC ${MacOS}/clivlc #useless?
 284         COMMAND printf "APPLVLC#" > ${CMAKE_CURRENT_BINARY_DIR}/VLC.app/Contents/PkgInfo
 285     )
 286     set( MacOS )
 287
 288 endif(APPLE)
 289
 290 ###########################################################
 291 # info
 292 ###########################################################
 293
 294 macro(command_to_configvar command var)
 295  execute_process(
 296   COMMAND sh -c "${command}"
 297   OUTPUT_VARIABLE ${var}
 298   OUTPUT_STRIP_TRAILING_WHITESPACE)
 299  string( REPLACE "\n" "\\n" ${var} "${${var}}")
 300 endmacro(command_to_configvar)
 301
 302 command_to_configvar( "whoami" VLC_COMPILE_BY )
 303 command_to_configvar( "hostname" VLC_COMPILE_HOST )
 304 command_to_configvar( "hostname" VLC_COMPILE_DOMAIN )
 305 command_to_configvar( "${CMAKE_C_COMPILER} --version" VLC_COMPILER )
 306 # FIXME: WTF? this is not the configure line!
 307 command_to_configvar( "${CMAKE_C_COMPILER} --version" CONFIGURE_LINE )
 308 set( VLC_COMPILER "${CMAKE_C_COMPILER}" )
 309
 310
 311 ###########################################################
 312 # Modules: Following are all listed in options
 313 ###########################################################
 314
 315 # This module will be enabled but user could disabled it
 316 vlc_enable_modules(dummy logger memcpy)
 317 vlc_enable_modules(mpgv mpga m4v m4a h264 vc1 demux_cdg cdg ps pva avi mp4 rawdv rawvid nsv real aiff mjpeg demuxdump flacsys tta)
 318 vlc_enable_modules(cvdsub svcdsub spudec subsdec subsusf t140 dvbsub cc mpeg_audio lpcm a52 dts cinepak flac)
 319 vlc_enable_modules(deinterlace invert adjust transform wave ripple psychedelic gradient motionblur rv32 rotate noise grain extract sharpen seamcarving)
 320 vlc_enable_modules(converter_fixed mono)
 321 vlc_enable_modules(trivial_resampler ugly_resampler)
 322 vlc_enable_modules(trivial_channel_mixer trivial_mixer)
 323 vlc_enable_modules(playlist export nsc xtag)
 324 vlc_enable_modules(i420_rgb grey_yuv rawvideo blend scale image logo magnify puzzle colorthres)
 325 vlc_enable_modules(wav araw subtitle vobsub adpcm a52sys dtssys au ty voc xa nuv smf)
 326 vlc_enable_modules(access_directory access_file access_udp access_tcp)
 327 vlc_enable_modules(access_http access_mms access_ftp)
 328 vlc_enable_modules(access_filter_bandwidth)
 329 vlc_enable_modules(packetizer_mpegvideo packetizer_h264)
 330 vlc_enable_modules(packetizer_mpeg4video packetizer_mpeg4audio)
 331 vlc_enable_modules(packetizer_vc1)
 332 vlc_enable_modules(spatializer)
 333
 334 if(NOT mingwce)
 335    set(enabled ON)
 336 endif(NOT mingwce)
 337 vlc_register_modules(${enabled} access_fake access_filter_timeshift access_filter_record access_filter_dump)
 338 vlc_register_modules(${enabled} gestures rc telnet hotkeys showintf marq podcast shout sap fake folder)
 339 vlc_register_modules(${enabled} rss mosaic wall motiondetect clone crop erase bluescreen alphamask gaussianblur)
 340 vlc_register_modules(${enabled} i420_yuy2 i422_yuy2 i420_ymga i422_i420 yuy2_i422 yuy2_i420 chroma_chain)
 341 vlc_register_modules(${enabled} aout_file linear_resampler bandlimited_resampler)
 342 vlc_register_modules(${enabled} float32_mixer spdif_mixer simple_channel_mixer)
 343 vlc_register_modules(${enabled} dolby_surround_decoder headphone_channel_mixer normvol equalizer param_eq)
 344 vlc_register_modules(${enabled} converter_float a52tospdif dtstospdif audio_format)
 345 set(enabled)
 346
 347 if(NOT WIN32)
 348    vlc_enable_modules(screensaver)
 349 endif(NOT WIN32)
 350
 351 # Following modules will be disabled but listed in options
 352
 353 vlc_disable_modules(asf)
 354
 355 # This module is disabled because the CMakeList.txt which
 356 # is generated isn't correct. We'll put that back
 357 # when cmake will be accepted as default build system
 358 vlc_disable_modules(motion)
 359
 360 ###########################################################
 361 # libraries
 362 ###########################################################
 363 OPTION( ENABLE_CONTRIB "Attempt to use VLC contrib system to get the third-party libraries" ON )
 364 if(ENABLE_CONTRIB)
 365   set( CONTRIB_INCLUDE ${CMAKE_SOURCE_DIR}/extras/contrib/include)
 366   set( CONTRIB_LIB ${CMAKE_SOURCE_DIR}/extras/contrib/lib)
 367   set( CONTRIB_PROGRAM ${CMAKE_SOURCE_DIR}/extras/contrib/bin)
 368   set( CMAKE_LIBRARY_PATH ${CONTRIB_LIB} ${CMAKE_LIBRARY_PATH} )
 369   set( CMAKE_PROGRAM_PATH ${CONTRIB_PROGRAM} ${CMAKE_PROGRAM_PATH} )
 370   set( CMAKE_C_LINK_FLAGS "${CMAKE_C_LINK_FLAGS} -L${CONTRIB_LIB}" )
 371   set( CMAKE_CXX_LINK_FLAGS "${CMAKE_CXX_LINK_FLAGS} -L${CONTRIB_LIB}" )
 372   set( CMAKE_SHARED_MODULE_CREATE_C_FLAGS "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
 373   set( CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS "${CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
 374   set( CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS} -L${CONTRIB_LIB}" )
 375   set( CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS "${CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS} -L${CONTRIB_LIB}" )
 376   add_definitions(-I${CONTRIB_INCLUDE})
 377 endif(ENABLE_CONTRIB)
 378
 379 set(CMAKE_REQUIRED_INCLUDES ${CONTRIB_INCLUDE})
 380
 381 #fixme: use find_package(cddb 0.9.5)
 382 pkg_check_modules(LIBCDDB libcddb>=0.9.5)
 383 if(${LIBCDDB_FOUND})
 384   vlc_module_add_link_libraries(cdda ${LIBCDDB_LIBRARIES})
 385   vlc_add_module_compile_flag(cdda ${LIBCDDB_CFLAGS} )
 386 endif(${LIBCDDB_FOUND})
 387
 388 find_package(Dlopen)
 389 set(HAVE_DL_DLOPEN ${Dlopen_FOUND})
 390
 391 # Advanced Linux Sound Architecture (ALSA)
 392 pkg_check_modules(ALSA alsa>=1.0.0-rc4)
 393 if (${ALSA_FOUND})
 394   set (HAVE_ALSA_NEW_API "1")
 395 else (${ALSA_FOUND})
 396   pkg_check_modules(ALSA alsa)
 397 endif (${ALSA_FOUND})
 398
 399 if (${ALSA_FOUND})
 400   set (HAVE_ALSA "1")
 401   vlc_enable_modules(alsa)
 402   vlc_add_module_compile_flag(alsa ${ALSA_CFLAGS})
 403   vlc_module_add_link_libraries(alsa ${ALSA_LIBRARIES})
 404 endif (${ALSA_FOUND})
 405
 406 # Open Sound System (OSS)
 407 # TODO
 408
 409 find_package(FFmpeg)
 410 if(FFmpeg_FOUND)
 411   vlc_check_include_files (ffmpeg/avcodec.h)
 412   vlc_check_include_files (ffmpeg/avutil.h)
 413   vlc_check_include_files (ffmpeg/swscale.h)
 414   check_include_files ("stdint.h;postproc/postprocess.h" HAVE_POSTPROC_POSTPROCESS_H)
 415   vlc_enable_modules(ffmpeg)
 416   vlc_add_module_compile_flag(ffmpeg ${FFmpeg_CFLAGS} )
 417   vlc_module_add_link_libraries(ffmpeg ${FFmpeg_LIBRARIES})
 418 endif(FFmpeg_FOUND)
 419
 420 find_package(Lua)
 421 if(Lua_FOUND)
 422   set(HAVE_LUA TRUE)
 423   vlc_enable_modules(lua)
 424   vlc_check_include_files (lua.h lualib.h)
 425   vlc_add_module_compile_flag(lua ${Lua_CFLAGS} )
 426   vlc_module_add_link_libraries(lua ${Lua_LIBRARIES})
 427 endif(Lua_FOUND)
 428
 429 find_package(Qt4)
 430 if(QT4_FOUND)
 431   set(HAVE_QT4 TRUE)
 432   include_directories(${QT_INCLUDES})
 433   vlc_check_include_files (qt.h)
 434   vlc_enable_modules(qt4)
 435   vlc_add_module_compile_flag(qt4 ${QT_CFLAGS} )
 436   vlc_module_add_link_libraries(qt4 ${QT_LIBRARIES})
 437
 438   # Define our own qt4_wrap_ui macro to match wanted behaviour
 439   MACRO (VLC_QT4_WRAP_UI outfiles )
 440     FOREACH (it ${ARGN})
 441      string(REPLACE ".ui" ".h" outfile "${it}")
 442       GET_FILENAME_COMPONENT(infile ${it} ABSOLUTE)
 443       SET(outfile ${CMAKE_CURRENT_BINARY_DIR}/${outfile})
 444       ADD_CUSTOM_COMMAND(OUTPUT ${outfile}
 445         COMMAND mkdir -p `dirname ${outfile}`
 446         COMMAND ${QT_UIC_EXECUTABLE}
 447         ARGS -o ${outfile} ${infile}
 448         MAIN_DEPENDENCY ${infile})
 449       SET(${outfiles} ${${outfiles}} ${outfile})
 450     ENDFOREACH (it)
 451   ENDMACRO (VLC_QT4_WRAP_UI)
 452
 453 endif(QT4_FOUND)
 454
 455 find_package(OpenGL)
 456 if(OPENGL_FOUND)
 457   vlc_enable_modules(opengl)
 458   vlc_check_include_files (gl/gl.h)
 459   vlc_check_include_files (gl/glu.h)
 460   vlc_check_include_files (gl/glx.h)
 461   vlc_add_module_compile_flag(opengl ${OPENGL_CFLAGS})
 462   vlc_module_add_link_libraries(opengl ${OPENGL_LIBRARIES})
 463 endif(OPENGL_FOUND)
 464
 465 find_package(Matroska 0.7.7)
 466 if(Matroska_FOUND)
 467   vlc_enable_modules(mkv)
 468   vlc_check_include_files (matroska/KaxAttachments.h)
 469   vlc_check_include_files (matroska/KaxVersion.h)
 470   vlc_module_add_link_libraries(mkv ${Matroska_LIBRARIES})
 471 endif(Matroska_FOUND)
 472
 473 find_package(Live555)
 474 if(Live555_FOUND)
 475   vlc_enable_modules(live555)
 476   vlc_add_module_compile_flag(live555 ${Live555_CFLAGS})
 477   vlc_module_add_link_libraries(live555 ${Live555_LIBRARIES})
 478 endif(Live555_FOUND)
 479
 480 find_package(Curses)
 481 if(CURSES_LIBRARIES)
 482   vlc_enable_modules(ncurses)
 483   vlc_module_add_link_libraries(ncurses ${CURSES_LIBRARIES})
 484 endif(CURSES_LIBRARIES)
 485
 486 set(CMAKE_REQUIRED_INCLUDES)
 487
 488 ###########################################################
 489 # Final configuration
 490 ###########################################################
 491 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/include/config.h)