git.sesse.net Git - ffmpeg/blob - libavcodec/arm/int_neon.S

   1 /*
   2  * ARM NEON optimised integer operations
   3  * Copyright (c) 2009 Kostya Shishkov
   4  *
   5  * This file is part of FFmpeg.
   6  *
   7  * FFmpeg is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * FFmpeg is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with FFmpeg; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  20  */
  21
  22 #include "asm.S"
  23
  24         preserve8
  25         .fpu neon
  26
  27 function ff_scalarproduct_int16_neon, export=1
  28         vmov.i16        q0,  #0
  29         vmov.i16        q1,  #0
  30         vmov.i16        q2,  #0
  31         vmov.i16        q3,  #0
  32 1:      vld1.16         {d16-d17}, [r0]!
  33         vld1.16         {d20-d21}, [r1,:128]!
  34         vmlal.s16       q0,  d16,  d20
  35         vld1.16         {d18-d19}, [r0]!
  36         vmlal.s16       q1,  d17,  d21
  37         vld1.16         {d22-d23}, [r1,:128]!
  38         vmlal.s16       q2,  d18,  d22
  39         vmlal.s16       q3,  d19,  d23
  40         subs            r2,  r2,   #16
  41         bne             1b
  42
  43         vpadd.s32       d16, d0,   d1
  44         vpadd.s32       d17, d2,   d3
  45         vpadd.s32       d10, d4,   d5
  46         vpadd.s32       d11, d6,   d7
  47         vpadd.s32       d0,  d16,  d17
  48         vpadd.s32       d1,  d10,  d11
  49         vpadd.s32       d2,  d0,   d1
  50         vpaddl.s32      d3,  d2
  51         vmov.32         r0,  d3[0]
  52         bx              lr
  53 endfunc
  54
  55 @ scalarproduct_and_madd_int16(/*aligned*/v0,v1,v2,order,mul)
  56 function ff_scalarproduct_and_madd_int16_neon, export=1
  57         vld1.16         {d28[],d29[]}, [sp]
  58         vmov.i16        q0,  #0
  59         vmov.i16        q1,  #0
  60         vmov.i16        q2,  #0
  61         vmov.i16        q3,  #0
  62         mov             r12, r0
  63
  64 1:      vld1.16         {d16-d17}, [r0,:128]!
  65         vld1.16         {d18-d19}, [r1]!
  66         vld1.16         {d20-d21}, [r2]!
  67         vld1.16         {d22-d23}, [r0,:128]!
  68         vld1.16         {d24-d25}, [r1]!
  69         vld1.16         {d26-d27}, [r2]!
  70         vmul.s16        q10, q10,  q14
  71         vmul.s16        q13, q13,  q14
  72         vmlal.s16       q0,  d16,  d18
  73         vmlal.s16       q1,  d17,  d19
  74         vadd.s16        q10, q8,   q10
  75         vadd.s16        q13, q11,  q13
  76         vmlal.s16       q2,  d22,  d24
  77         vmlal.s16       q3,  d23,  d25
  78         vst1.16         {q10},     [r12,:128]!
  79         subs            r3,  r3,   #16
  80         vst1.16         {q13},     [r12,:128]!
  81         bne             1b
  82
  83         vpadd.s32       d16, d0,   d1
  84         vpadd.s32       d17, d2,   d3
  85         vpadd.s32       d10, d4,   d5
  86         vpadd.s32       d11, d6,   d7
  87         vpadd.s32       d0,  d16,  d17
  88         vpadd.s32       d1,  d10,  d11
  89         vpadd.s32       d2,  d0,   d1
  90         vpaddl.s32      d3,  d2
  91         vmov.32         r0,  d3[0]
  92         bx              lr
  93 endfunc