git.sesse.net Git - ffmpeg/blob - libavcodec/arm/dcadsp_neon.S

   1 /*
   2  * Copyright (c) 2010 Mans Rullgard <mans@mansr.com>
   3  *
   4  * This file is part of FFmpeg.
   5  *
   6  * FFmpeg is free software; you can redistribute it and/or
   7  * modify it under the terms of the GNU Lesser General Public
   8  * License as published by the Free Software Foundation; either
   9  * version 2.1 of the License, or (at your option) any later version.
  10  *
  11  * FFmpeg is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14  * Lesser General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU Lesser General Public
  17  * License along with FFmpeg; if not, write to the Free Software
  18  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  19  */
  20
  21 #include "libavutil/arm/asm.S"
  22
  23 function ff_dca_lfe_fir0_neon, export=1
  24         push            {r4-r6,lr}
  25 NOVFP   vmov            s0,  r3                 @ scale
  26         mov             r3,  #32                @ decifactor
  27         mov             r6,  #256/32
  28         b               dca_lfe_fir
  29 endfunc
  30
  31 function ff_dca_lfe_fir1_neon, export=1
  32         push            {r4-r6,lr}
  33 NOVFP   vmov            s0,  r3                 @ scale
  34         mov             r3,  #64                @ decifactor
  35         mov             r6,  #256/64
  36 dca_lfe_fir:
  37         add             r4,  r0,  r3,  lsl #2   @ out2
  38         add             r5,  r2,  #256*4-16     @ cf1
  39         sub             r1,  r1,  #12
  40         mov             lr,  #-16
  41 1:
  42         vmov.f32        q2,  #0.0               @ v0
  43         vmov.f32        q3,  #0.0               @ v1
  44         mov             r12, r6
  45 2:
  46         vld1.32         {q8},     [r2,:128]!    @ cf0
  47         vld1.32         {q9},     [r5,:128], lr @ cf1
  48         vld1.32         {q1},     [r1], lr      @ in
  49         subs            r12, r12, #4
  50         vrev64.32       q10, q8
  51         vmla.f32        q3,  q1,  q9
  52         vmla.f32        d4,  d2,  d21
  53         vmla.f32        d5,  d3,  d20
  54         bne             2b
  55
  56         add             r1,  r1,  r6,  lsl #2
  57         subs            r3,  r3,  #1
  58         vadd.f32        d4,  d4,  d5
  59         vadd.f32        d6,  d6,  d7
  60         vpadd.f32       d4,  d4,  d6
  61         vmul.f32        d5,  d4,  d0[0]
  62         vst1.32         {d5[0]},  [r0,:32]!
  63         vst1.32         {d5[1]},  [r4,:32]!
  64         bne             1b
  65
  66         pop             {r4-r6,pc}
  67 endfunc