git.sesse.net Git - ffmpeg/blob - libavutil/x86/x86inc.asm

   1 ;*****************************************************************************
   2 ;* x86inc.asm: x264asm abstraction layer
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2005-2012 x264 project
   5 ;*
   6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
   7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
   8 ;*          Jason Garrett-Glaser <darkshikari@gmail.com>
   9 ;*          Henrik Gramner <hengar-6@student.ltu.se>
  10 ;*
  11 ;* Permission to use, copy, modify, and/or distribute this software for any
  12 ;* purpose with or without fee is hereby granted, provided that the above
  13 ;* copyright notice and this permission notice appear in all copies.
  14 ;*
  15 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  16 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  17 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  18 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  19 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  20 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  21 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  22 ;*****************************************************************************
  23
  24 ; This is a header file for the x264ASM assembly language, which uses
  25 ; NASM/YASM syntax combined with a large number of macros to provide easy
  26 ; abstraction between different calling conventions (x86_32, win64, linux64).
  27 ; It also has various other useful features to simplify writing the kind of
  28 ; DSP functions that are most often used in x264.
  29
  30 ; Unlike the rest of x264, this file is available under an ISC license, as it
  31 ; has significant usefulness outside of x264 and we want it to be available
  32 ; to the largest audience possible.  Of course, if you modify it for your own
  33 ; purposes to add a new feature, we strongly encourage contributing a patch
  34 ; as this feature might be useful for others as well.  Send patches or ideas
  35 ; to x264-devel@videolan.org .
  36
  37 %ifndef program_name
  38     %define program_name x264
  39 %endif
  40
  41 %define WIN64  0
  42 %define UNIX64 0
  43 %if ARCH_X86_64
  44     %ifidn __OUTPUT_FORMAT__,win32
  45         %define WIN64  1
  46     %elifidn __OUTPUT_FORMAT__,win64
  47         %define WIN64  1
  48     %else
  49         %define UNIX64 1
  50     %endif
  51 %endif
  52
  53 %ifdef PREFIX
  54     %define mangle(x) _ %+ x
  55 %else
  56     %define mangle(x) x
  57 %endif
  58
  59 ; Name of the .rodata section.
  60 ; Kludge: Something on OS X fails to align .rodata even given an align attribute,
  61 ; so use a different read-only section.
  62 %macro SECTION_RODATA 0-1 16
  63     %ifidn __OUTPUT_FORMAT__,macho64
  64         SECTION .text align=%1
  65     %elifidn __OUTPUT_FORMAT__,macho
  66         SECTION .text align=%1
  67         fakegot:
  68     %elifidn __OUTPUT_FORMAT__,aout
  69         section .text
  70     %else
  71         SECTION .rodata align=%1
  72     %endif
  73 %endmacro
  74
  75 ; aout does not support align=
  76 %macro SECTION_TEXT 0-1 16
  77     %ifidn __OUTPUT_FORMAT__,aout
  78         SECTION .text
  79     %else
  80         SECTION .text align=%1
  81     %endif
  82 %endmacro
  83
  84 %if WIN64
  85     %define PIC
  86 %elif ARCH_X86_64 == 0
  87 ; x86_32 doesn't require PIC.
  88 ; Some distros prefer shared objects to be PIC, but nothing breaks if
  89 ; the code contains a few textrels, so we'll skip that complexity.
  90     %undef PIC
  91 %endif
  92 %ifdef PIC
  93     default rel
  94 %endif
  95
  96 %macro CPUNOP 1
  97     %if HAVE_CPUNOP
  98         CPU %1
  99     %endif
 100 %endmacro
 101
 102 ; Always use long nops (reduces 0x90 spam in disassembly on x86_32)
 103 CPUNOP amdnop
 104
 105 ; Macros to eliminate most code duplication between x86_32 and x86_64:
 106 ; Currently this works only for leaf functions which load all their arguments
 107 ; into registers at the start, and make no other use of the stack. Luckily that
 108 ; covers most of x264's asm.
 109
 110 ; PROLOGUE:
 111 ; %1 = number of arguments. loads them from stack if needed.
 112 ; %2 = number of registers used. pushes callee-saved regs if needed.
 113 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
 114 ; %4 = (optional) stack size to be allocated. If not aligned (x86-32 ICC 10.x,
 115 ;      MSVC or YMM), the stack will be manually aligned (to 16 or 32 bytes),
 116 ;      and an extra register will be allocated to hold the original stack
 117 ;      pointer (to not invalidate r0m etc.). To prevent the use of an extra
 118 ;      register as stack pointer, request a negative stack size.
 119 ; %4+/%5+ = list of names to define to registers
 120 ; PROLOGUE can also be invoked by adding the same options to cglobal
 121
 122 ; e.g.
 123 ; cglobal foo, 2,3,0, dst, src, tmp
 124 ; declares a function (foo), taking two args (dst and src) and one local variable (tmp)
 125
 126 ; TODO Some functions can use some args directly from the stack. If they're the
 127 ; last args then you can just not declare them, but if they're in the middle
 128 ; we need more flexible macro.
 129
 130 ; RET:
 131 ; Pops anything that was pushed by PROLOGUE, and returns.
 132
 133 ; REP_RET:
 134 ; Same, but if it doesn't pop anything it becomes a 2-byte ret, for athlons
 135 ; which are slow when a normal ret follows a branch.
 136
 137 ; registers:
 138 ; rN and rNq are the native-size register holding function argument N
 139 ; rNd, rNw, rNb are dword, word, and byte size
 140 ; rNh is the high 8 bits of the word size
 141 ; rNm is the original location of arg N (a register or on the stack), dword
 142 ; rNmp is native size
 143
 144 %macro DECLARE_REG 2-3
 145     %define r%1q %2
 146     %define r%1d %2d
 147     %define r%1w %2w
 148     %define r%1b %2b
 149     %define r%1h %2h
 150     %define %2q %2
 151     %if %0 == 2
 152         %define r%1m  %2d
 153         %define r%1mp %2
 154     %elif ARCH_X86_64 ; memory
 155         %define r%1m [rstk + stack_offset + %3]
 156         %define r%1mp qword r %+ %1 %+ m
 157     %else
 158         %define r%1m [rstk + stack_offset + %3]
 159         %define r%1mp dword r %+ %1 %+ m
 160     %endif
 161     %define r%1  %2
 162 %endmacro
 163
 164 %macro DECLARE_REG_SIZE 3
 165     %define r%1q r%1
 166     %define e%1q r%1
 167     %define r%1d e%1
 168     %define e%1d e%1
 169     %define r%1w %1
 170     %define e%1w %1
 171     %define r%1h %3
 172     %define e%1h %3
 173     %define r%1b %2
 174     %define e%1b %2
 175 %if ARCH_X86_64 == 0
 176     %define r%1  e%1
 177 %endif
 178 %endmacro
 179
 180 DECLARE_REG_SIZE ax, al, ah
 181 DECLARE_REG_SIZE bx, bl, bh
 182 DECLARE_REG_SIZE cx, cl, ch
 183 DECLARE_REG_SIZE dx, dl, dh
 184 DECLARE_REG_SIZE si, sil, null
 185 DECLARE_REG_SIZE di, dil, null
 186 DECLARE_REG_SIZE bp, bpl, null
 187
 188 ; t# defines for when per-arch register allocation is more complex than just function arguments
 189
 190 %macro DECLARE_REG_TMP 1-*
 191     %assign %%i 0
 192     %rep %0
 193         CAT_XDEFINE t, %%i, r%1
 194         %assign %%i %%i+1
 195         %rotate 1
 196     %endrep
 197 %endmacro
 198
 199 %macro DECLARE_REG_TMP_SIZE 0-*
 200     %rep %0
 201         %define t%1q t%1 %+ q
 202         %define t%1d t%1 %+ d
 203         %define t%1w t%1 %+ w
 204         %define t%1h t%1 %+ h
 205         %define t%1b t%1 %+ b
 206         %rotate 1
 207     %endrep
 208 %endmacro
 209
 210 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14
 211
 212 %if ARCH_X86_64
 213     %define gprsize 8
 214 %else
 215     %define gprsize 4
 216 %endif
 217
 218 %macro PUSH 1
 219     push %1
 220     %ifidn rstk, rsp
 221         %assign stack_offset stack_offset+gprsize
 222     %endif
 223 %endmacro
 224
 225 %macro POP 1
 226     pop %1
 227     %ifidn rstk, rsp
 228         %assign stack_offset stack_offset-gprsize
 229     %endif
 230 %endmacro
 231
 232 %macro PUSH_IF_USED 1-*
 233     %rep %0
 234         %if %1 < regs_used
 235             PUSH r%1
 236         %endif
 237         %rotate 1
 238     %endrep
 239 %endmacro
 240
 241 %macro POP_IF_USED 1-*
 242     %rep %0
 243         %if %1 < regs_used
 244             pop r%1
 245         %endif
 246         %rotate 1
 247     %endrep
 248 %endmacro
 249
 250 %macro LOAD_IF_USED 1-*
 251     %rep %0
 252         %if %1 < num_args
 253             mov r%1, r %+ %1 %+ mp
 254         %endif
 255         %rotate 1
 256     %endrep
 257 %endmacro
 258
 259 %macro SUB 2
 260     sub %1, %2
 261     %ifidn %1, rstk
 262         %assign stack_offset stack_offset+(%2)
 263     %endif
 264 %endmacro
 265
 266 %macro ADD 2
 267     add %1, %2
 268     %ifidn %1, rstk
 269         %assign stack_offset stack_offset-(%2)
 270     %endif
 271 %endmacro
 272
 273 %macro movifnidn 2
 274     %ifnidn %1, %2
 275         mov %1, %2
 276     %endif
 277 %endmacro
 278
 279 %macro movsxdifnidn 2
 280     %ifnidn %1, %2
 281         movsxd %1, %2
 282     %endif
 283 %endmacro
 284
 285 %macro ASSERT 1
 286     %if (%1) == 0
 287         %error assert failed
 288     %endif
 289 %endmacro
 290
 291 %macro DEFINE_ARGS 0-*
 292     %ifdef n_arg_names
 293         %assign %%i 0
 294         %rep n_arg_names
 295             CAT_UNDEF arg_name %+ %%i, q
 296             CAT_UNDEF arg_name %+ %%i, d
 297             CAT_UNDEF arg_name %+ %%i, w
 298             CAT_UNDEF arg_name %+ %%i, h
 299             CAT_UNDEF arg_name %+ %%i, b
 300             CAT_UNDEF arg_name %+ %%i, m
 301             CAT_UNDEF arg_name %+ %%i, mp
 302             CAT_UNDEF arg_name, %%i
 303             %assign %%i %%i+1
 304         %endrep
 305     %endif
 306
 307     %xdefine %%stack_offset stack_offset
 308     %undef stack_offset ; so that the current value of stack_offset doesn't get baked in by xdefine
 309     %assign %%i 0
 310     %rep %0
 311         %xdefine %1q r %+ %%i %+ q
 312         %xdefine %1d r %+ %%i %+ d
 313         %xdefine %1w r %+ %%i %+ w
 314         %xdefine %1h r %+ %%i %+ h
 315         %xdefine %1b r %+ %%i %+ b
 316         %xdefine %1m r %+ %%i %+ m
 317         %xdefine %1mp r %+ %%i %+ mp
 318         CAT_XDEFINE arg_name, %%i, %1
 319         %assign %%i %%i+1
 320         %rotate 1
 321     %endrep
 322     %xdefine stack_offset %%stack_offset
 323     %assign n_arg_names %0
 324 %endmacro
 325
 326 %macro ALLOC_STACK 1-2 0 ; stack_size, n_xmm_regs (for win64 only)
 327     %ifnum %1
 328         %if %1 != 0
 329             %assign %%stack_alignment ((mmsize + 15) & ~15)
 330             %assign stack_size %1
 331             %if stack_size < 0
 332                 %assign stack_size -stack_size
 333             %endif
 334             %assign xmm_regs_used %2
 335             %if mmsize <= 16 && HAVE_ALIGNED_STACK
 336                 %assign stack_size_padded stack_size + %%stack_alignment - gprsize - (stack_offset & (%%stack_alignment - 1))
 337                 %if xmm_regs_used > 6
 338                     %assign stack_size_padded stack_size_padded + (xmm_regs_used - 6) * 16
 339                 %endif
 340                 SUB rsp, stack_size_padded
 341             %else
 342                 %assign reg_num (regs_used - 1)
 343                 %xdefine rstk r %+ reg_num
 344                 ; align stack, and save original stack location directly above
 345                 ; it, i.e. in [rsp+stack_size_padded], so we can restore the
 346                 ; stack in a single instruction (i.e. mov rsp, rstk or mov
 347                 ; rsp, [rsp+stack_size_padded])
 348                 mov  rstk, rsp
 349                 %assign stack_size_padded stack_size
 350                 %if xmm_regs_used > 6
 351                     %assign stack_size_padded stack_size_padded + (xmm_regs_used - 6) * 16
 352                 %endif
 353                 %if %1 < 0 ; need to store rsp on stack
 354                     sub  rsp, gprsize+stack_size_padded
 355                     and  rsp, ~(%%stack_alignment-1)
 356                     %xdefine rstkm [rsp+stack_size_padded]
 357                     mov rstkm, rstk
 358                 %else ; can keep rsp in rstk during whole function
 359                     sub  rsp, stack_size_padded
 360                     and  rsp, ~(%%stack_alignment-1)
 361                     %xdefine rstkm rstk
 362                 %endif
 363             %endif
 364             %if xmm_regs_used > 6
 365                 WIN64_PUSH_XMM
 366             %endif
 367         %endif
 368     %endif
 369 %endmacro
 370
 371 %macro SETUP_STACK_POINTER 1
 372     %ifnum %1
 373         %if %1 != 0 && (HAVE_ALIGNED_STACK == 0 || mmsize == 32)
 374             %if %1 > 0
 375                 %assign regs_used (regs_used + 1)
 376             %elif ARCH_X86_64 && regs_used == num_args && num_args <= 4 + UNIX64 * 2
 377                 %warning "Stack pointer will overwrite register argument"
 378             %endif
 379         %endif
 380     %endif
 381 %endmacro
 382
 383 %macro DEFINE_ARGS_INTERNAL 3+
 384     %ifnum %2
 385         DEFINE_ARGS %3
 386     %elif %1 == 4
 387         DEFINE_ARGS %2
 388     %elif %1 > 4
 389         DEFINE_ARGS %2, %3
 390     %endif
 391 %endmacro
 392
 393 %if WIN64 ; Windows x64 ;=================================================
 394
 395 DECLARE_REG 0,  rcx
 396 DECLARE_REG 1,  rdx
 397 DECLARE_REG 2,  R8
 398 DECLARE_REG 3,  R9
 399 DECLARE_REG 4,  R10, 40
 400 DECLARE_REG 5,  R11, 48
 401 DECLARE_REG 6,  rax, 56
 402 DECLARE_REG 7,  rdi, 64
 403 DECLARE_REG 8,  rsi, 72
 404 DECLARE_REG 9,  rbx, 80
 405 DECLARE_REG 10, rbp, 88
 406 DECLARE_REG 11, R12, 96
 407 DECLARE_REG 12, R13, 104
 408 DECLARE_REG 13, R14, 112
 409 DECLARE_REG 14, R15, 120
 410
 411 %macro PROLOGUE 2-5+ 0 ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
 412     %assign num_args %1
 413     %assign regs_used %2
 414     SETUP_STACK_POINTER %4
 415     ASSERT regs_used >= num_args
 416     ASSERT regs_used <= 15
 417     PUSH_IF_USED 7, 8, 9, 10, 11, 12, 13, 14
 418     %assign xmm_regs_used 0
 419     ALLOC_STACK %4, %3
 420     %if mmsize != 8 && stack_size == 0
 421         WIN64_SPILL_XMM %3
 422     %endif
 423     LOAD_IF_USED 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14
 424     DEFINE_ARGS_INTERNAL %0, %4, %5
 425 %endmacro
 426
 427 %macro WIN64_PUSH_XMM 0
 428     %assign %%i xmm_regs_used
 429     %rep (xmm_regs_used-6)
 430         %assign %%i %%i-1
 431         movdqa [rsp + (%%i-6)*16 + stack_size + (~stack_offset&8)], xmm %+ %%i
 432     %endrep
 433 %endmacro
 434
 435 %macro WIN64_SPILL_XMM 1
 436     %assign xmm_regs_used %1
 437     ASSERT xmm_regs_used <= 16
 438     %if xmm_regs_used > 6
 439         SUB rsp, (xmm_regs_used-6)*16+16
 440         WIN64_PUSH_XMM
 441     %endif
 442 %endmacro
 443
 444 %macro WIN64_RESTORE_XMM_INTERNAL 1
 445     %if xmm_regs_used > 6
 446         %assign %%i xmm_regs_used
 447         %rep (xmm_regs_used-6)
 448             %assign %%i %%i-1
 449             movdqa xmm %+ %%i, [%1 + (%%i-6)*16+stack_size+(~stack_offset&8)]
 450         %endrep
 451         %if stack_size_padded == 0
 452             add %1, (xmm_regs_used-6)*16+16
 453         %endif
 454     %endif
 455     %if stack_size_padded > 0
 456         %if stack_size > 0 && (mmsize == 32 || HAVE_ALIGNED_STACK == 0)
 457             mov rsp, rstkm
 458         %else
 459             add %1, stack_size_padded
 460         %endif
 461     %endif
 462 %endmacro
 463
 464 %macro WIN64_RESTORE_XMM 1
 465     WIN64_RESTORE_XMM_INTERNAL %1
 466     %assign stack_offset (stack_offset-stack_size_padded)
 467     %assign xmm_regs_used 0
 468 %endmacro
 469
 470 %define has_epilogue regs_used > 7 || xmm_regs_used > 6 || mmsize == 32 || stack_size > 0
 471
 472 %macro RET 0
 473     WIN64_RESTORE_XMM_INTERNAL rsp
 474     POP_IF_USED 14, 13, 12, 11, 10, 9, 8, 7
 475 %if mmsize == 32
 476     vzeroupper
 477 %endif
 478     ret
 479 %endmacro
 480
 481 %elif ARCH_X86_64 ; *nix x64 ;=============================================
 482
 483 DECLARE_REG 0,  rdi
 484 DECLARE_REG 1,  rsi
 485 DECLARE_REG 2,  rdx
 486 DECLARE_REG 3,  rcx
 487 DECLARE_REG 4,  R8
 488 DECLARE_REG 5,  R9
 489 DECLARE_REG 6,  rax, 8
 490 DECLARE_REG 7,  R10, 16
 491 DECLARE_REG 8,  R11, 24
 492 DECLARE_REG 9,  rbx, 32
 493 DECLARE_REG 10, rbp, 40
 494 DECLARE_REG 11, R12, 48
 495 DECLARE_REG 12, R13, 56
 496 DECLARE_REG 13, R14, 64
 497 DECLARE_REG 14, R15, 72
 498
 499 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
 500     %assign num_args %1
 501     %assign regs_used %2
 502     SETUP_STACK_POINTER %4
 503     ASSERT regs_used >= num_args
 504     ASSERT regs_used <= 15
 505     PUSH_IF_USED 9, 10, 11, 12, 13, 14
 506     ALLOC_STACK %4
 507     LOAD_IF_USED 6, 7, 8, 9, 10, 11, 12, 13, 14
 508     DEFINE_ARGS_INTERNAL %0, %4, %5
 509 %endmacro
 510
 511 %define has_epilogue regs_used > 9 || mmsize == 32 || stack_size > 0
 512
 513 %macro RET 0
 514 %if stack_size_padded > 0
 515 %if mmsize == 32 || HAVE_ALIGNED_STACK == 0
 516     mov rsp, rstkm
 517 %else
 518     add rsp, stack_size_padded
 519 %endif
 520 %endif
 521     POP_IF_USED 14, 13, 12, 11, 10, 9
 522 %if mmsize == 32
 523     vzeroupper
 524 %endif
 525     ret
 526 %endmacro
 527
 528 %else ; X86_32 ;==============================================================
 529
 530 DECLARE_REG 0, eax, 4
 531 DECLARE_REG 1, ecx, 8
 532 DECLARE_REG 2, edx, 12
 533 DECLARE_REG 3, ebx, 16
 534 DECLARE_REG 4, esi, 20
 535 DECLARE_REG 5, edi, 24
 536 DECLARE_REG 6, ebp, 28
 537 %define rsp esp
 538
 539 %macro DECLARE_ARG 1-*
 540     %rep %0
 541         %define r%1m [rstk + stack_offset + 4*%1 + 4]
 542         %define r%1mp dword r%1m
 543         %rotate 1
 544     %endrep
 545 %endmacro
 546
 547 DECLARE_ARG 7, 8, 9, 10, 11, 12, 13, 14
 548
 549 %macro PROLOGUE 2-5+ ; #args, #regs, #xmm_regs, [stack_size,] arg_names...
 550     %assign num_args %1
 551     %assign regs_used %2
 552     %if regs_used > 7
 553         %assign regs_used 7
 554     %endif
 555     SETUP_STACK_POINTER %4
 556     ASSERT regs_used <= 7
 557     ASSERT regs_used >= num_args
 558     PUSH_IF_USED 3, 4, 5, 6
 559     ALLOC_STACK %4
 560     LOAD_IF_USED 0, 1, 2, 3, 4, 5, 6
 561     DEFINE_ARGS_INTERNAL %0, %4, %5
 562 %endmacro
 563
 564 %define has_epilogue regs_used > 3 || mmsize == 32 || stack_size > 0
 565
 566 %macro RET 0
 567 %if stack_size_padded > 0
 568 %if mmsize == 32 || HAVE_ALIGNED_STACK == 0
 569     mov rsp, rstkm
 570 %else
 571     add rsp, stack_size_padded
 572 %endif
 573 %endif
 574     POP_IF_USED 6, 5, 4, 3
 575 %if mmsize == 32
 576     vzeroupper
 577 %endif
 578     ret
 579 %endmacro
 580
 581 %endif ;======================================================================
 582
 583 %if WIN64 == 0
 584 %macro WIN64_SPILL_XMM 1
 585 %endmacro
 586 %macro WIN64_RESTORE_XMM 1
 587 %endmacro
 588 %macro WIN64_PUSH_XMM 0
 589 %endmacro
 590 %endif
 591
 592 %macro REP_RET 0
 593     %if has_epilogue
 594         RET
 595     %else
 596         rep ret
 597     %endif
 598 %endmacro
 599
 600 %macro TAIL_CALL 2 ; callee, is_nonadjacent
 601     %if has_epilogue
 602         call %1
 603         RET
 604     %elif %2
 605         jmp %1
 606     %endif
 607 %endmacro
 608
 609 ;=============================================================================
 610 ; arch-independent part
 611 ;=============================================================================
 612
 613 %assign function_align 16
 614
 615 ; Begin a function.
 616 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
 617 ; subsequent uses of the function name automatically refer to the mangled version.
 618 ; Appends cpuflags to the function name if cpuflags has been specified.
 619 %macro cglobal 1-2+ ; name, [PROLOGUE args]
 620 %if %0 == 1
 621     cglobal_internal %1 %+ SUFFIX
 622 %else
 623     cglobal_internal %1 %+ SUFFIX, %2
 624 %endif
 625 %endmacro
 626 %macro cglobal_internal 1-2+
 627     %ifndef cglobaled_%1
 628         %xdefine %1 mangle(program_name %+ _ %+ %1)
 629         %xdefine %1.skip_prologue %1 %+ .skip_prologue
 630         CAT_XDEFINE cglobaled_, %1, 1
 631     %endif
 632     %xdefine current_function %1
 633     %ifidn __OUTPUT_FORMAT__,elf
 634         global %1:function hidden
 635     %else
 636         global %1
 637     %endif
 638     align function_align
 639     %1:
 640     RESET_MM_PERMUTATION ; not really needed, but makes disassembly somewhat nicer
 641     %xdefine rstk rsp
 642     %assign stack_offset 0
 643     %assign stack_size 0
 644     %assign stack_size_padded 0
 645     %if %0 > 1
 646         PROLOGUE %2
 647     %endif
 648 %endmacro
 649
 650 %macro cextern 1
 651     %xdefine %1 mangle(program_name %+ _ %+ %1)
 652     CAT_XDEFINE cglobaled_, %1, 1
 653     extern %1
 654 %endmacro
 655
 656 ; like cextern, but without the prefix
 657 %macro cextern_naked 1
 658     %xdefine %1 mangle(%1)
 659     CAT_XDEFINE cglobaled_, %1, 1
 660     extern %1
 661 %endmacro
 662
 663 %macro const 2+
 664     %xdefine %1 mangle(program_name %+ _ %+ %1)
 665     global %1
 666     %1: %2
 667 %endmacro
 668
 669 ; This is needed for ELF, otherwise the GNU linker assumes the stack is
 670 ; executable by default.
 671 %ifidn __OUTPUT_FORMAT__,elf
 672 SECTION .note.GNU-stack noalloc noexec nowrite progbits
 673 %endif
 674
 675 ; cpuflags
 676
 677 %assign cpuflags_mmx      (1<<0)
 678 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
 679 %assign cpuflags_3dnow    (1<<2) | cpuflags_mmx
 680 %assign cpuflags_3dnowext (1<<3) | cpuflags_3dnow
 681 %assign cpuflags_sse      (1<<4) | cpuflags_mmx2
 682 %assign cpuflags_sse2     (1<<5) | cpuflags_sse
 683 %assign cpuflags_sse2slow (1<<6) | cpuflags_sse2
 684 %assign cpuflags_sse3     (1<<7) | cpuflags_sse2
 685 %assign cpuflags_ssse3    (1<<8) | cpuflags_sse3
 686 %assign cpuflags_sse4     (1<<9) | cpuflags_ssse3
 687 %assign cpuflags_sse42    (1<<10)| cpuflags_sse4
 688 %assign cpuflags_avx      (1<<11)| cpuflags_sse42
 689 %assign cpuflags_xop      (1<<12)| cpuflags_avx
 690 %assign cpuflags_fma4     (1<<13)| cpuflags_avx
 691 %assign cpuflags_avx2     (1<<14)| cpuflags_avx
 692 %assign cpuflags_fma3     (1<<15)| cpuflags_avx
 693
 694 %assign cpuflags_cache32  (1<<16)
 695 %assign cpuflags_cache64  (1<<17)
 696 %assign cpuflags_slowctz  (1<<18)
 697 %assign cpuflags_lzcnt    (1<<19)
 698 %assign cpuflags_misalign (1<<20)
 699 %assign cpuflags_aligned  (1<<21) ; not a cpu feature, but a function variant
 700 %assign cpuflags_atom     (1<<22)
 701 %assign cpuflags_bmi1     (1<<23)
 702 %assign cpuflags_bmi2     (1<<24)|cpuflags_bmi1
 703 %assign cpuflags_tbm      (1<<25)|cpuflags_bmi1
 704
 705 %define    cpuflag(x) ((cpuflags & (cpuflags_ %+ x)) == (cpuflags_ %+ x))
 706 %define notcpuflag(x) ((cpuflags & (cpuflags_ %+ x)) != (cpuflags_ %+ x))
 707
 708 ; Takes up to 2 cpuflags from the above list.
 709 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
 710 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
 711 %macro INIT_CPUFLAGS 0-2
 712     CPUNOP amdnop
 713     %if %0 >= 1
 714         %xdefine cpuname %1
 715         %assign cpuflags cpuflags_%1
 716         %if %0 >= 2
 717             %xdefine cpuname %1_%2
 718             %assign cpuflags cpuflags | cpuflags_%2
 719         %endif
 720         %xdefine SUFFIX _ %+ cpuname
 721         %if cpuflag(avx)
 722             %assign avx_enabled 1
 723         %endif
 724         %if mmsize == 16 && notcpuflag(sse2)
 725             %define mova movaps
 726             %define movu movups
 727             %define movnta movntps
 728         %endif
 729         %if cpuflag(aligned)
 730             %define movu mova
 731         %elifidn %1, sse3
 732             %define movu lddqu
 733         %endif
 734         %if notcpuflag(mmx2)
 735             CPUNOP basicnop
 736         %endif
 737     %else
 738         %xdefine SUFFIX
 739         %undef cpuname
 740         %undef cpuflags
 741     %endif
 742 %endmacro
 743
 744 ; merge mmx and sse*
 745
 746 %macro CAT_XDEFINE 3
 747     %xdefine %1%2 %3
 748 %endmacro
 749
 750 %macro CAT_UNDEF 2
 751     %undef %1%2
 752 %endmacro
 753
 754 %macro INIT_MMX 0-1+
 755     %assign avx_enabled 0
 756     %define RESET_MM_PERMUTATION INIT_MMX %1
 757     %define mmsize 8
 758     %define num_mmregs 8
 759     %define mova movq
 760     %define movu movq
 761     %define movh movd
 762     %define movnta movntq
 763     %assign %%i 0
 764     %rep 8
 765     CAT_XDEFINE m, %%i, mm %+ %%i
 766     CAT_XDEFINE nmm, %%i, %%i
 767     %assign %%i %%i+1
 768     %endrep
 769     %rep 8
 770     CAT_UNDEF m, %%i
 771     CAT_UNDEF nmm, %%i
 772     %assign %%i %%i+1
 773     %endrep
 774     INIT_CPUFLAGS %1
 775 %endmacro
 776
 777 %macro INIT_XMM 0-1+
 778     %assign avx_enabled 0
 779     %define RESET_MM_PERMUTATION INIT_XMM %1
 780     %define mmsize 16
 781     %define num_mmregs 8
 782     %if ARCH_X86_64
 783     %define num_mmregs 16
 784     %endif
 785     %define mova movdqa
 786     %define movu movdqu
 787     %define movh movq
 788     %define movnta movntdq
 789     %assign %%i 0
 790     %rep num_mmregs
 791     CAT_XDEFINE m, %%i, xmm %+ %%i
 792     CAT_XDEFINE nxmm, %%i, %%i
 793     %assign %%i %%i+1
 794     %endrep
 795     INIT_CPUFLAGS %1
 796 %endmacro
 797
 798 %macro INIT_YMM 0-1+
 799     %assign avx_enabled 1
 800     %define RESET_MM_PERMUTATION INIT_YMM %1
 801     %define mmsize 32
 802     %define num_mmregs 8
 803     %if ARCH_X86_64
 804     %define num_mmregs 16
 805     %endif
 806     %define mova vmovaps
 807     %define movu vmovups
 808     %undef movh
 809     %define movnta vmovntps
 810     %assign %%i 0
 811     %rep num_mmregs
 812     CAT_XDEFINE m, %%i, ymm %+ %%i
 813     CAT_XDEFINE nymm, %%i, %%i
 814     %assign %%i %%i+1
 815     %endrep
 816     INIT_CPUFLAGS %1
 817 %endmacro
 818
 819 INIT_XMM
 820
 821 ; I often want to use macros that permute their arguments. e.g. there's no
 822 ; efficient way to implement butterfly or transpose or dct without swapping some
 823 ; arguments.
 824 ;
 825 ; I would like to not have to manually keep track of the permutations:
 826 ; If I insert a permutation in the middle of a function, it should automatically
 827 ; change everything that follows. For more complex macros I may also have multiple
 828 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
 829 ;
 830 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
 831 ; permutes its arguments. It's equivalent to exchanging the contents of the
 832 ; registers, except that this way you exchange the register names instead, so it
 833 ; doesn't cost any cycles.
 834
 835 %macro PERMUTE 2-* ; takes a list of pairs to swap
 836 %rep %0/2
 837     %xdefine tmp%2 m%2
 838     %xdefine ntmp%2 nm%2
 839     %rotate 2
 840 %endrep
 841 %rep %0/2
 842     %xdefine m%1 tmp%2
 843     %xdefine nm%1 ntmp%2
 844     %undef tmp%2
 845     %undef ntmp%2
 846     %rotate 2
 847 %endrep
 848 %endmacro
 849
 850 %macro SWAP 2-* ; swaps a single chain (sometimes more concise than pairs)
 851 %rep %0-1
 852 %ifdef m%1
 853     %xdefine tmp m%1
 854     %xdefine m%1 m%2
 855     %xdefine m%2 tmp
 856     CAT_XDEFINE n, m%1, %1
 857     CAT_XDEFINE n, m%2, %2
 858 %else
 859     ; If we were called as "SWAP m0,m1" rather than "SWAP 0,1" infer the original numbers here.
 860     ; Be careful using this mode in nested macros though, as in some cases there may be
 861     ; other copies of m# that have already been dereferenced and don't get updated correctly.
 862     %xdefine %%n1 n %+ %1
 863     %xdefine %%n2 n %+ %2
 864     %xdefine tmp m %+ %%n1
 865     CAT_XDEFINE m, %%n1, m %+ %%n2
 866     CAT_XDEFINE m, %%n2, tmp
 867     CAT_XDEFINE n, m %+ %%n1, %%n1
 868     CAT_XDEFINE n, m %+ %%n2, %%n2
 869 %endif
 870     %undef tmp
 871     %rotate 1
 872 %endrep
 873 %endmacro
 874
 875 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
 876 ; calls to that function will automatically load the permutation, so values can
 877 ; be returned in mmregs.
 878 %macro SAVE_MM_PERMUTATION 0-1
 879     %if %0
 880         %xdefine %%f %1_m
 881     %else
 882         %xdefine %%f current_function %+ _m
 883     %endif
 884     %assign %%i 0
 885     %rep num_mmregs
 886         CAT_XDEFINE %%f, %%i, m %+ %%i
 887     %assign %%i %%i+1
 888     %endrep
 889 %endmacro
 890
 891 %macro LOAD_MM_PERMUTATION 1 ; name to load from
 892     %ifdef %1_m0
 893         %assign %%i 0
 894         %rep num_mmregs
 895             CAT_XDEFINE m, %%i, %1_m %+ %%i
 896             CAT_XDEFINE n, m %+ %%i, %%i
 897         %assign %%i %%i+1
 898         %endrep
 899     %endif
 900 %endmacro
 901
 902 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
 903 %macro call 1
 904     call_internal %1 %+ SUFFIX, %1
 905 %endmacro
 906 %macro call_internal 2
 907     %xdefine %%i %2
 908     %ifndef cglobaled_%2
 909         %ifdef cglobaled_%1
 910             %xdefine %%i %1
 911         %endif
 912     %endif
 913     call %%i
 914     LOAD_MM_PERMUTATION %%i
 915 %endmacro
 916
 917 ; Substitutions that reduce instruction size but are functionally equivalent
 918 %macro add 2
 919     %ifnum %2
 920         %if %2==128
 921             sub %1, -128
 922         %else
 923             add %1, %2
 924         %endif
 925     %else
 926         add %1, %2
 927     %endif
 928 %endmacro
 929
 930 %macro sub 2
 931     %ifnum %2
 932         %if %2==128
 933             add %1, -128
 934         %else
 935             sub %1, %2
 936         %endif
 937     %else
 938         sub %1, %2
 939     %endif
 940 %endmacro
 941
 942 ;=============================================================================
 943 ; AVX abstraction layer
 944 ;=============================================================================
 945
 946 %assign i 0
 947 %rep 16
 948     %if i < 8
 949         CAT_XDEFINE sizeofmm, i, 8
 950     %endif
 951     CAT_XDEFINE sizeofxmm, i, 16
 952     CAT_XDEFINE sizeofymm, i, 32
 953 %assign i i+1
 954 %endrep
 955 %undef i
 956
 957 %macro CHECK_AVX_INSTR_EMU 3-*
 958     %xdefine %%opcode %1
 959     %xdefine %%dst %2
 960     %rep %0-2
 961         %ifidn %%dst, %3
 962             %error non-avx emulation of ``%%opcode'' is not supported
 963         %endif
 964         %rotate 1
 965     %endrep
 966 %endmacro
 967
 968 ;%1 == instruction
 969 ;%2 == 1 if float, 0 if int
 970 ;%3 == 1 if 4-operand (xmm, xmm, xmm, imm), 0 if 2- or 3-operand (xmm, xmm, xmm)
 971 ;%4 == number of operands given
 972 ;%5+: operands
 973 %macro RUN_AVX_INSTR 6-7+
 974     %ifid %6
 975         %define %%sizeofreg sizeof%6
 976     %elifid %5
 977         %define %%sizeofreg sizeof%5
 978     %else
 979         %define %%sizeofreg mmsize
 980     %endif
 981     %if %%sizeofreg==32
 982         %if %4>=3
 983             v%1 %5, %6, %7
 984         %else
 985             v%1 %5, %6
 986         %endif
 987     %else
 988         %if %%sizeofreg==8
 989             %define %%regmov movq
 990         %elif %2
 991             %define %%regmov movaps
 992         %else
 993             %define %%regmov movdqa
 994         %endif
 995
 996         %if %4>=3+%3
 997             %ifnidn %5, %6
 998                 %if avx_enabled && %%sizeofreg==16
 999                     v%1 %5, %6, %7
