git.sesse.net Git - ffmpeg/blob - libavcodec/bfin/idct_bfin.S

   1 /*
   2  * idct BlackFin
   3  *
   4  * Copyright (C) 2007 Marc Hoffman <marc.hoffman@analog.com>
   5  *
   6  * This file is part of Libav.
   7  *
   8  * Libav is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU Lesser General Public
  10  * License as published by the Free Software Foundation; either
  11  * version 2.1 of the License, or (at your option) any later version.
  12  *
  13  * Libav is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16  * Lesser General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU Lesser General Public
  19  * License along with Libav; if not, write to the Free Software
  20  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  21  */
  22 /*
  23    This blackfin DSP code implements an 8x8 inverse type II DCT.
  24
  25 Prototype       : void ff_bfin_idct(int16_t *in)
  26
  27 Registers Used  : A0, A1, R0-R7, I0-I3, B0, B2, B3, M0-M2, L0-L3, P0-P5, LC0.
  28
  29 Performance     :
  30                     Code Size   : 498 Bytes.
  31                     Cycle Count : 417 Cycles
  32
  33
  34 -----------------------------------------------------------
  35 Libav conformance testing results
  36 -----------------------------------------------------------
  37
  38 dct-test: modified with the following
  39             dct_error("BFINidct", 1, ff_bfin_idct, idct, test);
  40 produces the following output
  41
  42 libavcodec> ./dct-test -i
  43 Libav DCT/IDCT test
  44
  45     8    15    -2    21    24    17     0    10
  46     2   -10    -5    -5    -3     7   -14    -3
  47     2   -13   -10   -19    18    -6     6    -2
  48     9     4    16    -3     9    12    10    15
  49    15    -9    -2    10     1    16     0   -15
  50   -15     5     7     3    13     0    13    20
  51    -6   -15    24     9   -18     1     9   -22
  52    -8    25    23     2    -7     0    30    13
  53 IDCT BFINidct: err_inf=1 err2=0.01002344 syserr=0.00150000 maxout=266 blockSumErr=64
  54 IDCT BFINidct: 88.3 kdct/s
  55
  56 */
  57
  58 #include "libavutil/bfin/asm.h"
  59
  60 SECTION_L1_DATA_B
  61
  62 .align 4;
  63 coefs:
  64 .short 0x5a82;           //  C4
  65 .short 0x5a82;           //  C4
  66 .short 0x30FC;           //cos(3pi/8)  C6
  67 .short 0x7642;           //cos(pi/8)   C2
  68 .short 0x18F9;           //cos(7pi/16)
  69 .short 0x7D8A;           //cos(pi/16)
  70 .short 0x471D;           //cos(5pi/16)
  71 .short 0x6A6E;           //cos(3pi/16)
  72 .short 0x18F9;           //cos(7pi/16)
  73 .short 0x7D8A;           //cos(pi/16)
  74
  75 SECTION_L1_DATA_A
  76
  77 vtmp: .space 256
  78
  79 #define TMP0 FP-8
  80 #define TMP1 FP-12
  81 #define TMP2 FP-16
  82
  83
  84 .text
  85 DEFUN(idct,mL1,
  86         (int16_t *block)):
  87
  88 /********************** Function Prologue *********************************/
  89     link 16;
  90     [--SP] = (R7:4, P5:3);   // Push the registers onto the stack.
  91     B0 = R0;                 // Pointer to Input matrix
  92     RELOC(R1, P3, coefs);    // Pointer to Coefficients
  93     RELOC(R2, P3, vtmp);     // Pointer to Temporary matrix
  94     B3 = R1;
  95     B2 = R2;
  96     L3 = 20;                // L3 is used for making the coefficient array
  97                             // circular.
  98                             // MUST BE RESTORED TO ZERO at function exit.
  99     M1 = 16 (X);            // All these registers are initialized for
 100     M3 = 8(X);              // modifying address offsets.
 101
 102     I0 = B0;                // I0 points to Input Element (0, 0).
 103     I2 = B0;                // I2 points to Input Element (0, 0).
 104     I2 += M3 || R0.H = W[I0];
 105                             // Element 0 is read into R0.H
 106     I1 = I2;                // I1 points to input Element (0, 6).
 107     I1 += 4  || R0.L = W[I2++];
 108                             // I2 points to input Element (0, 4).
 109                             // Element 4 is read into R0.L.
 110     P2 = 8 (X);
 111     P3 = 32 (X);
 112     P4 = -32 (X);
 113     P5 = 98 (X);
 114     R7 = 0x8000(Z);
 115     I3 = B3;                // I3 points to Coefficients
 116     P0 = B2;                // P0 points to array Element (0, 0) of temp
 117     P1 = B2;
 118     R7 = [I3++] || [TMP2]=R7;            // Coefficient C4 is read into R7.H and R7.L.
 119     MNOP;
 120     NOP;
 121
 122     /*
 123      *   A1 =      Y0 * cos(pi/4)
 124      *   A0 =      Y0 * cos(pi/4)
 125      *   A1 = A1 + Y4 * cos(pi/4)
 126      *   A0 = A0 - Y4 * cos(pi/4)
 127      *   load:
 128      *     R1=(Y2,Y6)
 129      *     R7=(C2,C6)
 130      *   res:
 131      *     R3=Y0, R2=Y4
 132      */
 133     A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || I0+= 4       || R1.L=W[I1++];
 134     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++];
 135
 136     LSETUP (.0, .1) LC0 = P2; // perform 8 1d idcts
 137
 138     P2 = 112 (X);
 139     P1 = P1 + P2;           // P1 points to element (7, 0) of temp buffer.
 140     P2 = -94(X);
 141
 142 .0:
 143        /*
 144         *   A1 =      Y2 * cos(3pi/8)
 145         *   A0 =      Y2 * cos(pi/8)
 146         *   A1 = A1 - Y6 * cos(pi/8)
 147         *   A0 = A0 + Y6 * cos(3pi/8)
 148         *      R5 = (Y1,Y7)
 149         *      R7 = (C1,C7)
 150         *   res:
 151         *      R1=Y2, R0=Y6
 152         */
 153         A1=R7.L*R1.H,       A0=R7.H*R1.H (IS)        || I0+=4        || R5.H=W[I0];
 154         R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS)  || R5.L=W[I1--] || R7=[I3++];
 155         /*
 156         *   Y0 = Y0 + Y6.
 157         *   Y4 = Y4 + Y2.
 158         *   Y2 = Y4 - Y2.
 159         *   Y6 = Y0 - Y6.
 160         *     R3 is saved
 161         *     R6.l=Y3
 162         * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6
 163         */
 164         R3=R3+R0, R0=R3-R0;
 165         R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--];
 166         /*
 167          *  Compute the odd portion (1,3,5,7) even is done.
 168          *
 169          *  Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3.
 170          *  Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3.
 171          *  Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3.
 172          *  Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3.
 173          */
 174         //  R5=(Y1,Y7)  R6=(Y5,Y3)                                                   // R7=(C1,C7)
 175         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || [TMP1]=R2 || R6.H=W[I2--];
 176         A1-=R7.H*R5.L,       A0+=R7.L*R5.L (IS)       || I0-=4     || R7=[I3++];
 177         A1+=R7.H*R6.H,       A0+=R7.L*R6.H (IS)       || I0+=M1;                     // R7=(C3,C5)
 178         R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS);
 179         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || R4=[TMP0];
 180         A1+=R7.H*R5.L,       A0-=R7.L*R5.L (IS)       || I1+=M1    || R7=[I3++];     // R7=(C1,C7)
 181         A1+=R7.L*R6.H,       A0-=R7.H*R6.H (IS);
 182         R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1;
 183         // R3=Y1, R2=Y7, R7=Y5, R6=Y3
 184
 185         /* Transpose write column. */
 186         R5.H=R4+R2 (RND12);                                   // Y0=Y0+Y7
 187         R5.L=R4-R2 (RND12) || R4 = [TMP1];                    // Y7=Y7-Y0
 188         R2.H=R1+R7 (RND12) || W[P0++P3]=R5.H;                 // Y2=Y2+Y5 st Y0
 189         R2.L=R1-R7 (RND12) || W[P1++P4]=R5.L || R7=[I3++];    // Y5=Y2-Y5 st Y7
 190         R5.H=R0-R3 (RND12) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2
 191         R5.L=R0+R3 (RND12) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5
 192         R3.H=R4-R6 (RND12) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1
 193         R3.L=R4+R6 (RND12) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6
 194
 195         /* pipeline loop start, + drain Y3, Y4 */
 196         A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || W[P0++P2]= R3.H || R1.H = W[I0--];
 197 .1:     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++];
 198
 199
 200
 201     I0 = B2;                // I0 points to Input Element (0, 0)
 202     I2 = B2;                // I2 points to Input Element (0, 0)
 203     I2 += M3 || R0.H = W[I0];
 204                             // Y0 is read in R0.H
 205     I1 = I2;                // I1 points to input Element (0, 6)
 206     I1 += 4  || R0.L = W[I2++];
 207                             // I2 points to input Element (0, 4)
 208                             // Y4 is read in R0.L
 209     P2 = 8 (X);
 210     I3 = B3;                // I3 points to Coefficients
 211     P0 = B0;                // P0 points to array Element (0, 0) for writing
 212                             // output
 213     P1 = B0;
 214     R7 = [I3++];            // R7.H = C4 and R7.L = C4
 215     NOP;
 216
 217     /*
 218      *   A1 =      Y0 * cos(pi/4)
 219      *   A0 =      Y0 * cos(pi/4)
 220      *   A1 = A1 + Y4 * cos(pi/4)
 221      *   A0 = A0 - Y4 * cos(pi/4)
 222      *   load:
 223      *     R1=(Y2,Y6)
 224      *     R7=(C2,C6)
 225      *   res:
 226      *     R3=Y0, R2=Y4
 227      */
 228     A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || I0+=4        || R1.L=W[I1++];
 229     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++];
 230
 231     LSETUP (.2, .3) LC0 = P2; // peform 8 1d idcts
 232     P2 = 112 (X);
 233     P1 = P1 + P2;
 234     P2 = -94(X);
 235
 236 .2:
 237         /*
 238          *   A1 =      Y2 * cos(3pi/8)
 239          *   A0 =      Y2 * cos(pi/8)
 240          *   A1 = A1 - Y6 * cos(pi/8)
 241          *   A0 = A0 + Y6 * cos(3pi/8)
 242          *      R5 = (Y1,Y7)
 243          *      R7 = (C1,C7)
 244          *   res:
 245          *      R1=Y2, R0=Y6
 246          */
 247         A1=R7.L*R1.H,       A0=R7.H*R1.H (IS)        || I0+=4        || R5.H=W[I0];
 248         R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS)  || R5.L=W[I1--] || R7=[I3++];
 249         /*
 250         *   Y0 = Y0 + Y6.
 251         *   Y4 = Y4 + Y2.
 252         *   Y2 = Y4 - Y2.
 253         *   Y6 = Y0 - Y6.
 254         *     R3 is saved
 255         *     R6.l=Y3
 256         * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6
 257         */
 258         R3=R3+R0, R0=R3-R0;
 259         R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--];
 260         /*
 261          *  Compute the odd portion (1,3,5,7) even is done.
 262          *
 263          *  Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3.
 264          *  Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3.
 265          *  Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3.
 266          *  Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3.
 267          */
 268         //  R5=(Y1,Y7)  R6=(Y5,Y3)                                                   // R7=(C1,C7)
 269         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || [TMP1]=R2 || R6.H=W[I2--];
 270         A1-=R7.H*R5.L,       A0+=R7.L*R5.L (IS)       || I0-=4     || R7=[I3++];
 271         A1+=R7.H*R6.H,       A0+=R7.L*R6.H (IS)       || I0+=M1;                     // R7=(C3,C5)
 272         R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS);
 273         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || R4=[TMP0];
 274         A1+=R7.H*R5.L,       A0-=R7.L*R5.L (IS)       || I1+=M1    || R7=[I3++];     // R7=(C1,C7)
 275         A1+=R7.L*R6.H,       A0-=R7.H*R6.H (IS);
 276         R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1;
 277         // R3=Y1, R2=Y7, R7=Y5, R6=Y3
 278
 279         /* Transpose write column. */
 280         R5.H=R4+R2 (RND20);                                   // Y0=Y0+Y7
 281         R5.L=R4-R2 (RND20) || R4 = [TMP1];                    // Y7=Y7-Y0
 282         R2.H=R1+R7 (RND20) || W[P0++P3]=R5.H;                 // Y2=Y2+Y5 st Y0
 283         R2.L=R1-R7 (RND20) || W[P1++P4]=R5.L || R7=[I3++];    // Y5=Y2-Y5 st Y7
 284         R5.H=R0-R3 (RND20) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2
 285         R5.L=R0+R3 (RND20) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5
 286         R3.H=R4-R6 (RND20) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1
 287         R3.L=R4+R6 (RND20) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6
 288
 289         /* pipeline loop start, + drain Y3, Y4 */
 290         A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || W[P0++P2]= R3.H || R1.H = W[I0--];
 291 .3:     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++];
 292
 293     L3 = 0;
 294     (R7:4,P5:3)=[SP++];
 295     unlink;
 296     RTS;
 297 DEFUN_END(idct)