git.sesse.net Git - ffmpeg/blob - libavutil/x86/x86inc.asm

   1 ;*****************************************************************************
   2 ;* x86inc.asm: x264asm abstraction layer
   3 ;*****************************************************************************
   4 ;* Copyright (C) 2005-2011 x264 project
   5 ;*
   6 ;* Authors: Loren Merritt <lorenm@u.washington.edu>
   7 ;*          Anton Mitrofanov <BugMaster@narod.ru>
   8 ;*          Jason Garrett-Glaser <darkshikari@gmail.com>
   9 ;*
  10 ;* Permission to use, copy, modify, and/or distribute this software for any
  11 ;* purpose with or without fee is hereby granted, provided that the above
  12 ;* copyright notice and this permission notice appear in all copies.
  13 ;*
  14 ;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  15 ;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  16 ;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  17 ;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  18 ;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  19 ;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  20 ;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  21 ;*****************************************************************************
  22
  23 ; This is a header file for the x264ASM assembly language, which uses
  24 ; NASM/YASM syntax combined with a large number of macros to provide easy
  25 ; abstraction between different calling conventions (x86_32, win64, linux64).
  26 ; It also has various other useful features to simplify writing the kind of
  27 ; DSP functions that are most often used in x264.
  28
  29 ; Unlike the rest of x264, this file is available under an ISC license, as it
  30 ; has significant usefulness outside of x264 and we want it to be available
  31 ; to the largest audience possible.  Of course, if you modify it for your own
  32 ; purposes to add a new feature, we strongly encourage contributing a patch
  33 ; as this feature might be useful for others as well.  Send patches or ideas
  34 ; to x264-devel@videolan.org .
  35
  36 %define program_name ff
  37
  38 %define UNIX64 0
  39 %define WIN64  0
  40 %if ARCH_X86_64
  41     %ifidn __OUTPUT_FORMAT__,win32
  42         %define WIN64  1
  43     %else
  44         %define UNIX64 1
  45     %endif
  46 %endif
  47
  48 %ifdef PREFIX
  49     %define mangle(x) _ %+ x
  50 %else
  51     %define mangle(x) x
  52 %endif
  53
  54 ; FIXME: All of the 64bit asm functions that take a stride as an argument
  55 ; via register, assume that the high dword of that register is filled with 0.
  56 ; This is true in practice (since we never do any 64bit arithmetic on strides,
  57 ; and x264's strides are all positive), but is not guaranteed by the ABI.
  58
  59 ; Name of the .rodata section.
  60 ; Kludge: Something on OS X fails to align .rodata even given an align attribute,
  61 ; so use a different read-only section.
  62 %macro SECTION_RODATA 0-1 16
  63     %ifidn __OUTPUT_FORMAT__,macho64
  64         SECTION .text align=%1
  65     %elifidn __OUTPUT_FORMAT__,macho
  66         SECTION .text align=%1
  67         fakegot:
  68     %elifidn __OUTPUT_FORMAT__,aout
  69         section .text
  70     %else
  71         SECTION .rodata align=%1
  72     %endif
  73 %endmacro
  74
  75 ; aout does not support align=
  76 %macro SECTION_TEXT 0-1 16
  77     %ifidn __OUTPUT_FORMAT__,aout
  78         SECTION .text
  79     %else
  80         SECTION .text align=%1
  81     %endif
  82 %endmacro
  83
  84 %if WIN64
  85     %define PIC
  86 %elif !ARCH_X86_64
  87 ; x86_32 doesn't require PIC.
  88 ; Some distros prefer shared objects to be PIC, but nothing breaks if
  89 ; the code contains a few textrels, so we'll skip that complexity.
  90     %undef PIC
  91 %endif
  92 %ifdef PIC
  93     default rel
  94 %endif
  95
  96 ; Macros to eliminate most code duplication between x86_32 and x86_64:
  97 ; Currently this works only for leaf functions which load all their arguments
  98 ; into registers at the start, and make no other use of the stack. Luckily that
  99 ; covers most of x264's asm.
 100
 101 ; PROLOGUE:
 102 ; %1 = number of arguments. loads them from stack if needed.
 103 ; %2 = number of registers used. pushes callee-saved regs if needed.
 104 ; %3 = number of xmm registers used. pushes callee-saved xmm regs if needed.
 105 ; %4 = list of names to define to registers
 106 ; PROLOGUE can also be invoked by adding the same options to cglobal
 107
 108 ; e.g.
 109 ; cglobal foo, 2,3,0, dst, src, tmp
 110 ; declares a function (foo), taking two args (dst and src) and one local variable (tmp)
 111
 112 ; TODO Some functions can use some args directly from the stack. If they're the
 113 ; last args then you can just not declare them, but if they're in the middle
 114 ; we need more flexible macro.
 115
 116 ; RET:
 117 ; Pops anything that was pushed by PROLOGUE, and returns.
 118
 119 ; REP_RET:
 120 ; Same, but if it doesn't pop anything it becomes a 2-byte ret, for athlons
 121 ; which are slow when a normal ret follows a branch.
 122
 123 ; registers:
 124 ; rN and rNq are the native-size register holding function argument N
 125 ; rNd, rNw, rNb are dword, word, and byte size
 126 ; rNm is the original location of arg N (a register or on the stack), dword
 127 ; rNmp is native size
 128
 129 %macro DECLARE_REG 6
 130     %define r%1q %2
 131     %define r%1d %3
 132     %define r%1w %4
 133     %define r%1b %5
 134     %define r%1m %6
 135     %ifid %6 ; i.e. it's a register
 136         %define r%1mp %2
 137     %elif ARCH_X86_64 ; memory
 138         %define r%1mp qword %6
 139     %else
 140         %define r%1mp dword %6
 141     %endif
 142     %define r%1  %2
 143 %endmacro
 144
 145 %macro DECLARE_REG_SIZE 2
 146     %define r%1q r%1
 147     %define e%1q r%1
 148     %define r%1d e%1
 149     %define e%1d e%1
 150     %define r%1w %1
 151     %define e%1w %1
 152     %define r%1b %2
 153     %define e%1b %2
 154 %if ARCH_X86_64 == 0
 155     %define r%1  e%1
 156 %endif
 157 %endmacro
 158
 159 DECLARE_REG_SIZE ax, al
 160 DECLARE_REG_SIZE bx, bl
 161 DECLARE_REG_SIZE cx, cl
 162 DECLARE_REG_SIZE dx, dl
 163 DECLARE_REG_SIZE si, sil
 164 DECLARE_REG_SIZE di, dil
 165 DECLARE_REG_SIZE bp, bpl
 166
 167 ; t# defines for when per-arch register allocation is more complex than just function arguments
 168
 169 %macro DECLARE_REG_TMP 1-*
 170     %assign %%i 0
 171     %rep %0
 172         CAT_XDEFINE t, %%i, r%1
 173         %assign %%i %%i+1
 174         %rotate 1
 175     %endrep
 176 %endmacro
 177
 178 %macro DECLARE_REG_TMP_SIZE 0-*
 179     %rep %0
 180         %define t%1q t%1 %+ q
 181         %define t%1d t%1 %+ d
 182         %define t%1w t%1 %+ w
 183         %define t%1b t%1 %+ b
 184         %rotate 1
 185     %endrep
 186 %endmacro
 187
 188 DECLARE_REG_TMP_SIZE 0,1,2,3,4,5,6,7,8,9
 189
 190 %if ARCH_X86_64
 191     %define gprsize 8
 192 %else
 193     %define gprsize 4
 194 %endif
 195
 196 %macro PUSH 1
 197     push %1
 198     %assign stack_offset stack_offset+gprsize
 199 %endmacro
 200
 201 %macro POP 1
 202     pop %1
 203     %assign stack_offset stack_offset-gprsize
 204 %endmacro
 205
 206 %macro SUB 2
 207     sub %1, %2
 208     %ifidn %1, rsp
 209         %assign stack_offset stack_offset+(%2)
 210     %endif
 211 %endmacro
 212
 213 %macro ADD 2
 214     add %1, %2
 215     %ifidn %1, rsp
 216         %assign stack_offset stack_offset-(%2)
 217     %endif
 218 %endmacro
 219
 220 %macro movifnidn 2
 221     %ifnidn %1, %2
 222         mov %1, %2
 223     %endif
 224 %endmacro
 225
 226 %macro movsxdifnidn 2
 227     %ifnidn %1, %2
 228         movsxd %1, %2
 229     %endif
 230 %endmacro
 231
 232 %macro ASSERT 1
 233     %if (%1) == 0
 234         %error assert failed
 235     %endif
 236 %endmacro
 237
 238 %macro DEFINE_ARGS 0-*
 239     %ifdef n_arg_names
 240         %assign %%i 0
 241         %rep n_arg_names
 242             CAT_UNDEF arg_name %+ %%i, q
 243             CAT_UNDEF arg_name %+ %%i, d
 244             CAT_UNDEF arg_name %+ %%i, w
 245             CAT_UNDEF arg_name %+ %%i, b
 246             CAT_UNDEF arg_name %+ %%i, m
 247             CAT_UNDEF arg_name, %%i
 248             %assign %%i %%i+1
 249         %endrep
 250     %endif
 251
 252     %assign %%i 0
 253     %rep %0
 254         %xdefine %1q r %+ %%i %+ q
 255         %xdefine %1d r %+ %%i %+ d
 256         %xdefine %1w r %+ %%i %+ w
 257         %xdefine %1b r %+ %%i %+ b
 258         %xdefine %1m r %+ %%i %+ m
 259         CAT_XDEFINE arg_name, %%i, %1
 260         %assign %%i %%i+1
 261         %rotate 1
 262     %endrep
 263     %assign n_arg_names %%i
 264 %endmacro
 265
 266 %if WIN64 ; Windows x64 ;=================================================
 267
 268 DECLARE_REG 0, rcx, ecx, cx,  cl,  ecx
 269 DECLARE_REG 1, rdx, edx, dx,  dl,  edx
 270 DECLARE_REG 2, r8,  r8d, r8w, r8b, r8d
 271 DECLARE_REG 3, r9,  r9d, r9w, r9b, r9d
 272 DECLARE_REG 4, rdi, edi, di,  dil, [rsp + stack_offset + 40]
 273 DECLARE_REG 5, rsi, esi, si,  sil, [rsp + stack_offset + 48]
 274 DECLARE_REG 6, rax, eax, ax,  al,  [rsp + stack_offset + 56]
 275 %define r7m [rsp + stack_offset + 64]
 276 %define r8m [rsp + stack_offset + 72]
 277
 278 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
 279     %if %1 < %2
 280         mov r%1, [rsp + stack_offset + 8 + %1*8]
 281     %endif
 282 %endmacro
 283
 284 %macro PROLOGUE 2-4+ 0 ; #args, #regs, #xmm_regs, arg_names...
 285     ASSERT %2 >= %1
 286     %assign regs_used %2
 287     ASSERT regs_used <= 7
 288     %if regs_used > 4
 289         push r4
 290         push r5
 291         %assign stack_offset stack_offset+16
 292     %endif
 293     WIN64_SPILL_XMM %3
 294     LOAD_IF_USED 4, %1
 295     LOAD_IF_USED 5, %1
 296     LOAD_IF_USED 6, %1
 297     DEFINE_ARGS %4
 298 %endmacro
 299
 300 %macro WIN64_SPILL_XMM 1
 301     %assign xmm_regs_used %1
 302     %if mmsize == 8
 303         %assign xmm_regs_used 0
 304     %endif
 305     ASSERT xmm_regs_used <= 16
 306     %if xmm_regs_used > 6
 307         sub rsp, (xmm_regs_used-6)*16+16
 308         %assign stack_offset stack_offset+(xmm_regs_used-6)*16+16
 309         %assign %%i xmm_regs_used
 310         %rep (xmm_regs_used-6)
 311             %assign %%i %%i-1
 312             movdqa [rsp + (%%i-6)*16+8], xmm %+ %%i
 313         %endrep
 314     %endif
 315 %endmacro
 316
 317 %macro WIN64_RESTORE_XMM_INTERNAL 1
 318     %if xmm_regs_used > 6
 319         %assign %%i xmm_regs_used
 320         %rep (xmm_regs_used-6)
 321             %assign %%i %%i-1
 322             movdqa xmm %+ %%i, [%1 + (%%i-6)*16+8]
 323         %endrep
 324         add %1, (xmm_regs_used-6)*16+16
 325     %endif
 326 %endmacro
 327
 328 %macro WIN64_RESTORE_XMM 1
 329     WIN64_RESTORE_XMM_INTERNAL %1
 330     %assign stack_offset stack_offset-(xmm_regs_used-6)*16+16
 331     %assign xmm_regs_used 0
 332 %endmacro
 333
 334 %macro RET 0
 335     WIN64_RESTORE_XMM_INTERNAL rsp
 336     %if regs_used > 4
 337         pop r5
 338         pop r4
 339     %endif
 340     ret
 341 %endmacro
 342
 343 %macro REP_RET 0
 344     %if regs_used > 4 || xmm_regs_used > 6
 345         RET
 346     %else
 347         rep ret
 348     %endif
 349 %endmacro
 350
 351 %elif ARCH_X86_64 ; *nix x64 ;=============================================
 352
 353 DECLARE_REG 0, rdi, edi, di,  dil, edi
 354 DECLARE_REG 1, rsi, esi, si,  sil, esi
 355 DECLARE_REG 2, rdx, edx, dx,  dl,  edx
 356 DECLARE_REG 3, rcx, ecx, cx,  cl,  ecx
 357 DECLARE_REG 4, r8,  r8d, r8w, r8b, r8d
 358 DECLARE_REG 5, r9,  r9d, r9w, r9b, r9d
 359 DECLARE_REG 6, rax, eax, ax,  al,  [rsp + stack_offset + 8]
 360 %define r7m [rsp + stack_offset + 16]
 361 %define r8m [rsp + stack_offset + 24]
 362
 363 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
 364     %if %1 < %2
 365         mov r%1, [rsp - 40 + %1*8]
 366     %endif
 367 %endmacro
 368
 369 %macro PROLOGUE 2-4+ ; #args, #regs, #xmm_regs, arg_names...
 370     ASSERT %2 >= %1
 371     ASSERT %2 <= 7
 372     LOAD_IF_USED 6, %1
 373     DEFINE_ARGS %4
 374 %endmacro
 375
 376 %macro RET 0
 377     ret
 378 %endmacro
 379
 380 %macro REP_RET 0
 381     rep ret
 382 %endmacro
 383
 384 %else ; X86_32 ;==============================================================
 385
 386 DECLARE_REG 0, eax, eax, ax, al,   [esp + stack_offset + 4]
 387 DECLARE_REG 1, ecx, ecx, cx, cl,   [esp + stack_offset + 8]
 388 DECLARE_REG 2, edx, edx, dx, dl,   [esp + stack_offset + 12]
 389 DECLARE_REG 3, ebx, ebx, bx, bl,   [esp + stack_offset + 16]
 390 DECLARE_REG 4, esi, esi, si, null, [esp + stack_offset + 20]
 391 DECLARE_REG 5, edi, edi, di, null, [esp + stack_offset + 24]
 392 DECLARE_REG 6, ebp, ebp, bp, null, [esp + stack_offset + 28]
 393 %define r7m [esp + stack_offset + 32]
 394 %define r8m [esp + stack_offset + 36]
 395 %define rsp esp
 396
 397 %macro PUSH_IF_USED 1 ; reg_id
 398     %if %1 < regs_used
 399         push r%1
 400         %assign stack_offset stack_offset+4
 401     %endif
 402 %endmacro
 403
 404 %macro POP_IF_USED 1 ; reg_id
 405     %if %1 < regs_used
 406         pop r%1
 407     %endif
 408 %endmacro
 409
 410 %macro LOAD_IF_USED 2 ; reg_id, number_of_args
 411     %if %1 < %2
 412         mov r%1, [esp + stack_offset + 4 + %1*4]
 413     %endif
 414 %endmacro
 415
 416 %macro PROLOGUE 2-4+ ; #args, #regs, #xmm_regs, arg_names...
 417     ASSERT %2 >= %1
 418     %assign regs_used %2
 419     ASSERT regs_used <= 7
 420     PUSH_IF_USED 3
 421     PUSH_IF_USED 4
 422     PUSH_IF_USED 5
 423     PUSH_IF_USED 6
 424     LOAD_IF_USED 0, %1
 425     LOAD_IF_USED 1, %1
 426     LOAD_IF_USED 2, %1
 427     LOAD_IF_USED 3, %1
 428     LOAD_IF_USED 4, %1
 429     LOAD_IF_USED 5, %1
 430     LOAD_IF_USED 6, %1
 431     DEFINE_ARGS %4
 432 %endmacro
 433
 434 %macro RET 0
 435     POP_IF_USED 6
 436     POP_IF_USED 5
 437     POP_IF_USED 4
 438     POP_IF_USED 3
 439     ret
 440 %endmacro
 441
 442 %macro REP_RET 0
 443     %if regs_used > 3
 444         RET
 445     %else
 446         rep ret
 447     %endif
 448 %endmacro
 449
 450 %endif ;======================================================================
 451
 452 %if WIN64 == 0
 453 %macro WIN64_SPILL_XMM 1
 454 %endmacro
 455 %macro WIN64_RESTORE_XMM 1
 456 %endmacro
 457 %endif
 458
 459
 460
 461 ;=============================================================================
 462 ; arch-independent part
 463 ;=============================================================================
 464
 465 %assign function_align 16
 466
 467 ; Begin a function.
 468 ; Applies any symbol mangling needed for C linkage, and sets up a define such that
 469 ; subsequent uses of the function name automatically refer to the mangled version.
 470 ; Appends cpuflags to the function name if cpuflags has been specified.
 471 %macro cglobal 1-2+ ; name, [PROLOGUE args]
 472 %if %0 == 1
 473     cglobal_internal %1 %+ SUFFIX
 474 %else
 475     cglobal_internal %1 %+ SUFFIX, %2
 476 %endif
 477 %endmacro
 478 %macro cglobal_internal 1-2+
 479     %ifndef cglobaled_%1
 480         %xdefine %1 mangle(program_name %+ _ %+ %1)
 481         %xdefine %1.skip_prologue %1 %+ .skip_prologue
 482         CAT_XDEFINE cglobaled_, %1, 1
 483     %endif
 484     %xdefine current_function %1
 485     %ifidn __OUTPUT_FORMAT__,elf
 486         global %1:function hidden
 487     %else
 488         global %1
 489     %endif
 490     align function_align
 491     %1:
 492     RESET_MM_PERMUTATION ; not really needed, but makes disassembly somewhat nicer
 493     %assign stack_offset 0
 494     %if %0 > 1
 495         PROLOGUE %2
 496     %endif
 497 %endmacro
 498
 499 %macro cextern 1
 500     %xdefine %1 mangle(program_name %+ _ %+ %1)
 501     CAT_XDEFINE cglobaled_, %1, 1
 502     extern %1
 503 %endmacro
 504
 505 ; like cextern, but without the prefix
 506 %macro cextern_naked 1
 507     %xdefine %1 mangle(%1)
 508     CAT_XDEFINE cglobaled_, %1, 1
 509     extern %1
 510 %endmacro
 511
 512 %macro const 2+
 513     %xdefine %1 mangle(program_name %+ _ %+ %1)
 514     global %1
 515     %1: %2
 516 %endmacro
 517
 518 ; This is needed for ELF, otherwise the GNU linker assumes the stack is
 519 ; executable by default.
 520 %ifidn __OUTPUT_FORMAT__,elf
 521 SECTION .note.GNU-stack noalloc noexec nowrite progbits
 522 %endif
 523
 524 ; cpuflags
 525
 526 %assign cpuflags_mmx      (1<<0)
 527 %assign cpuflags_mmx2     (1<<1) | cpuflags_mmx
 528 %assign cpuflags_3dnow    (1<<2) | cpuflags_mmx
 529 %assign cpuflags_3dnow2   (1<<3) | cpuflags_3dnow
 530 %assign cpuflags_sse      (1<<4) | cpuflags_mmx2
 531 %assign cpuflags_sse2     (1<<5) | cpuflags_sse
 532 %assign cpuflags_sse2slow (1<<6) | cpuflags_sse2
 533 %assign cpuflags_sse3     (1<<7) | cpuflags_sse2
 534 %assign cpuflags_ssse3    (1<<8) | cpuflags_sse3
 535 %assign cpuflags_sse4     (1<<9) | cpuflags_ssse3
 536 %assign cpuflags_sse42    (1<<10)| cpuflags_sse4
 537 %assign cpuflags_avx      (1<<11)| cpuflags_sse42
 538 %assign cpuflags_xop      (1<<12)| cpuflags_avx
 539 %assign cpuflags_fma4     (1<<13)| cpuflags_avx
 540
 541 %assign cpuflags_cache32  (1<<16)
 542 %assign cpuflags_cache64  (1<<17)
 543 %assign cpuflags_slowctz  (1<<18)
 544 %assign cpuflags_lzcnt    (1<<19)
 545 %assign cpuflags_misalign (1<<20)
 546 %assign cpuflags_aligned  (1<<21) ; not a cpu feature, but a function variant
 547 %assign cpuflags_atom     (1<<22)
 548
 549 %define    cpuflag(x) ((cpuflags & (cpuflags_ %+ x)) == (cpuflags_ %+ x))
 550 %define notcpuflag(x) ((cpuflags & (cpuflags_ %+ x)) != (cpuflags_ %+ x))
 551
 552 ; Takes up to 2 cpuflags from the above list.
 553 ; All subsequent functions (up to the next INIT_CPUFLAGS) is built for the specified cpu.
 554 ; You shouldn't need to invoke this macro directly, it's a subroutine for INIT_MMX &co.
 555 %macro INIT_CPUFLAGS 0-2
 556     %if %0 >= 1
 557         %xdefine cpuname %1
 558         %assign cpuflags cpuflags_%1
 559         %if %0 >= 2
 560             %xdefine cpuname %1_%2
 561             %assign cpuflags cpuflags | cpuflags_%2
 562         %endif
 563         %xdefine SUFFIX _ %+ cpuname
 564         %if cpuflag(avx)
 565             %assign avx_enabled 1
 566         %endif
 567         %if mmsize == 16 && notcpuflag(sse2)
 568             %define mova movaps
 569             %define movu movups
 570             %define movnta movntps
 571         %endif
 572         %if cpuflag(aligned)
 573             %define movu mova
 574         %elifidn %1, sse3
 575             %define movu lddqu
 576         %endif
 577     %else
 578         %xdefine SUFFIX
 579         %undef cpuname
 580         %undef cpuflags
 581     %endif
 582 %endmacro
 583
 584 ; merge mmx and sse*
 585
 586 %macro CAT_XDEFINE 3
 587     %xdefine %1%2 %3
 588 %endmacro
 589
 590 %macro CAT_UNDEF 2
 591     %undef %1%2
 592 %endmacro
 593
 594 %macro INIT_MMX 0-1+
 595     %assign avx_enabled 0
 596     %define RESET_MM_PERMUTATION INIT_MMX %1
 597     %define mmsize 8
 598     %define num_mmregs 8
 599     %define mova movq
 600     %define movu movq
 601     %define movh movd
 602     %define movnta movntq
 603     %assign %%i 0
 604     %rep 8
 605     CAT_XDEFINE m, %%i, mm %+ %%i
 606     CAT_XDEFINE nmm, %%i, %%i
 607     %assign %%i %%i+1
 608     %endrep
 609     %rep 8
 610     CAT_UNDEF m, %%i
 611     CAT_UNDEF nmm, %%i
 612     %assign %%i %%i+1
 613     %endrep
 614     INIT_CPUFLAGS %1
 615 %endmacro
 616
 617 %macro INIT_XMM 0-1+
 618     %assign avx_enabled 0
 619     %define RESET_MM_PERMUTATION INIT_XMM %1
 620     %define mmsize 16
 621     %define num_mmregs 8
 622     %if ARCH_X86_64
 623     %define num_mmregs 16
 624     %endif
 625     %define mova movdqa
 626     %define movu movdqu
 627     %define movh movq
 628     %define movnta movntdq
 629     %assign %%i 0
 630     %rep num_mmregs
 631     CAT_XDEFINE m, %%i, xmm %+ %%i
 632     CAT_XDEFINE nxmm, %%i, %%i
 633     %assign %%i %%i+1
 634     %endrep
 635     INIT_CPUFLAGS %1
 636 %endmacro
 637
 638 ; FIXME: INIT_AVX can be replaced by INIT_XMM avx
 639 %macro INIT_AVX 0
 640     INIT_XMM
 641     %assign avx_enabled 1
 642     %define PALIGNR PALIGNR_SSSE3
 643     %define RESET_MM_PERMUTATION INIT_AVX
 644 %endmacro
 645
 646 %macro INIT_YMM 0-1+
 647     %assign avx_enabled 1
 648     %define RESET_MM_PERMUTATION INIT_YMM %1
 649     %define mmsize 32
 650     %define num_mmregs 8
 651     %if ARCH_X86_64
 652     %define num_mmregs 16
 653     %endif
 654     %define mova vmovaps
 655     %define movu vmovups
 656     %undef movh
 657     %define movnta vmovntps
 658     %assign %%i 0
 659     %rep num_mmregs
 660     CAT_XDEFINE m, %%i, ymm %+ %%i
 661     CAT_XDEFINE nymm, %%i, %%i
 662     %assign %%i %%i+1
 663     %endrep
 664     INIT_CPUFLAGS %1
 665 %endmacro
 666
 667 INIT_XMM
 668
 669 ; I often want to use macros that permute their arguments. e.g. there's no
 670 ; efficient way to implement butterfly or transpose or dct without swapping some
 671 ; arguments.
 672 ;
 673 ; I would like to not have to manually keep track of the permutations:
 674 ; If I insert a permutation in the middle of a function, it should automatically
 675 ; change everything that follows. For more complex macros I may also have multiple
 676 ; implementations, e.g. the SSE2 and SSSE3 versions may have different permutations.
 677 ;
 678 ; Hence these macros. Insert a PERMUTE or some SWAPs at the end of a macro that
 679 ; permutes its arguments. It's equivalent to exchanging the contents of the
 680 ; registers, except that this way you exchange the register names instead, so it
 681 ; doesn't cost any cycles.
 682
 683 %macro PERMUTE 2-* ; takes a list of pairs to swap
 684 %rep %0/2
 685     %xdefine tmp%2 m%2
 686     %xdefine ntmp%2 nm%2
 687     %rotate 2
 688 %endrep
 689 %rep %0/2
 690     %xdefine m%1 tmp%2
 691     %xdefine nm%1 ntmp%2
 692     %undef tmp%2
 693     %undef ntmp%2
 694     %rotate 2
 695 %endrep
 696 %endmacro
 697
 698 %macro SWAP 2-* ; swaps a single chain (sometimes more concise than pairs)
 699 %rep %0-1
 700 %ifdef m%1
 701     %xdefine tmp m%1
 702     %xdefine m%1 m%2
 703     %xdefine m%2 tmp
 704     CAT_XDEFINE n, m%1, %1
 705     CAT_XDEFINE n, m%2, %2
 706 %else
 707     ; If we were called as "SWAP m0,m1" rather than "SWAP 0,1" infer the original numbers here.
 708     ; Be careful using this mode in nested macros though, as in some cases there may be
 709     ; other copies of m# that have already been dereferenced and don't get updated correctly.
 710     %xdefine %%n1 n %+ %1
 711     %xdefine %%n2 n %+ %2
 712     %xdefine tmp m %+ %%n1
 713     CAT_XDEFINE m, %%n1, m %+ %%n2
 714     CAT_XDEFINE m, %%n2, tmp
 715     CAT_XDEFINE n, m %+ %%n1, %%n1
 716     CAT_XDEFINE n, m %+ %%n2, %%n2
 717 %endif
 718     %undef tmp
 719     %rotate 1
 720 %endrep
 721 %endmacro
 722
 723 ; If SAVE_MM_PERMUTATION is placed at the end of a function, then any later
 724 ; calls to that function will automatically load the permutation, so values can
 725 ; be returned in mmregs.
 726 %macro SAVE_MM_PERMUTATION 0-1
 727     %if %0
 728         %xdefine %%f %1_m
 729     %else
 730         %xdefine %%f current_function %+ _m
 731     %endif
 732     %assign %%i 0
 733     %rep num_mmregs
 734         CAT_XDEFINE %%f, %%i, m %+ %%i
 735     %assign %%i %%i+1
 736     %endrep
 737 %endmacro
 738
 739 %macro LOAD_MM_PERMUTATION 1 ; name to load from
 740     %ifdef %1_m0
 741         %assign %%i 0
 742         %rep num_mmregs
 743             CAT_XDEFINE m, %%i, %1_m %+ %%i
 744             CAT_XDEFINE n, m %+ %%i, %%i
 745         %assign %%i %%i+1
 746         %endrep
 747     %endif
 748 %endmacro
 749
 750 ; Append cpuflags to the callee's name iff the appended name is known and the plain name isn't
 751 %macro call 1
 752     call_internal %1, %1 %+ SUFFIX
 753 %endmacro
 754 %macro call_internal 2
 755     %xdefine %%i %1
 756     %ifndef cglobaled_%1
 757         %ifdef cglobaled_%2
 758             %xdefine %%i %2
 759         %endif
 760     %endif
 761     call %%i
 762     LOAD_MM_PERMUTATION %%i
 763 %endmacro
 764
 765 ; Substitutions that reduce instruction size but are functionally equivalent
 766 %macro add 2
 767     %ifnum %2
 768         %if %2==128
 769             sub %1, -128
 770         %else
 771             add %1, %2
 772         %endif
 773     %else
 774         add %1, %2
 775     %endif
 776 %endmacro
 777
 778 %macro sub 2
 779     %ifnum %2
 780         %if %2==128
 781             add %1, -128
 782         %else
 783             sub %1, %2
 784         %endif
 785     %else
 786         sub %1, %2
 787     %endif
 788 %endmacro
 789
 790 ;=============================================================================
 791 ; AVX abstraction layer
 792 ;=============================================================================
 793
 794 %assign i 0
 795 %rep 16
 796     %if i < 8
 797         CAT_XDEFINE sizeofmm, i, 8
 798     %endif
 799     CAT_XDEFINE sizeofxmm, i, 16
 800     CAT_XDEFINE sizeofymm, i, 32
 801 %assign i i+1
 802 %endrep
 803 %undef i
 804
 805 ;%1 == instruction
 806 ;%2 == 1 if float, 0 if int
 807 ;%3 == 1 if 4-operand (xmm, xmm, xmm, imm), 0 if 3-operand (xmm, xmm, xmm)
 808 ;%4 == number of operands given
 809 ;%5+: operands
 810 %macro RUN_AVX_INSTR 6-7+
 811     %ifid %5
 812         %define %%size sizeof%5
 813     %else
 814         %define %%size mmsize
 815     %endif
 816     %if %%size==32
 817         v%1 %5, %6, %7
 818     %else
 819         %if %%size==8
 820             %define %%regmov movq
 821         %elif %2
 822             %define %%regmov movaps
 823         %else
 824             %define %%regmov movdqa
 825         %endif
 826
 827         %if %4>=3+%3
 828             %ifnidn %5, %6
 829                 %if avx_enabled && sizeof%5==16
 830                     v%1 %5, %6, %7
 831                 %else
 832                     %%regmov %5, %6
 833                     %1 %5, %7
 834                 %endif
 835             %else
 836                 %1 %5, %7
 837             %endif
 838         %elif %3
 839             %1 %5, %6, %7
 840         %else
 841             %1 %5, %6
 842         %endif
 843     %endif
 844 %endmacro
 845
 846 ; 3arg AVX ops with a memory arg can only have it in src2,
 847 ; whereas SSE emulation of 3arg prefers to have it in src1 (i.e. the mov).
 848 ; So, if the op is symmetric and the wrong one is memory, swap them.
 849 %macro RUN_AVX_INSTR1 8
 850     %assign %%swap 0
 851     %if avx_enabled
 852         %ifnid %6
 853             %assign %%swap 1
 854         %endif
 855     %elifnidn %5, %6
 856         %ifnid %7
 857             %assign %%swap 1
 858         %endif
 859     %endif
 860     %if %%swap && %3 == 0 && %8 == 1
 861         RUN_AVX_INSTR %1, %2, %3, %4, %5, %7, %6
 862     %else
 863         RUN_AVX_INSTR %1, %2, %3, %4, %5, %6, %7
 864     %endif
 865 %endmacro
 866
 867 ;%1 == instruction
 868 ;%2 == 1 if float, 0 if int
 869 ;%3 == 1 if 4-operand (xmm, xmm, xmm, imm), 0 if 3-operand (xmm, xmm, xmm)
 870 ;%4 == 1 if symmetric (i.e. doesn't matter which src arg is which), 0 if not
 871 %macro AVX_INSTR 4
 872     %macro %1 2-9 fnord, fnord, fnord, %1, %2, %3, %4
 873         %ifidn %3, fnord
 874             RUN_AVX_INSTR %6, %7, %8, 2, %1, %2
 875         %elifidn %4, fnord
 876             RUN_AVX_INSTR1 %6, %7, %8, 3, %1, %2, %3, %9
 877         %elifidn %5, fnord
 878             RUN_AVX_INSTR %6, %7, %8, 4, %1, %2, %3, %4
 879         %else
 880             RUN_AVX_INSTR %6, %7, %8, 5, %1, %2, %3, %4, %5
 881         %endif
 882     %endmacro
 883 %endmacro
 884
 885 AVX_INSTR addpd, 1, 0, 1
 886 AVX_INSTR addps, 1, 0, 1
 887 AVX_INSTR addsd, 1, 0, 1
 888 AVX_INSTR addss, 1, 0, 1
 889 AVX_INSTR addsubpd, 1, 0, 0
 890 AVX_INSTR addsubps, 1, 0, 0
 891 AVX_INSTR andpd, 1, 0, 1
 892 AVX_INSTR andps, 1, 0, 1
 893 AVX_INSTR andnpd, 1, 0, 0
 894 AVX_INSTR andnps, 1, 0, 0
 895 AVX_INSTR blendpd, 1, 0, 0
 896 AVX_INSTR blendps, 1, 0, 0
 897 AVX_INSTR blendvpd, 1, 0, 0
 898 AVX_INSTR blendvps, 1, 0, 0
 899 AVX_INSTR cmppd, 1, 0, 0
 900 AVX_INSTR cmpps, 1, 0, 0
 901 AVX_INSTR cmpsd, 1, 0, 0
 902 AVX_INSTR cmpss, 1, 0, 0
 903 AVX_INSTR divpd, 1, 0, 0
 904 AVX_INSTR divps, 1, 0, 0
 905 AVX_INSTR divsd, 1, 0, 0
 906 AVX_INSTR divss, 1, 0, 0
 907 AVX_INSTR dppd, 1, 1, 0
 908 AVX_INSTR dpps, 1, 1, 0
 909 AVX_INSTR haddpd, 1, 0, 0
 910 AVX_INSTR haddps, 1, 0, 0
 911 AVX_INSTR hsubpd, 1, 0, 0
 912 AVX_INSTR hsubps, 1, 0, 0
 913 AVX_INSTR maxpd, 1, 0, 1
 914 AVX_INSTR maxps, 1, 0, 1
 915 AVX_INSTR maxsd, 1, 0, 1
 916 AVX_INSTR maxss, 1, 0, 1
 917 AVX_INSTR minpd, 1, 0, 1
 918 AVX_INSTR minps, 1, 0, 1
 919 AVX_INSTR minsd, 1, 0, 1
 920 AVX_INSTR minss, 1, 0, 1
 921 AVX_INSTR movhlps, 1, 0, 0
 922 AVX_INSTR movlhps, 1, 0, 0
 923 AVX_INSTR movsd, 1, 0, 0
 924 AVX_INSTR movss, 1, 0, 0
 925 AVX_INSTR mpsadbw, 0, 1, 0
 926 AVX_INSTR mulpd, 1, 0, 1
 927 AVX_INSTR mulps, 1, 0, 1
 928 AVX_INSTR mulsd, 1, 0, 1
 929 AVX_INSTR mulss, 1, 0, 1
 930 AVX_INSTR orpd, 1, 0, 1
 931 AVX_INSTR orps, 1, 0, 1
 932 AVX_INSTR packsswb, 0, 0, 0
 933 AVX_INSTR packssdw, 0, 0, 0
 934 AVX_INSTR packuswb, 0, 0, 0
 935 AVX_INSTR packusdw, 0, 0, 0
 936 AVX_INSTR paddb, 0, 0, 1
 937 AVX_INSTR paddw, 0, 0, 1
 938 AVX_INSTR paddd, 0, 0, 1
 939 AVX_INSTR paddq, 0, 0, 1
 940 AVX_INSTR paddsb, 0, 0, 1
 941 AVX_INSTR paddsw, 0, 0, 1
 942 AVX_INSTR paddusb, 0, 0, 1
 943 AVX_INSTR paddusw, 0, 0, 1
 944 AVX_INSTR palignr, 0, 1, 0
 945 AVX_INSTR pand, 0, 0, 1
 946 AVX_INSTR pandn, 0, 0, 0
 947 AVX_INSTR pavgb, 0, 0, 1
 948 AVX_INSTR pavgw, 0, 0, 1
 949 AVX_INSTR pblendvb, 0, 0, 0
 950 AVX_INSTR pblendw, 0, 1, 0
 951 AVX_INSTR pcmpestri, 0, 0, 0
 952 AVX_INSTR pcmpestrm, 0, 0, 0
 953 AVX_INSTR pcmpistri, 0, 0, 0
 954 AVX_INSTR pcmpistrm, 0, 0, 0
 955 AVX_INSTR pcmpeqb, 0, 0, 1
 956 AVX_INSTR pcmpeqw, 0, 0, 1
 957 AVX_INSTR pcmpeqd, 0, 0, 1
 958 AVX_INSTR pcmpeqq, 0, 0, 1
 959 AVX_INSTR pcmpgtb, 0, 0, 0
 960 AVX_INSTR pcmpgtw, 0, 0, 0
 961 AVX_INSTR pcmpgtd, 0, 0, 0
 962 AVX_INSTR pcmpgtq, 0, 0, 0
 963 AVX_INSTR phaddw, 0, 0, 0
 964 AVX_INSTR phaddd, 0, 0, 0
 965 AVX_INSTR phaddsw, 0, 0, 0
 966 AVX_INSTR phsubw, 0, 0, 0
 967 AVX_INSTR phsubd, 0, 0, 0
 968 AVX_INSTR phsubsw, 0, 0, 0
 969 AVX_INSTR pmaddwd, 0, 0, 1
 970 AVX_INSTR pmaddubsw, 0, 0, 0
 971 AVX_INSTR pmaxsb, 0, 0, 1
 972 AVX_INSTR pmaxsw, 0, 0, 1
 973 AVX_INSTR pmaxsd, 0, 0, 1
 974 AVX_INSTR pmaxub, 0, 0, 1
 975 AVX_INSTR pmaxuw, 0, 0, 1
 976 AVX_INSTR pmaxud, 0, 0, 1
 977 AVX_INSTR pminsb, 0, 0, 1
 978 AVX_INSTR pminsw, 0, 0, 1
 979 AVX_INSTR pminsd, 0, 0, 1
 980 AVX_INSTR pminub, 0, 0, 1
 981 AVX_INSTR pminuw, 0, 0, 1
 982 AVX_INSTR pminud, 0, 0, 1
 983 AVX_INSTR pmulhuw, 0, 0, 1
 984 AVX_INSTR pmulhrsw, 0, 0, 1
 985 AVX_INSTR pmulhw, 0, 0, 1
 986 AVX_INSTR pmullw, 0, 0, 1
 987 AVX_INSTR pmulld, 0, 0, 1
 988 AVX_INSTR pmuludq, 0, 0, 1
 989 AVX_INSTR pmuldq, 0, 0, 1
 990 AVX_INSTR por, 0, 0, 1
 991 AVX_INSTR psadbw, 0, 0, 1
 992 AVX_INSTR pshufb, 0, 0, 0
 993 AVX_INSTR psignb, 0, 0, 0
 994 AVX_INSTR psignw, 0, 0, 0
 995 AVX_INSTR psignd, 0, 0, 0
 996 AVX_INSTR psllw, 0, 0, 0
 997 AVX_INSTR pslld, 0, 0, 0
 998 AVX_INSTR psllq, 0, 0, 0
 999 AVX_INSTR pslldq, 0, 0, 0
1000 AVX_INSTR psraw, 0, 0, 0
1001 AVX_INSTR psrad, 0, 0, 0
1002 AVX_INSTR psrlw, 0, 0, 0
1003 AVX_INSTR psrld, 0, 0, 0
1004 AVX_INSTR psrlq, 0, 0, 0
1005 AVX_INSTR psrldq, 0, 0, 0
1006 AVX_INSTR psubb, 0, 0, 0
1007 AVX_INSTR psubw, 0, 0, 0
1008 AVX_INSTR psubd, 0, 0, 0
1009 AVX_INSTR psubq, 0, 0, 0
1010 AVX_INSTR psubsb, 0, 0, 0
1011 AVX_INSTR psubsw, 0, 0, 0
1012 AVX_INSTR psubusb, 0, 0, 0
1013 AVX_INSTR psubusw, 0, 0, 0
1014 AVX_INSTR punpckhbw, 0, 0, 0
1015 AVX_INSTR punpckhwd, 0, 0, 0
1016 AVX_INSTR punpckhdq, 0, 0, 0
1017 AVX_INSTR punpckhqdq, 0, 0, 0
1018 AVX_INSTR punpcklbw, 0, 0, 0
1019 AVX_INSTR punpcklwd, 0, 0, 0
1020 AVX_INSTR punpckldq, 0, 0, 0
1021 AVX_INSTR punpcklqdq, 0, 0, 0
1022 AVX_INSTR pxor, 0, 0, 1
1023 AVX_INSTR shufps, 1, 1, 0
1024 AVX_INSTR subpd, 1, 0, 0
1025 AVX_INSTR subps, 1, 0, 0
1026 AVX_INSTR subsd, 1, 0, 0
1027 AVX_INSTR subss, 1, 0, 0
1028 AVX_INSTR unpckhpd, 1, 0, 0
1029 AVX_INSTR unpckhps, 1, 0, 0
1030 AVX_INSTR unpcklpd, 1, 0, 0
1031 AVX_INSTR unpcklps, 1, 0, 0
1032 AVX_INSTR xorpd, 1, 0, 1
1033 AVX_INSTR xorps, 1, 0, 1
1034
1035 ; 3DNow instructions, for sharing code between AVX, SSE and 3DN
1036 AVX_INSTR pfadd, 1, 0, 1
1037 AVX_INSTR pfsub, 1, 0, 0
1038 AVX_INSTR pfmul, 1, 0, 1
1039
1040 ; base-4 constants for shuffles
1041 %assign i 0
1042 %rep 256
1043     %assign j ((i>>6)&3)*1000 + ((i>>4)&3)*100 + ((i>>2)&3)*10 + (i&3)
1044     %if j < 10
1045         CAT_XDEFINE q000, j, i
1046     %elif j < 100
1047         CAT_XDEFINE q00, j, i
1048     %elif j < 1000
1049         CAT_XDEFINE q0, j, i
1050     %else
1051         CAT_XDEFINE q, j, i
1052     %endif
1053 %assign i i+1
1054 %endrep
1055 %undef i
1056 %undef j
1057
1058 %macro FMA_INSTR 3
1059     %macro %1 4-7 %1, %2, %3
1060         %if cpuflag(xop)
1061             v%5 %1, %2, %3, %4
1062         %else
1063             %6 %1, %2, %3
1064             %7 %1, %4
1065         %endif
1066     %endmacro
1067 %endmacro
1068
1069 FMA_INSTR  pmacsdd,  pmulld, paddd
1070 FMA_INSTR  pmacsww,  pmullw, paddw
1071 FMA_INSTR pmadcswd, pmaddwd, paddd