1000                 %else
1001                     CHECK_AVX_INSTR_EMU {%1 %5, %6, %7}, %5, %7
1002                     %%regmov %5, %6
1003                     %1 %5, %7
1004                 %endif
1005             %else
1006                 %1 %5, %7
1007             %endif
1008         %elif %4>=3
1009             %1 %5, %6, %7
1010         %else
1011             %1 %5, %6
1012         %endif
1013     %endif
1014 %endmacro
1015
1016 ; 3arg AVX ops with a memory arg can only have it in src2,
1017 ; whereas SSE emulation of 3arg prefers to have it in src1 (i.e. the mov).
1018 ; So, if the op is symmetric and the wrong one is memory, swap them.
1019 %macro RUN_AVX_INSTR1 8
1020     %assign %%swap 0
1021     %if avx_enabled
1022         %ifnid %6
1023             %assign %%swap 1
1024         %endif
1025     %elifnidn %5, %6
1026         %ifnid %7
1027             %assign %%swap 1
1028         %endif
1029     %endif
1030     %if %%swap && %3 == 0 && %8 == 1
1031         RUN_AVX_INSTR %1, %2, %3, %4, %5, %7, %6
1032     %else
1033         RUN_AVX_INSTR %1, %2, %3, %4, %5, %6, %7
1034     %endif
1035 %endmacro
1036
1037 ;%1 == instruction
1038 ;%2 == 1 if float, 0 if int
1039 ;%3 == 1 if 4-operand (xmm, xmm, xmm, imm), 0 if 2- or 3-operand (xmm, xmm, xmm)
1040 ;%4 == 1 if symmetric (i.e. doesn't matter which src arg is which), 0 if not
1041 %macro AVX_INSTR 4
1042     %macro %1 2-9 fnord, fnord, fnord, %1, %2, %3, %4
1043         %ifidn %3, fnord
1044             RUN_AVX_INSTR %6, %7, %8, 2, %1, %2
1045         %elifidn %4, fnord
1046             RUN_AVX_INSTR1 %6, %7, %8, 3, %1, %2, %3, %9
1047         %elifidn %5, fnord
1048             RUN_AVX_INSTR %6, %7, %8, 4, %1, %2, %3, %4
1049         %else
1050             RUN_AVX_INSTR %6, %7, %8, 5, %1, %2, %3, %4, %5
1051         %endif
1052     %endmacro
1053 %endmacro
1054
1055 AVX_INSTR addpd, 1, 0, 1
1056 AVX_INSTR addps, 1, 0, 1
1057 AVX_INSTR addsd, 1, 0, 1
1058 AVX_INSTR addss, 1, 0, 1
1059 AVX_INSTR addsubpd, 1, 0, 0
1060 AVX_INSTR addsubps, 1, 0, 0
1061 AVX_INSTR andpd, 1, 0, 1
1062 AVX_INSTR andps, 1, 0, 1
1063 AVX_INSTR andnpd, 1, 0, 0
1064 AVX_INSTR andnps, 1, 0, 0
1065 AVX_INSTR blendpd, 1, 0, 0
1066 AVX_INSTR blendps, 1, 0, 0
1067 AVX_INSTR blendvpd, 1, 0, 0
1068 AVX_INSTR blendvps, 1, 0, 0
1069 AVX_INSTR cmppd, 1, 0, 0
1070 AVX_INSTR cmpps, 1, 0, 0
1071 AVX_INSTR cmpsd, 1, 0, 0
1072 AVX_INSTR cmpss, 1, 0, 0
1073 AVX_INSTR cvtdq2ps, 1, 0, 0
1074 AVX_INSTR cvtpd2dq, 1, 0, 0
1075 AVX_INSTR cvtps2dq, 1, 0, 0
1076 AVX_INSTR divpd, 1, 0, 0
1077 AVX_INSTR divps, 1, 0, 0
1078 AVX_INSTR divsd, 1, 0, 0
1079 AVX_INSTR divss, 1, 0, 0
1080 AVX_INSTR dppd, 1, 1, 0
1081 AVX_INSTR dpps, 1, 1, 0
1082 AVX_INSTR haddpd, 1, 0, 0
1083 AVX_INSTR haddps, 1, 0, 0
1084 AVX_INSTR hsubpd, 1, 0, 0
1085 AVX_INSTR hsubps, 1, 0, 0
1086 AVX_INSTR maxpd, 1, 0, 1
1087 AVX_INSTR maxps, 1, 0, 1
1088 AVX_INSTR maxsd, 1, 0, 1
1089 AVX_INSTR maxss, 1, 0, 1
1090 AVX_INSTR minpd, 1, 0, 1
1091 AVX_INSTR minps, 1, 0, 1
1092 AVX_INSTR minsd, 1, 0, 1
1093 AVX_INSTR minss, 1, 0, 1
1094 AVX_INSTR movhlps, 1, 0, 0
1095 AVX_INSTR movlhps, 1, 0, 0
1096 AVX_INSTR movsd, 1, 0, 0
1097 AVX_INSTR movss, 1, 0, 0
1098 AVX_INSTR mpsadbw, 0, 1, 0
1099 AVX_INSTR mulpd, 1, 0, 1
1100 AVX_INSTR mulps, 1, 0, 1
1101 AVX_INSTR mulsd, 1, 0, 1
1102 AVX_INSTR mulss, 1, 0, 1
1103 AVX_INSTR orpd, 1, 0, 1
1104 AVX_INSTR orps, 1, 0, 1
1105 AVX_INSTR pabsb, 0, 0, 0
1106 AVX_INSTR pabsw, 0, 0, 0
1107 AVX_INSTR pabsd, 0, 0, 0
1108 AVX_INSTR packsswb, 0, 0, 0
1109 AVX_INSTR packssdw, 0, 0, 0
1110 AVX_INSTR packuswb, 0, 0, 0
1111 AVX_INSTR packusdw, 0, 0, 0
1112 AVX_INSTR paddb, 0, 0, 1
1113 AVX_INSTR paddw, 0, 0, 1
1114 AVX_INSTR paddd, 0, 0, 1
1115 AVX_INSTR paddq, 0, 0, 1
1116 AVX_INSTR paddsb, 0, 0, 1
1117 AVX_INSTR paddsw, 0, 0, 1
1118 AVX_INSTR paddusb, 0, 0, 1
1119 AVX_INSTR paddusw, 0, 0, 1
1120 AVX_INSTR palignr, 0, 1, 0
1121 AVX_INSTR pand, 0, 0, 1
1122 AVX_INSTR pandn, 0, 0, 0
1123 AVX_INSTR pavgb, 0, 0, 1
1124 AVX_INSTR pavgw, 0, 0, 1
1125 AVX_INSTR pblendvb, 0, 0, 0
1126 AVX_INSTR pblendw, 0, 1, 0
1127 AVX_INSTR pcmpestri, 0, 0, 0
1128 AVX_INSTR pcmpestrm, 0, 0, 0
1129 AVX_INSTR pcmpistri, 0, 0, 0
1130 AVX_INSTR pcmpistrm, 0, 0, 0
1131 AVX_INSTR pcmpeqb, 0, 0, 1
1132 AVX_INSTR pcmpeqw, 0, 0, 1
1133 AVX_INSTR pcmpeqd, 0, 0, 1
1134 AVX_INSTR pcmpeqq, 0, 0, 1
1135 AVX_INSTR pcmpgtb, 0, 0, 0
1136 AVX_INSTR pcmpgtw, 0, 0, 0
1137 AVX_INSTR pcmpgtd, 0, 0, 0
1138 AVX_INSTR pcmpgtq, 0, 0, 0
1139 AVX_INSTR phaddw, 0, 0, 0
1140 AVX_INSTR phaddd, 0, 0, 0
1141 AVX_INSTR phaddsw, 0, 0, 0
1142 AVX_INSTR phsubw, 0, 0, 0
1143 AVX_INSTR phsubd, 0, 0, 0
1144 AVX_INSTR phsubsw, 0, 0, 0
1145 AVX_INSTR pmaddwd, 0, 0, 1
1146 AVX_INSTR pmaddubsw, 0, 0, 0
1147 AVX_INSTR pmaxsb, 0, 0, 1
1148 AVX_INSTR pmaxsw, 0, 0, 1
1149 AVX_INSTR pmaxsd, 0, 0, 1
1150 AVX_INSTR pmaxub, 0, 0, 1
1151 AVX_INSTR pmaxuw, 0, 0, 1
1152 AVX_INSTR pmaxud, 0, 0, 1
1153 AVX_INSTR pminsb, 0, 0, 1
1154 AVX_INSTR pminsw, 0, 0, 1
1155 AVX_INSTR pminsd, 0, 0, 1
1156 AVX_INSTR pminub, 0, 0, 1
1157 AVX_INSTR pminuw, 0, 0, 1
1158 AVX_INSTR pminud, 0, 0, 1
1159 AVX_INSTR pmovmskb, 0, 0, 0
1160 AVX_INSTR pmulhuw, 0, 0, 1
1161 AVX_INSTR pmulhrsw, 0, 0, 1
1162 AVX_INSTR pmulhw, 0, 0, 1
1163 AVX_INSTR pmullw, 0, 0, 1
1164 AVX_INSTR pmulld, 0, 0, 1
1165 AVX_INSTR pmuludq, 0, 0, 1
1166 AVX_INSTR pmuldq, 0, 0, 1
1167 AVX_INSTR por, 0, 0, 1
1168 AVX_INSTR psadbw, 0, 0, 1
1169 AVX_INSTR pshufb, 0, 0, 0
1170 AVX_INSTR pshufd, 0, 1, 0
1171 AVX_INSTR pshufhw, 0, 1, 0
1172 AVX_INSTR pshuflw, 0, 1, 0
1173 AVX_INSTR psignb, 0, 0, 0
1174 AVX_INSTR psignw, 0, 0, 0
1175 AVX_INSTR psignd, 0, 0, 0
1176 AVX_INSTR psllw, 0, 0, 0
1177 AVX_INSTR pslld, 0, 0, 0
1178 AVX_INSTR psllq, 0, 0, 0
1179 AVX_INSTR pslldq, 0, 0, 0
1180 AVX_INSTR psraw, 0, 0, 0
1181 AVX_INSTR psrad, 0, 0, 0
1182 AVX_INSTR psrlw, 0, 0, 0
1183 AVX_INSTR psrld, 0, 0, 0
1184 AVX_INSTR psrlq, 0, 0, 0
1185 AVX_INSTR psrldq, 0, 0, 0
1186 AVX_INSTR psubb, 0, 0, 0
1187 AVX_INSTR psubw, 0, 0, 0
1188 AVX_INSTR psubd, 0, 0, 0
1189 AVX_INSTR psubq, 0, 0, 0
1190 AVX_INSTR psubsb, 0, 0, 0
1191 AVX_INSTR psubsw, 0, 0, 0
1192 AVX_INSTR psubusb, 0, 0, 0
1193 AVX_INSTR psubusw, 0, 0, 0
1194 AVX_INSTR ptest, 0, 0, 0
1195 AVX_INSTR punpckhbw, 0, 0, 0
1196 AVX_INSTR punpckhwd, 0, 0, 0
1197 AVX_INSTR punpckhdq, 0, 0, 0
1198 AVX_INSTR punpckhqdq, 0, 0, 0
1199 AVX_INSTR punpcklbw, 0, 0, 0
1200 AVX_INSTR punpcklwd, 0, 0, 0
1201 AVX_INSTR punpckldq, 0, 0, 0
1202 AVX_INSTR punpcklqdq, 0, 0, 0
1203 AVX_INSTR pxor, 0, 0, 1
1204 AVX_INSTR shufps, 1, 1, 0
1205 AVX_INSTR subpd, 1, 0, 0
1206 AVX_INSTR subps, 1, 0, 0
1207 AVX_INSTR subsd, 1, 0, 0
1208 AVX_INSTR subss, 1, 0, 0
1209 AVX_INSTR unpckhpd, 1, 0, 0
1210 AVX_INSTR unpckhps, 1, 0, 0
1211 AVX_INSTR unpcklpd, 1, 0, 0
1212 AVX_INSTR unpcklps, 1, 0, 0
1213 AVX_INSTR xorpd, 1, 0, 1
1214 AVX_INSTR xorps, 1, 0, 1
1215
1216 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
1217 AVX_INSTR pfadd, 1, 0, 1
1218 AVX_INSTR pfsub, 1, 0, 0
1219 AVX_INSTR pfmul, 1, 0, 1
1220
1221 ; base-4 constants for shuffles
1222 %assign i 0
1223 %rep 256
1224     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
1225     %if j < 10
1226         CAT_XDEFINE q000, j, i
1227     %elif j < 100
1228         CAT_XDEFINE q00, j, i
1229     %elif j < 1000
1230         CAT_XDEFINE q0, j, i
1231     %else
1232         CAT_XDEFINE q, j, i
1233     %endif
1234 %assign i i+1
1235 %endrep
1236 %undef i
1237 %undef j
1238
1239 %macro FMA_INSTR 3
1240     %macro %1 5-8 %1, %2, %3
1241         %if cpuflag(xop) || cpuflag(fma4)
1242             v%6 %1, %2, %3, %4
1243         %else
1244             %ifidn %1, %4
1245                 %7 %5, %2, %3
1246                 %8 %1, %4, %5
1247             %else
1248                 %7 %1, %2, %3
1249                 %8 %1, %4
1250             %endif
1251         %endif
1252     %endmacro
1253 %endmacro
1254
1255 FMA_INSTR  fmaddps,   mulps, addps
1256 FMA_INSTR  pmacsdd,  pmulld, paddd
1257 FMA_INSTR  pmacsww,  pmullw, paddw
1258 FMA_INSTR pmadcswd, pmaddwd, paddd
1259
1260 ; tzcnt is equivalent to "rep bsf" and is backwards-compatible with bsf.
1261 ; This lets us use tzcnt without bumping the yasm version requirement yet.
1262 %define tzcnt rep bsf