git.sesse.net Git - ffmpeg/blob - libavcodec/arm/audiodsp_neon.S

   1 /*
   2  * ARM NEON optimised audio functions
   3  * Copyright (c) 2008 Mans Rullgard <mans@mansr.com>
   4  *
   5  * This file is part of FFmpeg.
   6  *
   7  * FFmpeg is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * FFmpeg is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with FFmpeg; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  20  */
  21
  22 #include "libavutil/arm/asm.S"
  23
  24 function ff_vector_clipf_neon, export=1
  25 VFP     vdup.32         q1,  d0[1]
  26 VFP     vdup.32         q0,  d0[0]
  27 NOVFP   vdup.32         q0,  r3
  28 NOVFP   vld1.32         {d2[],d3[]}, [sp]
  29         vld1.f32        {q2},[r1,:128]!
  30         vmin.f32        q10, q2,  q1
  31         vld1.f32        {q3},[r1,:128]!
  32         vmin.f32        q11, q3,  q1
  33 1:      vmax.f32        q8,  q10, q0
  34         vmax.f32        q9,  q11, q0
  35         subs            r2,  r2,  #8
  36         beq             2f
  37         vld1.f32        {q2},[r1,:128]!
  38         vmin.f32        q10, q2,  q1
  39         vld1.f32        {q3},[r1,:128]!
  40         vmin.f32        q11, q3,  q1
  41         vst1.f32        {q8},[r0,:128]!
  42         vst1.f32        {q9},[r0,:128]!
  43         b               1b
  44 2:      vst1.f32        {q8},[r0,:128]!
  45         vst1.f32        {q9},[r0,:128]!
  46         bx              lr
  47 endfunc
  48
  49 function ff_vector_clip_int32_neon, export=1
  50         vdup.32         q0,  r2
  51         vdup.32         q1,  r3
  52         ldr             r2,  [sp]
  53 1:
  54         vld1.32         {q2-q3},  [r1,:128]!
  55         vmin.s32        q2,  q2,  q1
  56         vmin.s32        q3,  q3,  q1
  57         vmax.s32        q2,  q2,  q0
  58         vmax.s32        q3,  q3,  q0
  59         vst1.32         {q2-q3},  [r0,:128]!
  60         subs            r2,  r2,  #8
  61         bgt             1b
  62         bx              lr
  63 endfunc