git.sesse.net Git - ffmpeg/blob - libavfilter/x86/af_afir.asm

   1 ;*****************************************************************************
   2 ;* x86-optimized functions for afir filter
   3 ;* Copyright (c) 2017 Paul B Mahol
   4 ;*
   5 ;* This file is part of FFmpeg.
   6 ;*
   7 ;* FFmpeg is free software; you can redistribute it and/or
   8 ;* modify it under the terms of the GNU Lesser General Public
   9 ;* License as published by the Free Software Foundation; either
  10 ;* version 2.1 of the License, or (at your option) any later version.
  11 ;*
  12 ;* FFmpeg is distributed in the hope that it will be useful,
  13 ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;* Lesser General Public License for more details.
  16 ;*
  17 ;* You should have received a copy of the GNU Lesser General Public
  18 ;* License along with FFmpeg; if not, write to the Free Software
  19 ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  20 ;******************************************************************************
  21
  22 %include "libavutil/x86/x86util.asm"
  23
  24 SECTION .text
  25
  26 ;------------------------------------------------------------------------------
  27 ; void ff_fcmul_add(float *sum, const float *t, const float *c, int len)
  28 ;------------------------------------------------------------------------------
  29
  30 INIT_XMM sse3
  31 cglobal fcmul_add, 4,4,6, sum, t, c, len
  32     shl       lend, 3
  33     add       lend, mmsize*2
  34     add         tq, lenq
  35     add         cq, lenq
  36     add       sumq, lenq
  37     neg       lenq
  38 ALIGN 16
  39 .loop:
  40     movsldup  m0, [tq + lenq]
  41     movsldup  m3, [tq + lenq+mmsize]
  42     movaps    m1, [cq + lenq]
  43     movaps    m4, [cq + lenq+mmsize]
  44     mulps     m0, m1
  45     mulps     m3, m4
  46     shufps    m1, m1, 0xb1
  47     shufps    m4, m4, 0xb1
  48     movshdup  m2, [tq + lenq]
  49     movshdup  m5, [tq + lenq+mmsize]
  50     mulps     m2, m1
  51     mulps     m5, m4
  52     addsubps  m0, m2
  53     addsubps  m3, m5
  54     addps     m0, [sumq + lenq]
  55     addps     m3, [sumq + lenq+mmsize]
  56     movaps    [sumq + lenq], m0
  57     movaps    [sumq + lenq+mmsize], m3
  58     add       lenq, mmsize*2
  59     jl .loop
  60     REP_RET