git.sesse.net Git - ffmpeg/blob - libavcodec/x86/vp9lpf.asm

   1 ;******************************************************************************
   2 ;* VP9 loop filter SIMD optimizations
   3 ;*
   4 ;* Copyright (C) 2013-2014 Clément Bœsch <u pkh me>
   5 ;*
   6 ;* This file is part of FFmpeg.
   7 ;*
   8 ;* FFmpeg is free software; you can redistribute it and/or
   9 ;* modify it under the terms of the GNU Lesser General Public
  10 ;* License as published by the Free Software Foundation; either
  11 ;* version 2.1 of the License, or (at your option) any later version.
  12 ;*
  13 ;* FFmpeg is distributed in the hope that it will be useful,
  14 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;* Lesser General Public License for more details.
  17 ;*
  18 ;* You should have received a copy of the GNU Lesser General Public
  19 ;* License along with FFmpeg; if not, write to the Free Software
  20 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  21 ;******************************************************************************
  22
  23 %if ARCH_X86_64
  24
  25 %include "libavutil/x86/x86util.asm"
  26
  27 SECTION_RODATA
  28
  29 cextern pb_3
  30 cextern pb_80
  31
  32 pb_4:   times 16 db 0x04
  33 pb_10:  times 16 db 0x10
  34 pb_40:  times 16 db 0x40
  35 pb_81:  times 16 db 0x81
  36 pb_f8:  times 16 db 0xf8
  37 pb_fe:  times 16 db 0xfe
  38
  39 pw_4:   times  8 dw 4
  40 pw_8:   times  8 dw 8
  41
  42 ; with mix functions, two 8-bit thresholds are stored in a 16-bit storage,
  43 ; the following mask is used to splat both in the same register
  44 mask_mix: times 8 db 0
  45           times 8 db 1
  46
  47 mask_mix84: times 8 db 0xff
  48             times 8 db 0x00
  49 mask_mix48: times 8 db 0x00
  50             times 8 db 0xff
  51
  52 SECTION .text
  53
  54 ; %1 = abs(%2-%3)
  55 %macro ABSSUB 4 ; dst, src1 (RO), src2 (RO), tmp
  56     psubusb             %1, %3, %2
  57     psubusb             %4, %2, %3
  58     por                 %1, %4
  59 %endmacro
  60
  61 ; %1 = %1<=%2
  62 %macro CMP_LTE 3-4 ; src/dst, cmp, tmp, pb_80
  63 %if %0 == 4
  64     pxor                %1, %4
  65 %endif
  66     pcmpgtb             %3, %2, %1          ; cmp > src?
  67     pcmpeqb             %1, %2              ; cmp == src? XXX: avoid this with a -1/+1 well placed?
  68     por                 %1, %3              ; cmp >= src?
  69 %endmacro
  70
  71 ; %1 = abs(%2-%3) <= %4
  72 %macro ABSSUB_CMP 6-7 [pb_80]; dst, src1, src2, cmp, tmp1, tmp2, [pb_80]
  73     ABSSUB              %1, %2, %3, %6      ; dst = abs(src1-src2)
  74     CMP_LTE             %1, %4, %6, %7      ; dst <= cmp
  75 %endmacro
  76
  77 %macro MASK_APPLY 4 ; %1=new_data/dst %2=old_data %3=mask %4=tmp
  78     pand                %1, %3              ; new &= mask
  79     pandn               %4, %3, %2          ; tmp = ~mask & old
  80     por                 %1, %4              ; new&mask | old&~mask
  81 %endmacro
  82
  83 %macro FILTER_SUBx2_ADDx2 8 ; %1=dst %2=h/l %3=cache %4=sub1 %5=sub2 %6=add1 %7=add2 %8=rshift
  84     punpck%2bw          %3, %4, m0
  85     psubw               %1, %3
  86     punpck%2bw          %3, %5, m0
  87     psubw               %1, %3
  88     punpck%2bw          %3, %6, m0
  89     paddw               %1, %3
  90     punpck%2bw          %3, %7, m0
  91     paddw               %1, %3
  92     mova                %3, %1
  93     psraw               %1, %8
  94 %endmacro
  95
  96 %macro FILTER_INIT 7-8 ; tmp1, tmp2, cacheL, cacheH, dstp, filterid, [source]
  97     FILTER%6_INIT       %1, l, %3
  98     FILTER%6_INIT       %2, h, %4
  99     packuswb            %1, %2
 100 %if %0 == 8
 101     MASK_APPLY          %1, %8, %7, %2
 102 %else
 103     MASK_APPLY          %1, %5, %7, %2
 104 %endif
 105     mova                %5, %1
 106 %endmacro
 107
 108 %macro FILTER_UPDATE 11-14 ; tmp1, tmp2, cacheL, cacheH, dstp, -, -, +, +, rshift, [source], [preload reg + value]
 109 %if %0 == 13 ; no source + preload
 110     mova                %12, %13
 111 %elif %0 == 14 ; source + preload
 112     mova                %13, %14
 113 %endif
 114     FILTER_SUBx2_ADDx2  %1, l, %3, %6, %7, %8, %9, %10
 115     FILTER_SUBx2_ADDx2  %2, h, %4, %6, %7, %8, %9, %10
 116     packuswb            %1, %2
 117 %if %0 == 12 || %0 == 14
 118     MASK_APPLY          %1, %12, %11, %2
 119 %else
 120     MASK_APPLY          %1, %5, %11, %2
 121 %endif
 122     mova                %5, %1
 123 %endmacro
 124
 125 %macro SRSHIFT3B_2X 4 ; reg1, reg2, [pb_10], tmp
 126     mova                %4, [pb_f8]
 127     pand                %1, %4
 128     pand                %2, %4
 129     psrlq               %1, 3
 130     psrlq               %2, 3
 131     pxor                %1, %3
 132     pxor                %2, %3
 133     psubb               %1, %3
 134     psubb               %2, %3
 135 %endmacro
 136
 137 %macro EXTRACT_POS_NEG 3 ; i8, neg, pos
 138     pxor                %3, %3
 139     pxor                %2, %2
 140     pcmpgtb             %3, %1                          ; i8 < 0 mask
 141     psubb               %2, %1                          ; neg values (only the originally - will be kept)
 142     pand                %2, %3                          ; negative values of i8 (but stored as +)
 143     pandn               %3, %1                          ; positive values of i8
 144 %endmacro
 145
 146 ; clip_u8(u8 + i8)
 147 %macro SIGN_ADD 5 ; dst, u8, i8, tmp1, tmp2
 148     EXTRACT_POS_NEG     %3, %4, %5
 149     psubusb             %1, %2, %4                      ; sub the negatives
 150     paddusb             %1, %5                          ; add the positives
 151 %endmacro
 152
 153 ; clip_u8(u8 - i8)
 154 %macro SIGN_SUB 5 ; dst, u8, i8, tmp1, tmp2
 155     EXTRACT_POS_NEG     %3, %4, %5
 156     psubusb             %1, %2, %5                      ; sub the positives
 157     paddusb             %1, %4                          ; add the negatives
 158 %endmacro
 159
 160 %macro FILTER6_INIT 3 ; %1=dst %2=h/l %3=cache
 161     punpck%2bw          %3, m14, m0                     ; p3: B->W
 162     mova                %1, %3                          ; p3
 163     paddw               %1, %3                          ; p3*2
 164     paddw               %1, %3                          ; p3*3
 165     punpck%2bw          %3, m15, m0                     ; p2: B->W
 166     paddw               %1, %3                          ; p3*3 + p2
 167     paddw               %1, %3                          ; p3*3 + p2*2
 168     punpck%2bw          %3, m10, m0                     ; p1: B->W
 169     paddw               %1, %3                          ; p3*3 + p2*2 + p1
 170     punpck%2bw          %3, m11, m0                     ; p0: B->W
 171     paddw               %1, %3                          ; p3*3 + p2*2 + p1 + p0
 172     punpck%2bw          %3, m12, m0                     ; q0: B->W
 173     paddw               %1, %3                          ; p3*3 + p2*2 + p1 + p0 + q0
 174     paddw               %1, [pw_4]                      ; p3*3 + p2*2 + p1 + p0 + q0 + 4
 175     mova                %3, %1                          ; base for next line (cache)
 176     psraw               %1, 3                           ; (p3*3 + p2*2 + p1 + p0 + q0 + 4) >> 3
 177 %endmacro
 178
 179 %macro FILTER14_INIT 3 ; %1=dst %2=h/l %3=cache
 180     punpck%2bw          %1, m2, m0                      ; p7: B->W
 181     mova                %3, %1
 182     psllw               %1, 3                           ; p7*8
 183     psubw               %1, %3                          ; p7*7
 184     punpck%2bw          %3, m3, m0                      ; p6: B->W
 185     paddw               %1, %3                          ; p7*7 + p6
 186     paddw               %1, %3                          ; p7*7 + p6*2
 187     punpck%2bw          %3, m8, m0                      ; p5: B->W
 188     paddw               %1, %3                          ; p7*7 + p6*2 + p5
 189     punpck%2bw          %3, m9, m0                      ; p4: B->W
 190     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + p4
 191     punpck%2bw          %3, m14, m0                     ; p3: B->W
 192     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + p4 + p3
 193     punpck%2bw          %3, m15, m0                     ; p2: B->W
 194     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + .. + p2
 195     punpck%2bw          %3, m10, m0                     ; p1: B->W
 196     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + .. + p1
 197     punpck%2bw          %3, m11, m0                     ; p0: B->W
 198     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + .. + p0
 199     punpck%2bw          %3, m12, m0                     ; q0: B->W
 200     paddw               %1, %3                          ; p7*7 + p6*2 + p5 + .. + p0 + q0
 201     paddw               %1, [pw_8]                      ; p7*7 + p6*2 + p5 + .. + p0 + q0 + 8
 202     mova                %3, %1                          ; base for next line (cache)
 203     psraw               %1, 4                           ; (p7*7 + p6*2 + p5 + .. + p0 + q0 + 8) >> 4
 204 %endmacro
 205
 206 %macro TRANSPOSE16x16B 17
 207     mova %17, m%16
 208     SBUTTERFLY bw,  %1,  %2,  %16
 209     SBUTTERFLY bw,  %3,  %4,  %16
 210     SBUTTERFLY bw,  %5,  %6,  %16
 211     SBUTTERFLY bw,  %7,  %8,  %16
 212     SBUTTERFLY bw,  %9,  %10, %16
 213     SBUTTERFLY bw,  %11, %12, %16
 214     SBUTTERFLY bw,  %13, %14, %16
 215     mova m%16,  %17
 216     mova  %17, m%14
 217     SBUTTERFLY bw,  %15, %16, %14
 218     SBUTTERFLY wd,  %1,  %3,  %14
 219     SBUTTERFLY wd,  %2,  %4,  %14
 220     SBUTTERFLY wd,  %5,  %7,  %14
 221     SBUTTERFLY wd,  %6,  %8,  %14
 222     SBUTTERFLY wd,  %9,  %11, %14
 223     SBUTTERFLY wd,  %10, %12, %14
 224     SBUTTERFLY wd,  %13, %15, %14
 225     mova m%14,  %17
 226     mova  %17, m%12
 227     SBUTTERFLY wd,  %14, %16, %12
 228     SBUTTERFLY dq,  %1,  %5,  %12
 229     SBUTTERFLY dq,  %2,  %6,  %12
 230     SBUTTERFLY dq,  %3,  %7,  %12
 231     SBUTTERFLY dq,  %4,  %8,  %12
 232     SBUTTERFLY dq,  %9,  %13, %12
 233     SBUTTERFLY dq,  %10, %14, %12
 234     SBUTTERFLY dq,  %11, %15, %12
 235     mova m%12, %17
 236     mova  %17, m%8
 237     SBUTTERFLY dq,  %12, %16, %8
 238     SBUTTERFLY qdq, %1,  %9,  %8
 239     SBUTTERFLY qdq, %2,  %10, %8
 240     SBUTTERFLY qdq, %3,  %11, %8
 241     SBUTTERFLY qdq, %4,  %12, %8
 242     SBUTTERFLY qdq, %5,  %13, %8
 243     SBUTTERFLY qdq, %6,  %14, %8
 244     SBUTTERFLY qdq, %7,  %15, %8
 245     mova m%8, %17
 246     mova %17, m%1
 247     SBUTTERFLY qdq, %8,  %16, %1
 248     mova m%1, %17
 249     SWAP %2,  %9
 250     SWAP %3,  %5
 251     SWAP %4,  %13
 252     SWAP %6,  %11
 253     SWAP %8,  %15
 254     SWAP %12, %14
 255 %endmacro
 256
 257 ; transpose 16 half lines (high part) to 8 full centered lines
 258 %macro TRANSPOSE16x8B 16
 259     punpcklbw   m%1,  m%2
 260     punpcklbw   m%3,  m%4
 261     punpcklbw   m%5,  m%6
 262     punpcklbw   m%7,  m%8
 263     punpcklbw   m%9,  m%10
 264     punpcklbw   m%11, m%12
 265     punpcklbw   m%13, m%14
 266     punpcklbw   m%15, m%16
 267     SBUTTERFLY  wd,  %1,  %3,  %2
 268     SBUTTERFLY  wd,  %5,  %7,  %2
 269     SBUTTERFLY  wd,  %9,  %11, %2
 270     SBUTTERFLY  wd,  %13, %15, %2
 271     SBUTTERFLY  dq,  %1,  %5,  %2
 272     SBUTTERFLY  dq,  %3,  %7,  %2
 273     SBUTTERFLY  dq,  %9,  %13, %2
 274     SBUTTERFLY  dq,  %11, %15, %2
 275     SBUTTERFLY  qdq, %1,  %9,  %2
 276     SBUTTERFLY  qdq, %3,  %11, %2
 277     SBUTTERFLY  qdq, %5,  %13, %2
 278     SBUTTERFLY  qdq, %7,  %15, %2
 279     SWAP %5, %1
 280     SWAP %6, %9
 281     SWAP %7, %1
 282     SWAP %8, %13
 283     SWAP %9, %3
 284     SWAP %10, %11
 285     SWAP %11, %1
 286     SWAP %12, %15
 287 %endmacro
 288
 289 %macro DEFINE_REAL_P7_TO_Q7 0-1 0
 290 %define P7 dst1q + 2*mstrideq  + %1
 291 %define P6 dst1q +   mstrideq  + %1
 292 %define P5 dst1q               + %1
 293 %define P4 dst1q +    strideq  + %1
 294 %define P3 dstq  + 4*mstrideq  + %1
 295 %define P2 dstq  +   mstride3q + %1
 296 %define P1 dstq  + 2*mstrideq  + %1
 297 %define P0 dstq  +   mstrideq  + %1
 298 %define Q0 dstq                + %1
 299 %define Q1 dstq  +   strideq   + %1
 300 %define Q2 dstq  + 2*strideq   + %1
 301 %define Q3 dstq  +   stride3q  + %1
 302 %define Q4 dstq  + 4*strideq   + %1
 303 %define Q5 dst2q + mstrideq    + %1
 304 %define Q6 dst2q               + %1
 305 %define Q7 dst2q +  strideq    + %1
 306 %endmacro
 307
 308 %macro SPLATB_MASK 2
 309 %if cpuflag(ssse3)
 310     pshufb     %1, %2
 311 %else
 312     punpcklbw  %1, %1
 313     punpcklqdq %1, %1
 314     pshuflw    %1, %1, 0
 315     pshufhw    %1, %1, 0x55
 316 %endif
 317 %endmacro
 318
 319 %macro LOOPFILTER 2 ; %1=v/h %2=size1
 320     lea mstrideq, [strideq]
 321     neg mstrideq
 322
 323     lea stride3q, [strideq+2*strideq]
 324     mov mstride3q, stride3q
 325     neg mstride3q
 326
 327 %ifidn %1, h
 328 %if %2 > 16
 329 %define movx movh
 330     lea dstq, [dstq + 8*strideq - 4]
 331 %else
 332 %define movx movu
 333     lea dstq, [dstq + 8*strideq - 8] ; go from top center (h pos) to center left (v pos)
 334 %endif
 335 %endif
 336
 337     lea dst1q, [dstq + 2*mstride3q]                         ; dst1q = &dst[stride * -6]
 338     lea dst2q, [dstq + 2* stride3q]                         ; dst2q = &dst[stride * +6]
 339
 340     DEFINE_REAL_P7_TO_Q7
 341
 342 %ifidn %1, h
 343     movx                    m0, [P7]
 344     movx                    m1, [P6]
 345     movx                    m2, [P5]
 346     movx                    m3, [P4]
 347     movx                    m4, [P3]
 348     movx                    m5, [P2]
 349     movx                    m6, [P1]
 350     movx                    m7, [P0]
 351     movx                    m8, [Q0]
 352     movx                    m9, [Q1]
 353     movx                   m10, [Q2]
 354     movx                   m11, [Q3]
 355     movx                   m12, [Q4]
 356     movx                   m13, [Q5]
 357     movx                   m14, [Q6]
 358     movx                   m15, [Q7]
 359 %define P7 rsp +   0
 360 %define P6 rsp +  16
 361 %define P5 rsp +  32
 362 %define P4 rsp +  48
 363 %define P3 rsp +  64
 364 %define P2 rsp +  80
 365 %define P1 rsp +  96
 366 %define P0 rsp + 112
 367 %define Q0 rsp + 128
 368 %define Q1 rsp + 144
 369 %define Q2 rsp + 160
 370 %define Q3 rsp + 176
 371 %define Q4 rsp + 192
 372 %define Q5 rsp + 208
 373 %define Q6 rsp + 224
 374 %define Q7 rsp + 240
 375
 376 %if %2 == 16
 377     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
 378     mova           [P7],  m0
 379     mova           [P6],  m1
 380     mova           [P5],  m2
 381     mova           [P4],  m3
 382 %else
 383     TRANSPOSE16x8B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15
 384 %endif
 385     mova           [P3],  m4
 386     mova           [P2],  m5
 387     mova           [P1],  m6
 388     mova           [P0],  m7
 389     mova           [Q0],  m8
 390     mova           [Q1],  m9
 391     mova           [Q2], m10
 392     mova           [Q3], m11
 393 %if %2 == 16
 394     mova           [Q4], m12
 395     mova           [Q5], m13
 396     mova           [Q6], m14
 397     mova           [Q7], m15
 398 %endif
 399 %endif
 400
 401     ; calc fm mask
 402 %if %2 == 16
 403 %if cpuflag(ssse3)
 404     pxor                m0, m0
 405 %endif
 406     SPLATB_REG          m2, I, m0                       ; I I I I ...
 407     SPLATB_REG          m3, E, m0                       ; E E E E ...
 408 %else
 409 %if cpuflag(ssse3)
 410     mova                m0, [mask_mix]
 411 %endif
 412     movd                m2, Id
 413     movd                m3, Ed
 414     SPLATB_MASK         m2, m0
 415     SPLATB_MASK         m3, m0
 416 %endif
 417     mova                m0, [pb_80]
 418     pxor                m2, m0
 419     pxor                m3, m0
 420 %ifidn %1, v
 421     mova                m8, [P3]
 422     mova                m9, [P2]
 423     mova               m10, [P1]
 424     mova               m11, [P0]
 425     mova               m12, [Q0]
 426     mova               m13, [Q1]
 427     mova               m14, [Q2]
 428     mova               m15, [Q3]
 429 %else
 430     SWAP                 8,  4, 12
 431     SWAP                 9,  5, 13
 432     SWAP                10,  6, 14
 433     SWAP                11,  7, 15
 434 %endif
 435     ABSSUB_CMP          m5,  m8,  m9, m2, m6, m7, m0    ; m5 = abs(p3-p2) <= I
 436     ABSSUB_CMP          m1,  m9, m10, m2, m6, m7, m0    ; m1 = abs(p2-p1) <= I
 437     pand                m5, m1
 438     ABSSUB_CMP          m1, m10, m11, m2, m6, m7, m0    ; m1 = abs(p1-p0) <= I
 439     pand                m5, m1
 440     ABSSUB_CMP          m1, m12, m13, m2, m6, m7, m0    ; m1 = abs(q1-q0) <= I
 441     pand                m5, m1
 442     ABSSUB_CMP          m1, m13, m14, m2, m6, m7, m0    ; m1 = abs(q2-q1) <= I
 443     pand                m5, m1
 444     ABSSUB_CMP          m1, m14, m15, m2, m6, m7, m0    ; m1 = abs(q3-q2) <= I
 445     pand                m5, m1
 446     ABSSUB              m1, m11, m12, m7                ; abs(p0-q0)
 447     paddusb             m1, m1                          ; abs(p0-q0) * 2
 448     ABSSUB              m2, m10, m13, m7                ; abs(p1-q1)
 449     pand                m2, [pb_fe]                     ; drop lsb so shift can work
 450     psrlq               m2, 1                           ; abs(p1-q1)/2
 451     paddusb             m1, m2                          ; abs(p0-q0)*2 + abs(p1-q1)/2
 452     pxor                m1, m0
 453     pcmpgtb             m4, m3, m1                      ; E > X?
 454     pcmpeqb             m3, m1                          ; E == X?
 455     por                 m3, m4                          ; E >= X?
 456     pand                m3, m5                          ; fm final value
 457
 458     ; (m3: fm, m8..15: p3 p2 p1 p0 q0 q1 q2 q3)
 459     ; calc flat8in (if not 44_16) and hev masks
 460     mova                m6, [pb_81]                     ; [1 1 1 1 ...] ^ 0x80
 461 %if %2 != 44
 462     ABSSUB_CMP          m2, m8, m11, m6, m4, m5         ; abs(p3 - p0) <= 1
 463     mova                m8, [pb_80]
 464     ABSSUB_CMP          m1, m9, m11, m6, m4, m5, m8     ; abs(p2 - p0) <= 1
 465     pand                m2, m1
 466     ABSSUB              m4, m10, m11, m5                ; abs(p1 - p0)
 467 %if %2 == 16
 468 %if cpuflag(ssse3)
 469     pxor                m0, m0
 470 %endif
 471     SPLATB_REG          m7, H, m0                       ; H H H H ...
 472 %else
 473     movd                m7, Hd
 474     SPLATB_MASK         m7, [mask_mix]
 475 %endif
 476     pxor                m7, m8
 477     pxor                m4, m8
 478     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
 479     CMP_LTE             m4, m6, m5                      ; abs(p1 - p0) <= 1
 480     pand                m2, m4                          ; (flat8in)
 481     ABSSUB              m4, m13, m12, m1                ; abs(q1 - q0)
 482     pxor                m4, m8
 483     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
 484     por                 m0, m5                          ; hev final value
 485     CMP_LTE             m4, m6, m5                      ; abs(q1 - q0) <= 1
 486     pand                m2, m4                          ; (flat8in)
 487     ABSSUB_CMP          m1, m14, m12, m6, m4, m5, m8    ; abs(q2 - q0) <= 1
 488     pand                m2, m1
 489     ABSSUB_CMP          m1, m15, m12, m6, m4, m5, m8    ; abs(q3 - q0) <= 1
 490     pand                m2, m1                          ; flat8in final value
 491 %if %2 == 84 || %2 == 48
 492     pand                m2, [mask_mix%2]
 493 %endif
 494 %else
 495     mova                m6, [pb_80]
 496     movd                m7, Hd
 497     SPLATB_MASK         m7, [mask_mix]
 498     pxor                m7, m6
 499     ABSSUB              m4, m10, m11, m1                ; abs(p1 - p0)
 500     pxor                m4, m6
 501     pcmpgtb             m0, m4, m7                      ; abs(p1 - p0) > H (1/2 hev condition)
 502     ABSSUB              m4, m13, m12, m1                ; abs(q1 - q0)
 503     pxor                m4, m6
 504     pcmpgtb             m5, m4, m7                      ; abs(q1 - q0) > H (2/2 hev condition)
 505     por                 m0, m5                          ; hev final value
 506 %endif
 507
 508 %if %2 == 16
 509     ; (m0: hev, m2: flat8in, m3: fm, m6: pb_81, m9..15: p2 p1 p0 q0 q1 q2 q3)
 510     ; calc flat8out mask
 511     mova                m8, [P7]
 512     mova                m9, [P6]
 513     ABSSUB_CMP          m1, m8, m11, m6, m4, m5         ; abs(p7 - p0) <= 1
 514     ABSSUB_CMP          m7, m9, m11, m6, m4, m5         ; abs(p6 - p0) <= 1
 515     pand                m1, m7
 516     mova                m8, [P5]
 517     mova                m9, [P4]
 518     ABSSUB_CMP          m7, m8, m11, m6, m4, m5         ; abs(p5 - p0) <= 1
 519     pand                m1, m7
 520     ABSSUB_CMP          m7, m9, m11, m6, m4, m5         ; abs(p4 - p0) <= 1
 521     pand                m1, m7
 522     mova                m14, [Q4]
 523     mova                m15, [Q5]
 524     ABSSUB_CMP          m7, m14, m12, m6, m4, m5        ; abs(q4 - q0) <= 1
 525     pand                m1, m7
 526     ABSSUB_CMP          m7, m15, m12, m6, m4, m5        ; abs(q5 - q0) <= 1
 527     pand                m1, m7
 528     mova                m14, [Q6]
 529     mova                m15, [Q7]
 530     ABSSUB_CMP          m7, m14, m12, m6, m4, m5        ; abs(q4 - q0) <= 1
 531     pand                m1, m7
 532     ABSSUB_CMP          m7, m15, m12, m6, m4, m5        ; abs(q5 - q0) <= 1
 533     pand                m1, m7                          ; flat8out final value
 534 %endif
 535
 536     ; if (fm) {
 537     ;     if (out && in) filter_14()
 538     ;     else if (in)   filter_6()
 539     ;     else if (hev)  filter_2()
 540     ;     else           filter_4()
 541     ; }
 542     ;
 543     ; f14:                                                                            fm &  out &  in
 544     ; f6:  fm & ~f14 & in        => fm & ~(out & in) & in                          => fm & ~out &  in
 545     ; f2:  fm & ~f14 & ~f6 & hev => fm & ~(out & in) & ~(~out & in) & hev          => fm &  ~in &  hev
 546     ; f4:  fm & ~f14 & ~f6 & ~f2 => fm & ~(out & in) & ~(~out & in) & ~(~in & hev) => fm &  ~in & ~hev
 547
 548     ; (m0: hev, [m1: flat8out], [m2: flat8in], m3: fm, m8..15: p5 p4 p1 p0 q0 q1 q6 q7)
 549     ; filter2()
 550 %if %2 != 44
 551     mova                m6, [pb_80]                     ; already in m6 if 44_16
 552 %endif
 553     pxor                m15, m12, m6                    ; q0 ^ 0x80
 554     pxor                m14, m11, m6                    ; p0 ^ 0x80
 555     psubsb              m15, m14                        ; (signed) q0 - p0
 556     pxor                m4, m10, m6                     ; p1 ^ 0x80
 557     pxor                m5, m13, m6                     ; q1 ^ 0x80
 558     psubsb              m4, m5                          ; (signed) p1 - q1
 559     paddsb              m4, m15                         ;   (q0 - p0) + (p1 - q1)
 560     paddsb              m4, m15                         ; 2*(q0 - p0) + (p1 - q1)
 561     paddsb              m4, m15                         ; 3*(q0 - p0) + (p1 - q1)
 562     paddsb              m6, m4, [pb_4]                  ; m6: f1 = clip(f + 4, 127)
 563     paddsb              m4, [pb_3]                      ; m4: f2 = clip(f + 3, 127)
 564     mova                m14, [pb_10]                    ; will be reused in filter4()
 565     SRSHIFT3B_2X        m6, m4, m14, m7                 ; f1 and f2 sign byte shift by 3
 566     SIGN_SUB            m7, m12, m6, m5, m9             ; m7 = q0 - f1
 567     SIGN_ADD            m8, m11, m4, m5, m9             ; m8 = p0 + f2
 568 %if %2 != 44
 569     pandn               m6, m2, m3                      ;  ~mask(in) & mask(fm)
 570     pand                m6, m0                          ; (~mask(in) & mask(fm)) & mask(hev)
 571 %else
 572     pand                m6, m3, m0
 573 %endif
 574     MASK_APPLY          m7, m12, m6, m5                 ; m7 = filter2(q0) & mask / we write it in filter4()
 575     MASK_APPLY          m8, m11, m6, m5                 ; m8 = filter2(p0) & mask / we write it in filter4()
 576
 577     ; (m0: hev, [m1: flat8out], [m2: flat8in], m3: fm, m7..m8: q0' p0', m10..13: p1 p0 q0 q1, m14: pb_10, m15: q0-p0)
 578     ; filter4()
 579     mova                m4, m15
 580     paddsb              m15, m4                         ; 2 * (q0 - p0)
 581     paddsb              m15, m4                         ; 3 * (q0 - p0)
 582     paddsb              m6, m15, [pb_4]                 ; m6:  f1 = clip(f + 4, 127)
 583     paddsb              m15, [pb_3]                     ; m15: f2 = clip(f + 3, 127)
 584     SRSHIFT3B_2X        m6, m15, m14, m9                ; f1 and f2 sign byte shift by 3
 585 %if %2 != 44
 586 %define p0tmp m7
 587 %define q0tmp m9
 588     pandn               m5, m2, m3                      ;               ~mask(in) & mask(fm)
 589     pandn               m0, m5                          ; ~mask(hev) & (~mask(in) & mask(fm))
 590 %else
 591 %define p0tmp m1
 592 %define q0tmp m2
 593     pandn               m0, m3
 594 %endif
 595     SIGN_SUB            q0tmp, m12, m6, m4, m14         ; q0 - f1
 596     MASK_APPLY          q0tmp, m7, m0, m5               ; filter4(q0) & mask
 597     mova                [Q0], q0tmp
 598     SIGN_ADD            p0tmp, m11, m15, m4, m14        ; p0 + f2
 599     MASK_APPLY          p0tmp, m8, m0, m5               ; filter4(p0) & mask
 600     mova                [P0], p0tmp
 601     paddb               m6, [pb_80]                     ;
 602     pxor                m8, m8                          ;   f=(f1+1)>>1
 603     pavgb               m6, m8                          ;
 604     psubb               m6, [pb_40]                     ;
 605     SIGN_ADD            m7, m10, m6, m8, m9             ; p1 + f
 606     SIGN_SUB            m4, m13, m6, m8, m9             ; q1 - f
 607     MASK_APPLY          m7, m10, m0, m14                ; m7 = filter4(p1)
 608     MASK_APPLY          m4, m13, m0, m14                ; m4 = filter4(q1)
 609     mova                [P1], m7
 610     mova                [Q1], m4
 611
 612     ; ([m1: flat8out], m2: flat8in, m3: fm, m10..13: p1 p0 q0 q1)
 613     ; filter6()
 614 %if %2 != 44
 615     pxor                m0, m0
 616 %if %2 > 16
 617     pand                m3, m2
 618 %else
 619     pand                m2, m3                          ;               mask(fm) & mask(in)
 620     pandn               m3, m1, m2                      ; ~mask(out) & (mask(fm) & mask(in))
 621 %endif
 622     mova               m14, [P3]
 623     mova               m15, [P2]
 624     mova                m8, [Q2]
 625     mova                m9, [Q3]
 626     FILTER_INIT         m4, m5, m6, m7, [P2], 6,                     m3, m15    ; [p2]
 627     FILTER_UPDATE       m6, m7, m4, m5, [P1], m14, m15, m10, m13, 3, m3         ; [p1] -p3 -p2 +p1 +q1
 628     FILTER_UPDATE       m4, m5, m6, m7, [P0], m14, m10, m11,  m8, 3, m3         ; [p0] -p3 -p1 +p0 +q2
 629     FILTER_UPDATE       m6, m7, m4, m5, [Q0], m14, m11, m12,  m9, 3, m3         ; [q0] -p3 -p0 +q0 +q3
 630     FILTER_UPDATE       m4, m5, m6, m7, [Q1], m15, m12, m13,  m9, 3, m3         ; [q1] -p2 -q0 +q1 +q3
 631     FILTER_UPDATE       m6, m7, m4, m5, [Q2], m10, m13,  m8,  m9, 3, m3,  m8    ; [q2] -p1 -q1 +q2 +q3
 632 %endif
 633
 634     ; (m0: 0, [m1: flat8out], m2: fm & flat8in, m8..15: q2 q3 p1 p0 q0 q1 p3 p2)
 635     ; filter14()
 636     ;
 637     ;                            m2  m3  m8  m9 m14 m15 m10 m11 m12 m13
 638     ;
 639     ;                                    q2  q3  p3  p2  p1  p0  q0  q1
 640     ; p6  -7                     p7  p6  p5  p4   .   .   .   .   .
 641     ; p5  -6  -p7 -p6 +p5 +q1     .   .   .                           .
 642     ; p4  -5  -p7 -p5 +p4 +q2     .       .   .                      q2
 643     ; p3  -4  -p7 -p4 +p3 +q3     .           .   .                  q3
 644     ; p2  -3  -p7 -p3 +p2 +q4     .               .   .              q4
 645     ; p1  -2  -p7 -p2 +p1 +q5     .                   .   .          q5
 646     ; p0  -1  -p7 -p1 +p0 +q6     .                       .   .      q6
 647     ; q0  +0  -p7 -p0 +q0 +q7     .                           .   .  q7
 648     ; q1  +1  -p6 -q0 +q1 +q7    q1   .                           .   .
 649     ; q2  +2  -p5 -q1 +q2 +q7     .  q2   .                           .
 650     ; q3  +3  -p4 -q2 +q3 +q7         .  q3   .                       .
 651     ; q4  +4  -p3 -q3 +q4 +q7             .  q4   .                   .
 652     ; q5  +5  -p2 -q4 +q5 +q7                 .  q5   .               .
 653     ; q6  +6  -p1 -q5 +q6 +q7                     .  q6   .           .
 654
 655 %if %2 == 16
 656     pand            m1, m2                                                              ; mask(out) & (mask(fm) & mask(in))
 657     mova            m2, [P7]
 658     mova            m3, [P6]
 659     mova            m8, [P5]
 660     mova            m9, [P4]
 661     FILTER_INIT     m4, m5, m6, m7, [P6],  14,                   m1,  m3
 662     FILTER_UPDATE   m6, m7, m4, m5, [P5],  m2,  m3,  m8, m13, 4, m1,  m8                ; [p5] -p7 -p6 +p5 +q1
 663     FILTER_UPDATE   m4, m5, m6, m7, [P4],  m2,  m8,  m9, m13, 4, m1,  m9, m13, [Q2]     ; [p4] -p7 -p5 +p4 +q2
 664     FILTER_UPDATE   m6, m7, m4, m5, [P3],  m2,  m9, m14, m13, 4, m1, m14, m13, [Q3]     ; [p3] -p7 -p4 +p3 +q3
 665     FILTER_UPDATE   m4, m5, m6, m7, [P2],  m2, m14, m15, m13, 4, m1,      m13, [Q4]     ; [p2] -p7 -p3 +p2 +q4
 666     FILTER_UPDATE   m6, m7, m4, m5, [P1],  m2, m15, m10, m13, 4, m1,      m13, [Q5]     ; [p1] -p7 -p2 +p1 +q5
 667     FILTER_UPDATE   m4, m5, m6, m7, [P0],  m2, m10, m11, m13, 4, m1,      m13, [Q6]     ; [p0] -p7 -p1 +p0 +q6
 668     FILTER_UPDATE   m6, m7, m4, m5, [Q0],  m2, m11, m12, m13, 4, m1,      m13, [Q7]     ; [q0] -p7 -p0 +q0 +q7
 669     FILTER_UPDATE   m4, m5, m6, m7, [Q1],  m3, m12,  m2, m13, 4, m1,       m2, [Q1]     ; [q1] -p6 -q0 +q1 +q7
 670     FILTER_UPDATE   m6, m7, m4, m5, [Q2],  m8,  m2,  m3, m13, 4, m1,       m3, [Q2]     ; [q2] -p5 -q1 +q2 +q7
 671     FILTER_UPDATE   m4, m5, m6, m7, [Q3],  m9,  m3,  m8, m13, 4, m1,  m8,  m8, [Q3]     ; [q3] -p4 -q2 +q3 +q7
 672     FILTER_UPDATE   m6, m7, m4, m5, [Q4], m14,  m8,  m9, m13, 4, m1,  m9,  m9, [Q4]     ; [q4] -p3 -q3 +q4 +q7
 673     FILTER_UPDATE   m4, m5, m6, m7, [Q5], m15,  m9, m14, m13, 4, m1, m14, m14, [Q5]     ; [q5] -p2 -q4 +q5 +q7
 674     FILTER_UPDATE   m6, m7, m4, m5, [Q6], m10, m14, m15, m13, 4, m1, m15, m15, [Q6]     ; [q6] -p1 -q5 +q6 +q7
 675 %endif
 676
 677 %ifidn %1, h
 678 %if %2 == 16
 679     mova                    m0, [P7]
 680     mova                    m1, [P6]
 681     mova                    m2, [P5]
 682     mova                    m3, [P4]
 683     mova                    m4, [P3]
 684     mova                    m5, [P2]
 685     mova                    m6, [P1]
 686     mova                    m7, [P0]
 687     mova                    m8, [Q0]
 688     mova                    m9, [Q1]
 689     mova                   m10, [Q2]
 690     mova                   m11, [Q3]
 691     mova                   m12, [Q4]
 692     mova                   m13, [Q5]
 693     mova                   m14, [Q6]
 694     mova                   m15, [Q7]
 695     TRANSPOSE16x16B 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, [rsp]
 696     DEFINE_REAL_P7_TO_Q7
 697     movu  [P7],  m0
 698     movu  [P6],  m1
 699     movu  [P5],  m2
 700     movu  [P4],  m3
 701     movu  [P3],  m4
 702     movu  [P2],  m5
 703     movu  [P1],  m6
 704     movu  [P0],  m7
 705     movu  [Q0],  m8
 706     movu  [Q1],  m9
 707     movu  [Q2], m10
 708     movu  [Q3], m11
 709     movu  [Q4], m12
 710     movu  [Q5], m13
 711     movu  [Q6], m14
 712     movu  [Q7], m15
 713 %elif %2 == 44
 714     SWAP 0, 7   ; m0 = p1
 715     SWAP 3, 4   ; m3 = q1
 716     DEFINE_REAL_P7_TO_Q7 2
 717     SBUTTERFLY  bw, 0, 1, 8
 718     SBUTTERFLY  bw, 2, 3, 8
 719     SBUTTERFLY  wd, 0, 2, 8
 720     SBUTTERFLY  wd, 1, 3, 8
 721     SBUTTERFLY  dq, 0, 4, 8
 722     SBUTTERFLY  dq, 1, 5, 8
 723     SBUTTERFLY  dq, 2, 6, 8
 724     SBUTTERFLY  dq, 3, 7, 8
 725     movd  [P7], m0
 726     punpckhqdq m0, m8
 727     movd  [P6], m0
 728     movd  [Q0], m1
 729     punpckhqdq  m1, m9
 730     movd  [Q1], m1
 731     movd  [P3], m2
 732     punpckhqdq  m2, m10
 733     movd  [P2], m2
 734     movd  [Q4], m3
 735     punpckhqdq m3, m11
 736     movd  [Q5], m3
 737     movd  [P5], m4
 738     punpckhqdq m4, m12
 739     movd  [P4], m4
 740     movd  [Q2], m5
 741     punpckhqdq m5, m13
 742     movd  [Q3], m5
 743     movd  [P1], m6
 744     punpckhqdq m6, m14
 745     movd  [P0], m6
 746     movd  [Q6], m7
 747     punpckhqdq m7, m8
 748     movd  [Q7], m7
 749 %else
 750     ; the following code do a transpose of 8 full lines to 16 half
 751     ; lines (high part). It is inlined to avoid the need of a staging area
 752     mova                    m0, [P3]
 753     mova                    m1, [P2]
 754     mova                    m2, [P1]
 755     mova                    m3, [P0]
 756     mova                    m4, [Q0]
 757     mova                    m5, [Q1]
 758     mova                    m6, [Q2]
 759     mova                    m7, [Q3]
 760     DEFINE_REAL_P7_TO_Q7
 761     SBUTTERFLY  bw,  0,  1, 8
 762     SBUTTERFLY  bw,  2,  3, 8
 763     SBUTTERFLY  bw,  4,  5, 8
 764     SBUTTERFLY  bw,  6,  7, 8
 765     SBUTTERFLY  wd,  0,  2, 8
 766     SBUTTERFLY  wd,  1,  3, 8
 767     SBUTTERFLY  wd,  4,  6, 8
 768     SBUTTERFLY  wd,  5,  7, 8
 769     SBUTTERFLY  dq,  0,  4, 8
 770     SBUTTERFLY  dq,  1,  5, 8
 771     SBUTTERFLY  dq,  2,  6, 8
 772     SBUTTERFLY  dq,  3,  7, 8
 773     movh  [P7], m0
 774     punpckhqdq m0, m8
 775     movh  [P6], m0
 776     movh  [Q0], m1
 777     punpckhqdq  m1, m9
 778     movh  [Q1], m1
 779     movh  [P3], m2
 780     punpckhqdq  m2, m10
 781     movh  [P2], m2
 782     movh  [Q4], m3
 783     punpckhqdq m3, m11
 784     movh  [Q5], m3
 785     movh  [P5], m4
 786     punpckhqdq m4, m12
 787     movh  [P4], m4
 788     movh  [Q2], m5
 789     punpckhqdq m5, m13
 790     movh  [Q3], m5
 791     movh  [P1], m6
 792     punpckhqdq m6, m14
 793     movh  [P0], m6
 794     movh  [Q6], m7
 795     punpckhqdq m7, m8
 796     movh  [Q7], m7
 797 %endif
 798 %endif
 799
 800     RET
 801 %endmacro
 802
 803 %macro LPF_16_VH 2
 804 INIT_XMM %2
 805 cglobal vp9_loop_filter_v_%1_16, 5,10,16,      dst, stride, E, I, H, mstride, dst1, dst2, stride3, mstride3
 806     LOOPFILTER v, %1
 807 cglobal vp9_loop_filter_h_%1_16, 5,10,16, 256, dst, stride, E, I, H, mstride, dst1, dst2, stride3, mstride3
 808     LOOPFILTER h, %1
 809 %endmacro
 810
 811 %macro LPF_16_VH_ALL_OPTS 1
 812 LPF_16_VH %1, sse2
 813 LPF_16_VH %1, ssse3
 814 LPF_16_VH %1, avx
 815 %endmacro
 816
 817 LPF_16_VH_ALL_OPTS 16
 818 LPF_16_VH_ALL_OPTS 44
 819 LPF_16_VH_ALL_OPTS 48
 820 LPF_16_VH_ALL_OPTS 84
 821 LPF_16_VH_ALL_OPTS 88
 822
 823 %endif ; x86-64