git.sesse.net Git - ffmpeg/blob - libavcodec/bfin/idct_bfin.S

   1 /*
   2  * idct BlackFin
   3  *
   4  * Copyright (C) 2007 Marc Hoffman <marc.hoffman@analog.com>
   5  *
   6  * This file is part of FFmpeg.
   7  *
   8  * FFmpeg is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU Lesser General Public
  10  * License as published by the Free Software Foundation; either
  11  * version 2.1 of the License, or (at your option) any later version.
  12  *
  13  * FFmpeg is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16  * Lesser General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU Lesser General Public
  19  * License along with FFmpeg; if not, write to the Free Software
  20  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  21  */
  22 /*
  23    This blackfin DSP code implements an 8x8 inverse type II DCT.
  24
  25 Prototype       : void ff_bfin_idct(DCTELEM *in)
  26
  27 Registers Used  : A0, A1, R0-R7, I0-I3, B0, B2, B3, M0-M2, L0-L3, P0-P5, LC0.
  28
  29 Performance     :
  30                     Code Size   : 498 Bytes.
  31                     Cycle Count : 417 Cycles
  32
  33
  34 -----------------------------------------------------------
  35 FFMPEG conformance testing results
  36 -----------------------------------------------------------
  37
  38 dct-test: modified with the following
  39             dct_error("BFINidct", 1, ff_bfin_idct, idct, test);
  40 produces the following output
  41
  42 root:/u/ffmpeg/bhead/libavcodec> ./dct-test -i
  43 ffmpeg DCT/IDCT test
  44
  45     8    15    -2    21    24    17     0    10
  46     2   -10    -5    -5    -3     7   -14    -3
  47     2   -13   -10   -19    18    -6     6    -2
  48     9     4    16    -3     9    12    10    15
  49    15    -9    -2    10     1    16     0   -15
  50   -15     5     7     3    13     0    13    20
  51    -6   -15    24     9   -18     1     9   -22
  52    -8    25    23     2    -7     0    30    13
  53 IDCT BFINidct: err_inf=1 err2=0.01002344 syserr=0.00150000 maxout=266 blockSumErr=64
  54 IDCT BFINidct: 88.3 kdct/s
  55
  56 */
  57
  58 #include "config_bfin.h"
  59
  60 .section .l1.data.B,"aw",@progbits
  61
  62 .align 4;
  63 coefs:
  64 .short 0x5a82;           //  C4
  65 .short 0x5a82;           //  C4
  66 .short 0x30FC;           //cos(3pi/8)  C6
  67 .short 0x7642;           //cos(pi/8)   C2
  68 .short 0x18F9;           //cos(7pi/16)
  69 .short 0x7D8A;           //cos(pi/16)
  70 .short 0x471D;           //cos(5pi/16)
  71 .short 0x6A6E;           //cos(3pi/16)
  72 .short 0x18F9;           //cos(7pi/16)
  73 .short 0x7D8A;           //cos(pi/16)
  74
  75 .section .l1.data.A
  76
  77 vtmp: .space 256
  78
  79 #define TMP0 FP-8
  80 #define TMP1 FP-12
  81 #define TMP2 FP-16
  82
  83
  84 DEFUN(idct,mL1,
  85         (DCTELEM *block)):
  86
  87 /********************** Function Prologue *********************************/
  88     link 16;
  89     [--SP] = (R7:4, P5:3);   // Push the registers onto the stack.
  90     B0 = R0;                 // Pointer to Input matrix
  91     R1 = [P3+coefs@GOT17M4]; // Pointer to Coefficients
  92     R2 = [P3+vtmp@GOT17M4];  // Pointer to Temporary matrix
  93     B3 = R1;
  94     B2 = R2;
  95     L3 = 20;                // L3 is used for making the coefficient array
  96                             // circular.
  97                             // MUST BE RESTORED TO ZERO at function exit.
  98     M1 = 16 (X);            // All these registers are initialized for
  99     M3 = 8(X);              // modifying address offsets.
 100
 101     I0 = B0;                // I0 points to Input Element (0, 0).
 102     I2 = B0;                // I2 points to Input Element (0, 0).
 103     I2 += M3 || R0.H = W[I0];
 104                             // Element 0 is read into R0.H
 105     I1 = I2;                // I1 points to input Element (0, 6).
 106     I1 += 4  || R0.L = W[I2++];
 107                             // I2 points to input Element (0, 4).
 108                             // Element 4 is read into R0.L.
 109     P2 = 8 (X);
 110     P3 = 32 (X);
 111     P4 = -32 (X);
 112     P5 = 98 (X);
 113     R7 = 0x8000(Z);
 114     I3 = B3;                // I3 points to Coefficients
 115     P0 = B2;                // P0 points to array Element (0, 0) of temp
 116     P1 = B2;
 117     R7 = [I3++] || [TMP2]=R7;            // Coefficient C4 is read into R7.H and R7.L.
 118     MNOP;
 119     NOP;
 120
 121     /*
 122      *   A1 =      Y0 * cos(pi/4)
 123      *   A0 =      Y0 * cos(pi/4)
 124      *   A1 = A1 + Y4 * cos(pi/4)
 125      *   A0 = A0 - Y4 * cos(pi/4)
 126      *   load:
 127      *     R1=(Y2,Y6)
 128      *     R7=(C2,C6)
 129      *   res:
 130      *     R3=Y0, R2=Y4
 131      */
 132     A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || I0+= 4       || R1.L=W[I1++];
 133     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++];
 134
 135     LSETUP (.0, .1) LC0 = P2; // perform 8 1d idcts
 136
 137     P2 = 112 (X);
 138     P1 = P1 + P2;           // P1 points to element (7, 0) of temp buffer.
 139     P2 = -94(X);
 140
 141 .0:
 142        /*
 143         *   A1 =      Y2 * cos(3pi/8)
 144         *   A0 =      Y2 * cos(pi/8)
 145         *   A1 = A1 - Y6 * cos(pi/8)
 146         *   A0 = A0 + Y6 * cos(3pi/8)
 147         *      R5 = (Y1,Y7)
 148         *      R7 = (C1,C7)
 149         *   res:
 150         *      R1=Y2, R0=Y6
 151         */
 152         A1=R7.L*R1.H,       A0=R7.H*R1.H (IS)        || I0+=4        || R5.H=W[I0];
 153         R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS)  || R5.L=W[I1--] || R7=[I3++];
 154         /*
 155         *   Y0 = Y0 + Y6.
 156         *   Y4 = Y4 + Y2.
 157         *   Y2 = Y4 - Y2.
 158         *   Y6 = Y0 - Y6.
 159         *     R3 is saved
 160         *     R6.l=Y3
 161         * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6
 162         */
 163         R3=R3+R0, R0=R3-R0;
 164         R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--];
 165         /*
 166          *  Compute the odd portion (1,3,5,7) even is done.
 167          *
 168          *  Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3.
 169          *  Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3.
 170          *  Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3.
 171          *  Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3.
 172          */
 173         //  R5=(Y1,Y7)  R6=(Y5,Y3)                                                   // R7=(C1,C7)
 174         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || [TMP1]=R2 || R6.H=W[I2--];
 175         A1-=R7.H*R5.L,       A0+=R7.L*R5.L (IS)       || I0-=4     || R7=[I3++];
 176         A1+=R7.H*R6.H,       A0+=R7.L*R6.H (IS)       || I0+=M1;                     // R7=(C3,C5)
 177         R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS);
 178         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || R4=[TMP0];
 179         A1+=R7.H*R5.L,       A0-=R7.L*R5.L (IS)       || I1+=M1    || R7=[I3++];     // R7=(C1,C7)
 180         A1+=R7.L*R6.H,       A0-=R7.H*R6.H (IS);
 181         R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1;
 182         // R3=Y1, R2=Y7, R7=Y5, R6=Y3
 183
 184         /* Transpose write column. */
 185         R5.H=R4+R2 (RND12);                                   // Y0=Y0+Y7
 186         R5.L=R4-R2 (RND12) || R4 = [TMP1];                    // Y7=Y7-Y0
 187         R2.H=R1+R7 (RND12) || W[P0++P3]=R5.H;                 // Y2=Y2+Y5 st Y0
 188         R2.L=R1-R7 (RND12) || W[P1++P4]=R5.L || R7=[I3++];    // Y5=Y2-Y5 st Y7
 189         R5.H=R0-R3 (RND12) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2
 190         R5.L=R0+R3 (RND12) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5
 191         R3.H=R4-R6 (RND12) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1
 192         R3.L=R4+R6 (RND12) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6
 193
 194         /* pipeline loop start, + drain Y3, Y4 */
 195         A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || W[P0++P2]= R3.H || R1.H = W[I0--];
 196 .1:     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++];
 197
 198
 199
 200     I0 = B2;                // I0 points to Input Element (0, 0)
 201     I2 = B2;                // I2 points to Input Element (0, 0)
 202     I2 += M3 || R0.H = W[I0];
 203                             // Y0 is read in R0.H
 204     I1 = I2;                // I1 points to input Element (0, 6)
 205     I1 += 4  || R0.L = W[I2++];
 206                             // I2 points to input Element (0, 4)
 207                             // Y4 is read in R0.L
 208     P2 = 8 (X);
 209     I3 = B3;                // I3 points to Coefficients
 210     P0 = B0;                // P0 points to array Element (0, 0) for writing
 211                             // output
 212     P1 = B0;
 213     R7 = [I3++];            // R7.H = C4 and R7.L = C4
 214     NOP;
 215
 216     /*
 217      *   A1 =      Y0 * cos(pi/4)
 218      *   A0 =      Y0 * cos(pi/4)
 219      *   A1 = A1 + Y4 * cos(pi/4)
 220      *   A0 = A0 - Y4 * cos(pi/4)
 221      *   load:
 222      *     R1=(Y2,Y6)
 223      *     R7=(C2,C6)
 224      *   res:
 225      *     R3=Y0, R2=Y4
 226      */
 227     A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || I0+=4        || R1.L=W[I1++];
 228     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || R1.H=W[I0--] || R7=[I3++];
 229
 230     LSETUP (.2, .3) LC0 = P2; // peform 8 1d idcts
 231     P2 = 112 (X);
 232     P1 = P1 + P2;
 233     P2 = -94(X);
 234
 235 .2:
 236         /*
 237          *   A1 =      Y2 * cos(3pi/8)
 238          *   A0 =      Y2 * cos(pi/8)
 239          *   A1 = A1 - Y6 * cos(pi/8)
 240          *   A0 = A0 + Y6 * cos(3pi/8)
 241          *      R5 = (Y1,Y7)
 242          *      R7 = (C1,C7)
 243          *   res:
 244          *      R1=Y2, R0=Y6
 245          */
 246         A1=R7.L*R1.H,       A0=R7.H*R1.H (IS)        || I0+=4        || R5.H=W[I0];
 247         R1=(A1-=R7.H*R1.L), R0=(A0+=R7.L*R1.L) (IS)  || R5.L=W[I1--] || R7=[I3++];
 248         /*
 249         *   Y0 = Y0 + Y6.
 250         *   Y4 = Y4 + Y2.
 251         *   Y2 = Y4 - Y2.
 252         *   Y6 = Y0 - Y6.
 253         *     R3 is saved
 254         *     R6.l=Y3
 255         * note: R3: Y0, R2: Y4, R1: Y2, R0: Y6
 256         */
 257         R3=R3+R0, R0=R3-R0;
 258         R2=R2+R1, R1=R2-R1 || [TMP0]=R3 || R6.L=W[I0--];
 259         /*
 260          *  Compute the odd portion (1,3,5,7) even is done.
 261          *
 262          *  Y1 = C7 * Y1 - C1 * Y7 + C3 * Y5 - C5 * Y3.
 263          *  Y7 = C1 * Y1 + C7 * Y7 + C5 * Y5 + C3 * Y3.
 264          *  Y5 = C5 * Y1 + C3 * Y7 + C7 * Y5 - C1 * Y3.
 265          *  Y3 = C3 * Y1 - C5 * Y7 - C1 * Y5 - C7 * Y3.
 266          */
 267         //  R5=(Y1,Y7)  R6=(Y5,Y3)                                                   // R7=(C1,C7)
 268         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || [TMP1]=R2 || R6.H=W[I2--];
 269         A1-=R7.H*R5.L,       A0+=R7.L*R5.L (IS)       || I0-=4     || R7=[I3++];
 270         A1+=R7.H*R6.H,       A0+=R7.L*R6.H (IS)       || I0+=M1;                     // R7=(C3,C5)
 271         R3 =(A1-=R7.L*R6.L), R2 =(A0+=R7.H*R6.L) (IS);
 272         A1 =R7.L*R5.H,       A0 =R7.H*R5.H (IS)       || R4=[TMP0];
 273         A1+=R7.H*R5.L,       A0-=R7.L*R5.L (IS)       || I1+=M1    || R7=[I3++];     // R7=(C1,C7)
 274         A1+=R7.L*R6.H,       A0-=R7.H*R6.H (IS);
 275         R7 =(A1-=R7.H*R6.L), R6 =(A0-=R7.L*R6.L) (IS) || I2+=M1;
 276         // R3=Y1, R2=Y7, R7=Y5, R6=Y3
 277
 278         /* Transpose write column. */
 279         R5.H=R4+R2 (RND20);                                   // Y0=Y0+Y7
 280         R5.L=R4-R2 (RND20) || R4 = [TMP1];                    // Y7=Y7-Y0
 281         R2.H=R1+R7 (RND20) || W[P0++P3]=R5.H;                 // Y2=Y2+Y5 st Y0
 282         R2.L=R1-R7 (RND20) || W[P1++P4]=R5.L || R7=[I3++];    // Y5=Y2-Y5 st Y7
 283         R5.H=R0-R3 (RND20) || W[P0++P3]=R2.H || R1.L=W[I1++]; // Y1=Y6-Y1 st Y2
 284         R5.L=R0+R3 (RND20) || W[P1++P4]=R2.L || R0.H=W[I0++]; // Y6=Y6+Y1 st Y5
 285         R3.H=R4-R6 (RND20) || W[P0++P3]=R5.H || R0.L=W[I2++]; // Y3=Y3-Y4 st Y1
 286         R3.L=R4+R6 (RND20) || W[P1++P4]=R5.L || R1.H=W[I0++]; // Y4=Y3+Y4 st Y6
 287
 288         /* pipeline loop start, + drain Y3, Y4 */
 289         A1=R7.H*R0.H,       A0=R7.H*R0.H (IS)       || W[P0++P2]= R3.H || R1.H = W[I0--];
 290 .3:     R3=(A1+=R7.H*R0.L), R2=(A0-=R7.H*R0.L) (IS) || W[P1++P5]= R3.L || R7 = [I3++];
 291
 292     L3 = 0;
 293     (R7:4,P5:3)=[SP++];
 294     unlink;
 295     RTS;
 296 DEFUN_END(idct)
 297
 298