git.sesse.net Git - ffmpeg/blob - libavcodec/arm/asm.S

   1 /*
   2  * Copyright (c) 2008 Mans Rullgard <mans@mansr.com>
   3  *
   4  * This file is part of FFmpeg.
   5  *
   6  * FFmpeg is free software; you can redistribute it and/or
   7  * modify it under the terms of the GNU Lesser General Public
   8  * License as published by the Free Software Foundation; either
   9  * version 2.1 of the License, or (at your option) any later version.
  10  *
  11  * FFmpeg is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14  * Lesser General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU Lesser General Public
  17  * License along with FFmpeg; if not, write to the Free Software
  18  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  19  */
  20
  21 #include "config.h"
  22
  23 #ifdef __ELF__
  24 #   define ELF
  25 #else
  26 #   define ELF @
  27 #endif
  28
  29 #if CONFIG_THUMB
  30 #   define A @
  31 #   define T
  32 #else
  33 #   define A
  34 #   define T @
  35 #endif
  36
  37 #if   HAVE_NEON
  38         .arch           armv7-a
  39 #elif HAVE_ARMV6T2
  40         .arch           armv6t2
  41 #elif HAVE_ARMV6
  42         .arch           armv6
  43 #elif HAVE_ARMV5TE
  44         .arch           armv5te
  45 #endif
  46
  47 #if   HAVE_NEON
  48         .fpu            neon
  49 #elif HAVE_ARMVFP
  50         .fpu            vfp
  51 #endif
  52
  53         .syntax unified
  54 T       .thumb
  55
  56 .macro  require8 val=1
  57 ELF     .eabi_attribute 24, \val
  58 .endm
  59
  60 .macro  preserve8 val=1
  61 ELF     .eabi_attribute 25, \val
  62 .endm
  63
  64 .macro  function name, export=0
  65     .macro endfunc
  66 ELF     .size   \name, . - \name
  67         .endfunc
  68         .purgem endfunc
  69     .endm
  70         .text
  71         .align          2
  72     .if \export
  73         .global EXTERN_ASM\name
  74 EXTERN_ASM\name:
  75     .endif
  76 ELF     .type   \name, %function
  77         .func   \name
  78 \name:
  79 .endm
  80
  81 .macro  const   name, align=2
  82     .macro endconst
  83 ELF     .size   \name, . - \name
  84         .purgem endconst
  85     .endm
  86         .section        .rodata
  87         .align          \align
  88 \name:
  89 .endm
  90
  91 .macro  mov32   rd, val
  92 #if HAVE_ARMV6T2
  93         movw            \rd, #(\val) & 0xffff
  94     .if (\val) >> 16
  95         movt            \rd, #(\val) >> 16
  96     .endif
  97 #else
  98         ldr             \rd, =\val
  99 #endif
 100 .endm
 101
 102 .macro  movrel rd, val
 103 #if HAVE_ARMV6T2 && !CONFIG_PIC && !defined(__APPLE__)
 104         movw            \rd, #:lower16:\val
 105         movt            \rd, #:upper16:\val
 106 #else
 107         ldr             \rd, =\val
 108 #endif
 109 .endm
 110
 111 .macro  ldr_pre         rt,  rn,  rm:vararg
 112 A       ldr             \rt, [\rn, \rm]!
 113 T       add             \rn, \rn, \rm
 114 T       ldr             \rt, [\rn]
 115 .endm
 116
 117 .macro  ldr_dpre        rt,  rn,  rm:vararg
 118 A       ldr             \rt, [\rn, -\rm]!
 119 T       sub             \rn, \rn, \rm
 120 T       ldr             \rt, [\rn]
 121 .endm
 122
 123 .macro  ldr_dpren       rt,  rn,  rm:vararg
 124 A       ldr             \rt, [\rn, -\rm]
 125 T       sub             \rt, \rn, \rm
 126 T       ldr             \rt, [\rt]
 127 .endm
 128
 129 .macro  ldr_post        rt,  rn,  rm:vararg
 130 A       ldr             \rt, [\rn], \rm
 131 T       ldr             \rt, [\rn]
 132 T       add             \rn, \rn, \rm
 133 .endm
 134
 135 .macro  ldrd_reg        rt,  rt2, rn,  rm
 136 A       ldrd            \rt, \rt2, [\rn, \rm]
 137 T       add             \rt, \rn, \rm
 138 T       ldrd            \rt, \rt2, [\rt]
 139 .endm
 140
 141 .macro  ldrd_post       rt,  rt2, rn,  rm
 142 A       ldrd            \rt, \rt2, [\rn], \rm
 143 T       ldrd            \rt, \rt2, [\rn]
 144 T       add             \rn, \rn, \rm
 145 .endm
 146
 147 .macro  ldrh_pre        rt,  rn,  rm
 148 A       ldrh            \rt, [\rn, \rm]!
 149 T       add             \rn, \rn, \rm
 150 T       ldrh            \rt, [\rn]
 151 .endm
 152
 153 .macro  ldrh_dpre       rt,  rn,  rm
 154 A       ldrh            \rt, [\rn, -\rm]!
 155 T       sub             \rn, \rn, \rm
 156 T       ldrh            \rt, [\rn]
 157 .endm
 158
 159 .macro  ldrh_post       rt,  rn,  rm
 160 A       ldrh            \rt, [\rn], \rm
 161 T       ldrh            \rt, [\rn]
 162 T       add             \rn, \rn, \rm
 163 .endm
 164
 165 .macro  ldrb_post       rt,  rn,  rm
 166 A       ldrb            \rt, [\rn], \rm
 167 T       ldrb            \rt, [\rn]
 168 T       add             \rn, \rn, \rm
 169 .endm
 170
 171 .macro  str_post       rt,  rn,  rm:vararg
 172 A       str             \rt, [\rn], \rm
 173 T       str             \rt, [\rn]
 174 T       add             \rn, \rn, \rm
 175 .endm
 176
 177 .macro  strb_post       rt,  rn,  rm:vararg
 178 A       strb            \rt, [\rn], \rm
 179 T       strb            \rt, [\rn]
 180 T       add             \rn, \rn, \rm
 181 .endm
 182
 183 .macro  strd_post       rt,  rt2, rn,  rm
 184 A       strd            \rt, \rt2, [\rn], \rm
 185 T       strd            \rt, \rt2, [\rn]
 186 T       add             \rn, \rn, \rm
 187 .endm
 188
 189 .macro  strh_pre        rt,  rn,  rm
 190 A       strh            \rt, [\rn, \rm]!
 191 T       add             \rn, \rn, \rm
 192 T       strh            \rt, [\rn]
 193 .endm
 194
 195 .macro  strh_dpre       rt,  rn,  rm
 196 A       strh            \rt, [\rn, -\rm]!
 197 T       sub             \rn, \rn, \rm
 198 T       strh            \rt, [\rn]
 199 .endm
 200
 201 .macro  strh_post       rt,  rn,  rm
 202 A       strh            \rt, [\rn], \rm
 203 T       strh            \rt, [\rn]
 204 T       add             \rn, \rn, \rm
 205 .endm
 206
 207 .macro  strh_dpost       rt,  rn,  rm
 208 A       strh            \rt, [\rn], -\rm
 209 T       strh            \rt, [\rn]
 210 T       sub             \rn, \rn, \rm
 211 .endm
 212
 213 #if HAVE_VFP_ARGS
 214         .eabi_attribute 28, 1
 215 #   define VFP
 216 #   define NOVFP @
 217 #else
 218 #   define VFP   @
 219 #   define NOVFP
 220 #endif
 221
 222 #define GLUE(a, b) a ## b
 223 #define JOIN(a, b) GLUE(a, b)
 224 #define X(s) JOIN(EXTERN_ASM, s)