git.sesse.net Git - ffmpeg/blob - libavcodec/x86/vp9lpf.asm

   1 ;******************************************************************************
   2 ;* VP9 loop filter SIMD optimizations
   3 ;*
   4 ;* Copyright (C) 2013-2014 Clément Bœsch <u pkh me>
   5 ;*
   6 ;* This file is part of FFmpeg.
   7 ;*
   8 ;* FFmpeg is free software; you can redistribute it and/or
   9 ;* modify it under the terms of the GNU Lesser General Public
  10 ;* License as published by the Free Software Foundation; either
  11 ;* version 2.1 of the License, or (at your option) any later version.
  12 ;*
  13 ;* FFmpeg is distributed in the hope that it will be useful,
  14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;* Lesser General Public License for more details.
  17 ;*
  18 ;* You should have received a copy of the GNU Lesser General Public
  19 ;* License along with FFmpeg; if not, write to the Free Software
  20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  21 ;******************************************************************************
  22
  23 %include "libavutil/x86/x86util.asm"
  24
  25 SECTION_RODATA
  26
  27 cextern pb_3
  28 cextern pb_80
  29
  30 pb_4:   times 16 db 0x04
  31 pb_10:  times 16 db 0x10
  32 pb_40:  times 16 db 0x40
  33 pb_81:  times 16 db 0x81
  34 pb_f8:  times 16 db 0xf8
  35 pb_fe:  times 16 db 0xfe
  36 pb_ff:  times 16 db 0xff
  37
  38 cextern pw_4
  39 cextern pw_8
  40
  41 ; with mix functions, two 8-bit thresholds are stored in a 16-bit storage,
  42 ; the following mask is used to splat both in the same register
  43 mask_mix: times 8 db 0
  44           times 8 db 1
  45
  46 mask_mix84: times 8 db 0xff
  47             times 8 db 0x00
  48 mask_mix48: times 8 db 0x00
  49             times 8 db 0xff
  50
  51 SECTION .text
  52
  53 %macro SCRATCH 3
  54 %if ARCH_X86_64
  55     SWAP                %1, %2
  56 %else
  57     mova              [%3], m%1
  58 %endif
  59 %endmacro
  60
  61 %macro UNSCRATCH 3
  62 %if ARCH_X86_64
  63     SWAP                %1, %2
  64 %else
  65     mova               m%1, [%3]
  66 %endif
  67 %endmacro
  68
  69 ; %1 = abs(%2-%3)
  70 %macro ABSSUB 4 ; dst, src1 (RO), src2 (RO), tmp
  71 %if ARCH_X86_64
  72     psubusb             %1, %3, %2
  73     psubusb             %4, %2, %3
  74 %else
  75     mova                %1, %3
  76     mova                %4, %2
  77     psubusb             %1, %2
  78     psubusb             %4, %3
  79 %endif
  80     por                 %1, %4
  81 %endmacro
  82
  83 ; %1 = %1>%2
  84 %macro CMP_GT 2-3 ; src/dst, cmp, pb_80
  85 %if %0 == 3
  86     pxor                %1, %3
  87 %endif
  88     pcmpgtb             %1, %2
  89 %endmacro
  90
  91 ; %1 = abs(%2-%3) > %4
  92 %macro ABSSUB_GT 5-6 [pb_80]; dst, src1, src2, cmp, tmp, [pb_80]
  93     ABSSUB              %1, %2, %3, %5      ; dst = abs(src1-src2)
  94     CMP_GT              %1, %4, %6          ; dst > cmp
  95 %endmacro
  96
  97 %macro MASK_APPLY 4 ; %1=new_data/dst %2=old_data %3=mask %4=tmp
  98     pand                %1, %3              ; new &= mask
  99     pandn               %4, %3, %2          ; tmp = ~mask & old
 100     por                 %1, %4              ; new&mask | old&~mask
 101 %endmacro
 102
 103 %macro UNPACK 4
 104 %if ARCH_X86_64
 105     punpck%1bw          %2, %3, %4
 106 %else
 107     mova                %2, %3
 108     punpck%1bw          %2, %4
 109 %endif
 110 %endmacro
 111
 112 %macro FILTER_SUBx2_ADDx2 11 ; %1=dst %2=h/l %3=cache %4=stack_off %5=sub1 %6=sub2 %7=add1
 113                              ; %8=add2 %9=rshift, [unpack], [unpack_is_mem_on_x86_32]
 114     psubw               %3, [rsp+%4+%5*32]
 115     psubw               %3, [rsp+%4+%6*32]
 116     paddw               %3, [rsp+%4+%7*32]
 117 %ifnidn %10, ""
 118 %if %11 == 0
 119     punpck%2bw          %1, %10, m0
 120 %else
 121     UNPACK          %2, %1, %10, m0
 122 %endif
 123     mova    [rsp+%4+%8*32], %1
 124     paddw               %3, %1
 125 %else
 126     paddw               %3, [rsp+%4+%8*32]
 127 %endif
 128     psraw               %1, %3, %9
 129 %endmacro
 130
 131 ; FIXME interleave l/h better (for instruction pairing)
 132 %macro FILTER_INIT 9 ; tmp1, tmp2, cacheL, cacheH, dstp, stack_off, filterid, mask, source
 133     FILTER%7_INIT       %1, l, %3, %6 +  0
 134     FILTER%7_INIT       %2, h, %4, %6 + 16
 135     packuswb            %1, %2
 136     MASK_APPLY          %1, %9, %8, %2
 137     mova                %5, %1
 138 %endmacro
 139
 140
 141 %macro FILTER_UPDATE 12-16 "", "", "", 0 ; tmp1, tmp2, cacheL, cacheH, dstp, stack_off, -, -, +, +, rshift,
 142                                          ; mask, [source], [unpack + src], [unpack_is_mem_on_x86_32]
 143 ; FIXME interleave this properly with the subx2/addx2
 144 %ifnidn %15, ""
 145 %if %16 == 0 || ARCH_X86_64
 146     mova               %14, %15
 147 %endif
 148 %endif
 149     FILTER_SUBx2_ADDx2  %1, l, %3, %6 +  0, %7, %8, %9, %10, %11, %14, %16
 150     FILTER_SUBx2_ADDx2  %2, h, %4, %6 + 16, %7, %8, %9, %10, %11, %14, %16
 151     packuswb            %1, %2
 152 %ifnidn %13, ""
 153     MASK_APPLY          %1, %13, %12, %2
 154 %else
 155     MASK_APPLY          %1, %5, %12, %2
 156 %endif
 157     mova                %5, %1
 158 %endmacro
 159
 160 %macro SRSHIFT3B_2X 4 ; reg1, reg2, [pb_10], tmp
 161     mova                %4, [pb_f8]
 162     pand                %1, %4
 163     pand                %2, %4
 164     psrlq               %1, 3
 165     psrlq               %2, 3
 166     pxor                %1, %3
 167     pxor                %2, %3
 168     psubb               %1, %3
 169     psubb               %2, %3
 170 %endmacro
 171
 172 %macro EXTRACT_POS_NEG 3 ; i8, neg, pos
 173     pxor                %3, %3
 174     pxor                %2, %2
 175     pcmpgtb             %3, %1                          ; i8 < 0 mask
 176     psubb               %2, %1                          ; neg values (only the originally - will be kept)
 177     pand                %2, %3                          ; negative values of i8 (but stored as +)
 178     pandn               %3, %1                          ; positive values of i8
 179 %endmacro
 180
 181 ; clip_u8(u8 + i8)
 182 %macro SIGN_ADD 4 ; dst, u8, i8, tmp1
 183     EXTRACT_POS_NEG     %3, %4, %1
 184     paddusb             %1, %2                          ; add the positives
 185     psubusb             %1, %4                          ; sub the negatives
 186 %endmacro
 187
 188 ; clip_u8(u8 - i8)
 189 %macro SIGN_SUB 4 ; dst, u8, i8, tmp1
 190     EXTRACT_POS_NEG     %3, %1, %4
 191     paddusb             %1, %2                          ; add the negatives
 192     psubusb             %1, %4                          ; sub the positives
 193 %endmacro
 194
 195 %macro FILTER6_INIT 4 ; %1=dst %2=h/l %3=cache, %4=stack_off
 196     UNPACK          %2, %1, rp3, m0                     ; p3: B->W
 197     mova     [rsp+%4+0*32], %1
 198     paddw               %3, %1, %1                      ; p3*2
 199     paddw               %3, %1                          ; p3*3
 200     punpck%2bw          %1, m1,  m0                     ; p2: B->W
 201     mova     [rsp+%4+1*32], %1
 202     paddw               %3, %1                          ; p3*3 + p2
 203     paddw               %3, %1                          ; p3*3 + p2*2
 204     UNPACK          %2, %1, rp1, m0                     ; p1: B->W
 205     mova     [rsp+%4+2*32], %1
 206     paddw               %3, %1                          ; p3*3 + p2*2 + p1
 207     UNPACK          %2, %1, rp0, m0                     ; p0: B->W
 208     mova     [rsp+%4+3*32], %1
 209     paddw               %3, %1                          ; p3*3 + p2*2 + p1 + p0
 210     UNPACK          %2, %1, rq0, m0                     ; q0: B->W
 211     mova     [rsp+%4+4*32], %1
 212     paddw               %3, %1                          ; p3*3 + p2*2 + p1 + p0 + q0
 213     paddw               %3, [pw_4]                      ; p3*3 + p2*2 + p1 + p0 + q0 + 4
 214     psraw               %1, %3, 3                       ; (p3*3 + p2*2 + p1 + p0 + q0 + 4) >> 3
 215 %endmacro
 216
 217 %macro FILTER14_INIT 4 ; %1=dst %2=h/l %3=cache, %4=stack_off
 218     punpck%2bw          %1, m2, m0                      ; p7: B->W
 219     mova    [rsp+%4+ 8*32], %1
 220     psllw               %3, %1, 3                       ; p7*8
 221     psubw               %3, %1                          ; p7*7
 222     punpck%2bw          %1, m3, m0                      ; p6: B->W
 223     mova    [rsp+%4+ 9*32], %1
 224     paddw               %3, %1                          ; p7*7 + p6
 225     paddw               %3, %1                          ; p7*7 + p6*2
 226     UNPACK          %2, %1, rp5, m0                     ; p5: B->W
 227     mova    [rsp+%4+10*32], %1
 228     paddw               %3, %1                          ; p7*7 + p6*2 + p5
 229     UNPACK          %2, %1, rp4, m0                     ; p4: B->W
 230     mova    [rsp+%4+11*32], %1
 231     paddw               %3, %1                          ; p7*7 + p6*2 + p5 + p4
 232     paddw               %3, [rsp+%4+ 0*32]              ; p7*7 + p6*2 + p5 + p4 + p3
 233     paddw               %3, [rsp+%4+ 1*32]              ; p7*7 + p6*2 + p5 + .. + p2
 234     paddw               %3, [rsp+%4+ 2*32]              ; p7*7 + p6*2 + p5 + .. + p1
 235     paddw               %3, [rsp+%4+ 3*32]              ; p7*7 + p6*2 + p5 + .. + p0
 236     paddw               %3, [rsp+%4+ 4*32]              ; p7*7 + p6*2 + p5 + .. + p0 + q0
 237     paddw               %3, [pw_8]                      ; p7*7 + p6*2 + p5 + .. + p0 + q0 + 8
 238     psraw               %1, %3, 4                       ; (p7*7 + p6*2 + p5 + .. + p0 + q0 + 8) >> 4
 239 %endmacro
 240
 241 %macro TRANSPOSE16x16B 17
 242     mova %17, m%16
 243     SBUTTERFLY bw,  %1,  %2,  %16
 244     SBUTTERFLY bw,  %3,  %4,  %16
 245     SBUTTERFLY bw,  %5,  %6,  %16
 246     SBUTTERFLY bw,  %7,  %8,  %16
 247     SBUTTERFLY bw,  %9,  %10, %16
 248     SBUTTERFLY bw,  %11, %12, %16
 249     SBUTTERFLY bw,  %13, %14, %16
 250     mova m%16,  %17
 251     mova  %17, m%14
 252     SBUTTERFLY bw,  %15, %16, %14
 253     SBUTTERFLY wd,  %1,  %3,  %14
 254     SBUTTERFLY wd,  %2,  %4,  %14
 255     SBUTTERFLY wd,  %5,  %7,  %14
 256     SBUTTERFLY wd,  %6,  %8,  %14
 257     SBUTTERFLY wd,  %9,  %11, %14
 258     SBUTTERFLY wd,  %10, %12, %14
 259     SBUTTERFLY wd,  %13, %15, %14
 260     mova m%14,  %17
 261     mova  %17, m%12
 262     SBUTTERFLY wd,  %14, %16, %12
 263     SBUTTERFLY dq,  %1,  %5,  %12
 264     SBUTTERFLY dq,  %2,  %6,  %12
 265     SBUTTERFLY dq,  %3,  %7,  %12
 266     SBUTTERFLY dq,  %4,  %8,  %12
 267     SBUTTERFLY dq,  %9,  %13, %12
 268     SBUTTERFLY dq,  %10, %14, %12
 269     SBUTTERFLY dq,  %11, %15, %12
 270     mova m%12, %17
 271     mova  %17, m%8
 272     SBUTTERFLY dq,  %12, %16, %8
 273     SBUTTERFLY qdq, %1,  %9,  %8
 274     SBUTTERFLY qdq, %2,  %10, %8
 275     SBUTTERFLY qdq, %3,  %11, %8
 276     SBUTTERFLY qdq, %4,  %12, %8
 277     SBUTTERFLY qdq, %5,  %13, %8
 278     SBUTTERFLY qdq, %6,  %14, %8
 279     SBUTTERFLY qdq, %7,  %15, %8
 280     mova m%8, %17
 281     mova %17, m%1
 282     SBUTTERFLY qdq, %8,  %16, %1
 283     mova m%1, %17
 284     SWAP %2,  %9
 285     SWAP %3,  %5
 286     SWAP %4,  %13
 287     SWAP %6,  %11
 288     SWAP %8,  %15
 289     SWAP %12, %14
 290 %endmacro
 291
 292 ; transpose 16 half lines (high part) to 8 full centered lines
 293 %macro TRANSPOSE16x8B 16
 294     punpcklbw   m%1,  m%2
 295     punpcklbw   m%3,  m%4
 296     punpcklbw   m%5,  m%6
 297     punpcklbw   m%7,  m%8
 298     punpcklbw   m%9,  m%10
 299     punpcklbw   m%11, m%12
 300     punpcklbw   m%13, m%14
 301     punpcklbw   m%15, m%16
 302     SBUTTERFLY  wd,  %1,  %3,  %2
 303     SBUTTERFLY  wd,  %5,  %7,  %2
 304     SBUTTERFLY  wd,  %9,  %11, %2
 305     SBUTTERFLY  wd,  %13, %15, %2
 306     SBUTTERFLY  dq,  %1,  %5,  %2
 307     SBUTTERFLY  dq,  %3,  %7,  %2
 308     SBUTTERFLY  dq,  %9,  %13, %2
 309     SBUTTERFLY  dq,  %11, %15, %2
 310     SBUTTERFLY  qdq, %1,  %9,  %2
 311     SBUTTERFLY  qdq, %3,  %11, %2
 312     SBUTTERFLY  qdq, %5,  %13, %2
 313     SBUTTERFLY  qdq, %7,  %15, %2
 314     SWAP %5, %1
 315     SWAP %6, %9
 316     SWAP %7, %1
 317     SWAP %8, %13
 318     SWAP %9, %3
 319     SWAP %10, %11
 320     SWAP %11, %1
 321     SWAP %12, %15
 322 %endmacro
 323
 324 %macro DEFINE_REAL_P7_TO_Q7 0-1 0
 325 %define P7 dstq  + 4*mstrideq  + %1
 326 %define P6 dstq  +   mstride3q + %1
 327 %define P5 dstq  + 2*mstrideq  + %1
 328 %define P4 dstq  +   mstrideq  + %1
 329 %define P3 dstq                + %1
 330 %define P2 dstq  +    strideq  + %1
 331 %define P1 dstq  + 2* strideq  + %1
 332 %define P0 dstq  +    stride3q + %1
 333 %define Q0 dstq  + 4* strideq  + %1
 334 %define Q1 dst2q +   mstride3q + %1
 335 %define Q2 dst2q + 2*mstrideq  + %1
 336 %define Q3 dst2q +   mstrideq  + %1
 337 %define Q4 dst2q               + %1
 338 %define Q5 dst2q +    strideq  + %1
 339 %define Q6 dst2q + 2* strideq  + %1
 340 %define Q7 dst2q +    stride3q + %1
 341 %endmacro
 342
 343 ; ..............AB -> AAAAAAAABBBBBBBB
 344 %macro SPLATB_MIX 1-2 [mask_mix]
 345 %if cpuflag(ssse3)
 346     pshufb     %1, %2
 347 %else
 348     punpcklbw  %1, %1
 349     punpcklwd  %1, %1
 350     punpckldq  %1, %1
 351 %endif
 352 %endmacro
 353
 354 %macro LOOPFILTER 5 ; %1=v/h %2=size1 %3+%4=stack, %5=32bit stack only
 355 %if UNIX64
 356 cglobal vp9_loop_filter_%1_%2_16, 5, 9, 16, %3 + %4, dst, stride, E, I, H, mstride, dst2, stride3, mstride3
 357 %else
 358 %if WIN64
 359 cglobal vp9_loop_filter_%1_%2_16, 4, 8, 16, %3 + %4, dst, stride, E, I, mstride, dst2, stride3, mstride3
 360 %else
 361 cglobal vp9_loop_filter_%1_%2_16, 2, 6, 16, %3 + %4 + %5, dst, stride, mstride, dst2, stride3, mstride3
 362 %define Ed dword r2m
 363 %define Id dword r3m
 364 %endif
 365 %define Hd dword r4m
 366 %endif
 367
 368     mov               mstrideq, strideq
 369     neg               mstrideq
 370
 371     lea               stride3q, [strideq*3]
 372     lea              mstride3q, [mstrideq*3]
 373
 374 %ifidn %1, h
 375 %if %2 > 16
 376 %define movx movh
 377     lea                   dstq, [dstq + 4*strideq - 4]
 378 %else
 379 %define movx movu
 380     lea                   dstq, [dstq + 4*strideq - 8] ; go from top center (h pos) to center left (v pos)
 381 %endif
 382     lea                  dst2q, [dstq + 8*strideq]
 383 %else
 384     lea                   dstq, [dstq + 4*mstrideq]
 385     lea                  dst2q, [dstq + 8*strideq]
 386 %endif
 387
 388     DEFINE_REAL_P7_TO_Q7
 389
 390 %ifidn %1, h
 391     movx                    m0, [P7]
 392     movx                    m1, [P6]
 393     movx                    m2, [P5]
 394     movx                    m3, [P4]
 395     movx                    m4, [P3]
 396     movx                    m5, [P2]
 397     movx                    m6, [P1]
 398     movx                    m7, [P0]
 399     movx                    m8, [Q0]
 400     movx                    m9, [Q1]
 401     movx                   m10, [Q2]
 402     movx                   m11, [Q3]
 403     movx                   m12, [Q4]
 404     movx                   m13, [Q5]
 405     movx                   m14, [Q6]
 406     movx                   m15, [Q7]
 407 %define P7 rsp +   0
 408 %define P6 rsp +  16
 409 %define P5 rsp +  32
 410 %define P4 rsp +  48
 411 %define P3 rsp +  64
 412 %define P2 rsp +  80
 413 %define P1 rsp +  96
 414 %define P0 rsp + 112
 415 %define Q0 rsp + 128
 416 %define Q1 rsp + 144
 417 %define Q2 rsp + 160
 418 %define Q3 rsp + 176
 419 %define Q4 rsp + 192
 420 %define Q5 rsp + 208
 421 %define Q6 rsp + 224
 422 %define Q7 rsp + 240
 423
 424 %if %2 == 16
 425     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
 426     mova           [P7],  m0
 427     mova           [P6],  m1
 428     mova           [P5],  m2
 429     mova           [P4],  m3
 430 %else
 431     TRANSPOSE16x8B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15
 432 %endif
 433     mova           [P3],  m4
 434     mova           [P2],  m5
 435     mova           [P1],  m6
 436     mova           [P0],  m7
 437     mova           [Q0],  m8
 438     mova           [Q1],  m9
 439     mova           [Q2], m10
 440     mova           [Q3], m11
 441 %if %2 == 16
 442     mova           [Q4], m12
 443     mova           [Q5], m13
 444     mova           [Q6], m14
 445     mova           [Q7], m15
 446 %endif
 447 %endif
 448
 449     ; calc fm mask
 450 %if %2 == 16
 451 %if cpuflag(ssse3)
 452     pxor                m0, m0
 453 %endif
 454     SPLATB_REG          m2, I, m0                       ; I I I I ...
 455     SPLATB_REG          m3, E, m0                       ; E E E E ...
 456 %else
 457 %if cpuflag(ssse3)
 458     mova                m0, [mask_mix]
 459 %endif
 460     movd                m2, Id
 461     movd                m3, Ed
 462     SPLATB_MIX          m2, m0
 463     SPLATB_MIX          m3, m0
 464 %endif
 465     mova                m0, [pb_80]
 466     pxor                m2, m0
 467     pxor                m3, m0
 468 %if ARCH_X86_64
 469 %ifidn %1, v
 470     mova                m8, [P3]
 471     mova                m9, [P2]
 472     mova               m10, [P1]
 473     mova               m11, [P0]
 474     mova               m12, [Q0]
 475     mova               m13, [Q1]
 476     mova               m14, [Q2]
 477     mova               m15, [Q3]
 478 %else
 479     ; In case of horizontal, P3..Q3 are already present in some registers due
 480     ; to the previous transpose, so we just swap registers.
 481     SWAP                 8,  4, 12
 482     SWAP                 9,  5, 13
 483     SWAP                10,  6, 14
 484     SWAP                11,  7, 15
 485 %endif
 486 %define rp3 m8
 487 %define rp2 m9
 488 %define rp1 m10
 489 %define rp0 m11
 490 %define rq0 m12
 491 %define rq1 m13
 492 %define rq2 m14
 493 %define rq3 m15
 494 %else
 495 %define rp3 [P3]
 496 %define rp2 [P2]
 497 %define rp1 [P1]
 498 %define rp0 [P0]
 499 %define rq0 [Q0]
 500 %define rq1 [Q1]
 501 %define rq2 [Q2]
 502 %define rq3 [Q3]
 503 %endif
 504     ABSSUB_GT           m5, rp3, rp2, m2, m7, m0        ; m5 = abs(p3-p2) <= I
 505     ABSSUB_GT           m1, rp2, rp1, m2, m7, m0        ; m1 = abs(p2-p1) <= I
 506     por                 m5, m1
 507     ABSSUB_GT           m1, rp1, rp0, m2, m7, m0        ; m1 = abs(p1-p0) <= I
 508     por                 m5, m1
 509     ABSSUB_GT           m1, rq0, rq1, m2, m7, m0        ; m1 = abs(q1-q0) <= I
 510     por                 m5, m1
 511     ABSSUB_GT           m1, rq1, rq2, m2, m7, m0        ; m1 = abs(q2-q1) <= I
 512     por                 m5, m1
 513     ABSSUB_GT           m1, rq2, rq3, m2, m7, m0        ; m1 = abs(q3-q2) <= I
 514     por                 m5, m1
 515     ABSSUB              m1, rp0, rq0, m7                ; abs(p0-q0)
 516     paddusb             m1, m1                          ; abs(p0-q0) * 2
 517     ABSSUB              m2, rp1, rq1, m7                ; abs(p1-q1)
 518     pand                m2, [pb_fe]                     ; drop lsb so shift can work
 519     psrlq               m2, 1                           ; abs(p1-q1)/2
 520     paddusb             m1, m2                          ; abs(p0-q0)*2 + abs(p1-q1)/2
 521     pxor                m1, m0
 522     pcmpgtb             m1, m3
 523     por                 m1, m5                          ; fm final value
 524     SWAP                 1, 3
 525     pxor                m3, [pb_ff]
 526
 527     ; (m3: fm, m8..15: p3 p2 p1 p0 q0 q1 q2 q3)
 528     ; calc flat8in (if not 44_16) and hev masks
 529 %if %2 != 44
 530     mova                m6, [pb_81]                     ; [1 1 1 1 ...] ^ 0x80
 531     ABSSUB_GT           m2, rp3, rp0, m6, m5            ; abs(p3 - p0) <= 1
 532 %if ARCH_X86_64
 533     mova                m8, [pb_80]
 534 %define rb80 m8
 535 %else
 536 %define rb80 [pb_80]
 537 %endif
 538     ABSSUB_GT           m1, rp2, rp0, m6, m5, rb80      ; abs(p2 - p0) <= 1
 539     por                 m2, m1
 540     ABSSUB              m4, rp1, rp0, m5                ; abs(p1 - p0)
 541 %if %2 == 16
 542 %if cpuflag(ssse3)
 543     pxor                m0, m0
 544 %endif
 545     SPLATB_REG          m7, H, m0                       ; H H H H ...
 546 %else
 547     movd                m7, Hd
 548     SPLATB_MIX          m7
 549 %endif
 550     pxor                m7, rb80
 551     pxor                m4, rb80
 552     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
 553     CMP_GT              m4, m6                          ; abs(p1 - p0) <= 1
 554     por                 m2, m4                          ; (flat8in)
 555     ABSSUB              m4, rq1, rq0, m1                ; abs(q1 - q0)
 556     pxor                m4, rb80
 557     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
 558     por                 m0, m5                          ; hev final value
 559     CMP_GT              m4, m6                          ; abs(q1 - q0) <= 1
 560     por                 m2, m4                          ; (flat8in)
 561     ABSSUB_GT           m1, rq2, rq0, m6, m5, rb80      ; abs(q2 - q0) <= 1
 562     por                 m2, m1
 563     ABSSUB_GT           m1, rq3, rq0, m6, m5, rb80      ; abs(q3 - q0) <= 1
 564     por                 m2, m1                          ; flat8in final value
 565     pxor                m2, [pb_ff]
 566 %if %2 == 84 || %2 == 48
 567     pand                m2, [mask_mix%2]
 568 %endif
 569 %else
 570     mova                m6, [pb_80]
 571     movd                m7, Hd
 572     SPLATB_MIX          m7
 573     pxor                m7, m6
 574     ABSSUB              m4, rp1, rp0, m1                ; abs(p1 - p0)
 575     pxor                m4, m6
 576     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
 577     ABSSUB              m4, rq1, rq0, m1                ; abs(q1 - q0)
 578     pxor                m4, m6
 579     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
 580     por                 m0, m5                          ; hev final value
 581 %endif
 582
 583 %if %2 == 16
 584     ; (m0: hev, m2: flat8in, m3: fm, m6: pb_81, m9..15: p2 p1 p0 q0 q1 q2 q3)
 585     ; calc flat8out mask
 586 %if ARCH_X86_64
 587     mova                m8, [P7]
 588     mova                m9, [P6]
 589 %define rp7 m8
 590 %define rp6 m9
 591 %else
 592 %define rp7 [P7]
 593 %define rp6 [P6]
 594 %endif
 595     ABSSUB_GT           m1, rp7, rp0, m6, m5            ; abs(p7 - p0) <= 1
 596     ABSSUB_GT           m7, rp6, rp0, m6, m5            ; abs(p6 - p0) <= 1
 597     por                 m1, m7
 598 %if ARCH_X86_64
 599     mova                m8, [P5]
 600     mova                m9, [P4]
 601 %define rp5 m8
 602 %define rp4 m9
 603 %else
 604 %define rp5 [P5]
 605 %define rp4 [P4]
 606 %endif
 607     ABSSUB_GT           m7, rp5, rp0, m6, m5            ; abs(p5 - p0) <= 1
 608     por                 m1, m7
 609     ABSSUB_GT           m7, rp4, rp0, m6, m5            ; abs(p4 - p0) <= 1
 610     por                 m1, m7
 611 %if ARCH_X86_64
 612     mova                m14, [Q4]
 613     mova                m15, [Q5]
 614 %define rq4 m14
 615 %define rq5 m15
 616 %else
 617 %define rq4 [Q4]
 618 %define rq5 [Q5]
 619 %endif
 620     ABSSUB_GT           m7, rq4, rq0, m6, m5            ; abs(q4 - q0) <= 1
 621     por                 m1, m7
 622     ABSSUB_GT           m7, rq5, rq0, m6, m5            ; abs(q5 - q0) <= 1
 623     por                 m1, m7
 624 %if ARCH_X86_64
 625     mova                m14, [Q6]
 626     mova                m15, [Q7]
 627 %define rq6 m14
 628 %define rq7 m15
 629 %else
 630 %define rq6 [Q6]
 631 %define rq7 [Q7]
 632 %endif
 633     ABSSUB_GT           m7, rq6, rq0, m6, m5            ; abs(q4 - q0) <= 1
 634     por                 m1, m7
 635     ABSSUB_GT           m7, rq7, rq0, m6, m5            ; abs(q5 - q0) <= 1
 636     por                 m1, m7                          ; flat8out final value
 637     pxor                m1, [pb_ff]
 638 %endif
 639
 640     ; if (fm) {
 641     ;     if (out && in) filter_14()
 642     ;     else if (in)   filter_6()
 643     ;     else if (hev)  filter_2()
 644     ;     else           filter_4()
 645     ; }
 646     ;
 647     ; f14:                                                                            fm &  out &  in
 648     ; f6:  fm & ~f14 & in        => fm & ~(out & in) & in                          => fm & ~out &  in
 649     ; f2:  fm & ~f14 & ~f6 & hev => fm & ~(out & in) & ~(~out & in) & hev          => fm &  ~in &  hev
 650     ; f4:  fm & ~f14 & ~f6 & ~f2 => fm & ~(out & in) & ~(~out & in) & ~(~in & hev) => fm &  ~in & ~hev
 651
 652     ; (m0: hev, [m1: flat8out], [m2: flat8in], m3: fm, m8..15: p5 p4 p1 p0 q0 q1 q6 q7)
 653     ; filter2()
 654 %if %2 != 44
 655     mova                m6, [pb_80]                     ; already in m6 if 44_16
 656     SCRATCH              2, 15, rsp+%3+%4
 657 %if %2 == 16
 658     SCRATCH              1,  8, rsp+%3+%4+16
 659 %endif
 660 %endif
 661     pxor                m2, m6, rq0                     ; q0 ^ 0x80
 662     pxor                m4, m6, rp0                     ; p0 ^ 0x80
 663     psubsb              m2, m4                          ; (signed) q0 - p0
 664     pxor                m4, m6, rp1                     ; p1 ^ 0x80
 665     pxor                m5, m6, rq1                     ; q1 ^ 0x80
 666     psubsb              m4, m5                          ; (signed) p1 - q1
 667     paddsb              m4, m2                          ;   (q0 - p0) + (p1 - q1)
 668     paddsb              m4, m2                          ; 2*(q0 - p0) + (p1 - q1)
 669     paddsb              m4, m2                          ; 3*(q0 - p0) + (p1 - q1)
 670     paddsb              m6, m4, [pb_4]                  ; m6: f1 = clip(f + 4, 127)
 671     paddsb              m4, [pb_3]                      ; m4: f2 = clip(f + 3, 127)
 672 %if ARCH_X86_64
 673     mova                m14, [pb_10]                    ; will be reused in filter4()
 674 %define rb10 m14
 675 %else
 676 %define rb10 [pb_10]
 677 %endif
 678     SRSHIFT3B_2X        m6, m4, rb10, m7                ; f1 and f2 sign byte shift by 3
 679     SIGN_SUB            m7, rq0, m6, m5                 ; m7 = q0 - f1
 680     SIGN_ADD            m1, rp0, m4, m5                 ; m1 = p0 + f2
 681 %if %2 != 44
 682 %if ARCH_X86_64
 683     pandn               m6, m15, m3                     ;  ~mask(in) & mask(fm)
 684 %else
 685     mova                m6, [rsp+%3+%4]
 686     pandn               m6, m3
 687 %endif
 688     pand                m6, m0                          ; (~mask(in) & mask(fm)) & mask(hev)
 689 %else
 690     pand                m6, m3, m0
 691 %endif
 692     MASK_APPLY          m7, rq0, m6, m5                 ; m7 = filter2(q0) & mask / we write it in filter4()
 693     MASK_APPLY          m1, rp0, m6, m5                 ; m1 = filter2(p0) & mask / we write it in filter4()
 694
 695     ; (m0: hev, m1: p0', m2: q0-p0, m3: fm, m7: q0', [m8: flat8out], m10..13: p1 p0 q0 q1, m14: pb_10, [m15: flat8in], )
 696     ; filter4()
 697     mova                m4, m2
 698     paddsb              m2, m4                          ; 2 * (q0 - p0)
 699     paddsb              m2, m4                          ; 3 * (q0 - p0)
 700     paddsb              m6, m2, [pb_4]                  ; m6:  f1 = clip(f + 4, 127)
 701     paddsb              m2, [pb_3]                      ; m2: f2 = clip(f + 3, 127)
 702     SRSHIFT3B_2X        m6, m2, rb10, m4                ; f1 and f2 sign byte shift by 3
 703 %if %2 != 44
 704 %if ARCH_X86_64
 705     pandn               m5, m15, m3                     ;               ~mask(in) & mask(fm)
 706 %else
 707     mova                m5, [rsp+%3+%4]
 708     pandn               m5, m3
 709 %endif
 710     pandn               m0, m5                          ; ~mask(hev) & (~mask(in) & mask(fm))
 711 %else
 712     pandn               m0, m3
 713 %endif
 714     SIGN_SUB            m5, rq0, m6, m4                 ; q0 - f1
 715     MASK_APPLY          m5, m7, m0, m4                  ; filter4(q0) & mask
 716     mova                [Q0], m5
 717     SIGN_ADD            m7, rp0, m2, m4                 ; p0 + f2
 718     MASK_APPLY          m7, m1, m0, m4                  ; filter4(p0) & mask
 719     mova                [P0], m7
 720     paddb               m6, [pb_80]                     ;
 721     pxor                m1, m1                          ;   f=(f1+1)>>1
 722     pavgb               m6, m1                          ;
 723     psubb               m6, [pb_40]                     ;
 724     SIGN_ADD            m1, rp1, m6, m2                 ; p1 + f
 725     SIGN_SUB            m4, rq1, m6, m2                 ; q1 - f
 726     MASK_APPLY          m1, rp1, m0, m2                 ; m1 = filter4(p1)
 727     MASK_APPLY          m4, rq1, m0, m2                 ; m4 = filter4(q1)
 728     mova                [P1], m1
 729     mova                [Q1], m4
 730
 731 %if %2 != 44
 732     UNSCRATCH            2, 15, rsp+%3+%4
 733 %endif
 734
 735     ; ([m1: flat8out], m2: flat8in, m3: fm, m10..13: p1 p0 q0 q1)
 736     ; filter6()
 737 %if %2 != 44
 738     pxor                m0, m0
 739 %if %2 > 16
 740     pand                m3, m2
 741 %else
 742     pand                m2, m3                          ;               mask(fm) & mask(in)
 743 %if ARCH_X86_64
 744     pandn               m3, m8, m2                      ; ~mask(out) & (mask(fm) & mask(in))
 745 %else
 746     mova                m3, [rsp+%3+%4+16]
 747     pandn               m3, m2
 748 %endif
 749 %endif
 750 %if ARCH_X86_64
 751     mova               m14, [P3]
 752     mova                m9, [Q3]
 753 %define rp3 m14
 754 %define rq3 m9
 755 %else
 756 %define rp3 [P3]
 757 %define rq3 [Q3]
 758 %endif
 759     mova                m1, [P2]
 760     FILTER_INIT         m4, m5, m6, m7, [P2], %4, 6,             m3,  m1             ; [p2]
 761     mova                m1, [Q2]
 762     FILTER_UPDATE       m4, m5, m6, m7, [P1], %4, 0, 1, 2, 5, 3, m3,  "", rq1, "", 1 ; [p1] -p3 -p2 +p1 +q1
 763     FILTER_UPDATE       m4, m5, m6, m7, [P0], %4, 0, 2, 3, 6, 3, m3,  "", m1         ; [p0] -p3 -p1 +p0 +q2
 764     FILTER_UPDATE       m4, m5, m6, m7, [Q0], %4, 0, 3, 4, 7, 3, m3,  "", rq3, "", 1 ; [q0] -p3 -p0 +q0 +q3
 765     FILTER_UPDATE       m4, m5, m6, m7, [Q1], %4, 1, 4, 5, 7, 3, m3,  ""             ; [q1] -p2 -q0 +q1 +q3
 766     FILTER_UPDATE       m4, m5, m6, m7, [Q2], %4, 2, 5, 6, 7, 3, m3,  m1             ; [q2] -p1 -q1 +q2 +q3
 767 %endif
 768
 769 %if %2 == 16
 770     UNSCRATCH            1,  8, rsp+%3+%4+16
 771 %endif
 772
 773     ; (m0: 0, [m1: flat8out], m2: fm & flat8in, m8..15: q2 q3 p1 p0 q0 q1 p3 p2)
 774     ; filter14()
 775     ;
 776     ;                            m2  m3  m8  m9 m14 m15 m10 m11 m12 m13
 777     ;
 778     ;                                    q2  q3  p3  p2  p1  p0  q0  q1
 779     ; p6  -7                     p7  p6  p5  p4   .   .   .   .   .
 780     ; p5  -6  -p7 -p6 +p5 +q1     .   .   .                           .
 781     ; p4  -5  -p7 -p5 +p4 +q2     .       .   .                      q2
 782     ; p3  -4  -p7 -p4 +p3 +q3     .           .   .                  q3
 783     ; p2  -3  -p7 -p3 +p2 +q4     .               .   .              q4
 784     ; p1  -2  -p7 -p2 +p1 +q5     .                   .   .          q5
 785     ; p0  -1  -p7 -p1 +p0 +q6     .                       .   .      q6
 786     ; q0  +0  -p7 -p0 +q0 +q7     .                           .   .  q7
 787     ; q1  +1  -p6 -q0 +q1 +q7    q1   .                           .   .
 788     ; q2  +2  -p5 -q1 +q2 +q7     .  q2   .                           .
 789     ; q3  +3  -p4 -q2 +q3 +q7         .  q3   .                       .
 790     ; q4  +4  -p3 -q3 +q4 +q7             .  q4   .                   .
 791     ; q5  +5  -p2 -q4 +q5 +q7                 .  q5   .               .
 792     ; q6  +6  -p1 -q5 +q6 +q7                     .  q6   .           .
 793
 794 %if %2 == 16
 795     pand            m1, m2                                                              ; mask(out) & (mask(fm) & mask(in))
 796     mova            m2, [P7]
 797     mova            m3, [P6]
 798 %if ARCH_X86_64
 799     mova            m8, [P5]
 800     mova            m9, [P4]
 801 %define rp5 m8
 802 %define rp4 m9
 803 %define rp5s m8
 804 %define rp4s m9
 805 %define rp3s m14
 806 %define rq4 m8
 807 %define rq5 m9
 808 %define rq6 m14
 809 %define rq7 m15
 810 %define rq4s m8
 811 %define rq5s m9
 812 %define rq6s m14
 813 %else
 814 %define rp5 [P5]
 815 %define rp4 [P4]
 816 %define rp5s ""
 817 %define rp4s ""
 818 %define rp3s ""
 819 %define rq4 [Q4]
 820 %define rq5 [Q5]
 821 %define rq6 [Q6]
 822 %define rq7 [Q7]
 823 %define rq4s ""
 824 %define rq5s ""
 825 %define rq6s ""
 826 %endif
 827     FILTER_INIT     m4, m5, m6, m7, [P6], %4, 14,                m1,  m3            ; [p6]
 828     FILTER_UPDATE   m4, m5, m6, m7, [P5], %4,  8,  9, 10,  5, 4, m1, rp5s           ; [p5] -p7 -p6 +p5 +q1
 829     FILTER_UPDATE   m4, m5, m6, m7, [P4], %4,  8, 10, 11,  6, 4, m1, rp4s           ; [p4] -p7 -p5 +p4 +q2
 830     FILTER_UPDATE   m4, m5, m6, m7, [P3], %4,  8, 11,  0,  7, 4, m1, rp3s           ; [p3] -p7 -p4 +p3 +q3
 831     FILTER_UPDATE   m4, m5, m6, m7, [P2], %4,  8,  0,  1, 12, 4, m1,  "", rq4, [Q4], 1 ; [p2] -p7 -p3 +p2 +q4
 832     FILTER_UPDATE   m4, m5, m6, m7, [P1], %4,  8,  1,  2, 13, 4, m1,  "", rq5, [Q5], 1 ; [p1] -p7 -p2 +p1 +q5
 833     FILTER_UPDATE   m4, m5, m6, m7, [P0], %4,  8,  2,  3, 14, 4, m1,  "", rq6, [Q6], 1 ; [p0] -p7 -p1 +p0 +q6
 834     FILTER_UPDATE   m4, m5, m6, m7, [Q0], %4,  8,  3,  4, 15, 4, m1,  "", rq7, [Q7], 1 ; [q0] -p7 -p0 +q0 +q7
 835     FILTER_UPDATE   m4, m5, m6, m7, [Q1], %4,  9,  4,  5, 15, 4, m1,  ""            ; [q1] -p6 -q0 +q1 +q7
 836     FILTER_UPDATE   m4, m5, m6, m7, [Q2], %4, 10,  5,  6, 15, 4, m1,  ""            ; [q2] -p5 -q1 +q2 +q7
 837     FILTER_UPDATE   m4, m5, m6, m7, [Q3], %4, 11,  6,  7, 15, 4, m1,  ""            ; [q3] -p4 -q2 +q3 +q7
 838     FILTER_UPDATE   m4, m5, m6, m7, [Q4], %4,  0,  7, 12, 15, 4, m1, rq4s           ; [q4] -p3 -q3 +q4 +q7
 839     FILTER_UPDATE   m4, m5, m6, m7, [Q5], %4,  1, 12, 13, 15, 4, m1, rq5s           ; [q5] -p2 -q4 +q5 +q7
 840     FILTER_UPDATE   m4, m5, m6, m7, [Q6], %4,  2, 13, 14, 15, 4, m1, rq6s           ; [q6] -p1 -q5 +q6 +q7
 841 %endif
 842
 843 %ifidn %1, h
 844 %if %2 == 16
 845     mova                    m0, [P7]
 846     mova                    m1, [P6]
 847     mova                    m2, [P5]
 848     mova                    m3, [P4]
 849     mova                    m4, [P3]
 850     mova                    m5, [P2]
 851     mova                    m6, [P1]
 852     mova                    m7, [P0]
 853     mova                    m8, [Q0]
 854     mova                    m9, [Q1]
 855     mova                   m10, [Q2]
 856     mova                   m11, [Q3]
 857     mova                   m12, [Q4]
 858     mova                   m13, [Q5]
 859     mova                   m14, [Q6]
 860     mova                   m15, [Q7]
 861     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
 862     DEFINE_REAL_P7_TO_Q7
 863     movu  [P7],  m0
 864     movu  [P6],  m1
 865     movu  [P5],  m2
 866     movu  [P4],  m3
 867     movu  [P3],  m4
 868     movu  [P2],  m5
 869     movu  [P1],  m6
 870     movu  [P0],  m7
 871     movu  [Q0],  m8
 872     movu  [Q1],  m9
 873     movu  [Q2], m10
 874     movu  [Q3], m11
 875     movu  [Q4], m12
 876     movu  [Q5], m13
 877     movu  [Q6], m14
 878     movu  [Q7], m15
 879 %elif %2 == 44
 880     SWAP 0, 1   ; m0 = p1
 881     SWAP 1, 7   ; m1 = p0
 882     SWAP 2, 5   ; m2 = q0
 883     SWAP 3, 4   ; m3 = q1
 884     DEFINE_REAL_P7_TO_Q7 2
 885     SBUTTERFLY  bw, 0, 1, 4
 886     SBUTTERFLY  bw, 2, 3, 4
 887     SBUTTERFLY  wd, 0, 2, 4
 888     SBUTTERFLY  wd, 1, 3, 4
 889     movd  [P7], m0
 890     movd  [P3], m2
 891     movd  [Q0], m1
 892     movd  [Q4], m3
 893     psrldq  m0, 4
 894     psrldq  m1, 4
 895     psrldq  m2, 4
 896     psrldq  m3, 4
 897     movd  [P6], m0
 898     movd  [P2], m2
 899     movd  [Q1], m1
 900     movd  [Q5], m3
 901     psrldq  m0, 4
 902     psrldq  m1, 4
 903     psrldq  m2, 4
 904     psrldq  m3, 4
 905     movd  [P5], m0
 906     movd  [P1], m2
 907     movd  [Q2], m1
 908     movd  [Q6], m3
 909     psrldq  m0, 4
 910     psrldq  m1, 4
 911     psrldq  m2, 4
 912     psrldq  m3, 4
 913     movd  [P4], m0
 914     movd  [P0], m2
 915     movd  [Q3], m1
 916     movd  [Q7], m3
 917 %else
 918     ; the following code do a transpose of 8 full lines to 16 half
 919     ; lines (high part). It is inlined to avoid the need of a staging area
 920     mova                    m0, [P3]
 921     mova                    m1, [P2]
 922     mova                    m2, [P1]
 923     mova                    m3, [P0]
 924     mova                    m4, [Q0]
 925     mova                    m5, [Q1]
 926     mova                    m6, [Q2]
 927     mova                    m7, [Q3]
 928     DEFINE_REAL_P7_TO_Q7
 929     SBUTTERFLY  bw,  0,  1, 8
 930     SBUTTERFLY  bw,  2,  3, 8
 931     SBUTTERFLY  bw,  4,  5, 8
 932     SBUTTERFLY  bw,  6,  7, 8
 933     SBUTTERFLY  wd,  0,  2, 8
 934     SBUTTERFLY  wd,  1,  3, 8
 935     SBUTTERFLY  wd,  4,  6, 8
 936     SBUTTERFLY  wd,  5,  7, 8
 937     SBUTTERFLY  dq,  0,  4, 8
 938     SBUTTERFLY  dq,  1,  5, 8
 939     SBUTTERFLY  dq,  2,  6, 8
 940     SBUTTERFLY  dq,  3,  7, 8
 941     movh   [P7], m0
 942     movhps [P6], m0
 943     movh   [Q0], m1
 944     movhps [Q1], m1
 945     movh   [P3], m2
 946     movhps [P2], m2
 947     movh   [Q4], m3
 948     movhps [Q5], m3
 949     movh   [P5], m4
 950     movhps [P4], m4
 951     movh   [Q2], m5
 952     movhps [Q3], m5
 953     movh   [P1], m6
 954     movhps [P0], m6
 955     movh   [Q6], m7
 956     movhps [Q7], m7
 957 %endif
 958 %endif
 959
 960     RET
 961 %endmacro
 962
 963 %macro LPF_16_VH 4
 964 INIT_XMM %4
 965 LOOPFILTER v, %1, %2,   0, %3
 966 %if ARCH_X86_64
 967 LOOPFILTER h, %1, %2, 256, %3
 968 %endif
 969 %endmacro
 970
 971 %macro LPF_16_VH_ALL_OPTS 2-3 0
 972 LPF_16_VH %1, %2, %3, sse2
 973 LPF_16_VH %1, %2, %3, ssse3
 974 LPF_16_VH %1, %2, %3, avx
 975 %endmacro
 976
 977 LPF_16_VH_ALL_OPTS 16, 512, 32
 978 LPF_16_VH_ALL_OPTS 44,   0,  0
 979 LPF_16_VH_ALL_OPTS 48, 256, 16
 980 LPF_16_VH_ALL_OPTS 84, 256, 16
 981 LPF_16_VH_ALL_OPTS 88, 256, 16