git.sesse.net Git - ffmpeg/blob - libavcodec/bfin/idct_bfin.S

   1 /*
   2  * idct BlackFin
   3  *
   4  * Copyright (C) 2007 Marc Hoffman <marc.hoffman@analog.com>
   5  *
   6  * This file is part of FFmpeg.
   7  *
   8  * FFmpeg is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU Lesser General Public
  10  * License as published by the Free Software Foundation; either
  11  * version 2.1 of the License, or (at your option) any later version.
  12  *
  13  * FFmpeg is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16  * Lesser General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU Lesser General Public
  19  * License along with FFmpeg; if not, write to the Free Software
  20  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  21  */
  22 /*
  23    This blackfin DSP code implements an 8x8 inverse type II DCT.
  24
  25 Prototype       : void ff_bfin_idct(DCTELEM *in)
  26
  27 Registers Used  : A0, A1, R0-R7, I0-I3, B0, B2, B3, M0-M2, L0-L3, P0-P5, LC0.
  28
  29 Performance     :
  30                     Code Size   : 498 Bytes.
  31                     Cycle Count : 417 Cycles
  32
  33
  34 -----------------------------------------------------------
  35 FFMPEG conformance testing results
  36 -----------------------------------------------------------
  37
  38 dct-test: modified with the following
  39             dct_error("BFINidct", 1, ff_bfin_idct, idct, test);
  40 produces the following output
  41
  42 root:/u/ffmpeg/bhead/libavcodec> ./dct-test -i
  43 ffmpeg DCT/IDCT test
  44
  45     8    15    -2    21    24    17     0    10
  46     2   -10    -5    -5    -3     7   -14    -3
  47     2   -13   -10   -19    18    -6     6    -2
  48     9     4    16    -3     9    12    10    15
  49    15    -9    -2    10     1    16     0   -15
  50   -15     5     7     3    13     0    13    20
  51    -6   -15    24     9   -18     1     9   -22
  52    -8    25    23     2    -7     0    30    13
  53 IDCT BFINidct: err_inf=1 err2=0.01002344 syserr=0.00150000 maxout=266 blockSumErr=64
  54 IDCT BFINidct: 88.3 kdct/s
  55
  56 */
  57
  58 #include "config_bfin.h"
  59
  60 #ifdef __FDPIC__
  61 .section .l1.data.B,"aw",@progbits
  62 #else
  63 .data
  64 #endif
  65
  66 .align 4;
  67 coefs:
  68 .short 0x5a82;           //  C4
  69 .short 0x5a82;           //  C4
  70 .short 0x30FC;           //cos(3pi/8)  C6
  71 .short 0x7642;           //cos(pi/8)   C2
  72 .short 0x18F9;           //cos(7pi/16)
  73 .short 0x7D8A;           //cos(pi/16)
  74 .short 0x471D;           //cos(5pi/16)
  75 .short 0x6A6E;           //cos(3pi/16)
  76 .short 0x18F9;           //cos(7pi/16)
  77 .short 0x7D8A;           //cos(pi/16)
  78
  79 #ifdef __FDPIC__
  80 .section .l1.data.A,"aw",@progbits
  81 #endif
  82
  83 vtmp: .space 256
  84
  85 #define TMP0 FP-8
  86 #define TMP1 FP-12
  87 #define TMP2 FP-16
  88
  89
  90 .text
  91 DEFUN(idct,mL1,
  92         (DCTELEM *block)):
  93
  94 /********************** Function Prologue *********************************/
  95     link 16;
  96     [--SP] = (R7:4, P5:3);   // Push the registers onto the stack.
  97     B0 = R0;                 // Pointer to Input matrix
  98     RELOC(R1, P3, coefs);    // Pointer to Coefficients
  99     RELOC(R2, P3, vtmp);     // Pointer to Temporary matrix
 100     B3 = R1;
 101     B2 = R2;
 102     L3 = 20;                // L3 is used for making the coefficient array
 103                             // circular.
 104                             // MUST BE RESTORED TO ZERO at function exit.
 105     M1 = 16 (X);            // All these registers are initialized for
 106     M3 = 8(X);              // modifying address offsets.
 107
 108     I0 = B0;                // I0 points to Input Element (0, 0).
 109     I2 = B0;                // I2 points to Input Element (0, 0).
 110     I2 += M3 || R0.H = W[I0];
 111                             // Element 0 is read into R0.H
 112     I1 = I2;                // I1 points to input Element (0, 6).
 113     I1 += 4  || R0.L = W[I2++];
 114                             // I2 points to input Element (0, 4).
 115                             // Element 4 is read into R0.L.
 116     P2 = 8 (X);
 117     P3 = 32 (X);
 118     P4 = -32 (X);
 119     P5 = 98 (X);
 120     R7 = 0x8000(Z);
 121     I3 = B3;                // I3 points to Coefficients
 122     P0 = B2;                // P0 points to array Element (0, 0) of temp
 123     P1 = B2;
 124     R7 = [I3++] || [TMP2]=R7;            // Coefficient C4 is read into R7.H and R7.L.
 125     MNOP;
 126     NOP;
 127
 128     /*
 129      *   A1 =      Y0 * cos(pi/4)
 130      *   A0 =      Y0 * cos(pi/4)
 131      *   A1 = A1 + Y4 * cos(pi/4)
 132      *   A0 = A0 - Y4 * cos(pi/4)
 133      *   load:
 134      *     R1=(Y2,Y6)
 135      *     R7=(C2,C6)
 136      *   res:
 137      *     R3=Y0, R2=Y4
 138      */
 139     A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || I0+= 4       || R1.L=W[I1++];
 140     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++];
 141
 142     LSETUP (.0, .1) LC0 = P2; // perform 8 1d idcts
 143
 144     P2 = 112 (X);
 145     P1 = P1 + P2;           // P1 points to element (7, 0) of temp buffer.
 146     P2 = -94(X);
 147
 148 .0:
 149        /*
 150         *   A1 =      Y2 * cos(3pi/8)
 151         *   A0 =      Y2 * cos(pi/8)
 152         *   A1 = A1 - Y6 * cos(pi/8)
 153         *   A0 = A0 + Y6 * cos(3pi/8)
 154         *      R5 = (Y1,Y7)
 155         *      R7 = (C1,C7)
 156         *   res:
 157         *      R1=Y2, R0=Y6
 158         */
 159         A1=R7.L*R1.H,       A0=R7.H*R1.H (IS)        || I0+=4        || R5.H=W[I0];
 160         R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS)  || R5.L=W[I1--] || R7=[I3++];
 161         /*
 162         *   Y0 = Y0 + Y6.
 163         *   Y4 = Y4 + Y2.
 164         *   Y2 = Y4 - Y2.
 165         *   Y6 = Y0 - Y6.
 166         *     R3 is saved
 167         *     R6.l=Y3
 168         * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6
 169         */
 170         R3=R3+R0, R0=R3-R0;
 171         R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--];
 172         /*
 173          *  Compute the odd portion (1,3,5,7) even is done.
 174          *
 175          *  Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3.
 176          *  Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3.
 177          *  Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3.
 178          *  Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3.
 179          */
 180         //  R5=(Y1,Y7)  R6=(Y5,Y3)                                                   // R7=(C1,C7)
 181         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || [TMP1]=R2 || R6.H=W[I2--];
 182         A1-=R7.H*R5.L,       A0+=R7.L*R5.L (IS)       || I0-=4     || R7=[I3++];
 183         A1+=R7.H*R6.H,       A0+=R7.L*R6.H (IS)       || I0+=M1;                     // R7=(C3,C5)
 184         R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS);
 185         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || R4=[TMP0];
 186         A1+=R7.H*R5.L,       A0-=R7.L*R5.L (IS)       || I1+=M1    || R7=[I3++];     // R7=(C1,C7)
 187         A1+=R7.L*R6.H,       A0-=R7.H*R6.H (IS);
 188         R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1;
 189         // R3=Y1, R2=Y7, R7=Y5, R6=Y3
 190
 191         /* Transpose write column. */
 192         R5.H=R4+R2 (RND12);                                   // Y0=Y0+Y7
 193         R5.L=R4-R2 (RND12) || R4 = [TMP1];                    // Y7=Y7-Y0
 194         R2.H=R1+R7 (RND12) || W[P0++P3]=R5.H;                 // Y2=Y2+Y5 st Y0
 195         R2.L=R1-R7 (RND12) || W[P1++P4]=R5.L || R7=[I3++];    // Y5=Y2-Y5 st Y7
 196         R5.H=R0-R3 (RND12) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2
 197         R5.L=R0+R3 (RND12) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5
 198         R3.H=R4-R6 (RND12) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1
 199         R3.L=R4+R6 (RND12) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6
 200
 201         /* pipeline loop start, + drain Y3, Y4 */
 202         A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || W[P0++P2]= R3.H || R1.H = W[I0--];
 203 .1:     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++];
 204
 205
 206
 207     I0 = B2;                // I0 points to Input Element (0, 0)
 208     I2 = B2;                // I2 points to Input Element (0, 0)
 209     I2 += M3 || R0.H = W[I0];
 210                             // Y0 is read in R0.H
 211     I1 = I2;                // I1 points to input Element (0, 6)
 212     I1 += 4  || R0.L = W[I2++];
 213                             // I2 points to input Element (0, 4)
 214                             // Y4 is read in R0.L
 215     P2 = 8 (X);
 216     I3 = B3;                // I3 points to Coefficients
 217     P0 = B0;                // P0 points to array Element (0, 0) for writing
 218                             // output
 219     P1 = B0;
 220     R7 = [I3++];            // R7.H = C4 and R7.L = C4
 221     NOP;
 222
 223     /*
 224      *   A1 =      Y0 * cos(pi/4)
 225      *   A0 =      Y0 * cos(pi/4)
 226      *   A1 = A1 + Y4 * cos(pi/4)
 227      *   A0 = A0 - Y4 * cos(pi/4)
 228      *   load:
 229      *     R1=(Y2,Y6)
 230      *     R7=(C2,C6)
 231      *   res:
 232      *     R3=Y0, R2=Y4
 233      */
 234     A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || I0+=4        || R1.L=W[I1++];
 235     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++];
 236
 237     LSETUP (.2, .3) LC0 = P2; // peform 8 1d idcts
 238     P2 = 112 (X);
 239     P1 = P1 + P2;
 240     P2 = -94(X);
 241
 242 .2:
 243         /*
 244          *   A1 =      Y2 * cos(3pi/8)
 245          *   A0 =      Y2 * cos(pi/8)
 246          *   A1 = A1 - Y6 * cos(pi/8)
 247          *   A0 = A0 + Y6 * cos(3pi/8)
 248          *      R5 = (Y1,Y7)
 249          *      R7 = (C1,C7)
 250          *   res:
 251          *      R1=Y2, R0=Y6
 252          */
 253         A1=R7.L*R1.H,       A0=R7.H*R1.H (IS)        || I0+=4        || R5.H=W[I0];
 254         R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS)  || R5.L=W[I1--] || R7=[I3++];
 255         /*
 256         *   Y0 = Y0 + Y6.
 257         *   Y4 = Y4 + Y2.
 258         *   Y2 = Y4 - Y2.
 259         *   Y6 = Y0 - Y6.
 260         *     R3 is saved
 261         *     R6.l=Y3
 262         * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6
 263         */
 264         R3=R3+R0, R0=R3-R0;
 265         R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--];
 266         /*
 267          *  Compute the odd portion (1,3,5,7) even is done.
 268          *
 269          *  Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3.
 270          *  Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3.
 271          *  Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3.
 272          *  Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3.
 273          */
 274         //  R5=(Y1,Y7)  R6=(Y5,Y3)                                                   // R7=(C1,C7)
 275         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || [TMP1]=R2 || R6.H=W[I2--];
 276         A1-=R7.H*R5.L,       A0+=R7.L*R5.L (IS)       || I0-=4     || R7=[I3++];
 277         A1+=R7.H*R6.H,       A0+=R7.L*R6.H (IS)       || I0+=M1;                     // R7=(C3,C5)
 278         R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS);
 279         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || R4=[TMP0];
 280         A1+=R7.H*R5.L,       A0-=R7.L*R5.L (IS)       || I1+=M1    || R7=[I3++];     // R7=(C1,C7)
 281         A1+=R7.L*R6.H,       A0-=R7.H*R6.H (IS);
 282         R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1;
 283         // R3=Y1, R2=Y7, R7=Y5, R6=Y3
 284
 285         /* Transpose write column. */
 286         R5.H=R4+R2 (RND20);                                   // Y0=Y0+Y7
 287         R5.L=R4-R2 (RND20) || R4 = [TMP1];                    // Y7=Y7-Y0
 288         R2.H=R1+R7 (RND20) || W[P0++P3]=R5.H;                 // Y2=Y2+Y5 st Y0
 289         R2.L=R1-R7 (RND20) || W[P1++P4]=R5.L || R7=[I3++];    // Y5=Y2-Y5 st Y7
 290         R5.H=R0-R3 (RND20) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2
 291         R5.L=R0+R3 (RND20) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5
 292         R3.H=R4-R6 (RND20) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1
 293         R3.L=R4+R6 (RND20) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6
 294
 295         /* pipeline loop start, + drain Y3, Y4 */
 296         A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || W[P0++P2]= R3.H || R1.H = W[I0--];
 297 .3:     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++];
 298
 299     L3 = 0;
 300     (R7:4,P5:3)=[SP++];
 301     unlink;
 302     RTS;
 303 DEFUN_END(idct)
 304
 305